Tutoriali shpjegon funksionet e Excel REPLACE dhe SUBSTITUTE me shembuj përdorimesh. Shihni se si të përdorni funksionin REPLACE me vargjet e tekstit, numrat dhe datat dhe si të futni disa funksione REPLACE ose SUBSTITUTE brenda një formule.

Javën e kaluar ne diskutuam mënyra të ndryshme të përdorimit të funksioneve FIND dhe SEARCH brenda fletët tuaja të punës në Excel. Sot, ne do të hedhim një vështrim më të thellë në dy funksione të tjera për të zëvendësuar tekstin në një qelizë bazuar në vendndodhjen e tij ose për të zëvendësuar një varg teksti me një tjetër të bazuar në përmbajtje. Siç mund ta keni marrë me mend, po flas për funksionet e Excel REPLACE dhe SUBSTITUTE.

Funksioni REPLACE Excel

Funksioni REPLACE në Excel ju lejon të ndërroni një ose disa karaktere në një varg teksti me një karakter tjetër ose një grup karakteresh.

Siç e shihni, funksioni Excel REPLACE ka 4 argumente, të cilat të gjitha janë të nevojshme.

• Teksti i vjetër - teksti origjinal (ose një referencë për një qelizë me tekstin origjinal) në të cilën dëshironi të zëvendësoni disa karaktere.
• Numri_Start - pozicioni i karakterit të parë brenda tekstit të vjetër që dëshironi të zëvendësoni.
• Num_karakteret - numri i karaktereve që dëshironi të zëvendësoni.
• New_text - teksti zëvendësues.

Për shembull, për të ndryshuar fjalën " diell " në " bir ", mund të përdorni sa vijonformula:

=REPLACE("sun", 2, 1, "o")

Dhe nëse e vendosni fjalën origjinale në ndonjë qelizë, le të themi A2, mund të jepni referencën përkatëse të qelizës në argumentin old_text:

=REPLACE(A2, 2, 1, "o")

Shënim. Nëse argumenti start_num ose num_chars është negativ ose jo numerik, një formulë Excel Replace kthen #VALUE! gabim.

Përdorimi i funksionit Excel REPLACE me vlera numerike

Funksioni REPLACE në Excel është krijuar për të punuar me vargjet e tekstit. Natyrisht, mund ta përdorni për të zëvendësuar karakteret numerike që janë pjesë e një vargu teksti, për shembull:

=REPLACE(A2, 7, 4, "2016")

Vini re se bashkëngjitni "2016 " në thonjëza të dyfishta siç bëni zakonisht me vlerat e tekstit.

Në mënyrë të ngjashme, mund të zëvendësoni një ose më shumë shifra brenda një numri. Për shembull:

=REPLACE(A4, 4, 4,"6")

Dhe përsëri, duhet të vendosni vlerën e zëvendësimit në thonjëza të dyfishta ("6").

Shënim. Një formulë e Excel REPLACE kthen gjithmonë një varg teksti , jo një numër. Në pamjen e mësipërme, vini re shtrirjen majtas të vlerës së tekstit të kthyer në B2 dhe krahasojeni atë me numrin origjinal të rreshtuar djathtas në A2. Dhe për shkak se është një vlerë teksti, nuk do të mund ta përdorni në llogaritjet e tjera nëse nuk e ktheni përsëri në numër, për shembull duke shumëzuar me 1 ose duke përdorur ndonjë metodë tjetër të përshkruar në Si të konvertohet teksti në numër.

Përdorimi i funksionit Excel REPLACE me datat

Siç e keni parë sapo, funksioni REPLACE funksionon mirë menumrat, përveç që kthen një varg teksti :) Duke kujtuar se në sistemin e brendshëm Excel, datat ruhen si numra, mund të provoni të përdorni disa formula Replace për datat. Rezultatet do të ishin mjaft të sikletshme.

