ٹیوٹوریل استعمال کی مثالوں کے ساتھ Excel REPLACE اور SUBSTITUTE افعال کی وضاحت کرتا ہے۔ REPLACE فنکشن کو ٹیکسٹ سٹرنگز، نمبرز اور ڈیٹس کے ساتھ استعمال کرنے کا طریقہ دیکھیں، اور ایک فارمولے کے اندر کئی REPLACE یا SUBSTITUTE فنکشنز کو کیسے نیسٹ کیا جائے۔

پچھلے ہفتے ہم نے FIND اور SEARCH فنکشنز کو استعمال کرنے کے مختلف طریقوں پر تبادلہ خیال کیا۔ آپ کی ایکسل ورک شیٹس۔ آج، ہم سیل میں متن کو اس کے محل وقوع کی بنیاد پر تبدیل کرنے یا مواد کی بنیاد پر ایک ٹیکسٹ سٹرنگ کو دوسرے سے بدلنے کے لیے دو دیگر فنکشنز پر گہری نظر ڈالیں گے۔ جیسا کہ آپ نے اندازہ لگایا ہوگا، میں ایکسل REPLACE اور SUBSTITUTE فنکشنز کے بارے میں بات کر رہا ہوں۔

Excel REPLACE فنکشن

ایکسل میں REPLACE فنکشن آپ کو ایک یا کئی کو تبدیل کرنے کی اجازت دیتا ہے۔ کسی دوسرے کریکٹر یا حروف کے سیٹ کے ساتھ ٹیکسٹ سٹرنگ میں حروف۔

جیسا کہ آپ دیکھ رہے ہیں، Excel REPLACE فنکشن میں 4 آرگیومینٹس ہیں، جن میں سے سبھی کی ضرورت ہے۔

• Old_text - اصل متن (یا اصل متن والے سیل کا حوالہ) جس میں آپ کچھ حروف کو تبدیل کرنا چاہتے ہیں۔
• Start_num - پرانے_متن میں پہلے کریکٹر کی پوزیشن جسے آپ تبدیل کرنا چاہتے ہیں۔
• Num_chars - ان حروف کی تعداد جسے آپ تبدیل کرنا چاہتے ہیں۔
• نیا_متن - متبادل متن۔

مثال کے طور پر، لفظ " سورج " کو " بیٹا " میں تبدیل کرنے کے لیے، آپ درج ذیلفارمولہ:

=REPLACE("sun", 2, 1, "o")

اور اگر آپ اصل لفظ کو کسی سیل میں ڈالتے ہیں تو A2 کہتے ہیں، آپ پرانے_ٹیکسٹ دلیل میں متعلقہ سیل حوالہ فراہم کر سکتے ہیں:

=REPLACE(A2, 2, 1, "o")

نوٹ۔ اگر start_num یا num_chars کی دلیل منفی یا غیر عددی ہے تو ایکسل ریپلیس فارمولہ #VALUE! غلطی۔

عددی اقدار کے ساتھ ایکسل ریپلیس فنکشن کا استعمال

ایکسل میں ریپلیس فنکشن کو ٹیکسٹ سٹرنگز کے ساتھ کام کرنے کے لیے ڈیزائن کیا گیا ہے۔ بلاشبہ، آپ اسے عددی حروف کو تبدیل کرنے کے لیے استعمال کر سکتے ہیں جو ٹیکسٹ سٹرنگ کا حصہ ہیں، مثال کے طور پر:

=REPLACE(A2, 7, 4, "2016")

نوٹس کریں کہ ہم نے "2016 " دوہرے اقتباسات میں جیسا کہ آپ عام طور پر ٹیکسٹ ویلیو کے ساتھ کرتے ہیں۔

اسی طرح، آپ کسی نمبر کے اندر ایک یا زیادہ ہندسوں کو بدل سکتے ہیں۔ مثال کے طور پر:

=REPLACE(A4, 4, 4,"6")

اور ایک بار پھر، آپ کو متبادل قیمت کو ڈبل کوٹس ("6") میں بند کرنا ہوگا۔

