Får du mange #N/A-feil i regnearkene dine og er nysgjerrig på om det er en måte å vise en egendefinert tekst på i stedet? IFNA-formelen er løsningen du trenger.

Når en Excel-formel ikke kan identifisere eller finne noe, gir den #N/A-feilen. For å fange opp en slik feil og erstatte den med en brukervennlig melding, kan du bruke IFNA-funksjonen. Med andre ord, #N/A er Excels måte å si at verdien du leter etter ikke finnes i det refererte datasettet. IFNA er din måte å fange og håndtere den feilen på.

IFNA-funksjon i Excel

Excel IFNA-funksjonen er beregnet på å fange opp og håndtere #N/A-feil. Hvis en formel evalueres til #N/A, fanger IFNA den feilen og erstatter den med en egendefinert verdi du angir; returnerer ellers et normalt resultat av formelen.

IFNA-syntaks

Syntaksen til IFNA-funksjonen er som følger:

Hvor:

Verdi (obligatorisk) – formelen, verdien eller referansen for å se etter en #N/A-feil.

Value_if_na (obligatorisk) – verdien for å returnere hvis en #N/A feil oppdages.

Bruksmerknader

• IFNA-funksjonen håndterer bare #N/A uten å undertrykke andre feil.
• Hvis argumentet verdi er en matriseformel , returnerer IFNA en rekke resultater, én per celle, som vist i dette eksemplet.

IFNA-tilgjengelighet

IFNA-funksjonen ble introdusert iExcel 2013 og er tilgjengelig i alle påfølgende versjoner, inkludert Excel 2016, Excel 2019, Excel 2021 og Microsoft 365.

I tidligere versjoner kan du fange #N/A-feil ved å bruke IF- og ISNA-funksjonene sammen.

Hvordan bruke IFNA-funksjonen i Excel

For å effektivt bruke IFNA i Excel, følg denne generiske tilnærmingen:

