Tha an oideachadh a’ mìneachadh gnìomhan Excel REPLACE agus SUBSTITUTE le eisimpleirean de chleachdadh. Faic mar a chleachdas tu an gnìomh REPLACE le sreangan teacsa, àireamhan agus cinn-latha, agus mar a neadaicheas tu grunn ghnìomhan REPLACE no SUBSTITUTE taobh a-staigh aon fhoirmle.

An t-seachdain sa chaidh bhruidhinn sinn air diofar dhòighean air gnìomhan FIND and SEARCH a chleachdadh taobh a-staigh na duilleagan-obrach Excel agad. An-diugh, bidh sinn a’ toirt sùil nas doimhne air dà ghnìomh eile gus teacsa a chuir an àite cealla stèidhichte air far a bheil e no sreang teacsa a chuir an àite tè eile stèidhichte air susbaint. Mar is dòcha gu bheil thu air smaoineachadh, tha mi a’ bruidhinn mu dheidhinn gnìomhan Excel REPLACE agus SUBSTITUTE.

Leigidh an gnìomh REPLACE ann an Excel dhut aon no grunnan atharrachadh. caractaran ann an sreang teacsa le caractar eile no seata charactaran.

Mar a chì thu, tha 4 argamaidean aig gnìomh Excel REPLACE, agus tha feum orra uile.<3

• Old_text - an teacsa tùsail (no iomradh air cealla leis an teacsa tùsail) anns a bheil thu airson cuid de charactairean a chur nan àite.
• Start_num - suidheachadh a' chiad charactair am broinn old_text a tha thu airson a chur na àite.
• Num_chars - an àireamh de charactairean a tha thu airson a chur nan àite.
• New_text - an teacsa ùr.

Mar eisimpleir, airson am facal " sun " atharrachadh gu " son ", faodaidh tu na leanas a chleachdadhfoirmle:

=REPLACE("sun", 2, 1, "o")

Agus ma chuireas tu am facal tùsail ann an cealla air choireigin, can A2, is urrainn dhut an t-iomradh cealla co-fhreagarrach a thoirt seachad san argamaid old_text:

=REPLACE(A2, 2, 1, "o") <3

Nòta. Ma tha an argamaid start_num no num_chars àicheil no neo-àireamhach, tillidh foirmle Excel Replace an #VALUE! mearachd.

A’ cleachdadh gnìomh Excel REPLACE le luachan àireamhach

Tha an gnìomh REPLACE ann an Excel air a dhealbhadh gus obrachadh le sreangan teacsa. Gun teagamh, 's urrainn dhut a chleachdadh gus caractaran àireamhach a tha nam pàirt de shreang teacsa a chur an àite, mar eisimpleir:

=REPLACE(A2, 7, 4, "2016")

Thoir an aire gu bheil sinn a' cuartachadh "2016 " ann an briathran dùbailte mar a nì thu le luachan teacsa mar as trice.

San aon dòigh, 's urrainn dhut aon fhigear no barrachd a chur na àite am broinn àireamh. Mar eisimpleir:

=REPLACE(A4, 4, 4,"6")

Agus a-rithist, feumaidh tu an luach ùr a chur a-steach ann an luachan dùbailte ("6").

Thoir an aire. Bidh foirmle Excel REPLACE an-còmhnaidh a’ tilleadh sreang teacsa , chan e àireamh. Anns an dealbh-sgrìn gu h-àrd, mothaich co-thaobhadh clì luach an teacsa a chaidh a thilleadh ann am B2, agus dèan coimeas eadar e agus an àireamh thùsail a tha co-thaobhadh ris an taobh dheas ann an A2. Agus a chionn 's gur e luach teacsa a th' ann chan urrainn dhut a chleachdadh ann an àireamhachadh eile mura h-atharraich thu e gu àireamh, mar eisimpleir le bhith ag iomadachadh le 1 no le bhith a' cleachdadh dòigh sam bith eile a tha air a mhìneachadh ann an Mar a dh'atharraicheas tu teacsa gu àireamh.

A’ cleachdadh gnìomh Excel REPLACE le cinn-latha

Mar a tha thu dìreach air fhaicinn, tha an gnìomh REPLACE ag obair gu math leàireamhan, ach a-mhàin gun till e sreang teacsa :) A’ cuimhneachadh gu bheil cinn-latha air an stòradh mar àireamhan san t-siostam Excel a-staigh, faodaidh tu feuchainn ri cuid de na foirmlean Ath-chuir air cinn-latha a chleachdadh. Bhiodh toraidhean caran nàire.

