Ուսուցումը քննարկում է COUNTBLANK ֆունկցիայի շարահյուսությունը և հիմնական օգտագործումը Excel-ում դատարկ բջիջների քանակը հաշվելու համար:

Մի քանի վերջին հրապարակումների ընթացքում մենք քննարկել ենք տարբեր եղանակներ բացահայտել դատարկ բջիջները և ընդգծել դատարկությունները Excel-ում: Որոշ իրավիճակներում, այնուամենայնիվ, դուք կարող եք ցանկանալ իմանալ, թե քանի բջիջ իրենց մեջ ոչինչ չունեն: Microsoft Excel-ն ունի նաև հատուկ գործառույթ դրա համար: Այս ձեռնարկը ձեզ ցույց կտա ամենաարագ և ամենահարմար մեթոդները՝ տիրույթում դատարկ բջիջների թիվը, ինչպես նաև բացարձակ դատարկ տողերը ստանալու համար:

Excel COUNTBLANK ֆունկցիան

The COUNTBLANK ֆունկցիան Excel-ում նախատեսված է դատարկ բջիջները հաշվելու համար նշված տիրույթում: Այն պատկանում է վիճակագրական գործառույթների կատեգորիային և հասանելի է Excel-ի բոլոր տարբերակներում Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 և Excel 2007:

Այս ֆունկցիայի շարահյուսությունը շատ պարզ է: և պահանջում է ընդամենը մեկ արգումենտ.

Որտեղ տիրույթը բջիջների այն տիրույթն է, որտեղ դատարկները պետք է հաշվվեն:

Ահա COUNTBLANK-ի օրինակ: բանաձևը Excel-ում իր ամենապարզ ձևով.

=COUNTBLANK(A2:D2)

Բանաձևը, որը մուտքագրվել է E2-ում և պատճենվել մինչև E7, որոշում է դատարկ բջիջների քանակը A-ից D սյունակներում յուրաքանչյուր տողում և վերադարձնում դրանք: արդյունքներ՝

Խորհուրդ. Excel-ում ոչ դատարկ բջիջները հաշվելու համար օգտագործեք COUNTA ֆունկցիան:

COUNTBLANK ֆունկցիա - 3ինչ պետք է հիշել

Excel-ի բանաձևն արդյունավետ օգտագործելու դատարկ բջիջները հաշվելու համար, կարևոր է հասկանալ, թե COUNTBLANK ֆունկցիան ինչ բջիջներ է համարում «դատարկ»:

1. Բջիջներ, որոնք պարունակում են ցանկացած տեքստ: , թվերը, ամսաթվերը, տրամաբանական արժեքները, բացատները կամ սխալները չեն հաշվվում:
2. զրո պարունակող բջիջները համարվում են ոչ դատարկ և չեն հաշվվում:
3. Բջիջները, որոնք պարունակում են բանաձևեր, որոնք վերադարձնել դատարկ տողերը ("") համարվում են դատարկ և հաշվվում են:

Նայելով վերևի սքրինշոթին, նկատեք, որ A7 բջիջը պարունակում է բանաձևը, որը վերադարձնում է դատարկ տողը, հաշվվում է երկու անգամ.

• COUNTBLANK-ը զրոյական երկարությամբ տողը համարում է դատարկ բջիջ, քանի որ այն դատարկ է թվում:
• COUNTA-ն վերաբերվում է զրոյական երկարությամբ տողին որպես ոչ դատարկ բջիջ, քանի որ այն իրականում պարունակում է բանաձև:

Դա կարող է մի փոքր անտրամաբանական թվալ, բայց Excel-ն այսպես է աշխատում :)

Ինչպես հաշվել դատարկ բջիջները Excel-ում - բանաձևի օրինակներ

COUNTBLANK-ը ամենահարմարն է, բայց ոչ միացվածը Excel-ում դատարկ բջիջները հաշվելու պարզ եղանակ: Հետևյալ օրինակները ցույց են տալիս մի քանի այլ մեթոդներ և բացատրում են, թե որ բանաձևը որ սցենարում է լավագույնս օգտագործելու համար:

Հաշվե՛ք տիրույթում դատարկ բջիջները COUNTBLANK-ով

Երբ որ Ձեզ անհրաժեշտ է հաշվել դատարկությունները Excel-ում, COUNTBLANK առաջին գործառույթն է, որը պետք է փորձել:

Օրինակ, ստորև բերված աղյուսակում յուրաքանչյուր տողում դատարկ բջիջների քանակը ստանալու համար մենք մուտքագրում ենքF2-ում հետևյալ բանաձևը.

=COUNTBLANK(A2:E2)

Քանի որ մենք օգտագործում ենք հարաբերական հղումներ տիրույթի համար, մենք կարող ենք պարզապես քաշել բանաձևը ներքև, և հղումները ավտոմատ կերպով կկարգավորվեն յուրաքանչյուր տողի համար՝ ստանալով հետևյալ արդյունքը. 3>