Për shembull, ju keni një datë në A2, le të themi 1-tetor-14, dhe dëshironi të ndryshoni " tetor " në " nëntor ". Pra, ju shkruani formulën REPLACE (A2, 4, 3, "Nën") që i thotë Excel të zëvendësojë 3 karaktere në qelizat A2 duke filluar me karakterin e 4-të… dhe keni rezultatin e mëposhtëm:

Pse është kështu? Sepse "01-Tet-14" është vetëm një paraqitje vizuale e numrit bazë të serisë (41913) që përfaqëson datën. Pra, formula jonë Replace ndryshon 3 shifrat e fundit në numrin serial të mësipërm në " Nëntor " dhe kthen vargun e tekstit "419Nën".

Për të marrë funksionin e Excel REPLACE për të punuar saktë me datat, fillimisht mund t'i konvertoni datat në vargje teksti duke përdorur funksionin TEXT ose ndonjë teknikë tjetër të demonstruar në Si të konvertohet data në tekst në Excel. Përndryshe, ju mund të futni funksionin TEXT direkt në argumentin old_text të funksionit REPLACE:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Ju lutemi mbani mend se rezultati i formulës së mësipërme është një varg teksti , dhe për këtë arsye kjo zgjidhje funksionon vetëm nëse nuk planifikoni të përdorni datat e modifikuara në llogaritjet e mëtejshme. Nëse keni nevojë për data në vend të vargjeve të tekstit, përdorni funksionin DATEVALUE për të kthyer vlerat e kthyera ngafunksioni Excel REPLACE kthehet në datat:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Funksionet e ndërlidhura REPLACE për të bërë zëvendësime të shumta në një qelizë

Shpesh, mund t'ju duhet të bëni më shumë se një zëvendësim në e njëjta qelizë. Sigurisht, mund të bëni një zëvendësim, të nxirrni një rezultat të ndërmjetëm në një kolonë shtesë dhe më pas të përdorni funksionin REPLACE përsëri. Megjithatë, një mënyrë më e mirë dhe më profesionale është përdorimi i funksioneve të ndërlidhura REPLACE që ju lejojnë të kryeni disa zëvendësime me një formulë të vetme. Në këtë kontekst, "foleja" nënkupton vendosjen e një funksioni brenda një tjetri.

Shqyrtoni shembullin e mëposhtëm. Supozoni se keni një listë të numrave të telefonit në kolonën A të formatuar si "123456789" dhe dëshironi t'i bëni ata të duken më shumë si numra telefoni duke shtuar viza. Me fjalë të tjera, qëllimi juaj është të ktheni "123456789" në "123-456-789".

Futja e vizës së parë është e lehtë. Ju shkruani një formulë të zakonshme Excel Replace që zëvendëson zero karaktere me një vizë, d.m.th. shton një vizë në pozicionin e katërt në një qelizë:

=REPLACE(A2,4,0,"-")

Rezultati i Formula e mësipërme Replace është si më poshtë:

Mirë, dhe tani duhet të fusim një vizë më shumë në pozicionin e 8-të. Për ta bërë këtë, ju vendosni formulën e mësipërme brenda një funksioni tjetër Excel REPLACE. Më saktësisht, ju e futni atë në argumentin teksti i vjetër i funksionit tjetër, në mënyrë që funksioni i dytë REPLACE të trajtojë vlerën e kthyer ngasë pari REPLACE, dhe jo vlerën në qelizën A2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Si rezultat, ju merrni numrat e telefonit në formatimin e dëshiruar:

Në mënyrë të ngjashme, mund të përdorni funksionet e ndërlidhura REPLACE për t'i bërë vargjet e tekstit të duken si data duke shtuar një prerje përpara (/) aty ku është e përshtatshme:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Për më tepër, ju mund të konvertoni vargjet e tekstit në data reale duke mbështjellë formulën e mësipërme REPLACE me funksionin DATEVALUE:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Dhe natyrisht, nuk jeni të kufizuar në numrin e funksioneve ju mund të vendosni fole brenda një formule (versionet moderne të Excel 2010, 2013 dhe 2016 lejojnë deri në 8192 karaktere dhe deri në 64 funksione të ndërlidhura në një formulë).

