O'quv qo'llanma Excelning ALSHIRISh va O'ZBIRISh funksiyalarini foydalanish misollari bilan tushuntiradi. ALSHISH funksiyasidan matn satrlari, raqamlar va sanalar bilan qanday foydalanish va bir nechta ALSHIRISH yoki ALTISH funksiyalarini bitta formula ichiga joylashtirishni ko‘ring.

O‘tgan hafta biz TOPISh va QIDIRISH funksiyalaridan foydalanishning turli usullarini muhokama qildik. Excel ish varaqlaringiz. Bugun biz hujayradagi matnni joylashuviga qarab almashtirish yoki mazmuniga ko'ra bitta matn qatorini boshqasiga almashtirish uchun yana ikkita funktsiyani chuqurroq ko'rib chiqamiz. Siz taxmin qilganingizdek, men Excelning ALSHIRISh va ALTISH funksiyalari haqida gapiryapman.

Excel ALMASH funksiyasi

Excel-dagi ALTISH funksiyasi bir yoki bir nechtasini almashtirish imkonini beradi. matn satridagi belgilar boshqa belgi yoki belgilar toʻplamiga ega.

Koʻrib turganingizdek, Excel ALMASH funksiyasi 4 ta argumentga ega, ularning barchasi talab qilinadi.