Ինչպես հաշվել դատարկ բջիջները Excel-ում՝ օգտագործելով COUNTIFS կամ COUNTIF

Excel-ում դատարկ բջիջները հաշվելու մեկ այլ եղանակ է օգտագործել COUNTIF կամ COUNTIFS ֆունկցիան կամ դատարկ տողը ("") որպես չափանիշ:

Մեր դեպքում բանաձևերը կլինեն հետևյալը.

=COUNTIF(B2:E2, "")

Կամ

=COUNTIFS(B2:E2, "")

Ինչպես տեսնում եք ստորև ներկայացված սքրինշոթում, COUNTIFS-ի արդյունքները ճիշտ նույնն են, ինչ COUNTBLANK-ի արդյունքները, ուստի այս սցենարում որ բանաձևն օգտագործելը ձեր անձնական նախասիրության հարցն է:

Հաշվել դատարկ բջիջները պայմանով

Այն իրավիճակում, երբ ցանկանում եք հաշվել դատարկ բջիջները՝ հիմնվելով ինչ-որ պայմանի վրա, COUNTIFS-ը ճիշտ ֆունկցիան է, որը պետք է օգտագործել, քանի որ դրա շարահյուսությունը նախատեսում է բազմաթիվ: չափանիշներ .

Օրինակ՝ որոշել բջիջների թիվը, որոնք ունեն «Apple» սյունակում umn A և C սյունակի դատարկ տեղերը, օգտագործեք այս բանաձևը.

=COUNTIFS(A2:A9, "apples", C2:C9, "")

Կամ մուտքագրեք պայմանը նախապես սահմանված բջիջում, ասենք F1, և նշեք այդ բջիջը որպես չափանիշ. 0> =COUNTIFS(A2:A9, F1, C2:C9, "")

IF COUNTBLANK Excel-ում

Որոշ դեպքերում ձեզ կարող է անհրաժեշտ լինել ոչ միայն հաշվել տիրույթի դատարկ բջիջները, այլ նաև որոշակի գործողություններ կատարել՝ կախված նրանից. արդյոք կան դատարկ բջիջներ, թե ոչ:

Չնայած չկա ներկառուցված IFCOUNTBLANK ֆունկցիա Excel-ում, դուք հեշտությամբ կարող եք ստեղծել ձեր սեփական բանաձևը՝ օգտագործելով IF և COUNTBLANK ֆունկցիաները միասին: Ահա թե ինչպես.

• Ստուգեք, արդյոք դատարկ տեղերի քանակը հավասար է զրոյի և դրեք այս արտահայտությունը IF-ի տրամաբանական թեստում.

  COUNTBLANK(B2:D2)=0

• Եթե տրամաբանական թեստը գնահատվում է TRUE: , թողարկեք «Ոչ մի դատարկ»:
• Եթե տրամաբանական թեստը գնահատվում է FALSE, ապա թողարկեք «Blanks»:

Ամբողջական բանաձևը ստանում է հետևյալ ձևը.

=IF(COUNTBLANK(B2:D2)=0, "No blanks", "Blanks")

Արդյունքում բանաձևը նույնացնում է բոլոր այն տողերը, որտեղ բացակայում են մեկ կամ մի քանի արժեքներ.

Կամ կարող եք գործարկել մեկ այլ ֆունկցիա՝ կախված դատարկ տեղերի քանակից: Օրինակ, եթե B2:D2 միջակայքում դատարկ բջիջներ չկան (այսինքն, եթե COUNTBLANK-ը վերադարձնում է 0), ապա գումարեք արժեքները, հակառակ դեպքում վերադարձրեք «Blanks»:

=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")

Ինչպես հաշվել դատարկ տողերը Excel-ում

Ենթադրենք, որ դուք ունեք աղյուսակ, որտեղ որոշ տողեր պարունակում են տեղեկատվություն, մինչդեռ մյուս տողերը լիովին դատարկ են: Հարցն այն է, թե ինչպե՞ս եք ստանում տողերի թիվը, որոնք իրենց մեջ ոչինչ չեն պարունակում:

Ամենահեշտ լուծումը, որ գալիս է ձեր մտքին, օգնական սյունակ ավելացնելն է և այն լրացնել Excel COUNTBLANK բանաձևով, որը գտնում է յուրաքանչյուր տողում դատարկ բջիջների թիվը՝

=COUNTBLANK(A2:E2)

Եվ այնուհետև օգտագործեք COUNTIF ֆունկցիան՝ պարզելու, թե քանի տողում են բոլոր բջիջները դատարկ: Քանի որ մեր սկզբնաղբյուր աղյուսակը պարունակում է 5 սյունակ (A-ից E), մենք հաշվում ենք այն տողերը, որոնք ունեն 5 դատարկ բջիջ.

=COUNTIF(F2:F8, 5))

