Tinatalakay ng tutorial ang syntax at mga pangunahing gamit ng COUNTBLANK function upang mabilang ang bilang ng mga blangkong cell sa Excel.

Sa ilang kamakailang post, tinalakay namin ang iba't ibang paraan upang matukoy ang mga blangkong cell at i-highlight ang mga blangko sa Excel. Sa ilang mga sitwasyon, gayunpaman, maaaring gusto mong malaman kung gaano karaming mga cell ang walang anumang bagay sa kanila. Ang Microsoft Excel ay may espesyal na function para din dito. Ipapakita sa iyo ng tutorial na ito ang pinakamabilis at pinaka-maginhawang paraan upang makuha ang bilang ng mga walang laman na cell sa isang hanay pati na rin ang mga blangko na hanay.

Excel COUNTBLANK function

Ang Ang function na COUNTBLANK sa Excel ay idinisenyo upang mabilang ang mga walang laman na cell sa isang tinukoy na hanay. Nabibilang ito sa kategorya ng mga Statistical function at available sa lahat ng bersyon ng Excel para sa Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, at Excel 2007.

Napakasimple ng syntax ng function na ito at nangangailangan lamang ng isang argument:

Kung saan ang range ay ang hanay ng mga cell kung saan bibilangin ang mga blangko.

Narito ang isang halimbawa ng COUNTBLANK formula sa Excel sa pinakasimpleng anyo nito:

=COUNTBLANK(A2:D2)

Ang formula, na inilagay sa E2 at kinopya pababa sa E7, ay tumutukoy sa bilang ng mga walang laman na cell sa column A hanggang D sa bawat row at ibinabalik ang mga ito mga resulta:

Tip. Upang mabilang ang hindi blangko na mga cell sa Excel, gamitin ang COUNTA function.

COUNTBLANK function - 3mga bagay na dapat tandaan

Upang epektibong gumamit ng Excel formula para sa pagbibilang ng mga blangkong cell, mahalagang maunawaan kung anong mga cell ang itinuturing ng COUNTBLANK function bilang "mga blangko".

1. Mga cell na naglalaman ng anumang text , mga numero, petsa, lohikal na halaga, espasyo o error ay hindi binibilang.
2. Ang mga cell na naglalaman ng zero ay itinuturing na hindi blangko at hindi binibilang.
3. Ang mga cell na naglalaman ng mga formula na ibalik ang mga walang laman na string ("") ay itinuturing na blangko at binibilang.

Pagtingin sa screenshot sa itaas, pakipansin na naglalaman ang cell A7 ang isang formula na nagbabalik ng walang laman na string ay binibilang nang dalawang beses:

• Itinuturing ng COUNTBLANK ang isang zero-length na string bilang isang walang laman na cell dahil lumilitaw itong blangko.
• Tinatrato ng COUNTA ang isang zero-length na string bilang isang hindi walang laman na cell dahil naglalaman talaga ito ng formula.

Maaaring medyo hindi makatwiran iyon, ngunit gumagana ang Excel sa ganitong paraan :)

Paano magbilang ng mga blangkong cell sa Excel - mga halimbawa ng formula

COUNTBLANK ang pinaka-maginhawa ngunit hindi ang on ly paraan upang mabilang ang mga walang laman na cell sa Excel. Ang mga sumusunod na halimbawa ay nagpapakita ng ilang iba pang mga pamamaraan at ipinapaliwanag kung aling formula ang pinakamahusay na gagamitin sa kung aling sitwasyon.

Bilangin ang mga blangkong cell na nasa hanay gamit ang COUNTBLANK

Sa tuwing kailangan mong magbilang ng mga blangko sa Excel, COUNTBLANK ay ang unang function na susubukan.

Halimbawa, upang makuha ang bilang ng mga walang laman na cell sa bawat hilera sa talahanayan sa ibaba, ipinasok namin angsumusunod na formula sa F2:

=COUNTBLANK(A2:E2)

Habang gumagamit kami ng mga kaugnay na sanggunian para sa hanay, maaari naming i-drag lang ang formula pababa at ang mga sanggunian ay awtomatikong magsasaayos para sa bawat hilera, na magbubunga ng sumusunod na resulta:

Paano magbilang ng mga blangkong cell sa Excel gamit ang COUNTIFS o COUNTIF

Ang isa pang paraan upang mabilang ang mga walang laman na cell sa Excel ay ang paggamit ng COUNTIF o COUNTIFS function o gamit ang isang walang laman na string ("") bilang pamantayan.

Sa aming kaso, magiging ganito ang mga formula:

=COUNTIF(B2:E2, "")

O

=COUNTIFS(B2:E2, "")

Tulad ng nakikita mo sa screenshot sa ibaba, ang mga resulta ng COUNTIFS ay eksaktong kapareho ng mga resulta ng COUNTBLANK, kaya kung aling formula ang gagamitin sa sitwasyong ito ay isang bagay sa iyong personal na kagustuhan.

Bilangin ang mga blangkong cell na may kundisyon

Sa isang sitwasyon, kapag gusto mong magbilang ng mga walang laman na cell batay sa ilang kundisyon, ang COUNTIFS ay ang tamang function na gagamitin dahil ang syntax nito ay nagbibigay para sa marami pamantayan .

Halimbawa, upang matukoy ang bilang ng mga cell na mayroong "Mansanas" sa col umn A at mga blangko sa column C, gamitin ang formula na ito:

=COUNTIFS(A2:A9, "apples", C2:C9, "")

O ipasok ang kundisyon sa isang paunang natukoy na cell, sabihin ang F1, at tukuyin ang cell na iyon bilang pamantayan:

=COUNTIFS(A2:A9, F1, C2:C9, "")

KUNG COUNTBLANK sa Excel

Sa ilang sitwasyon, maaaring hindi mo lang bilangin ang mga blangkong cell sa isang hanay, ngunit gumawa ng ilang pagkilos depende sa kung mayroong anumang mga cell na walang laman o wala.

Bagaman walang built-in na IFCOUNTBLANK function sa Excel, madali kang makakagawa ng sarili mong formula sa pamamagitan ng paggamit ng IF at COUNTBLANK function nang magkasama. Ganito:

• Tingnan kung ang bilang ng mga blangko ay katumbas ng zero at ilagay ang expression na ito sa lohikal na pagsubok ng IF:

  COUNTBLANK(B2:D2)=0

• Kung ang lohikal na pagsubok ay nagsusuri sa TRUE , output "Walang mga blangko".
• Kung ang lohikal na pagsubok ay mag-evaluate sa FALSE, i-output ang "Blanks".

Ang kumpletong formula ay ganito ang hugis:

=IF(COUNTBLANK(B2:D2)=0, "No blanks", "Blanks")

Bilang resulta, tinutukoy ng formula ang lahat ng row kung saan nawawala ang isa o higit pang mga value:

O maaari kang magpatakbo ng isa pang function depende sa bilang ng mga blangko. Halimbawa, kung walang mga cell na walang laman sa hanay na B2:D2 (ibig sabihin, kung ang COUNTBLANK ay nagbabalik ng 0), pagkatapos ay isama ang mga halaga, kung hindi, ibalik ang "Mga Blangko":

=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")

Paano magbilang ng mga blangkong row sa Excel

Ipagpalagay na mayroon kang talahanayan kung saan ang ilang mga row ay naglalaman ng impormasyon habang ang ibang mga row ay ganap na blangko. Ang tanong ay - paano mo makukuha ang bilang ng mga row na walang anumang nilalaman sa mga ito?

Ang pinakamadaling solusyon na naiisip ay magdagdag ng helper column at punan ito ng Excel COUNTBLANK formula na nakakahanap ng bilang ng mga blangkong cell sa bawat row:

=COUNTBLANK(A2:E2)

At pagkatapos, gamitin ang COUNTIF function upang malaman kung ilang row ang lahat ng cell ay blangko. Dahil ang aming source table ay naglalaman ng 5 column (A hanggang E), binibilang namin ang mga row na mayroong 5 walang laman na cell:

=COUNTIF(F2:F8, 5))

