Təlimatda istifadə nümunələri ilə Excel-in DƏYİŞDİRİLMƏ və ƏVƏZİNƏ ET funksiyaları izah edilir. Əvəz etmə funksiyasından mətn sətirləri, nömrələr və tarixlərlə necə istifadə olunacağına və bir düstur daxilində bir neçə Əvəz etmə və ya Əvəz etmə funksiyalarının necə yerləşdirilməsinə baxın.

Keçən həftə biz FIND və AXTAR funksiyalarından istifadənin müxtəlif yollarını müzakirə etdik. Excel iş vərəqləriniz. Bu gün biz xanadakı mətni yerləşdiyi yerə görə əvəz etmək və ya məzmuna əsasən bir mətn sətirini digəri ilə əvəz etmək üçün digər iki funksiyaya daha dərindən nəzər salacağıq. Təxmin etdiyiniz kimi, mən Excelin DƏYİŞTİRMƏ və ƏVƏZ ET funksiyalarından danışıram.

Excel REPLACE funksiyası

Excel-də Əvəz etmə funksiyası bir və ya bir neçəsini dəyişdirməyə imkan verir. mətn sətirində başqa simvol və ya simvol dəsti ilə simvollar.

Gördüyünüz kimi, Excel REPLACE funksiyasının 4 arqumenti var, bunların hamısı tələb olunur.

• Köhnə_mətn - bəzi simvolları əvəz etmək istədiyiniz orijinal mətn (və ya orijinal mətni olan xanaya istinad).
• Başlanğıc_num - əvəz etmək istədiyiniz köhnə_mətn daxilində birinci simvolun mövqeyi.
• Num_simvol - əvəz etmək istədiyiniz simvolların sayı.
• Yeni_mətn - əvəzedici mətn.

Məsələn, " günəş " sözünü " oğul " olaraq dəyişdirmək üçün aşağıdakılardan istifadə edə bilərsiniz.düstur:

=REPLACE("sun", 2, 1, "o")

Əgər orijinal sözü hansısa xanaya yerləşdirsəniz, A2 deyin, köhnə_mətn arqumentində müvafiq xana istinadını təmin edə bilərsiniz:

=REPLACE(A2, 2, 1, "o")

Qeyd. Başlanğıc_sayı və ya simvollar arqumenti mənfi və ya rəqəmsizdirsə, Excel Dəyişdirmə düsturu #DƏYƏR! xəta.

Excel-in REPLACE funksiyasının rəqəmsal dəyərlərlə istifadəsi

Excel-də REPLACE funksiyası mətn sətirləri ilə işləmək üçün nəzərdə tutulub. Əlbəttə ki, siz ondan mətn sətirinin bir hissəsi olan rəqəmli simvolları əvəz etmək üçün istifadə edə bilərsiniz, məsələn:

=REPLACE(A2, 7, 4, "2016")

Qeyd edək ki, "2016-cı il" əlavə edirik. " adətən mətn dəyərlərində olduğu kimi qoşa dırnaq içərisində.

Oxşar şəkildə, siz ədəd daxilində bir və ya daha çox rəqəmi əvəz edə bilərsiniz. Məsələn:

=REPLACE(A4, 4, 4,"6")

Və yenə əvəzedici dəyəri qoşa dırnaq ("6") içərisinə daxil etməlisiniz.

Qeyd. Excel REPLACE düsturu həmişə rəqəmi deyil, mətn sətrini qaytarır. Yuxarıdakı ekran görüntüsündə B2-də qaytarılmış mətn dəyərinin sola düzülməsinə diqqət yetirin və onu A2-də sağa yığılmış orijinal nömrə ilə müqayisə edin. Və bu, mətn dəyəri olduğundan, onu yenidən rəqəmə çevirməyincə, məsələn, 1-ə vurmaqla və ya Mətni rəqəmə çevirmək haqqında məqalədə təsvir olunan hər hansı digər üsuldan istifadə etməsəniz, onu başqa hesablamalarda istifadə edə bilməyəcəksiniz.

Excel-in REPLACE funksiyasından tarixlərlə istifadə etmək

İndi gördüyünüz kimi, DƏYİŞTİR funksiyası ilə yaxşı işləyir.rəqəmlər, mətn sətirini qaytarması istisna olmaqla :) Daxili Excel sistemində tarixlərin rəqəmlər kimi saxlandığını xatırlayaraq, tarixlərdə bəzi Dəyişdirmə düsturlarından istifadə etməyə cəhd edə bilərsiniz. Nəticələr olduqca utandırıcı olardı.