Për shembull, mund të përdorni 3 funksione të ndërlidhura REPLACE për të të ketë një numër në A2 të shfaqet si data dhe ora:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Zëvendësimi i një vargu që shfaqet në një pozicion të ndryshëm në secilën qelizë

Deri më tani, në të gjithë shembujt kemi të bëjmë me vlera të natyrës së ngjashme dhe kemi bërë zëvendësime në të njëjtin pozicion. në çdo qelizë. Por detyrat e jetës reale janë shpesh më të komplikuara se kaq. Në fletët tuaja të punës, karakteret që do të zëvendësohen mund të mos shfaqen domosdoshmërisht në të njëjtin vend në secilën qelizë, dhe për këtë arsye do t'ju duhet të gjeni pozicionin e karakterit të parë që duhet të zëvendësohet. Shembulli i mëposhtëm do të tregojë se për çfarë po flas.

Sikur të supozojmë se keni një listë me emailduke adresuar në kolonën A. Dhe emri i një kompanie ka ndryshuar nga "ABC" në, të themi, "BCA". Pra, ju duhet të përditësoni të gjitha adresat e emailit të klientëve në përputhje me rrethanat.

Por problemi është se emrat e klientëve janë me gjatësi të ndryshme, dhe kjo është arsyeja pse ju nuk mund të specifikoni saktësisht se ku fillon emri i kompanisë. Me fjalë të tjera, ju nuk e dini se çfarë vlere duhet të jepni në argumentin start_num të funksionit Excel REPLACE. Për ta zbuluar atë, përdorni funksionin Excel FIND për të përcaktuar pozicionin e karakterit të parë në vargun "@abc":

=FIND("@abc",A2)

Dhe më pas, jepni funksionin e mësipërm FIND në start_num argumenti i formulës suaj REPLACE:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Këshillë. Ne përfshijmë "@" në formulën tonë Excel Find and Replace për të shmangur zëvendësimet aksidentale në pjesën e emrit të adresave të emailit. Sigurisht, ka një shans shumë të vogël që të ndodhin ndeshje të tilla, dhe prapë mund të dëshironi të jeni në anën e sigurt.

Siç e shihni në pamjen e mëposhtme të ekranit, formula nuk ka asnjë problem me gjetjen dhe zëvendësimin e teksti i vjetër me të riun. Megjithatë, nëse vargu i tekstit që do të zëvendësohet nuk gjendet, formula kthen #VALUE! gabim:

Dhe ne duam që formula të kthejë adresën origjinale të emailit në vend të gabimit. Pra, le t'i bashkangjisim FIND & REPLACE formule në funksionin IFERROR:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Dhe kjo formulë e përmirësuar funksionon në mënyrë perfekte, apo jo?

Një tjetër praktikeaplikimi i funksionit REPLACE është të shkruash shkronjën e parë në një qelizë. Kurdoherë që merreni me një listë emrash, produktesh dhe të ngjashme, mund të përdorni formulën e mësipërme për të ndryshuar shkronjën e parë në SHQIPËRI.

Këshillë. Nëse dëshironi të bëni zëvendësimet në të dhënat origjinale, një mënyrë më e lehtë do të ishte përdorimi i dialogut Excel FIND and REPLACE.

Funksioni SUBSTITUTE Excel

Funksioni SUBSTITUTE në Excel zëvendëson një ose më shumë shembuj të një karakteri ose vargu teksti të caktuar me një karakter(a) të specifikuar.

Sintaksa e funksionit SUBSTITUTE Excel është si më poshtë:

Tre argumentet e para kërkohen dhe i fundit është opsional.

• Tekst - teksti origjinal në të cilin dëshironi të zëvendësoni karakteret. Mund të ofrohet si një varg testimi, referencë qelize ose si rezultat i një formule tjetër.
• Teksti i vjetër - karakteri(at) që dëshironi të zëvendësoni.
• Tekst_i ri - karakteri(at) e ri për të zëvendësuar tekstin e vjetër.
• Numri_shembull - shfaqja e tekstit të vjetër që dëshironi të zëvendësoni. Nëse hiqet, çdo dukuri e tekstit të vjetër do të ndryshohet në tekstin e ri.