Mar eisimpleir, tha ceann-latha agad ann an A2, can 1-Dàmhair-14, agus tha thu airson " Dàmhair " atharrachadh gu " Samhain ". Mar sin, bidh thu a’ sgrìobhadh am foirmle REPLACE(A2, 4, 3, “Nov”) a dh’ iarras air Excel 3 chars a chuir an àite ceallan A2 a’ tòiseachadh leis a’ char 4th… agus fhuair thu an toradh a leanas:

Carson a tha sin? Leis nach eil ann an “01-Oct-14” ach riochdachadh lèirsinneach den àireamh sreathach bhunaiteach (41913) a tha a’ riochdachadh a’ chinn-latha. Mar sin, bidh ar foirmle Replace ag atharrachadh na 3 àireamhan mu dheireadh san àireamh sreathach gu h-àrd gu " Samhain " agus a' tilleadh an t-sreang teacsa "419Nov".

Gus am faigh an gnìomh Excel REPLACE obrachadh leis gu ceart. cinn-latha, faodaidh tu cinn-latha a thionndadh gu sreangan teacsa an-toiseach le bhith a’ cleachdadh an gnìomh TEXT no dòigh sam bith eile a chithear ann an Mar a thionndaidheas tu ceann-latha gu teacsa ann an Excel. Air neo, faodaidh tu an gnìomh TEXT fhighe a-steach gu dìreach san argamaid old_text den ghnìomh REPLACE:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Cuimhnich gur e toradh na foirmle gu h-àrd sreang teacsa , agus mar sin chan obraich am fuasgladh seo ach mura h-eil thu am beachd na cinn-latha atharraichte a chleachdadh ann an àireamhachadh eile. Ma tha cinn-latha a dhìth ort seach teudan teacsa, cleachd an gnìomh DATEVALUE gus na luachan a thilleas tu a thionndadhan gnìomh Excel REPLACE air ais gu cinn-latha:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Gnìomhan REPLACE neadaichte gus iomadh ath-chur a dhèanamh ann an cealla

Gu math tric, is dòcha gum feum thu barrachd air aon ath-chur a-steach an aon chill. Gu dearbh, dh'fhaodadh tu aon ath-chur a dhèanamh, toradh eadar-mheadhanach a thoirt a-steach do cholbh a bharrachd, agus an uairsin cleachd an gnìomh REPLACE a-rithist. Ach, is e dòigh nas fheàrr agus nas proifeiseanta a bhith a’ cleachdadh gnìomhan REPLACE neadachaidh a leigeas leat grunn rudan ùra a dhèanamh le aon fhoirmle. Sa cho-theacs seo, tha "neadachadh" a' ciallachadh a bhith a' cur aon ghnìomh am broinn fear eile.

Smaoinich air an eisimpleir a leanas. Leis gu bheil liosta de dh'àireamhan fòn agad ann an colbh A ann an cruth "123456789" agus gu bheil thu airson toirt orra coimhead nas coltaiche ri àireamhan fòn le bhith a' cur tàthan ris. Ann am faclan eile, 's e an t-amas agad "123456789" a thionndadh gu "123-456-789".

Tha e furasta a' chiad tàthan a chur a-steach. Bidh thu a’ sgrìobhadh foirmle àbhaisteach Excel Replace a chuireas tàthan an àite charactaran neoni , i.e. a’ cur tàthan anns a’ 4mh suidheachadh ann an cealla:

=REPLACE(A2,4,0,"-")

Toradh an gu h-àrd Cuir an àite foirmle mar a leanas:

Ceart gu leòr, agus a-nis feumaidh sinn aon tàthan eile a chuir a-steach san 8mh suidheachadh. Gus seo a dhèanamh, cuiridh tu am foirmle gu h-àrd taobh a-staigh gnìomh Excel REPLACE eile. Nas mionaidiche, chuir thu a-steach e san argamaid old_text den ghnìomh eile, gus an làimhsich an dàrna gnìomh REPLACE an luach a thilleasan toiseach REPLACE, agus chan e an luach ann an cealla A2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Mar thoradh air an sin, gheibh thu na h-àireamhan fòn san fhòrmat a tha thu ag iarraidh:

San aon dòigh, faodaidh tu gnìomhan REPLACE neadachaidh a chleachdadh gus teudan teacsa a bhith coltach ri cinn-latha le bhith a’ cur slais air adhart (/) far a bheil sin iomchaidh:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

<3

A bharrachd air an sin, is urrainn dhut sreangan teacsa a thionndadh gu cinn-latha fìor le bhith a’ pasgadh na foirmle REPLACE gu h-àrd leis a’ ghnìomh DATEVALUE:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Agus gu nàdarrach, chan eil thu cuingealaichte san àireamh de ghnìomhan faodaidh tu neadachadh taobh a-staigh aon fhoirmle (tha na dreachan ùr-nodha de Excel 2010, 2013 agus 2016 a’ ceadachadh suas ri 8192 caractar agus suas ri 64 gnìomh neadachaidh ann am foirmle).

