Содржина
Во упатството се дискутира за синтаксата и основните употреби на функцијата COUNTBLANK за броење на бројот на празни ќелии во Excel.
Во неколку неодамнешни објави, разговаравме за различни начини да се идентификуваат празни ќелии и да се означат празнините во Excel. Меѓутоа, во некои ситуации, можеби ќе сакате да знаете колку клетки немаат ништо во нив. Microsoft Excel има посебна функција и за ова. Овој туторијал ќе ви ги покаже најбрзите и најзгодните методи за да го добиете бројот на празни ќелии во опсегот, како и целосно празни редови.
Функција COUNTBLANK на Excel
Функцијата COUNTBLANK во Excel е дизајнирана да брои празни ќелии во одреден опсег. Припаѓа на категоријата статистички функции и е достапна во сите верзии на Excel за Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 и Excel 2007.
Синтаксата на оваа функција е многу јасна и бара само еден аргумент:
COUNTBLANK(опсег)Каде што опсег е опсегот на ќелиите во кои треба да се бројат празнините.
Еве пример за COUNTBLANK формулата во Excel во нејзината наједноставна форма:
=COUNTBLANK(A2:D2)
Формулата, внесена во E2 и копирана на E7, го одредува бројот на празни ќелии во колоните A до D во секој ред и ги враќа овие резултати:
Совет. За да броите непразни ќелии во Excel, користете ја функцијата COUNTA.
COUNTBLANK функција - 3работи што треба да се запамети
За ефикасно користење на формулата на Excel за броење празни ќелии, важно е да разберете кои ќелии функцијата COUNTBLANK ги смета за „празни“.
- Ќелиите што содржат каков било текст , броевите, датумите, логичките вредности, празни места или грешки не се бројат.
- Клетките што содржат нули се сметаат за непразни и не се бројат.
- Клетките што содржат формули кои врати празни низи ("") се сметаат за празни и се бројат.
Гледајќи ја горната слика од екранот, забележете дека ќелијата А7 содржи формулата што враќа празна низа се брои двапати:
- COUNTBLANK ја смета низата со нулта должина како празна ќелија бидејќи се чини празна.
- COUNTA ја третира низата со нулта должина како непразна ќелија затоа што всушност содржи формула.
Тоа можеби звучи малку нелогично, но Excel функционира на овој начин :)
Како да ги броите празните ќелии во Excel - примери на формула
COUNTBLANK е најзгодно, но не и вклучено Лесен начин за броење празни ќелии во Excel. Следниве примери покажуваат неколку други методи и објаснуваат која формула е најдобро да се користи во кое сценарио.
Бротајте ги празните ќелии во опсегот со COUNTBLANK
Секогаш кога треба да броите празни места во Excel, COUNTBLANK е првата функција што треба да се обиде.
На пример, за да го добиеме бројот на празни ќелии во секој ред во табелата подолу, внесувамеследнава формула во F2:
=COUNTBLANK(A2:E2)
Како што користиме релативни референци за опсегот, едноставно можеме да ја повлечеме формулата надолу и референците автоматски ќе се приспособат за секој ред, давајќи го следниов резултат:
Како да броите празни ќелии во Excel користејќи COUNTIFS или COUNTIF
Друг начин за броење празни ќелии во Excel е да ја користите функцијата COUNTIF или COUNTIFS или со празна низа ("") како критериум.
Во нашиот случај, формулите ќе одат на следниов начин:
=COUNTIF(B2:E2, "")
Или
=COUNTIFS(B2:E2, "")
Како што можете да видите на сликата од екранот подолу, резултатите од COUNTIFS се сосема исти како оние на COUNTBLANK, така што која формула да се користи во ова сценарио е прашање на ваш личен избор.
Брои празни ќелии со услов
Во ситуација, кога сакате да броите празни ќелии врз основа на некој услов, COUNTIFS е вистинската функција што треба да се користи бидејќи нејзината синтакса предвидува повеќе критериуми .
На пример, да се одреди бројот на ќелии кои имаат „Јаболка“ во колоната umn A и празни места во колоната C, користете ја оваа формула:
=COUNTIFS(A2:A9, "apples", C2:C9, "")
Или внесете ја состојбата во претходно дефинирана ќелија, да речете F1, и означете ја таа ќелија како критериуми:
=COUNTIFS(A2:A9, F1, C2:C9, "")
IF COUNTBLANK во Excel
Во некои случаи, можеби ќе треба не само да броите празни ќелии во опсегот, туку да преземете некои активности во зависност од дали има празни ќелии или не.
Иако нема вградено IFФункција COUNTBLANK во Excel, можете лесно да направите своја формула користејќи ги заедно функциите IF и COUNTBLANK. Еве како:
- Проверете дали бројот на празни места е еднаков на нула и ставете го овој израз во логичкиот тест на IF:
COUNTBLANK(B2:D2)=0 - Ако логичкиот тест се оцени како TRUE , излез „Без празни места“.
- Ако логичкиот тест се процени на FALSE, излез „Blanks“.
Целосната формула ја има оваа форма:
=IF(COUNTBLANK(B2:D2)=0, "No blanks", "Blanks")
Како резултат, формулата ги идентификува сите редови каде што недостасуваат една или повеќе вредности:
Или можете да извршите друга функција во зависност од бројот на празни места. На пример, ако нема празни ќелии во опсегот B2:D2 (т.е. ако COUNTBLANK врати 0), тогаш сумирајте ги вредностите, инаку вратете „Blanks“:
=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")
Како да броите празни редови во Excel
Да претпоставиме дека имате табела во која некои редови содржат информации додека другите редови се целосно празни. Прашањето е - како да го добиете бројот на редови кои не содржат ништо во нив?
Најлесно решение што ви паѓа на ум е да додадете помошна колона и да ја пополните со формулата Excel COUNTBLANK која ја наоѓа број на празни ќелии во секој ред:
=COUNTBLANK(A2:E2)
И потоа, користете ја функцијата COUNTIF за да дознаете во колку редови сите ќелии се празни. Бидејќи нашата изворна табела содржи 5 колони (А до Е), ги броиме редовите што имаат 5 празни ќелии:
=COUNTIF(F2:F8, 5))
Наместо„хардкодирање“ на бројот на колони, можете да ја користите функцијата COLUMNS за да го пресметате автоматски:
=COUNTIF(F2:F8, COLUMNS(A2:E2))
Ако не сакате да ја извалкате структурата од вашиот прекрасно дизајниран работен лист, можете да го постигнете истиот резултат со многу покомплексна формула која сепак не бара помошни колони, ниту пак внесување низа:
=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))
Работејќи од внатре кон надвор, еве што прави формулата:
- Прво, го проверувате целиот опсег за непразни ќелии со користење на изразот како A2:E8““, а потоа принудете вратените логички вредности на TRUE и FALSE на 1 и 0 со користење на двојниот унарен оператор (--). Резултатот од оваа операција е дводимензионална низа од единици (не-празни) и нули (празни).
- Целта на делот ROW е да генерира вертикална низа од нумерички не-нула вредности, во кои бројот на елементи е еднаков на бројот на колони од опсегот. Во нашиот случај, опсегот се состои од 5 колони (A2:E8), така што ја добиваме оваа низа: {1;2;3;4;5}
- Функцијата MMULT го пресметува матричниот производ на горенаведените низи и произведува резултат како: {11;0;15;8;0;8;10}. Во оваа низа, единственото нешто што е важно за нас е 0 вредности кои ги претставуваат редовите каде што сите ќелии се празни.
- На крајот, го споредувате секој елемент од горната низа со нула, принудете TRUE и FALSE на 1 и 0, а потоа сумирајте ги елементите на ова финалениза: {0;1;0;0;1;0;0}. Имајќи предвид дека 1 одговара на празните редови, го добивате посакуваниот резултат.
Ако горната формула ви изгледа премногу тешка за разбирање, можеби ќе ви се допадне оваа повеќе:
=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))
Овде, ја користите функцијата COUNTIF за да откриете колку непразни ќелии има во секој ред, а INDIRECT ги „храни“ редовите на COUNTIF еден по еден. Резултатот од оваа операција е низа како {4;0;5;3;0;3;4}. Проверка за 0, ја трансформира горната низа во {0;1;0;0;1;0;0} каде што 1 претставува празни редови, така што треба само да ги соберете.
Бротајте вистински празни ќелии со исклучок на празни низи
Во сите претходни примери, ги броевме празните ќелии, вклучувајќи ги и оние што се појавуваат само празни, но, во реалноста, содржат празни низи („“) вратени со некои формули. Во случај да сакате да ги исклучите низите со нулта должина од резултатот, можете да ја користите оваа генеричка формула:
ROWS( опсег) * COLUMNS( опсег) - COUNTA( опсег)Она што го прави формулата е да се множи бројот на редови со бројот на колони за да се добие вкупниот број на ќелии во опсегот, од кои го одземате бројот на не-празни вратени со COUNTA . Како што се сеќавате, функцијата Excel COUNTA ги смета празните низи како непразни ќелии, така што тие нема да бидат вклучени во конечниот резултат.
На пример, за да се одреди колку апсолутно празни ќелии има во опсег A2:A8, еве ја формулата закористете:
=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)
На сликата подолу е прикажан резултатот:
Така се брои празните ќелии во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!
Достапни преземања
Бротајте ги празните ќелии примери на формула