نوٹ. ایکسل REPLACE فارمولہ ہمیشہ ٹیکسٹ سٹرنگ لوٹاتا ہے، نمبر نہیں۔ اوپر والے اسکرین شاٹ میں، B2 میں واپس کردہ ٹیکسٹ ویلیو کی بائیں سیدھ کو دیکھیں، اور اس کا A2 میں دائیں سیدھ والے اصل نمبر سے موازنہ کریں۔ اور چونکہ یہ ایک ٹیکسٹ ویلیو ہے آپ اسے دوسرے حسابات میں استعمال نہیں کر پائیں گے جب تک کہ آپ اسے دوبارہ نمبر میں تبدیل نہ کر دیں، مثال کے طور پر 1 سے ضرب کر کے یا متن کو نمبر میں کیسے تبدیل کریں میں بیان کردہ کوئی دوسرا طریقہ استعمال کر کے۔

مثال کے طور پر، A2 میں آپ کی ایک تاریخ ہے، 1-اکتوبر-14 کا کہنا ہے، اور آپ " Oct " کو " Nov<میں تبدیل کرنا چاہتے ہیں۔ 2>"۔ لہذا، آپ فارمولہ REPLACE(A2, 4, 3, "Nov") لکھتے ہیں جو کہ Excel کو 3 حروف کو سیل A2 میں 4th char سے شروع کرنے کے لیے کہتا ہے… اور درج ذیل نتیجہ ملا:

ایسا کیوں ہے؟ کیونکہ "01-Oct-14" بنیادی سیریل نمبر (41913) کی صرف ایک بصری نمائندگی ہے جو تاریخ کی نمائندگی کرتا ہے۔ لہذا، ہمارا ریپلیس فارمولہ اوپر والے سیریل نمبر کے آخری 3 ہندسوں کو " Nov " میں تبدیل کرتا ہے اور ٹیکسٹ سٹرنگ "419Nov" لوٹاتا ہے۔

ایکسل REPLACE فنکشن کو صحیح طریقے سے کام کرنے کے لیے حاصل کرنے کے لیے۔ تاریخوں میں، آپ TEXT فنکشن یا کسی دوسری تکنیک کا استعمال کرکے تاریخوں کو پہلے ٹیکسٹ سٹرنگز میں تبدیل کر سکتے ہیں جو کہ ایکسل میں تاریخ کو متن میں کیسے تبدیل کیا جائے میں دکھایا گیا ہے۔ متبادل طور پر، آپ TEXT فنکشن کو براہ راست REPLACE فنکشن کے old_text دلیل میں ایمبیڈ کر سکتے ہیں:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

براہ کرم یاد رکھیں کہ مذکورہ فارمولے کا نتیجہ ہے a text string ، اور اس لیے یہ حل صرف اس صورت میں کام کرتا ہے جب آپ مزید حسابات میں ترمیم شدہ تاریخوں کو استعمال کرنے کا ارادہ نہیں کر رہے ہیں۔ اگر آپ کو ٹیکسٹ اسٹرنگ کے بجائے تاریخوں کی ضرورت ہے، تو DATEVALUE فنکشن کا استعمال کریںExcel REPLACE فنکشن کی تاریخوں میں واپس:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

کسی سیل میں متعدد تبدیلیاں کرنے کے لیے نیسٹڈ REPLACE فنکشنز

اکثر، آپ کو ایک سے زیادہ تبدیلیاں کرنے کی ضرورت پڑسکتی ہے۔ ایک ہی سیل. یقینا، آپ ایک متبادل کر سکتے ہیں، ایک اضافی کالم میں ایک انٹرمیڈیٹ نتیجہ نکال سکتے ہیں، اور پھر REPLACE فنکشن کو دوبارہ استعمال کر سکتے ہیں۔ تاہم، ایک بہتر اور زیادہ پیشہ ورانہ طریقہ یہ ہے کہ نیسٹڈ REPLACE فنکشنز کو استعمال کیا جائے جو آپ کو ایک فارمولے کے ساتھ متعدد تبدیلیاں انجام دینے دیتے ہیں۔ اس تناظر میں، "نیسٹنگ" کا مطلب ہے ایک فنکشن کو دوسرے میں رکھنا۔