Sa halip na"hardcoding" ang bilang ng mga column, maaari mong gamitin ang COLUMNS function para awtomatikong kalkulahin ito:

=COUNTIF(F2:F8, COLUMNS(A2:E2))

Kung ayaw mong masira ang istraktura ng iyong worksheet na maganda ang disenyo, makakamit mo ang parehong resulta na may mas kumplikadong formula na hindi nangangailangan ng anumang helper column o kahit na array na pumapasok sa:

=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))

Paggawa mula sa loob palabas, narito kung ano ang ginagawa ng formula:

• Una, suriin mo ang buong hanay para sa mga di-blangko na mga cell sa pamamagitan ng paggamit ng expression tulad ng A2:E8"", at pagkatapos ay pilitin ang ibinalik na lohikal na halaga ng TRUE at FALSE sa 1's at 0's sa pamamagitan ng paggamit ng double unary operator (--). Ang resulta ng operasyong ito ay isang dalawang-dimensional na hanay ng mga (hindi blangko) at mga sero (mga blangko).
• Ang layunin ng bahaging ROW ay bumuo ng patayong hanay ng mga numero hindi zero. na mga halaga, kung saan ang bilang ng mga elemento ay katumbas ng bilang ng mga column ng hanay. Sa aming kaso, ang hanay ay binubuo ng 5 column (A2:E8), kaya nakuha namin ang array na ito: {1;2;3;4;5}
• Kinakalkula ng MMULT function ang matrix product ng mga array sa itaas at gumagawa ng resulta tulad ng: {11;0;15;8;0;8;10}. Sa array na ito, ang tanging bagay na mahalaga para sa amin ay 0 value na kumakatawan sa mga row kung saan blangko ang lahat ng cell.
• Sa wakas, ihahambing mo ang bawat elemento ng array sa itaas laban sa zero, pilitin ang TRUE at FALSE sa 1 at 0, at pagkatapos ay buuin ang mga elemento ng panghuling itoarray: {0;1;0;0;1;0;0}. Tandaan na ang 1 ay tumutugma sa mga blangkong row, makukuha mo ang ninanais na resulta.

Kung ang formula sa itaas ay mukhang napakahirap para sa iyo na maunawaan, maaaring mas gusto mo ang isang ito:

=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))

Dito, ginagamit mo ang function na COUNTIF para malaman kung gaano karaming mga cell na hindi blangko ang nasa bawat row, at isa-isang "pinapakain" ng INDIRECT ang mga row sa COUNTIF. Ang resulta ng operasyong ito ay isang array tulad ng {4;0;5;3;0;3;4}. Ang isang tseke para sa 0, ay binabago ang array sa itaas sa {0;1;0;0;1;0;0} kung saan ang 1 ay kumakatawan sa mga blangkong row, kaya kailangan mo lang silang idagdag.

Bilangin ang tunay na mga blangkong cell hindi kasama ang mga walang laman na string

Sa lahat ng nakaraang halimbawa, binibilang namin ang mga blangkong cell kasama ang mga lalabas lang na blangko ngunit, sa katotohanan, naglalaman ng mga walang laman na string ("") na ibinalik ng ilang formula. Kung sakaling gusto mong ibukod ang mga zero-length na string mula sa resulta, maaari mong gamitin ang generic na formula na ito:

Ang ginagawa ng formula ay paramihin ang bilang ng mga row sa bilang ng mga column para makuha ang kabuuang mga cell sa range, kung saan mo ibabawas ang bilang ng mga hindi blangko na ibinalik ng COUNTA . Tulad ng natatandaan mo, ang Excel COUNTA function ay isinasaalang-alang ang mga walang laman na string bilang hindi blangko na mga cell, kaya hindi sila isasama sa huling resulta.

Halimbawa, upang matukoy kung gaano karaming ganap na walang laman na mga cell ang mayroon sa range A2:A8, narito ang formula sagamitin ang:

=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)

Ipinapakita ng screenshot sa ibaba ang resulta:

Ganyan ang pagbilang ng mga walang laman na cell sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

Bilangin ang mga halimbawa ng formula ng mga blank cell