Məsələn, A2-də bir tarix var, deyək ki, 1-Oktyabr-14 və siz " Oktyabr "-ni " Noyabr<" olaraq dəyişmək istəyirsiniz. 2>". Beləliklə, siz Excel-ə A2 xanalarında 4-cü simvolla başlayan 3 simvolu əvəz etməyi əmr edən REPLACE(A2, 4, 3, "Noyabr") düsturunu yazırsınız... və aşağıdakı nəticəni əldə edirsiniz:

Niyə belədir? Çünki "01-Oktyabr-14" yalnız tarixi təmsil edən əsas seriya nömrəsinin (41913) vizual təsviridir. Beləliklə, Dəyişdir düsturumuz yuxarıdakı seriya nömrəsindəki son 3 rəqəmi " Noyabr " olaraq dəyişdirir və "419Nov" mətn sətirini qaytarır.

Excel ilə düzgün işləmək üçün DƏYİŞTİR funksiyasını əldə etmək üçün Tarixlər üçün, siz Excel-də tarixi mətnə ​​necə çevirmək olar bölməsində nümayiş etdirilən MƏTN funksiyasından və ya hər hansı digər texnikadan istifadə edərək əvvəlcə tarixləri mətn sətirlərinə çevirə bilərsiniz. Alternativ olaraq, siz MƏTN funksiyasını birbaşa DƏYİŞTİRMƏ funksiyasının köhnə_mətn arqumentində yerləşdirə bilərsiniz:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Yuxarıdakı düsturun nəticəsinin a mətn sətri və buna görə də bu həll yalnız dəyişdirilmiş tarixləri sonrakı hesablamalarda istifadə etməyi planlaşdırmadığınız halda işləyir. Əgər mətn sətirləri əvəzinə tarixlərə ehtiyacınız varsa, qaytarılan dəyərləri çevirmək üçün DATEVALUE funksiyasından istifadə edin.Excel REPLACE funksiyası tarixlərə qayıdır:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Xüceyrədə çoxsaylı əvəzləmələr etmək üçün iç-içə DƏYİŞTİRİLMİŞ funksiyaları

Tez-tez birdən çox dəyişdirmə etməli ola bilərsiniz. eyni hüceyrə. Əlbəttə ki, siz bir əvəz edə, aralıq nəticəni əlavə sütuna çıxara və sonra yenidən DƏYİŞTİR funksiyasından istifadə edə bilərsiniz. Bununla belə, daha yaxşı və peşəkar üsul, bir düsturla bir neçə əvəzləməni həyata keçirməyə imkan verən iç-içə daxil edilmiş DƏYİŞTİRME funksiyalarından istifadə etməkdir. Bu kontekstdə "yuva yerləşdirmə" bir funksiyanın digərinin içinə yerləşdirilməsi deməkdir.

Aşağıdakı nümunəyə nəzər salın. Tutaq ki, sizin A sütununda "123456789" kimi formatlanmış telefon nömrələrinin siyahısı var və siz defis əlavə etməklə onları daha çox telefon nömrələrinə bənzətmək istəyirsiniz. Başqa sözlə, məqsədiniz "123456789"-u "123-456-789"-a çevirməkdir.

Birinci tire daxil etmək asandır. Siz sıfır simvolu tire ilə əvəz edən, yəni xanada 4-cü mövqeyə tire əlavə edən adi Excel Dəyişdirmə düsturunu yazırsınız:

=REPLACE(A2,4,0,"-")

Nəticəsi yuxarıda Dəyişdir düsturu aşağıdakı kimidir:

Yaxşı, indi 8-ci mövqeyə daha bir tire qoymalıyıq. Bunu etmək üçün yuxarıdakı düsturu başqa bir Excel REPLACE funksiyası daxilində yerləşdirirsiniz. Daha dəqiq desək, siz onu digər funksiyanın köhnə_mətn arqumentinə yerləşdirirsiniz ki, ikinci REPLACE funksiyası tərəfindən qaytarılan dəyəri idarə edəcək.A2 xanasındakı dəyəri yox, əvvəlcə REPLACE:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Nəticədə siz istədiyiniz formatda telefon nömrələrini alırsınız:

Oxşar şəkildə, mətn sətirlərini tarixlərə bənzətmək üçün uyğun olan yerdə əyri xətt (/) əlavə edərək iç-içə DƏYİŞTİRİŞ funksiyalarından istifadə edə bilərsiniz:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Bundan əlavə, yuxarıdakı DƏYİŞTİR düsturunu TARİXVALUE funksiyası ilə bükərək mətn sətirlərini real tarixlərə çevirə bilərsiniz:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Və təbii ki, funksiyaların sayında məhdud deyilsiniz. siz bir düstur daxilində yuva qura bilərsiniz (Excel 2010, 2013 və 2016-nın müasir versiyaları düsturda 8192 simvola və 64-ə qədər iç-içə funksiyaya icazə verir).

Məsələn, siz 3 yuvalanmış DƏYİŞTİR funksiyasından istifadə edə bilərsiniz. A2-də nömrənin tarix və vaxt kimi görünməsi:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Hər xanada fərqli mövqedə görünən sətri əvəz etmək

İndiyə qədər bütün nümunələrdə oxşar xarakterli dəyərlərlə məşğul olmuşuq və eyni pozitivdə əvəzlər etmişik. hər hüceyrədə. Ancaq real həyatdakı tapşırıqlar çox vaxt bundan daha mürəkkəbdir. İş vərəqlərinizdə dəyişdiriləcək simvollar mütləq hər xanada eyni yerdə görünməyə bilər və buna görə də siz əvəz edilməli olan ilk simvolun mövqeyini tapmalı olacaqsınız. Aşağıdakı nümunə nə haqqında danışdığımı nümayiş etdirəcək.

Fərz edək ki, sizdə e-poçt siyahısı var.A sütununda ünvanlanır. Və bir şirkətin adı "ABC"dən, məsələn, "BCA"ya dəyişdi. Beləliklə, siz müştərilərin bütün e-poçt ünvanlarını müvafiq olaraq yeniləməlisiniz.

Lakin problem müştəri adlarının müxtəlif uzunluqda olmasıdır və buna görə də siz şirkət adının haradan başladığını dəqiq deyə bilməzsiniz. Başqa sözlə, Excel REPLACE funksiyasının start_num arqumentində hansı dəyəri təqdim edəcəyinizi bilmirsiniz. Bunu tapmaq üçün Excel FIND funksiyasından istifadə edərək "@abc" sətirində birinci simvolun yerini təyin edin:

=FIND("@abc",A2)

Və sonra yuxarıdakı FIND funksiyasını start_num-da təmin edin. DƏYİŞTİR düsturunuzun arqumenti:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

İpucu. E-poçt ünvanlarının ad hissəsində təsadüfən dəyişdirilməməsi üçün Excel Tap və Dəyişdir düsturumuza "@" əlavə edirik. Əlbəttə ki, bu cür uyğunlaşmaların baş vermə ehtimalı çox azdır və siz hələ də təhlükəsiz tərəfdə olmaq istəyə bilərsiniz.

Aşağıdakı ekran görüntüsündə gördüyünüz kimi, düsturun tapmaq və dəyişdirməkdə problemi yoxdur. köhnə mətn yenisi ilə. Lakin, dəyişdiriləcək mətn sətri tapılmadıqda, düstur #VALUE! xəta:

Və biz düsturun səhv əvəzinə orijinal e-poçt ünvanını qaytarmasını istəyirik. Beləliklə, bizim FIND & amp; IFERROR funksiyasında DƏYİŞTİR düsturunu:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Və bu təkmilləşdirilmiş düstur mükəmməl işləyir, elə deyilmi?

Başqa praktikiREPLACE funksiyasının tətbiqi xanadakı ilk hərfi böyük hərflə yazmaqdır. Adlar, məhsullar və s. siyahısı ilə məşğul olduğunuz zaman, ilk hərfi BÖYÜK HƏRFƏ dəyişmək üçün yuxarıdakı düsturdan istifadə edə bilərsiniz.

İpucu. Əvəzetmələri orijinal məlumatda etmək istəyirsinizsə, daha asan yol Excel TAP və DƏYİŞTİR dialoq qutusundan istifadə etməkdir.

Excel ƏVƏZİNƏ funksiyası

Excel-də Əvəz etmə funksiyası bir və ya bir neçə nümunəni əvəz edir. verilmiş simvol və ya müəyyən simvol(lar) ilə mətn sətirinin.

Excel ƏVƏZİNƏ funksiyasının sintaksisi aşağıdakı kimidir:

İlk üç arqument tələb olunur, sonuncu isə isteğe bağlıdır.