• Eski_matn - siz ba'zi belgilar almashtirmoqchi bo'lgan asl matn (yoki asl matnga ega bo'lgan katakka havola).
• Start_num - siz almashtirmoqchi bo'lgan eski_matn ichidagi birinchi belgining o'rni.
• Num_chars - siz almashtirmoqchi bo'lgan belgilar soni.
• Yangi_matn - almashtirish matni.

Masalan, " quyosh " so'zini " son " ga o'zgartirish uchun siz quyidagilardan foydalanishingiz mumkin.formula:

=REPLACE("sun", 2, 1, "o")

Agar siz asl so'zni biron bir katakka qo'ysangiz, A2 deb ayting, eski matn argumentida mos keladigan katakcha havolasini taqdim etishingiz mumkin:

=REPLACE(A2, 2, 1, "o")

Eslatma. Agar boshlang'ich_raqam yoki belgilar soni argumenti manfiy yoki raqamli bo'lmasa, Excel almashtirish formulasi #VALUE! xato.

Excelning REPLACE funksiyasidan raqamli qiymatlar bilan foydalanish

Excel'dagi REPLACE funksiyasi matn satrlari bilan ishlash uchun mo'ljallangan. Albatta, siz undan matn qatorining bir qismi bo'lgan raqamli belgilarni almashtirish uchun foydalanishingiz mumkin, masalan:

=REPLACE(A2, 7, 4, "2016")

E'tibor bering, biz "2016 yil" " matn qiymatlari bilan odatdagidek qo'sh tirnoq ichida.

Shunga o'xshab, siz raqam ichidagi bir yoki bir nechta raqamni almashtirishingiz mumkin. Masalan:

=REPLACE(A4, 4, 4,"6")

Va yana o'zgartirish qiymatini qo'sh tirnoq ("6") ichiga kiritishingiz kerak.

Eslatma. Excel REPLACE formulasi har doim raqamni emas, matn satrini qaytaradi. Yuqoridagi skrinshotda B2 da qaytarilgan matn qiymatining chap hizalanishiga e'tibor bering va uni A2 dagi o'ngga tekislangan asl raqam bilan solishtiring. Va bu matn qiymati boʻlgani uchun uni raqamga qaytarmaguningizcha, masalan, 1 ga koʻpaytirish yoki Matnni raqamga qanday oʻzgartirish boʻlimida tasvirlangan boshqa usullardan foydalanmaguningizcha, uni boshqa hisob-kitoblarda ishlata olmaysiz.

Excelning REPLACE funksiyasidan sanalar bilan foydalanish

Ko'rib turganingizdek, REPLACE funksiyasi bilan yaxshi ishlaydi.raqamlar, faqat matn qatorini qaytaradi :) Ichki Excel tizimida sanalar raqamlar sifatida saqlanishini eslab, sanalarda ba'zi almashtirish formulalaridan foydalanishga urinib ko'rishingiz mumkin. Natijalar juda noqulay bo'lardi.

Masalan, A2 formatida sana bor, deylik, 1-oktabr-14 va siz " oktabr "ni " noyabr<" ga o'zgartirmoqchisiz. 2>". Shunday qilib, siz Excelga 4-belgidan boshlanadigan A2 katakchalaridagi 3 ta belgini almashtirishni bildiruvchi ALTISH(A2, 4, 3, “Noyabr”) formulasini yozasiz va quyidagi natijaga erishasiz:

Nega shunday? Chunki "01-oktabr-14" faqat sanani bildiruvchi asosiy seriya raqamining (41913) vizual ko'rinishidir. Shunday qilib, bizning "Almashtirish" formulamiz yuqoridagi seriya raqamidagi oxirgi 3 ta raqamni " Noyabr " ga o'zgartiradi va "419Nov" matn qatorini qaytaradi.

Excel bilan to'g'ri ishlash uchun O'Z VARISH funksiyasini olish uchun. sanalar uchun, siz Excelda sanani matnga qanday o'zgartirish bo'limida ko'rsatilgan TEXT funksiyasidan yoki boshqa har qanday texnikadan foydalanib, sanalarni matn satrlariga o'zgartirishingiz mumkin. Shu bilan bir qatorda, TEXT funksiyasini to‘g‘ridan-to‘g‘ri REPLACE funksiyasining eski matn argumentiga joylashtirishingiz mumkin:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Yuqoridagi formulaning natijasi quyidagicha ekanligini unutmang. a matn qatori va shuning uchun bu yechim faqat keyingi hisob-kitoblarda o'zgartirilgan sanalardan foydalanishni rejalashtirmagan bo'lsangiz ishlaydi. Agar sizga matn satrlari o'rniga sanalar kerak bo'lsa, qaytarilgan qiymatlarni aylantirish uchun DATEVALUE funksiyasidan foydalaning.Excel REPLACE funksiyasi sanaga qaytdi:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Yacheykada bir nechta almashtirishlarni amalga oshirish uchun ichki o'rnatilgan ALGILASH funksiyalari

Ko'pincha, bir nechta almashtirishni amalga oshirishingiz kerak bo'lishi mumkin. bir xil hujayra. Albatta, siz bitta almashtirishni amalga oshirishingiz, oraliq natijani qo'shimcha ustunga chiqarishingiz va keyin REPLACE funksiyasidan yana foydalanishingiz mumkin. Biroq, yaxshiroq va professionalroq usul ichiga o'rnatilgan REPLACE funksiyalaridan foydalanishdir, bu sizga bitta formula bilan bir nechta almashtirishlarni amalga oshirish imkonini beradi. Shu nuqtai nazardan, "uya joylashtirish" bir funktsiyani boshqasiga joylashtirishni anglatadi.

Quyidagi misolni ko'rib chiqing. Aytaylik, sizda A ustunida "123456789" sifatida formatlangan telefon raqamlari ro'yxati bor va siz defis qo'shish orqali ularni telefon raqamlariga o'xshatishni xohlaysiz. Boshqacha qilib aytganda, sizning maqsadingiz "123456789" ni "123-456-789" ga aylantirishdir.

Birinchi defisni qo'yish oson. Siz nol belgilar o'rnini defis bilan almashtiradigan, ya'ni hujayradagi 4-o'ringa defis qo'shadigan odatiy Excel almashtirish formulasini yozasiz:

=REPLACE(A2,4,0,"-")

Natija Yuqoridagi almashtirish formulasi quyidagicha:

Yaxshi, endi 8-holatga yana bitta defis qo'yishimiz kerak. Buni amalga oshirish uchun siz yuqoridagi formulani Excelning boshqa ALTISH funksiyasiga joylashtirasiz. Aniqroq qilib aytganda, siz uni boshqa funktsiyaning eski_matn argumentiga joylashtirasiz, shunda ikkinchi REPLACE funksiyasi qaytarilgan qiymatni boshqaradi.birinchi navbatda A2 katakchadagi qiymatni emas, ALGILASH:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Natijada siz kerakli formatdagi telefon raqamlarini olasiz:

Shunga o'xshab, matn satrlarini sanaga o'xshatish uchun ichki o'rnatilgan REPLACE funksiyalaridan foydalanishingiz mumkin, kerak bo'lganda qiyshiq chiziq (/) qo'shishingiz mumkin:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Bundan tashqari, yuqoridagi REPLACE formulasini DATEVALUE funksiyasi bilan oʻrash orqali matn satrlarini haqiqiy sanaga aylantirishingiz mumkin:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Va tabiiyki, siz funksiyalar soni bilan cheklanmaysiz. siz bitta formula ichiga joylashtirishingiz mumkin (Excel 2010, 2013 va 2016 ning zamonaviy versiyalari formulada 8192 tagacha belgi va 64 tagacha ichki funksiyalarga ruxsat beradi).

Masalan, siz 3 ta ichki oʻrnatilgan ALTISH funksiyasidan foydalanishingiz mumkin. A2 formatidagi raqam sana va vaqt kabi ko'rinadi:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Har bir katakchada boshqa holatda paydo bo'ladigan qatorni almashtirish

Hozirgacha barcha misollarda biz o'xshash xarakterdagi qiymatlar bilan ishladik va bir xil pozitivda almashtirdik. har bir hujayrada. Ammo real hayotdagi vazifalar ko'pincha undan murakkabroq. Ish varaqlarida almashtirilishi kerak bo'lgan belgilar har bir katakda bir xil joyda ko'rsatilmasligi mumkin va shuning uchun siz almashtirilishi kerak bo'lgan birinchi belgining o'rnini topishingiz kerak bo'ladi. Quyidagi misol men nima haqida gapirayotganimni ko'rsatadi.

Agar sizda elektron pochta ro'yxati mavjud bo'lsa.A ustunidagi manzillash. Va bitta kompaniyaning nomi "ABC" dan, aytaylik, "BCA" ga o'zgartirildi. Shunday qilib, siz barcha mijozlarning elektron pochta manzillarini mos ravishda yangilashingiz kerak.

Ammo muammo shundaki, mijoz nomlari turli uzunlikda va shu sababli kompaniya nomi aynan qaerdan boshlanishini aniqlay olmaysiz. Boshqacha qilib aytadigan bo'lsak, Excel REPLACE funksiyasining start_num argumentida qanday qiymat berishni bilmayapsiz. Buni bilish uchun "@abc" qatoridagi birinchi belgining o'rnini aniqlash uchun Excel FIND funksiyasidan foydalaning:

=FIND("@abc",A2)

Va keyin yuqoridagi FIND funksiyasini start_numga kiriting. ALSHISH formulangizning argumenti:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Maslahat. Elektron pochta manzillarining nom qismi tasodifiy almashtirilmasligi uchun Excel topish va almashtirish formulamizga "@" qo'shamiz. Albatta, bunday o'yinlar yuzaga kelishi ehtimoli juda kichik va siz hali ham xavfsiz tomonda bo'lishni xohlashingiz mumkin.

Keyingi skrinshotda ko'rib turganingizdek, formulani topish va almashtirishda hech qanday muammo yo'q. eski matn yangisi bilan. Biroq, agar almashtiriladigan matn qatori topilmasa, formula #VALUE! xato:

Va biz formula xato o'rniga asl elektron pochta manzilini qaytarishini xohlaymiz. Shunday qilib, keling, bizning FIND & amp; IFERROR funksiyasidagi formulani ALTISHTIRISH:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Va bu takomillashtirilgan formula mukammal ishlaydi, shunday emasmi?

Boshqa amaliyREPLACE funksiyasining qo'llanilishi hujayradagi birinchi harfni bosh harf bilan yozishdan iborat. Ismlar, mahsulotlar va shunga o'xshashlar ro'yxati bilan shug'ullanganingizda, birinchi harfni YUQORI XARFga o'zgartirish uchun yuqoridagi formuladan foydalanishingiz mumkin.

Maslahat. Agar siz asl maʼlumotlarga oʻzgartirish kiritmoqchi boʻlsangiz, Excelning TOPISh va ALSHIRISh dialog oynasidan foydalanish osonroq boʻladi.

Excel ALTIB OLISH funksiyasi

Exceldagi SUBSTITUTE funksiyasi bir yoki bir nechta misollarni almashtiradi. berilgan belgi yoki belgilangan belgi(lar)ga ega matn qatori.

Excel SUBSTITUTE funksiyasining sintaksisi quyidagicha:

Birinchi uchta argument talab qilinadi, oxirgisi esa ixtiyoriy.

• Matn - belgilarni almashtirmoqchi bo'lgan asl matn. Sinov qatori, yacheyka ma'lumotnomasi yoki boshqa formula natijasi sifatida taqdim etilishi mumkin.
• Eski_matn - siz almashtirmoqchi bo'lgan belgi(lar).
• Yangi_matn - eski_matnni almashtirish uchun yangi belgi(lar).
• Masalan_num - siz almashtirmoqchi bo'lgan eski_matnning paydo bo'lishi. Agar o'tkazib yuborilsa, eski matnning har bir takrori yangi matnga o'zgartiriladi.

Masalan, quyida keltirilgan barcha formulalar A2 katakchadagi "1" ni "2" bilan almashtiradi, lekin turli natijalar beradi. Oxirgi argumentda qaysi raqamni berganingizga qarab:

=SUBSTITUTE(A2, "1", "2", 1) - "1" ning birinchi ko'rinishini bilan almashtiradi"2".

=SUBSTITUTE(A2, "1", "2", 2) - "1" ning ikkinchi ko'rinishini "2" bilan almashtiradi.

=SUBSTITUTE(A2, "1", "2") - "1" ning barcha holatlarini "2" bilan almashtiradi.

Amalda SUBSTITUTE funksiyasi kataklardan keraksiz belgilarni olib tashlash uchun ham ishlatiladi. Haqiqiy misollar uchun qarang:

• Stringdan belgilar yoki so'zlarni qanday olib tashlash
• Yacheykalardan keraksiz belgilarni qanday o'chirish

Eslatma. Excelda SUBSTITUTE funksiyasi katta harflarni sezgir . Masalan, quyidagi formula A2 katakdagi “X” bosh harfining barcha nusxalarini “Y” bilan almashtiradi, biroq u kichik “x” harflarining hech bir nusxasini almashtirmaydi.

Bir nechta qiymatlarni bitta formula bilan almashtiring (ichiga oʻrnatilgan ALGILASH)

Excel ALTISH funksiyasida boʻlgani kabi, bir vaqtning oʻzida bir nechta almashtirishni amalga oshirish uchun bir nechta ALTISH funksiyalarini bitta formula ichiga joylashtirishingiz mumkin, yaʼni almashtirish bitta formulaga ega bir nechta belgilar yoki pastki qatorlar.

A2 katakchada " PR1, ML1, T1 " kabi matn qatori bor, bu erda "PR" "Loyiha, "ML" degan ma'noni anglatadi. " "Milestone" degan ma'noni anglatadi va "T" "Vazifa" degan ma'noni anglatadi. Siz uchta kodni to'liq nomlar bilan almashtirishni xohlaysiz. Bunga erishish uchun siz 3 xil O'ZBEKISTON formulasini yozishingiz mumkin:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

Va keyin ularni bir-biriga joylashtiring:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

E'tibor bering, biz oxiriga bo'sh joy qo'shdik. har bir new_text argumenti yaxshiroqo'qilishi.

Bir vaqtning o'zida bir nechta qiymatlarni almashtirishning boshqa usullarini o'rganish uchun Excelda qanday qilib ommaviy topish va almashtirishni ko'ring.

Excel REPLACE vs. Excel ALGIShI

Excel ALMASH va O'ZBIRISh funksiyalari bir-biriga juda o'xshash, chunki ikkalasi ham matn satrlarini almashtirish uchun mo'ljallangan. Ikki funktsiya orasidagi farqlar quyidagicha:

• SUBSTITUTE berilgan belgi yoki matn qatorining bir yoki bir nechta nasollarini almashtiradi. Shunday qilib, agar siz almashtirilishi kerak bo'lgan matnni bilsangiz, Excel SUBSTITUTE funksiyasidan foydalaning.
• REPLACE matn satrining belgilangan pozitsiyasi dagi belgilarni o'zgartiradi. Shunday qilib, agar siz almashtiriladigan belgi(lar)ning o'rnini bilsangiz, Excelning ALSHIRISh funksiyasidan foydalaning.
• Excel'dagi ALGILASH funksiyasi ixtiyoriy parametrni (instance_num) qo'shish imkonini beradi, u qaysi voqe bo'lishini qismi yangi_matnga oʻzgartirilishi kerak.

Excelda ALTISH va ALSHIRISh funksiyalaridan shunday foydalanasiz. Umid qilamizki, bu misollar sizning vazifalaringizni hal qilishda foydali bo'ladi. O'qiganingiz uchun tashakkur va keyingi hafta blogimizda ko'rishga umid qilaman!

Mashq qilish bo'yicha ish kitobini yuklab oling

O'ZIB OLISH va O'ZIB OLISH formulalari (.xlsx fayli)