Mar eisimpleir, faodaidh tu 3 gnìomhan REPLACE neadachaidh a chleachdadh gu cuir àireamh ann an A2 coltach ri ceann-latha agus àm:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

A’ cur an àite sreang a nochdas ann an suidheachadh eadar-dhealaichte anns gach cealla

Gu ruige seo, anns a h-uile h-eisimpleir tha sinn air a bhith a’ dèiligeadh ri luachan den aon seòrsa agus tha sinn air feadhainn a chur nan àite san aon suidheachadh anns gach cill. Ach tha gnìomhan fìor gu tric nas iom-fhillte na sin. Anns na duilleagan-obrach agad, dh’fhaoidte nach bi na caractaran a thèid a chur nan àite a’ nochdadh san aon àite anns gach cealla, agus mar sin feumaidh tu suidheachadh a’ chiad charactair a lorg a bu chòir a chur na àite. Seallaidh an t-eisimpleir a leanas na tha mi a’ bruidhinn.

A’ gabhail ris gu bheil liosta post-d agada' seòladh ann an colbh A. Agus tha ainm aon chompanaidh air atharrachadh bho "ABC" gu, can, "BCA". Mar sin, feumaidh tu seòladh puist-d a h-uile neach-dèiligidh ùrachadh a rèir sin.

Ach 's e an duilgheadas a th' ann gu bheil ainmean an luchd-cleachdaidh de dh'fhaid eadar-dhealaichte, agus is e sin as coireach nach urrainn dhut sònrachadh dìreach far a bheil ainm a' chompanaidh a' tòiseachadh. Ann am faclan eile, chan eil fios agad dè an luach a bu chòir a thoirt seachad san argamaid start_num den ghnìomh Excel REPLACE. Gus faighinn a-mach, cleachd an gnìomh Excel FIND gus suidheachadh a’ chiad char san t-sreang “@abc” a dhearbhadh:

=FIND("@abc",A2)

Agus an uairsin, thoir seachad an gnìomh FIND gu h-àrd anns an start_num argamaid mun fhoirmle REPLACE agad:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Tip. Bidh sinn a’ toirt a-steach “@” anns an fhoirmle Excel Find and Replace againn gus ath-chuiridhean tubaisteach a sheachnadh anns a’ phàirt ainm de sheòlaidhean puist-d. Gun teagamh, tha teansa glè bheag ann gun tachair geamannan mar seo, agus fhathast 's dòcha gum bi thu airson a bhith air an taobh shàbhailte.

Mar a chì thu san ath-sgrìn a leanas, chan eil duilgheadas sam bith aig an fhoirmle le bhith a' lorg agus ag ath-shuidheachadh an fhaidhle seann teacsa leis an fhear ùr. Ach, mura lorgar an sreang teacsa a thèid a h-àite, tillidh am foirmle an #VALUE! mearachd:

Agus tha sinn ag iarraidh air an fhoirmle an seòladh puist-d tùsail a thilleadh an àite na mearachd. Mar sin, leig dhuinn ar FIND & ATH-LEASACHADH foirmle san ghnìomh IFERROR:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Agus tha am foirmle leasaichte seo ag obair gu foirfe, nach eil?is e cleachdadh na gnìomh REPLACE a’ chiad litir ann an cealla a chalpachadh. Nuair a dhèiligeas tu ri liosta ainmean, thoraidhean is an leithid, faodaidh tu am foirmle gu h-àrd a chleachdadh gus a’ chiad litir atharrachadh gu UPPERCASE.

Tip. Ma tha thu airson na h-atharraichean a dhèanamh anns an dàta thùsail, bhiodh e na b’ fhasa a bhith a’ cleachdadh a’ chòmhraidh Excel FIND and REPLACE.

Gnìomh SUBSTITUTE Excel

Tha an gnìomh SUBSTITUTE ann an Excel a’ dol an àite aon suidheachadh no barrachd de charactar sònraichte no sreang teacsa le caractar(an) ainmichte.

Tha co-chòrdadh gnìomh Excel SUBSTITUTE mar a leanas:

Tha a' chiad trì argamaidean a dhìth agus tha an tè mu dheireadh roghainneil.