• Mətn - simvolları əvəz etmək istədiyiniz orijinal mətn. Test sətri, xana arayışı və ya başqa düsturun nəticəsi kimi təqdim edilə bilər.
• Köhnə_mətn - əvəz etmək istədiyiniz simvol(lar).
• Yeni_mətn - köhnə_mətni əvəz etmək üçün yeni simvol(lar).
• Nümunə_num - əvəz etmək istədiyiniz köhnə_mətnin baş verməsi. Əgər buraxılmasa, köhnə mətnin hər təkrarı yeni mətnə ​​dəyişdiriləcək.

Məsələn, aşağıdakı düsturların hamısı A2 xanasında "1"i "2" ilə əvəz edir, lakin fərqli nəticələr verir. son arqumentdə hansı rəqəmi təqdim etdiyinizdən asılı olaraq:

=SUBSTITUTE(A2, "1", "2", 1) - "1"-in ilk başını ilə əvəz edir"2".

=SUBSTITUTE(A2, "1", "2", 2) - "1"-in ikinci halını "2" ilə əvəz edir.

=SUBSTITUTE(A2, "1", "2") - "1"-in bütün təkrarlarını "2" ilə əvəz edir.

Praktikada Əvəz etmə funksiyası xanalardan arzuolunmaz simvolları silmək üçün də istifadə olunur. Real həyat nümunələri üçün baxın:

• Sətrdən simvol və ya sözləri necə silmək olar
• Xüceyrələrdən arzuolunmaz simvolları necə silmək olar

Qeyd. Excel-də Əvəz etmə funksiyası hərflərə həssasdır . Məsələn, aşağıdakı düstur A2 xanasında böyük "X" hərfinin "Y" ilə bütün nümunələrini əvəz edir, lakin o, kiçik "x" hərfinin heç bir nümunəsini əvəz etməyəcək.

Birdən çox dəyəri tək bir düsturla əvəz edin (iç-içə daxil edilmiş ƏVƏZİNƏ)

Excel DƏYİŞTİR funksiyasında olduğu kimi, eyni anda bir neçə əvəzetmə etmək üçün bir neçə ƏVƏZİNƏ funksiyasını bir düstur daxilində yerləşdirə bilərsiniz, yəni. bir düsturlu bir neçə simvol və ya alt sətir.

Fərz edək ki, A2 xanasında " PR1, ML1, T1 " kimi mətn sətri var, burada "PR" "Layihə, "ML" deməkdir. " "Milestone" deməkdir və "T" "Tapşırıq" deməkdir. İstədiyiniz üç kodu tam adlarla əvəz etməkdir. Buna nail olmaq üçün 3 fərqli ƏVƏZİNƏ düsturunu yaza bilərsiniz:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

Və sonra onları bir-birinə yerləşdirin:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

Diqqət yetirin ki, sonuna boşluq əlavə etmişik. daha yaxşı üçün hər yeni mətn arqumentioxunaqlılıq.

Eyni anda birdən çox dəyəri əvəz etməyin digər yollarını öyrənmək üçün Excel-də kütləvi tapma və dəyişdirmə üsullarına baxın.

Excel REPLACE vs. Excel ƏVƏZİNƏ

Excel ƏVƏZİNƏ və ƏVƏZƏT funksiyaları bir-birinə çox bənzəyir, çünki hər ikisi mətn sətirlərini dəyişdirmək üçün nəzərdə tutulub. İki funksiya arasındakı fərqlər aşağıdakı kimidir:

• ƏVƏZİNƏ verilmiş simvolun və ya mətn sətirinin bir və ya daha çox nümunəsini əvəz edir. Beləliklə, dəyişdiriləcək mətni bilirsinizsə, Excel ƏVƏZİNƏT funksiyasından istifadə edin.
• ƏYİNƏ mətn sətirinin müəyyən edilmiş mövqeyində simvol dəyişir. Beləliklə, dəyişdiriləcək simvol(lar)ın mövqeyini bilirsinizsə, Excel-in DƏYİŞTİRMƏ funksiyasından istifadə edin.
• Excel-də ƏVƏZİNƏ ET funksiyası hansı başvermə -u yeni_mətnə ​​dəyişdirilməlidir.

Excel-də ƏVƏZİNƏ və ƏVVƏLƏT funksiyalarından belə istifadə edirsiniz. Ümid edirik ki, bu nümunələr vəzifələrinizin həllində faydalı olacaq. Oxuduğunuz üçün sizə təşəkkür edirəm və ümid edirəm ki, gələn həftə bloqumuzda görəcəyəm!

Təcrübə iş dəftərini endirin

DÜSTÜNLƏRİ ƏLAQƏ EDİN və ƏVƏZ EDİN (.xlsx faylı)