Tutoriali diskuton sintaksën dhe përdorimet bazë të funksionit COUNTBLANK për të numëruar numrin e qelizave bosh në Excel.

Në disa postime të fundit, ne kemi diskutuar mënyra të ndryshme për të identifikuar qelizat bosh dhe për të theksuar boshllëqet në Excel. Në disa situata, megjithatë, mund të dëshironi të dini se sa qeliza nuk kanë asgjë në to. Microsoft Excel ka një funksion të veçantë edhe për këtë. Ky tutorial do t'ju tregojë metodat më të shpejta dhe më të përshtatshme për të marrë numrin e qelizave boshe në një gamë, si dhe rreshtat plotësisht bosh.

Funksioni COUNTBLANK i Excel

Funksioni Funksioni COUNTBLANK në Excel është krijuar për të numëruar qelizat boshe në një interval të caktuar. Ai i përket kategorisë së funksioneve statistikore dhe është i disponueshëm në të gjitha versionet e Excel për Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 dhe Excel 2007.

Sintaksa e këtij funksioni është shumë e drejtpërdrejtë dhe kërkon vetëm një argument:

Ku vargu është diapazoni i qelizave në të cilat do të numërohen boshllëqet.

Këtu është një shembull i COUNTBLANK formula në Excel në formën e saj më të thjeshtë:

=COUNTBLANK(A2:D2)

Formula, e futur në E2 dhe e kopjuar në E7, përcakton numrin e qelizave boshe në kolonat A deri në D në çdo rresht dhe i kthen këto rezultatet:

Këshillë. Për të numëruar qelizat jo bosh në Excel, përdorni funksionin COUNTA.

Funksioni COUNTBLANK - 3gjëra për të mbajtur mend

Për të përdorur në mënyrë efektive një formulë Excel për numërimin e qelizave bosh, është e rëndësishme të kuptoni se cilat qeliza i konsideron funksioni COUNTBLANK si "bosh".

1. Qelizat që përmbajnë çdo tekst , numrat, datat, vlerat logjike, hapësirat ose gabimet nuk numërohen.
2. Qelizat që përmbajnë zero konsiderohen jo bosh dhe nuk numërohen.
3. Qelizat që përmbajnë formula që ktheni vargjet boshe ("") konsiderohen bosh dhe numërohen.

Duke parë pamjen e mësipërme, vini re se qeliza A7 përmban një formulë që kthen një varg bosh numërohet dy herë:

• COUNTBLANK konsideron një varg me gjatësi zero si një qelizë bosh sepse duket bosh.
• COUNTA trajton një varg me gjatësi zero si një qelizë jo bosh sepse në të vërtetë përmban një formulë.

Kjo mund të tingëllojë paksa e palogjikshme, por Excel funksionon në këtë mënyrë :)

Si të numërohen qelizat bosh në Excel - shembuj formule

COUNTBLANK është më i përshtatshmi, por jo i ndezur Mënyra më e mirë për të numëruar qelizat boshe në Excel. Shembujt e mëposhtëm demonstrojnë disa metoda të tjera dhe shpjegojnë se cila formulë është më e mirë për t'u përdorur në cilin skenar.

Numëroni qelizat bosh në interval me COUNTBLANK

Sa herë që keni nevojë të numëroni boshllëqet në Excel, COUNTBLANK është funksioni i parë që provohet.

Për shembull, për të marrë numrin e qelizave boshe në çdo rresht në tabelën e mëposhtme, ne futimformulën e mëposhtme në F2:

=COUNTBLANK(A2:E2)

Ndërsa përdorim referenca relative për diapazonin, thjesht mund ta zvarritim formulën poshtë dhe referencat do të përshtaten automatikisht për çdo rresht, duke prodhuar rezultatin e mëposhtëm:

Si të numëroni qelizat bosh në Excel duke përdorur COUNTIFS ose COUNTIF

Një mënyrë tjetër për të numëruar qelizat boshe në Excel është përdorimi i funksionit COUNTIF ose COUNTIFS ose me një vargu bosh ("") si kriter.

Në rastin tonë, formulat do të shkonin si më poshtë:

=COUNTIF(B2:E2, "")

Ose

=COUNTIFS(B2:E2, "")

Siç mund ta shihni në pamjen e mëposhtme të ekranit, rezultatet e COUNTIFS janë saktësisht të njëjta me ato të COUNTBLANK, kështu që cila formulë të përdoret në këtë skenar është një çështje e preferencës suaj personale.

Numëroni qelizat bosh me kusht

Në një situatë, kur dëshironi të numëroni qeliza boshe bazuar në një kusht, COUNTIFS është funksioni i duhur për t'u përdorur pasi sintaksa e tij parashikon shumëfish kriteret .

Për shembull, për të përcaktuar numrin e qelizave që kanë "Mollët" në kolonë umn A dhe boshllëqet në kolonën C, përdorni këtë formulë:

=COUNTIFS(A2:A9, "apples", C2:C9, "")

Ose futni kushtin në një qelizë të paracaktuar, le të themi F1, dhe referojuni asaj qelize si kriter:

=COUNTIFS(A2:A9, F1, C2:C9, "")

IF COUNTBLANK në Excel

Në disa raste, mund t'ju duhet jo vetëm të numëroni qelizat bosh në një varg, por të ndërmerrni disa veprime në varësi të nëse ka qeliza boshe apo jo.

Megjithëse nuk ka IF të integruarFunksioni COUNTBLANK në Excel, lehtë mund të krijoni formulën tuaj duke përdorur funksionet IF dhe COUNTBLANK së bashku. Ja se si:

• Kontrolloni nëse numri i boshllëqeve është i barabartë me zero dhe vendoseni këtë shprehje në testin logjik të IF:

  COUNTBLANK(B2:D2)=0

• Nëse testi logjik vlerësohet në TRUE , jep "Nuk ka bosh".
• Nëse testi logjik vlerësohet në FALSE, dal "Blanks".

Formula e plotë merr këtë formë:

=IF(COUNTBLANK(B2:D2)=0, "No blanks", "Blanks")

Si rezultat, formula identifikon të gjitha rreshtat ku mungojnë një ose më shumë vlera:

Ose mund të ekzekutoni një funksion tjetër në varësi të numrit të boshllëqeve. Për shembull, nëse nuk ka qeliza boshe në intervalin B2:D2 (d.m.th. nëse COUNTBLANK kthen 0), atëherë mblidhni vlerat, përndryshe ktheni "Blanks":

=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")

Si të numërohen rreshtat bosh në Excel

Si të supozojmë se keni një tabelë në të cilën disa rreshta përmbajnë informacion ndërsa rreshtat e tjerë janë krejtësisht bosh. Pyetja është - si e gjeni numrin e rreshtave që nuk përmbajnë asgjë në to?

Zgjidhja më e lehtë që ju vjen në mendje është të shtoni një kolonë ndihmëse dhe ta plotësoni me formulën Excel COUNTBLANK që gjen numri i qelizave bosh në çdo rresht:

=COUNTBLANK(A2:E2)

Dhe më pas, përdorni funksionin COUNTIF për të gjetur se në sa rreshta të gjitha qelizat janë bosh. Meqenëse tabela jonë e burimit përmban 5 kolona (A deri në E), ne numërojmë rreshtat që kanë 5 qeliza boshe:

=COUNTIF(F2:F8, 5))

Në vend të"hardkodimi" i numrit të kolonave, mund të përdorni funksionin COLUMNS për ta llogaritur atë automatikisht:

=COUNTIF(F2:F8, COLUMNS(A2:E2))

Nëse nuk dëshironi të ngatërroni strukturën e fletës suaj të punës të dizajnuar bukur, ju mund të arrini të njëjtin rezultat me një formulë shumë më komplekse që megjithatë nuk kërkon asnjë kolonë ndihmëse dhe as grup që të futet:

=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))

Duke punuar nga brenda jashtë, ja çfarë bën formula:

• Së pari, kontrolloni të gjithë gamën për qeliza jo bosh duke përdorur shprehjen si A2:E8"", dhe më pas shtrëngoni vlerat logjike të kthyera të TRUE dhe FALSE në 1 dhe 0 duke përdorur operatorin e dyfishtë unar (--). Rezultati i këtij operacioni është një grup dydimensional i njëshe (jo bosh) dhe zero (boshllëqe).
• Qëllimi i pjesës ROW është të gjenerojë një grup vertikal të numerikës jo-zero vlera, në të cilat numri i elementeve është i barabartë me numrin e kolonave të diapazonit. Në rastin tonë, diapazoni përbëhet nga 5 kolona (A2:E8), kështu që marrim këtë grup: {1;2;3;4;5}
• Funksioni MMULT llogarit produktin e matricës së vargjeve të mësipërme dhe prodhon një rezultat si: {11;0;15;8;0;8;10}. Në këtë grup, e vetmja gjë që ka rëndësi për ne janë vlerat 0 që përfaqësojnë rreshtat ku të gjitha qelizat janë bosh.
• Më në fund, ju krahasoni çdo element të grupit të mësipërm kundrejt zeros, shtrëngoni TRUE dhe FALSE në 1 dhe 0, dhe pastaj përmblidhni elementet e kësaj finalegrup: {0;1;0;0;1;0;0}. Duke pasur parasysh se 1 korrespondojnë me rreshtat bosh, ju merrni rezultatin e dëshiruar.

Nëse formula e mësipërme ju duket shumë e vështirë për t'u kuptuar, mund t'ju pëlqejë më mirë kjo:

=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))

Këtu, ju përdorni funksionin COUNTIF për të gjetur se sa qeliza jo bosh ka në çdo rresht dhe INDIRECT "ushqen" rreshtat në COUNTIF një nga një. Rezultati i këtij operacioni është një grup si {4;0;5;3;0;3;4}. Një kontroll për 0, transformon grupin e mësipërm në {0;1;0;0;1;0;0} ku 1 përfaqësojnë rreshta bosh, kështu që ju vetëm duhet t'i shtoni ato.

Numëroni qelizat vërtet bosh duke përjashtuar vargjet boshe

Në të gjithë shembujt e mëparshëm, ne po numëronim qelizat boshe duke përfshirë ato që duken vetëm bosh, por, në realitet, përmbajnë vargje boshe ("") të kthyera nga disa formula. Në rast se dëshironi të përjashtoni vargjet me gjatësi zero nga rezultati, mund të përdorni këtë formulë të përgjithshme:

Ajo që bën formula është të shumëzojë numrin e rreshtave me numrin e kolonave për të marrë totalin e qelizave në interval, nga i cili zbrisni numrin e jo boshllëqeve të kthyera me COUNTA . Siç mund ta mbani mend, funksioni Excel COUNTA i konsideron vargjet boshe si qeliza jo bosh, kështu që ato nuk do të përfshihen në rezultatin përfundimtar.

Për shembull, për të përcaktuar se sa qeliza absolutisht boshe ka në diapazoni A2:A8, këtu është formula për tëpërdorni:

=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)

Paraqitja e ekranit më poshtë tregon rezultatin:

Kjo është se si të numërohen qelizat boshe në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën tjetër!

Shkarkimet e disponueshme

Numëroni shembujt e formulave të qelizave bosh