مندرجہ ذیل مثال پر غور کریں۔ فرض کریں کہ آپ کے پاس کالم A میں ٹیلی فون نمبرز کی ایک فہرست ہے جسے "123456789" کے طور پر فارمیٹ کیا گیا ہے اور آپ ہائفنز کا اضافہ کر کے انہیں فون نمبرز جیسا بنانا چاہتے ہیں۔ دوسرے الفاظ میں، آپ کا مقصد "123456789" کو "123-456-789" میں تبدیل کرنا ہے۔

پہلا ہائفن داخل کرنا آسان ہے۔ آپ ایک معمول کا ایکسل ریپلیس فارمولہ لکھتے ہیں جو صفر حروف کو ہائفن سے بدل دیتا ہے، یعنی سیل میں چوتھی پوزیشن میں ایک ہائفن شامل کرتا ہے:

=REPLACE(A2,4,0,"-")

کا نتیجہ اوپر Replace فارمولہ درج ذیل ہے:

ٹھیک ہے، اور اب ہمیں آٹھویں پوزیشن میں ایک اور ہائفن داخل کرنے کی ضرورت ہے۔ ایسا کرنے کے لیے، آپ اوپر والے فارمولے کو ایک دوسرے Excel REPLACE فنکشن میں رکھیں۔ مزید واضح طور پر، آپ اسے دوسرے فنکشن کے old_text دلیل میں ایمبیڈ کرتے ہیں، تاکہ دوسرا REPLACE فنکشن اس قدر کو سنبھال لے جوپہلے REPLACE، سیل A2 میں ویلیو نہیں:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

نتیجتاً، آپ کو مطلوبہ فارمیٹنگ میں فون نمبر ملتے ہیں:

اسی طرح، آپ نیسٹڈ REPLACE فنکشنز کا استعمال کر سکتے ہیں تاکہ متن کے تاروں کو تاریخوں کی طرح دکھائی دینے کے لیے جہاں مناسب ہو فارورڈ سلیش (/) شامل کریں:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

مزید برآں، آپ اوپر والے REPLACE فارمولے کو DATEVALUE فنکشن کے ساتھ لپیٹ کر ٹیکسٹ سٹرنگز کو حقیقی تاریخوں میں تبدیل کر سکتے ہیں:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

اور قدرتی طور پر، آپ فنکشنز کی تعداد میں محدود نہیں ہیں۔ آپ ایک فارمولے کے اندر اندر گھونسلے بنا سکتے ہیں (ایکسل 2010، 2013 اور 2016 کے جدید ورژن ایک فارمولے میں 8192 حروف اور 64 نیسٹڈ فنکشنز تک کی اجازت دیتے ہیں)۔

مثال کے طور پر، آپ 3 نیسٹڈ REPLACE فنکشنز استعمال کر سکتے ہیں۔ A2 میں ایک نمبر ہونا جیسے تاریخ اور وقت ظاہر ہوتا ہے:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

ہر سیل میں مختلف پوزیشن میں ظاہر ہونے والی اسٹرنگ کو تبدیل کرنا

اب تک، تمام مثالوں میں ہم ایک جیسی نوعیت کی اقدار سے نمٹ رہے ہیں اور ایک ہی پوزیشن میں تبدیلیاں کی ہیں۔ ہر سیل میں. لیکن حقیقی زندگی کے کام اکثر اس سے زیادہ پیچیدہ ہوتے ہیں۔ آپ کی ورک شیٹس میں، ممکن ہے کہ تبدیل کیے جانے والے حروف ہر سیل میں ایک ہی جگہ پر ظاہر نہ ہوں، اور اس لیے آپ کو پہلے کردار کی پوزیشن تلاش کرنی ہوگی جسے تبدیل کیا جانا چاہیے۔ درج ذیل مثال ظاہر کرے گی کہ میں کس کے بارے میں بات کر رہا ہوں۔

فرض کریں کہ آپ کے پاس ای میل کی فہرست ہےکالم A میں خطاب کرنا۔ اور ایک کمپنی کا نام "ABC" سے بدل کر "BCA" ہو گیا ہے۔ لہذا، آپ کو کلائنٹس کے تمام ای میل ایڈریسنگ کو اسی کے مطابق اپ ڈیٹ کرنا ہوگا۔