• Teacsa - an teacsa tùsail anns a bheil thu airson caractaran a chur nan àite. Gabhaidh a sholarachadh mar shreang deuchainn, mar iomradh cealla, no mar thoradh air foirmle eile.
• Old_text - an caractar(an) a tha thu airson a chur na àite.
• >New_text - an caractar(an) ùr a thèid an àite old_text le.
• Instance_num - mar a tha old_text a tha thu airson a chur na àite. Ma thèid a fàgail air falbh, thèid a h-uile tachartas den t-seann teacsa atharrachadh dhan teacsa ùr.

Mar eisimpleir, cuiridh na foirmlean gu h-ìosal "1" an àite "2" ann an ceal A2, ach tillidh iad toraidhean eadar-dhealaichte a rèir dè an àireamh a bheir thu seachad san argamaid mu dheireadh:

=SUBSTITUTE(A2, "1", "2", 1) - A’ cur a’ chiad tachartas de “1” an àite"2".

=SUBSTITUTE(A2, "1", "2", 2) - A' cur "2" an àite an dàrna tachartas de "1".

=SUBSTITUTE(A2, "1", "2") - A' cur "2" a h-uile tachartas de "1" an àite "2".

Ann an cleachdadh, tha an gnìomh SUBSTITUTE cuideachd air a chleachdadh airson caractaran nach eileas ag iarraidh a thoirt air falbh bho cheallan. Airson eisimpleirean fìor, faic:

• Mar a bheir thu air falbh caractaran no faclan bhon t-sreang
• Mar a sguabas tu às caractaran nach eileas ag iarraidh à ceallan

Nota. Tha an gnìomh SUBSTITUTE ann an Excel mothachail air cùis . Mar eisimpleir, tha an fhoirmle a leanas a' dol an àite a h-uile suidheachadh den phrìomh "X" le "Y" ann an ceal A2, ach cha chuir e an àite suidheachadh sam bith den litrichean beaga "x".

Cuir an àite ioma luachan le aon fhoirmle (SUBSTITUTE neadachaidh)

Mar a thachras leis a’ ghnìomh Excel REPLACE, faodaidh tu grunn ghnìomhan SUBSTITUTE a neadachadh taobh a-staigh aon fhoirmle gus grunn luchd-ionaid a dhèanamh aig an aon àm, i.e. grunn charactaran no fo-thalagan le aon fhoirmle.

A’ gabhail ris gu bheil sreang teacsa agad mar “ PR1, ML1, T1 ” ann an ceal A2, far a bheil “PR” a’ seasamh airson “Project,“ ML " a' ciallachadh "Clach-mhìle" agus "T" a' ciallachadh "Tasg". 'S e na tha thu ag iarraidh ainmean slàn a chur an àite nan trì còdan. Gus seo a choileanadh, 's urrainn dhut 3 foirmlean SUBSTITUTE eadar-dhealaichte a sgrìobhadh:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

Agus an uairsin neadaich a-steach dha chèile:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

Thoir an aire gu bheil sinn air beàrn a chuir ris aig deireadh na gach argamaid ùr_text airson nas fheàrrcomas leughaidh.

Gus dòighean eile ionnsachadh gus iomadach luach a chur an àite aig aon àm, faic Mar a nì thu mòr-lorg agus ath-chur ann an Excel.

Excel REPLACE vs . Excel SUBSTITUTE

Tha gnìomhan Excel REPLACE agus SUBSTITUTE glè choltach ri chèile leis gu bheil an dà chuid air an dealbhadh gus sreangan teacsa atharrachadh. Tha na h-eadar-dhealachaidhean eadar an dà ghnìomh mar a leanas:

• SUBSTITUTE a’ dol an àite aon no barrachd suidheachadh de charactar ainmichte no sreang teacsa. Mar sin, ma tha thu eòlach air an teacsa a thèid a chur na àite, cleachd an gnìomh Excel SUBSTITUTE.
• Atharraichidh REPLACE caractaran ann an suidheachadh ainmichte de shreang teacsa. Mar sin, ma tha fios agad air suidheachadh a’ charactar(an) a thèid a chur na àite, cleachd an gnìomh Excel REPLACE.
• Tha an gnìomh SUBSTITUTE ann an Excel a’ ceadachadh paramadair roghnach (instance_num) a chur ris a shònraicheas dè tachartas de old_text atharrachadh gu new_text.

Seo mar a chleachdas tu na gnìomhan SUBSTITUTE agus REPLACE ann an Excel. Tha sinn an dòchas gum bi na h-eisimpleirean seo feumail ann a bhith a’ fuasgladh do ghnìomhan. Tha mi a’ toirt taing dhut airson leughadh agus tha mi an dòchas faicinn air ar blog an ath sheachdain!

Luchdaich sìos leabhar-obrach cleachdaidh

eisimpleirean foirmle REPLACE and SUBSTITUTE (faidhle .xlsx)