1. I det første argumentet ( verdi ), sett inn en formel påvirket av #N/A-feilen.
2. I det andre argumentet ( value_if_na ), skriv inn teksten du vil returnere i stedet for standard feilnotasjon. For å returnere en tom celle når ingenting blir funnet, oppgi en tom streng (""").

For å returnere egendefinert tekst er den generiske formelen:

For å returnere en tom celle er den generiske formelen:

La oss se hvordan det fungerer på et enkelt eksempel. I tabellen nedenfor, anta at du vil vite hvordan en poengsum til en gitt student rangerer blant andre. Siden dataene er sortert etter Poengsum -kolonnen fra høyeste til laveste, vil rangeringen samsvare med den relative plasseringen til eleven i tabellen. Og for å få posisjonen kan du bruke MATCH-funksjonen i sin enkleste form:

=MATCH(E1, A2:A10, 0)

Fordi oppslagsverdien (Neal) ikke er tilgjengelig i oppslagsmatrisen (A2:A10), det oppstår en #N/A-feil.

Uerfarne brukere tror kanskje det er noe galt med denne feilen.formel, og du som arbeidsbokskaper vil få mange spørsmål. For å unngå dette kan du eksplisitt indikere at formelen er riktig, den finner bare ikke verdien den blir bedt om å se etter. Så du legger MATCH-formelen i det første argumentet til IFNA, og i det andre argumentet skriver du inn din egendefinerte tekst, "Ikke funnet" i vårt tilfelle:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Nå, i stedet for standard feilnotasjon, din egen tekst vises i en celle, og informerer brukerne om at oppslagsverdien ikke er til stede i datasettet:

Hvordan bruke IFNA med VLOOKUP

Oftest oppstår #N/A-feilen i funksjoner som ser etter noe som VLOOKUP, HLOOKUP, LOOKUP og MATCH. Eksemplene nedenfor dekker noen typiske brukstilfeller.

Eksempel 1. Grunnleggende IFNA VLOOKUP-formel

For å fange #N/A-feil som oppstår når VLOOKUP ikke kan finne en treff, sjekk resultatet ved å bruke IFNA og angi verdien som skal vises i stedet for feilen. Vanlig praksis er å pakke IFNA-funksjonen rundt den eksisterende VLOOKUP-formelen ved å bruke denne syntaksen:

I eksempeltabellen vår, anta at du vil hente en poengsum til en bestemt elev (E1). For dette bruker du denne klassiske VLOOKUP-formelen:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Problemet er at Neal ikke tok eksamen, derfor er navnet hans ikke på listen, og VLOOKUP klarer ikke å finne en kamp.

For å skjule feilen har vipakk inn VLOOKUP i IFNA slik:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Nå ser ikke resultatet så skremmende ut for brukeren og er mye mer informativt:

Eksempel 2. IFNA VLOOKUP for å slå opp på tvers av flere ark

IFNA-funksjonen er også nyttig for å utføre såkalte sekvensielle eller kjedede oppslag på tvers av flere ark eller forskjellige arbeidsbøker. Tanken er at du legger noen forskjellige IFNA(VLOOKUP(...))-formler inn i hverandre på denne måten:

Hvis en primær VLOOKUP ikke finner noe, kjører IFNA-funksjonen den neste VLOOKUP til den ønskede verdien er funnet. Hvis alle oppslag mislykkes, vil formelen returnere den angitte teksten.

Forutsatt at du har poengsummene til forskjellige klasser oppført i forskjellige ark (kalt Klasse A , Klasse B og Klasse C ). Målet ditt er å få poengsummen til en bestemt elev, hvis navn er skrevet inn i celle B1 i det gjeldende regnearket ditt. For å fullføre oppgaven, bruk denne formelen:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Formelen ser sekvensielt opp etter det spesifiserte navnet i tre forskjellige ark i rekkefølgen VLOOKUP er nestet og gir det første funnet samsvaret:

Eksempel 3. IFNA med INDEX MATCH

På lignende måte kan IFNA fange #N/A feil generert av andre oppslagsfunksjoner. Som et eksempel, la oss bruke det sammen med INDEX MATCHformel:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Kjernen i formelen er den samme som i alle tidligere eksempler - INDEX MATCH utfører et oppslag, og IFNA evaluerer resultatet og fanger opp en #N/A feil hvis referert verdi ble ikke funnet.

IFNA for å returnere flere resultater

Hvis den indre funksjonen (dvs. formelen plassert i verdien<2)> argument) returnerer flere verdier, vil IFNA teste hver returnerte verdi individuelt og sende ut en rekke resultater. For eksempel:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

I Dynamic Array Excel (Microsoft 365 og Excel 2021), søler en vanlig formel i den øverste cellen (E2) automatisk alle resultatene i nabocellene (med hensyn til av Excel, kalles det et spillområde).

I pre-dynamiske versjoner (Excel 2019 og lavere) kan en lignende effekt oppnås ved å bruke en flercellet matrise formel, som fullføres med Ctrl + Shift + Enter-snarveien.

Hva er forskjellen mellom IFNA og IFERROR?

Avhengig av grunnårsaken til problem, kan en Excel-formel utløse forskjellige feil som #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM og andre. IFERROR-funksjonen fanger opp alle disse feilene mens IFNA er begrenset til bare #N/A. Hvilken er bedre å velge? Det avhenger av situasjonen.

Hvis du ønsker å undertrykke enhver form for feil , så bruk IFERROR-funksjonen. Det er spesielt nyttig i komplekse beregninger når en formelinneholder flere funksjoner som kan generere forskjellige feil.

Med oppslagsfunksjoner bør du bruke IFNA, siden den viser et tilpasset resultat bare når en oppslagsverdi ikke er funnet og ikke skjuler underliggende problemer med selve formelen.

For å illustrere forskjellen, la oss ta tilbake vår grunnleggende IFNA VLOOKUP-formel og "tilfeldigvis" stave funksjonens navn feil (VLOKUP i stedet for VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA undertrykker ikke denne feilen, så du kan tydelig se at noe er galt med et av funksjonsnavnene:

Nå, la oss se hva som skjer hvis du bruker IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm... det står at Olivia ikke tok eksamen, noe som ikke er sant! Dette er fordi IFERROR-funksjonen fanger #NAME? feil og returnerer den egendefinerte teksten i stedet. I denne situasjonen returnerer den ikke bare feil informasjon, men skjuler også problemet med formelen.

Slik bruker du IFNA-formelen i Excel. Jeg takker for at du leser og ser frem til å se deg på bloggen vår neste uke!

Tilgjengelige nedlastinger

Excel IFNA-formeleksempler (.xlsx-fil)