Për shembull, të gjitha formulat e mëposhtme zëvendësojnë "1" me "2" në qelizën A2, por kthejnë rezultate të ndryshme varësisht nga cili numër jepni në argumentin e fundit:

=SUBSTITUTE(A2, "1", "2", 1) - Zëvendëson shfaqjen e parë të "1" me"2".

=SUBSTITUTE(A2, "1", "2", 2) - Zëvendëson shfaqjen e dytë të "1" me "2".

=SUBSTITUTE(A2, "1", "2") - Zëvendëson të gjitha dukuritë e "1" me "2".

Në praktikë, funksioni SUBSTITUTE përdoret gjithashtu për heqjen e karaktereve të padëshiruara nga qelizat. Për shembuj të jetës reale, ju lutemi shihni:

• Si të hiqni karakteret ose fjalët nga vargu
• Si të fshini karakteret e padëshiruar nga qelizat

Shënim. Funksioni SUBSTITUTE në Excel është ndjeshëm ndaj shkronjave të vogla . Për shembull, formula e mëposhtme zëvendëson të gjitha instancat e shkronjave të mëdha "X" me "Y" në qelizën A2, por nuk do të zëvendësojë asnjë shembull të shkronjës "x" të vogël.

Zëvendësoni vlera të shumta me një formulë të vetme (zëvendësues i vendosur)

Siç është rasti me funksionin Excel REPLACE, mund të futni disa funksione SUBSTITUTE brenda një formule të vetme për të bërë disa zëvendësime në të njëjtën kohë, d.m.th. disa karaktere ose nënvargje me një formulë të vetme.

Duke supozuar se keni një varg teksti si " PR1, ML1, T1 " në qelizën A2, ku "PR" do të thotë "Project, "ML " do të thotë "Milestone" dhe "T" do të thotë "Detyrë". Ajo që dëshironi është të zëvendësoni tre kodet me emrat e plotë. Për ta arritur këtë, mund të shkruani 3 formula të ndryshme SUBSTITUTE:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

Dhe pastaj futini ato në njëra-tjetrën:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

Vini re se kemi shtuar një hapësirë ​​në fund të çdo argument new_text për më mirëlexueshmëria.

Për të mësuar mënyra të tjera për të zëvendësuar vlera të shumta në të njëjtën kohë, ju lutemi shikoni Si të bëni gjetjen dhe zëvendësimin masiv në Excel.

Excel REPLACE vs Excel SUBSTITUTE

Funksionet e Excel REPLACE dhe SUBSTITUTE janë shumë të ngjashme me njëri-tjetrin në atë që të dyja janë krijuar për të ndërruar vargjet e tekstit. Ndryshimet midis dy funksioneve janë si më poshtë:

• SUBSTITUTE zëvendëson një ose më shumë instanca të një karakteri të caktuar ose të një vargu teksti. Pra, nëse e dini tekstin që do të zëvendësohet, përdorni funksionin Excel SUBSTITUTE.
• REPLACE ndryshon karakteret në një pozicion të caktuar të një vargu teksti. Pra, nëse e dini pozicionin e karaktereve që do të zëvendësohen, përdorni funksionin Excel REPLACE.
• Funksioni SUBSTITUTE në Excel lejon shtimin e një parametri opsional (instance_num) që specifikon se cilën ndodhje e Old_text duhet të ndryshohet në new_text.

Kjo është mënyra se si përdorni funksionet SUBSTITUTE dhe REPLACE në Excel. Shpresojmë, këta shembuj do të jenë të dobishëm në zgjidhjen e detyrave tuaja. Ju falënderoj që lexoni dhe shpresoj ta shohim në blogun tonë javën e ardhshme!

Shkarko librin e punës praktike

SHEMBUJ REPLACE dhe ZËVENDËSO formule (skedari .xlsx)