Փոխարենը.«կոշտ կոդավորելով» սյունակների քանակը, կարող եք օգտագործել COLUMNS ֆունկցիան՝ այն ավտոմատ կերպով հաշվարկելու համար.

=COUNTIF(F2:F8, COLUMNS(A2:E2))

Եթե չեք ցանկանում խեղաթյուրել կառուցվածքը: Ձեր գեղեցիկ ձևավորված աշխատաթերթից դուք կարող եք նույն արդյունքին հասնել շատ ավելի բարդ բանաձևով, որը, սակայն, չի պահանջում որևէ օգնական սյունակ կամ նույնիսկ զանգվածի մուտքագրում.

=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))

Աշխատելով ներսից դուրս, ահա թե ինչ է անում բանաձևը.

• Սկզբում դուք ստուգում եք ամբողջ տիրույթը ոչ դատարկ բջիջների համար՝ օգտագործելով A2:E8» արտահայտությունը, այնուհետև հարկադրել TRUE-ի և FALSE-ի տրամաբանական արժեքները վերադարձվել են 1-ի և 0-ի՝ օգտագործելով կրկնակի ունարային օպերատորը (--): Այս գործողության արդյունքը միերի (ոչ դատարկ) և զրոների (դատարկ) երկչափ զանգված է:
• ROW մասի նպատակն է ստեղծել ոչ զրոյական թվային ուղղահայաց զանգված: արժեքներ, որոնցում տարրերի թիվը հավասար է տիրույթի սյունակների թվին: Մեր դեպքում միջակայքը բաղկացած է 5 սյունակից (A2:E8), ուստի մենք ստանում ենք այս զանգվածը՝ {1;2;3;4;5}
• MMULT ֆունկցիան հաշվարկում է վերը նշված զանգվածների մատրիցային արտադրյալը և առաջացնում է այնպիսի արդյունք, ինչպիսին է՝ {11;0;15;8;0;8;10}: Այս զանգվածում միակ բանը, որ կարևոր է մեզ համար 0 արժեքներն են, որոնք ներկայացնում են այն տողերը, որտեղ բոլոր բջիջները դատարկ են:
• Վերջապես, դուք համեմատում եք վերը նշված զանգվածի յուրաքանչյուր տարր զրոյի հետ, հարկադրում եք TRUE և FALSE 1-ին և 0, այնուհետև գումարեք այս եզրափակիչի տարրերըզանգված՝ {0;1;0;0;1;0;0}: Նկատի ունենալով, որ 1-ը համապատասխանում է դատարկ տողերին, դուք ստանում եք ցանկալի արդյունքը:

Եթե վերը նշված բանաձևը ձեզ համար չափազանց դժվար է ընկալել, կարող է ձեզ ավելի լավ դուր գալ հետևյալը.

=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))

Այստեղ դուք օգտագործում եք COUNTIF ֆունկցիան՝ գտնելու համար, թե քանի ոչ դատարկ բջիջ կա յուրաքանչյուր տողում, և INDIRECT-ը տողերը մեկ առ մեկ «սնում է» COUNTIF-ին: Այս գործողության արդյունքը {4;0;5;3;0;3;4} նման զանգված է: 0-ի ստուգումը վերը նշված զանգվածը վերածում է {0;1;0;0;1;0;0}-ի, որտեղ 1-ը ներկայացնում է դատարկ տողեր, այնպես որ դուք պարզապես պետք է դրանք գումարեք:

Հաշվե՛ք իսկական դատարկ բջիջները: բացառելով դատարկ տողերը

Բոլոր նախորդ օրինակներում մենք հաշվում էինք դատարկ բջիջները, ներառյալ նրանք, որոնք միայն դատարկ են թվում, բայց իրականում պարունակում են դատարկ տողեր (""), որոնք վերադարձվել են որոշ բանաձևերով: Եթե ​​ցանկանում եք բացառել զրոյական երկարությամբ տողերը արդյունքից, կարող եք օգտագործել այս ընդհանուր բանաձևը՝

Այն, ինչ անում է բանաձևը, տողերի քանակը բազմապատկելն է սյունակների քանակով, որպեսզի ստացվի միջակայքի բջիջների ընդհանուր թիվը, որից հանում եք վերադարձված ոչ դատարկ տողերի քանակը COUNTA-ով: . Ինչպես հիշում եք, Excel COUNTA ֆունկցիան դատարկ տողերը համարում է ոչ դատարկ բջիջներ, ուստի դրանք չեն ներառվի վերջնական արդյունքում:

Օրինակ՝ որոշելու համար, թե բացարձակապես քանի դատարկ բջիջ կա A2:A8 միջակայք, ահա բանաձևըօգտագործել՝

=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)

Սքրինշոթը ստորև ցույց է տալիս արդյունքը.

Այսպես կարելի է հաշվել դատարկ բջիջները Excel-ում: Շնորհակալ եմ կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Հասանելի ներբեռնումներ

Հաշվե՛ք դատարկ բջիջների բանաձևի օրինակները