Opplæringen diskuterer syntaks og grunnleggende bruk av COUNTBLANK-funksjonen for å telle antall tomme celler i Excel.

I et par nyere innlegg har vi diskutert forskjellige måter for å identifisere tomme celler og markere tomme felter i Excel. I noen situasjoner kan det imidlertid være lurt å vite hvor mange celler som ikke har noe i seg. Microsoft Excel har også en spesiell funksjon for dette. Denne opplæringen vil vise deg de raskeste og mest praktiske metodene for å få antall tomme celler i et område, så vel som helt tomme rader.

Excel COUNTBLANK-funksjonen

COUNTBLANK-funksjonen i Excel er designet for å telle tomme celler i et spesifisert område. Den tilhører kategorien statistiske funksjoner og er tilgjengelig i alle versjoner av Excel for Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 og Excel 2007.

Syntaksen til denne funksjonen er veldig grei og krever bare ett argument:

Hvor område er celleområdet som blanke skal telles i.

Her er et eksempel på COUNTBLANK formel i Excel i sin enkleste form:

=COUNTBLANK(A2:D2)

Formelen, angitt i E2 og kopiert ned til E7, bestemmer antall tomme celler i kolonnene A til D i hver rad og returnerer disse resultater:

Tips. For å telle ikke-tomme celler i Excel, bruk COUNTA-funksjonen.

COUNTBLANK-funksjonen - 3ting å huske

For effektivt å bruke en Excel-formel for å telle tomme celler, er det viktig å forstå hvilke celler COUNTBLANK-funksjonen anser som "blanks".

1. Celler som inneholder tekst , tall, datoer, logiske verdier, mellomrom eller feil telles ikke.
2. Celler som inneholder null regnes som ikke-tomme og telles ikke.
3. Celler som inneholder formler som returner tomme strenger ("") anses som tomme og telles.

Når du ser på skjermbildet ovenfor, legg merke til at celle A7 inneholder en formel som returnerer en tom streng telles to ganger:

• COUNTBLANK anser en null-lengde streng som en tom celle fordi den vises tom.
• COUNTA behandler en null-lengde streng som en ikke-tom celle fordi den faktisk inneholder en formel.

Det høres kanskje litt ulogisk ut, men Excel fungerer på denne måten :)

Hvordan telle tomme celler i Excel - formeleksempler

COUNTBLANK er det mest praktiske, men ikke på en enkel måte å telle tomme celler i Excel. Følgende eksempler viser noen få andre metoder og forklarer hvilken formel som er best å bruke i hvilket scenario.

Tell tomme celler i området med COUNTBLANK

Når du trenger å telle tomme i Excel, COUNTBLANK er den første funksjonen du prøver.

For eksempel, for å få antall tomme celler i hver rad i tabellen nedenfor, skriver vi innfølgende formel i F2:

=COUNTBLANK(A2:E2)

Når vi bruker relative referanser for området, kan vi ganske enkelt dra formelen ned og referansene justeres automatisk for hver rad, og gir følgende resultat:

Hvordan telle tomme celler i Excel ved å bruke COUNTIFS eller COUNTIFS

En annen måte å telle tomme celler i Excel er å bruke COUNTIF- eller COUNTIFS-funksjonen eller med en tom streng ("") som kriteriet.

I vårt tilfelle vil formlene være som følger:

=COUNTIF(B2:E2, "")

Eller

=COUNTIFS(B2:E2, "")

Som du kan se på skjermbildet nedenfor, er resultatene av COUNTIFS nøyaktig de samme som for COUNTBLANK, så hvilken formel du skal bruke i dette scenariet er et spørsmål om din personlige preferanse.

Telle tomme celler med betingelse

I en situasjon, når du ønsker å telle tomme celler basert på en tilstand, er COUNTIFS den riktige funksjonen å bruke, siden syntaksen sørger for flere kriterier .

For eksempel for å bestemme antall celler som har "epler" i kol. umn A og blanke felter i kolonne C, bruk denne formelen:

=COUNTIFS(A2:A9, "apples", C2:C9, "")

Eller skriv inn betingelsen i en forhåndsdefinert celle, si F1, og referer til den cellen som kriteriet:

=COUNTIFS(A2:A9, F1, C2:C9, "")

HVIS COUNTBLANK i Excel

I noen tilfeller må du kanskje ikke bare telle tomme celler i et område, men ta noen handlinger avhengig av om det er noen tomme celler eller ikke.

Selv om det ikke er innebygd IFCOUNTBLANK-funksjonen i Excel kan du enkelt lage din egen formel ved å bruke IF- og COUNTBLANK-funksjonene sammen. Slik gjør du det:

• Sjekk om antallet tomme felt er lik null og sett dette uttrykket i den logiske testen av IF:

  COUNTBLANK(B2:D2)=0

• Hvis den logiske testen evalueres til TRUE , utdata "Ingen blanks".
• Hvis den logiske testen evalueres til FALSE, utdata "Blanks".

Den komplette formelen har denne formen:

=IF(COUNTBLANK(B2:D2)=0, "No blanks", "Blanks")

Som et resultat identifiserer formelen alle radene der en eller flere verdier mangler:

Eller du kan kjøre en annen funksjon avhengig av antall tomme felter. For eksempel, hvis det ikke er tomme celler i området B2:D2 (dvs. hvis COUNTBLANK returnerer 0), summerer du verdiene, ellers returnerer du "Blanks":

=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")

Hvordan telle tomme rader i Excel

Anta at du har en tabell der noen rader inneholder informasjon mens andre rader er helt tomme. Spørsmålet er - hvordan får du antall rader som ikke inneholder noe i dem?

Den enkleste løsningen du tenker på er å legge til en hjelpekolonne og fylle den med Excel COUNTBLANK formelen som finner antall tomme celler i hver rad:

=COUNTBLANK(A2:E2)

Og bruk deretter COUNTIF-funksjonen for å finne ut i hvor mange rader alle cellene er tomme. Siden kildetabellen vår inneholder 5 kolonner (A til E), teller vi radene som har 5 tomme celler:

=COUNTIF(F2:F8, 5))

I stedet for"hardkoding" antall kolonner, kan du bruke COLUMNS-funksjonen til å beregne det automatisk:

=COUNTIF(F2:F8, COLUMNS(A2:E2))

Hvis du ikke vil mangle strukturen av det vakkert utformede regnearket ditt, kan du oppnå det samme resultatet med mye mer kompleks formel som imidlertid ikke krever noen hjelpekolonner eller til og med matriseinntasting:

=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))

Hvis du jobber fra innsiden og ut, er dette hva formelen gjør:

• Først sjekker du hele området for ikke-tomme celler ved å bruke uttrykket som A2:E8"", og tvinger deretter de returnerte logiske verdiene av TRUE og FALSE til 1-er og 0-er ved å bruke den doble unære operatoren (--). Resultatet av denne operasjonen er en todimensjonal matrise med enere (ikke-blanke) og nuller (blanke).
• Hensikten med ROW-delen er å generere en vertikal matrise med numerisk ikke-null. -verdier, der antall elementer er lik antall kolonner i området. I vårt tilfelle består området av 5 kolonner (A2:E8), så vi får denne matrisen: {1;2;3;4;5}
• MMULT-funksjonen beregner matriseproduktet av ovenstående matriser og gir et resultat som: {11;0;15;8;0;8;10}. I denne matrisen er det eneste som betyr noe for oss 0 verdier som representerer radene der alle cellene er tomme.
• Til slutt sammenligner du hvert element i oppstillingen ovenfor mot null, tvinger SANN og USANN til 1 og 0, og summer deretter elementene i denne finalenarray: {0;1;0;0;1;0;0}. Husk at 1-er tilsvarer tomme rader, får du ønsket resultat.

Hvis formelen ovenfor virker for vanskelig for deg å forstå, kan det hende du liker denne bedre:

=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))

Her bruker du funksjonen COUNTIF for å finne hvor mange ikke-blanke celler det er i hver rad, og INDIREKTE "mater" radene til COUNTIF en etter en. Resultatet av denne operasjonen er en matrise som {4;0;5;3;0;3;4}. En kontroll for 0, transformerer matrisen ovenfor til {0;1;0;0;1;0;0} der 1-er representerer tomme rader, så du trenger bare å legge dem sammen.

Tell virkelig tomme celler unntatt tomme strenger

I alle de foregående eksemplene teller vi tomme celler inkludert de som bare vises tomme, men som i virkeligheten inneholder tomme strenger ("") returnert av noen formler. I tilfelle du ønsker å ekskludere null-lengde strenger fra resultatet, kan du bruke denne generiske formelen:

Det formelen gjør er å multiplisere antall rader med antall kolonner for å få summen av celler i området, som du trekker fra antall ikke-blanke felt returnert av COUNTA . Som du kanskje husker, anser Excel COUNTA-funksjonen tomme strenger som ikke-tomme celler, så de vil ikke bli inkludert i det endelige resultatet.

For å finne ut hvor mange absolutt tomme celler det er i område A2:A8, her er formelen tilbruk:

=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)

Skjermbildet nedenfor viser resultatet:

Slik teller du tomme celler i Excel. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Tilgjengelige nedlastinger

Tell blanke celler formeleksempler