لیکن مسئلہ یہ ہے کہ کلائنٹ کے نام مختلف لمبائی کے ہیں، اور اسی وجہ سے آپ یہ واضح نہیں کر سکتے کہ کمپنی کا نام کہاں سے شروع ہوتا ہے۔ دوسرے لفظوں میں، آپ نہیں جانتے کہ Excel REPLACE فنکشن کے start_num دلیل میں کیا قیمت فراہم کرنی ہے۔ اسے تلاش کرنے کے لیے، "@abc" سٹرنگ میں پہلے حرف کی پوزیشن کا تعین کرنے کے لیے Excel FIND فنکشن کا استعمال کریں:

=FIND("@abc",A2)

اور پھر، start_num میں اوپر FIND فنکشن فراہم کریں۔ آپ کے REPLACE فارمولے کی دلیل:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

ٹپ۔ ای میل پتوں کے نام والے حصے میں حادثاتی تبدیلیوں سے بچنے کے لیے ہم اپنے Excel تلاش اور بدلنے کے فارمولے میں "@" کو شامل کرتے ہیں۔ یقیناً، اس طرح کے میچز ہونے کا بہت کم امکان ہے، اور پھر بھی آپ محفوظ رہنا چاہیں گے۔

جیسا کہ آپ مندرجہ ذیل اسکرین شاٹ میں دیکھ رہے ہیں، فارمولے کو تلاش کرنے اور تبدیل کرنے میں کوئی مسئلہ نہیں ہے۔ نئے کے ساتھ پرانا متن۔ تاہم، اگر ٹیکسٹ اسٹرنگ کو تبدیل کرنا نہیں ملتا ہے، تو فارمولہ #VALUE! error:

اور ہم چاہتے ہیں کہ فارمولہ غلطی کی بجائے اصل ای میل پتہ واپس کرے۔ تو، آئیے اپنی تلاش کو منسلک کریں اور IFERROR فنکشن میں REPLACE فارمولہ:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

اور یہ بہتر فارمولہ بالکل کام کرتا ہے، ہے نا؟

24>

ایک اور عملیREPLACE فنکشن کا اطلاق سیل میں پہلے حرف کو بڑا کرنا ہے۔ جب بھی آپ ناموں، پروڈکٹس اور اس طرح کی فہرست سے نمٹتے ہیں، آپ اوپر سے منسلک فارمولے کو استعمال کر کے پہلے حرف کو UPPERCASE میں تبدیل کر سکتے ہیں۔

ٹِپ۔ اگر آپ اصل ڈیٹا میں تبدیلیاں کرنا چاہتے ہیں، تو ایک آسان طریقہ Excel FIND اور REPLACE ڈائیلاگ کو استعمال کرنا ہوگا۔

Excel SUBSTITUTE function

Excel میں SUBSTITUTE فنکشن ایک یا زیادہ مثالوں کی جگہ لے لیتا ہے۔ دیئے گئے کریکٹر یا ٹیکسٹ سٹرنگ کا ایک مخصوص کریکٹر (کریکٹرز) کے ساتھ۔

ایکسل SUBSTITUTE فنکشن کا نحو اس طرح ہے:

پہلے تین دلائل درکار ہیں اور آخری ایک اختیاری ہے۔

• ٹیکسٹ - اصل متن جس میں آپ حروف کو تبدیل کرنا چاہتے ہیں۔ ٹیسٹ سٹرنگ، سیل ریفرنس، یا کسی اور فارمولے کے نتیجے کے طور پر فراہم کیا جا سکتا ہے۔
• Old_text - وہ کردار(حروف) جسے آپ تبدیل کرنا چاہتے ہیں۔
• New_text - پرانے_متن کو تبدیل کرنے کے لیے نئے حروف۔
• Instance_num - پرانے_متن کی موجودگی جسے آپ تبدیل کرنا چاہتے ہیں۔ اگر چھوڑ دیا جائے تو، پرانے متن کی ہر موجودگی کو نئے متن میں تبدیل کر دیا جائے گا۔

مثال کے طور پر، ذیل کے تمام فارمولے سیل A2 میں "2" کے ساتھ "1" کی جگہ لے لیتے ہیں، لیکن مختلف نتائج لوٹاتے ہیں۔ اس بات پر منحصر ہے کہ آپ آخری دلیل میں کون سا نمبر فراہم کرتے ہیں:

=SUBSTITUTE(A2, "1", "2", 1) - "1" کی پہلی موجودگی کو اس کے ساتھ بدل دیتا ہے"2"۔

=SUBSTITUTE(A2, "1", "2", 2) - "1" کی دوسری صورت کو "2" سے بدل دیتا ہے۔

=SUBSTITUTE(A2, "1", "2") - "1" کے تمام وقوعات کو "2" سے بدل دیتا ہے۔

عملی طور پر، SUBSTITUTE فنکشن سیلز سے ناپسندیدہ حروف کو ہٹانے کے لیے بھی استعمال ہوتا ہے۔ حقیقی زندگی کی مثالوں کے لیے، براہ کرم دیکھیں:

• حروف یا الفاظ کو سٹرنگ سے کیسے ہٹایا جائے
• خلیوں سے ناپسندیدہ حروف کو کیسے حذف کریں

نوٹ۔ ایکسل میں SUBSTITUTE فنکشن کیس حساس ہے۔ مثال کے طور پر، درج ذیل فارمولہ سیل A2 میں بڑے "X" کی تمام مثالوں کو "Y" سے بدل دیتا ہے، لیکن یہ چھوٹے "x" کی کسی بھی مثال کی جگہ نہیں لے گا۔

فرض کریں کہ آپ کے پاس سیل A2 میں " PR1, ML1, T1 " جیسی ٹیکسٹ سٹرنگ ہے، جہاں "PR" کا مطلب ہے "Project, "ML " کا مطلب ہے "سنگ میل" اور "T" کا مطلب ہے "ٹاسک"۔ آپ تینوں کوڈز کو مکمل ناموں سے بدلنا چاہتے ہیں۔ اس کو حاصل کرنے کے لیے، آپ 3 مختلف متبادل فارمولے لکھ سکتے ہیں:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

اور پھر انہیں ایک دوسرے میں گھسیٹیں:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

دیکھیں کہ ہم نے کے آخر میں ایک جگہ شامل کی ہے بہتر کے لیے ہر نئی_متن دلیلپڑھنے کی اہلیت۔

ایک وقت میں متعدد اقدار کو تبدیل کرنے کے دوسرے طریقے جاننے کے لیے، براہ کرم ایکسل میں بڑے پیمانے پر تلاش اور تبدیلی کا طریقہ دیکھیں۔

Excel REPLACE بمقابلہ Excel SUBSTITUTE

Excel REPLACE اور SUBSTITUTE فنکشنز ایک دوسرے سے بہت ملتے جلتے ہیں کیونکہ دونوں کو ٹیکسٹ سٹرنگز کو تبدیل کرنے کے لیے ڈیزائن کیا گیا ہے۔ دونوں فنکشنز کے درمیان فرق مندرجہ ذیل ہیں:

• SUBSTITUTE ایک یا ایک سے زیادہ مثالوں کو دیئے گئے کریکٹر یا ٹیکسٹ سٹرنگ کی جگہ لے لیتا ہے۔ لہذا، اگر آپ جانتے ہیں کہ متن کو تبدیل کیا جانا ہے، تو Excel SUBSTITUTE فنکشن استعمال کریں۔
• REPLACE کسی ٹیکسٹ اسٹرنگ کی مخصوص پوزیشن میں حروف کو تبدیل کرتا ہے۔ لہٰذا، اگر آپ کو معلوم ہے کہ کرداروں کی پوزیشن تبدیل کی جائے تو، ایکسل REPLACE فنکشن کا استعمال کریں۔
• ایکسل میں SUBSTITUTE فنکشن ایک اختیاری پیرامیٹر (instance_num) شامل کرنے کی اجازت دیتا ہے جو یہ بتاتا ہے کہ کون سا وقوعہ old_text کو new_text میں تبدیل کیا جانا چاہیے۔

اس طرح آپ Excel میں SUBSTITUTE اور REPLACE فنکشنز استعمال کرتے ہیں۔ امید ہے کہ یہ مثالیں آپ کے کاموں کو حل کرنے میں کارآمد ثابت ہوں گی۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ اگلے ہفتے ہمارے بلاگ پر نظر آؤں گا!

پریکٹس ورک بک ڈاؤن لوڈ کریں

ریپلیس اور متبادل فارمولے کی مثالیں (.xlsx فائل)