Bu eğitimde, Excel'deki boş hücrelerin sayısını saymak için COUNTBLANK işlevinin sözdizimi ve temel kullanımları ele alınmaktadır.

Son birkaç gönderide, Excel'de boş hücreleri tanımlamanın ve boşlukları vurgulamanın farklı yollarını tartıştık. Ancak bazı durumlarda, içinde hiçbir şey olmayan kaç hücre olduğunu bilmek isteyebilirsiniz. Microsoft Excel'in bunun için de özel bir işlevi vardır. Bu eğitimde, bir aralıktaki boş hücrelerin sayısını ve tamamen boş hücreleri elde etmenin en hızlı ve en uygun yöntemlerini göstereceğizSatırlar.

Excel COUNTBLANK işlevi

Excel'deki COUNTBLANK işlevi, belirli bir aralıktaki boş hücreleri saymak için tasarlanmıştır. İstatistiksel işlevler kategorisine aittir ve Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 ve Excel 2007 için Excel'in tüm sürümlerinde kullanılabilir.

Bu fonksiyonun söz dizimi çok basittir ve sadece bir argüman gerektirir:

Nerede aralık boşlukların sayılacağı hücre aralığıdır.

İşte en basit haliyle Excel'deki COUNTBLANK formülünün bir örneği:

=COUNTBLANK(A2:D2)

E2'ye girilen ve E7'ye kopyalanan formül, her satırdaki A'dan D'ye kadar olan sütunlarda bulunan boş hücrelerin sayısını belirler ve bu sonuçları döndürür:

İpucu. Saymak için boş olmayan Excel'deki hücreler için COUNTA işlevini kullanın.

COUNTBLANK fonksiyonu - Hatırlanması gereken 3 şey

Boş hücreleri saymaya yönelik bir Excel formülünü etkili bir şekilde kullanmak için, COUNTBLANK işlevinin hangi hücreleri "boşluk" olarak kabul ettiğini anlamak önemlidir.

1. Herhangi bir metin, sayı, tarih, mantıksal değer, boşluk veya hata içeren hücreler sayılmaz.
2. Aşağıdakileri içeren hücreler sıfırlar boş olmayan olarak kabul edilir ve sayılmaz.
3. Dönen formüller içeren hücreler boş dizeler ("") boş olarak kabul edilir ve sayılır.

Yukarıdaki ekran görüntüsüne bakıldığında, boş dize döndüren bir formül içeren A7 hücresinin iki kez sayıldığına lütfen dikkat edin:

• COUNTBLANK, boş göründüğü için sıfır uzunluklu bir dizeyi boş bir hücre olarak kabul eder.
• COUNTA, sıfır uzunluklu bir dizeyi boş olmayan bir hücre olarak değerlendirir çünkü aslında bir formül içerir.

Bu biraz mantıksız gelebilir, ancak Excel bu şekilde çalışır :)

Excel'de boş hücreler nasıl sayılır - formül örnekleri

COUNTBLANK Excel'de boş hücreleri saymanın en uygun ancak tek yolu değildir. Aşağıdaki örnekler diğer birkaç yöntemi gösterir ve hangi senaryoda hangi formülün kullanılmasının en iyi olduğunu açıklar.

COUNTBLANK ile aralıktaki boş hücreleri sayma

Excel'de boşlukları saymanız gerektiğinde, COUNTBLANK denenecek ilk işlevdir.

Örneğin, aşağıdaki tabloda her satırdaki boş hücre sayısını elde etmek için F2'ye aşağıdaki formülü giriyoruz:

=COUNTBLANK(A2:E2)

Aralık için göreli referanslar kullandığımızdan, formülü basitçe aşağı sürükleyebiliriz ve referanslar her satır için otomatik olarak ayarlanarak aşağıdaki sonucu üretir:

Excel'de COUNTIFS veya COUNTIF kullanarak boş hücreleri sayma

Excel'de boş hücreleri saymanın bir başka yolu da EĞERSAY veya EĞERSAY işlevini kullanmak veya ölçüt olarak boş bir dize ("") kullanmaktır.

Bizim durumumuzda formüller aşağıdaki gibi olacaktır:

=COUNTIF(B2:E2, "")

Ya da

=COUNTIFS(B2:E2, "")

Aşağıdaki ekran görüntüsünde görebileceğiniz gibi, COUNTIFS'in sonuçları COUNTBLANK'inkilerle tamamen aynıdır, bu nedenle bu senaryoda hangi formülün kullanılacağı kişisel tercihinize bağlıdır.

Koşullu boş hücreleri sayma

Bazı koşullara bağlı olarak boş hücreleri saymak istediğiniz bir durumda, sözdizimi aşağıdakileri sağladığı için COUNTIFS kullanılacak doğru fonksiyondur çoklu kriterler .

Örneğin, A sütununda "Elmalar" ve C sütununda boşluklar bulunan hücrelerin sayısını belirlemek için bu formülü kullanın:

=COUNTIFS(A2:A9, "apples", C2:C9, "")

Ya da koşulu önceden tanımlanmış bir hücreye, örneğin F1'e girin ve bu hücreye ölçüt olarak bakın:

=COUNTIFS(A2:A9, F1, C2:C9, "")

Excel'de EĞER COUNTBLANK

Bazı durumlarda, bir aralıktaki boş hücreleri saymakla kalmayıp, boş hücre olup olmamasına bağlı olarak bazı eylemler gerçekleştirmeniz gerekebilir.

Excel'de yerleşik IF COUNTBLANK işlevi olmamasına rağmen, IF ve COUNTBLANK işlevlerini birlikte kullanarak kendi formülünüzü kolayca oluşturabilirsiniz. İşte nasıl yapılacağı:

• Boşluk sayısının sıfıra eşit olup olmadığını kontrol edin ve bu ifadeyi IF mantıksal testine koyun:

  COUNTBLANK(B2:D2)=0

• Mantıksal test TRUE olarak değerlendirilirse, "No blanks" çıktısı verilir.
• Mantıksal test FALSE olarak değerlendirilirse, "Blanks" çıktısı verilir.

Tam formül bu şekli alır:

=IF(COUNTBLANK(B2:D2)=0, "Boşluk yok", "Boşluklar")

Sonuç olarak formül, bir veya daha fazla değerin eksik olduğu tüm satırları tanımlar:

Veya boşluk sayısına bağlı olarak başka bir işlev çalıştırabilirsiniz. Örneğin, B2:D2 aralığında boş hücre yoksa (yani COUNTBLANK 0 döndürürse), değerleri toplayın, aksi takdirde "Boşlar" döndürün:

=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")

Excel'de boş satırlar nasıl sayılır

Bazı satırların bilgi içerdiği, diğer satırların ise tamamen boş olduğu bir tablonuz olduğunu varsayalım. Soru şu: İçinde hiçbir şey içermeyen satırların sayısını nasıl elde edersiniz?

Akla gelen en kolay çözüm, bir yardımcı sütun eklemek ve bunu her satırdaki boş hücre sayısını bulan Excel COUNTBLANK formülü ile doldurmaktır:

=COUNTBLANK(A2:E2)

Ardından, tüm hücrelerin kaç satırda boş olduğunu bulmak için COUNTIF işlevini kullanın. Kaynak tablomuz 5 sütun (A'dan E'ye) içerdiğinden, 5 boş hücreye sahip satırları sayıyoruz:

=COUNTIF(F2:F8, 5))

Sütun sayısını "sabit kodlamak" yerine, otomatik olarak hesaplamak için COLUMNS işlevini kullanabilirsiniz:

=COUNTIF(F2:F8, COLUMNS(A2:E2))

Güzelce tasarlanmış çalışma sayfanızın yapısını bozmak istemiyorsanız, aynı sonucu çok daha karmaşık bir formülle elde edebilirsiniz, ancak bu formül herhangi bir yardımcı sütun veya hatta dizi girilmesini gerektirmez:

=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))

İçten dışa doğru çalışarak, işte formülün yaptığı şey:

• İlk olarak, A2:E8"" gibi bir ifade kullanarak boş olmayan hücreler için tüm aralığı kontrol eder ve ardından çift tekli işleci (--) kullanarak döndürülen DOĞRU ve YANLIŞ mantıksal değerlerini 1'lere ve 0'lara zorlarsınız. Bu işlemin sonucu, birler (boş olmayanlar) ve sıfırlardan (boşluklar) oluşan iki boyutlu bir dizidir.
• SATIR bölümünün amacı, dikey bir sayısal dizi oluşturmaktır sıfır olmayan eleman sayısının aralığın sütun sayısına eşit olduğu değerler. Bizim durumumuzda, aralık 5 sütundan (A2:E8) oluşur, bu nedenle şu diziyi elde ederiz: {1;2;3;4;5}
• MMULT fonksiyonu yukarıdaki dizilerin matris çarpımını hesaplar ve şöyle bir sonuç üretir: {11;0;15;8;0;8;10}. Bu dizide bizim için önemli olan tek şey, tüm hücrelerin boş olduğu satırları temsil eden 0 değerleridir.
• Son olarak, yukarıdaki dizinin her bir elemanını sıfırla karşılaştırır, TRUE ve FALSE değerlerini 1 ve 0'a zorlar ve ardından bu son dizinin elemanlarını toplarsınız: {0;1;0;0;1;0;0}. 1'lerin boş satırlara karşılık geldiğini akılda tutarak, istenen sonucu elde edersiniz.

Yukarıdaki formülü anlamak sizin için çok zor görünüyorsa, bunu daha çok sevebilirsiniz:

=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))

Burada, her satırda kaç tane boş olmayan hücre olduğunu bulmak için COUNTIF işlevini kullanırsınız ve INDIRECT satırları tek tek COUNTIF'e "besler." Bu işlemin sonucu {4;0;5;3;0;3;4} gibi bir dizidir. 0 için bir kontrol, yukarıdaki diziyi {0;1;0;0;1;0;0}'a dönüştürür, burada 1'ler boş satırları temsil eder, bu yüzden sadece bunları toplamanız gerekir.

Boş dizeler hariç gerçekten boş hücreleri sayın

Önceki tüm örneklerde, yalnızca boş görünen ancak gerçekte bazı formüller tarafından döndürülen boş dizeler ("") içerenler de dahil olmak üzere boş hücreleri sayıyorduk. Sıfır uzunluklu dizeleri sonuçtan hariç tutmak istemeniz durumunda, bu genel formülü kullanabilirsiniz:

Formülün yaptığı şey, aralıktaki hücrelerin toplamını elde etmek için satır sayısını sütun sayısıyla çarpmak ve COUNTA tarafından döndürülen boş olmayanların sayısını çıkarmaktır. Hatırlayabileceğiniz gibi, Excel COUNTA işlevi boş dizeleri boş olmayan hücreler olarak kabul eder, bu nedenle nihai sonuca dahil edilmezler.

Örneğin, A2:A8 aralığında kaç tane tamamen boş hücre olduğunu belirlemek için kullanılacak formül aşağıda verilmiştir:

=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)

Aşağıdaki ekran görüntüsü sonucu göstermektedir:

Excel'de boş hücreleri saymanın yolu budur. Okuduğunuz için teşekkür ediyor ve gelecek hafta blogumuzda görüşmeyi umuyorum!

Mevcut indirmeler

Boş hücreleri say formül örnekleri