Spis treści
Samouczek omawia składnię i podstawowe zastosowania funkcji COUNTBLANK do zliczania liczby pustych komórek w Excelu.
W kilku ostatnich postach omawialiśmy różne sposoby identyfikacji pustych komórek i podświetlania pustych miejsc w Excelu. W niektórych sytuacjach możesz jednak chcieć wiedzieć, ile komórek nie ma w nich nic. Microsoft Excel ma do tego również specjalną funkcję. W tym poradniku pokażemy Ci najszybsze i najwygodniejsze metody uzyskiwania liczby pustych komórek w zakresie, jak również całkowicie pustychwiersze.
Funkcja COUNTBLANK w programie Excel
Funkcja COUNTBLANK w programie Excel służy do zliczania pustych komórek w określonym zakresie. Należy do kategorii funkcji statystycznych i jest dostępna we wszystkich wersjach programu Excel dla Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.
Składnia tej funkcji jest bardzo prosta i wymaga tylko jednego argumentu:
COUNTBLANK(zakres)Gdzie zakres to zakres komórek, w których mają być zliczane puste miejsca.
Oto przykład formuły COUNTBLANK w Excelu w najprostszej postaci:
=COUNTBLANK(A2:D2)
Formuła, wprowadzona w E2 i skopiowana w dół do E7, określa liczbę pustych komórek w kolumnach od A do D w każdym wierszu i zwraca te wyniki:
Wskazówka. Do liczenia non-blank komórek w Excelu, należy użyć funkcji COUNTA.
Funkcja COUNTBLANK - 3 rzeczy, o których należy pamiętać
Aby skutecznie wykorzystać formułę Excela do liczenia pustych komórek, należy zrozumieć, jakie komórki funkcja COUNTBLANK uważa za "puste".
- Komórki, które zawierają jakikolwiek tekst, liczby, daty, wartości logiczne, spacje lub błędy nie są zliczane.
- Komórki zawierające zera są uważane za niepuste i nie są liczone.
- Komórki zawierające formuły zwracające puste ciągi ("") są traktowane jako puste i są liczone.
Patrząc na powyższy zrzut ekranu, zauważ, że komórka A7 zawierająca formułę, która zwraca pusty ciąg, jest liczona dwukrotnie:
- COUNTBLANK traktuje ciąg o zerowej długości jako pustą komórkę, ponieważ pojawia się ona pusta.
- COUNTA traktuje ciąg o zerowej długości jako niepustą komórkę, ponieważ w rzeczywistości zawiera formułę.
Może to brzmi trochę nielogicznie, ale Excel tak działa :)
Jak policzyć puste komórki w Excelu - przykłady formuł
COUNTBLANK to najwygodniejszy, ale nie jedyny sposób liczenia pustych komórek w Excelu. Poniższe przykłady demonstrują kilka innych metod i wyjaśniają, której formuły najlepiej użyć w danym scenariuszu.
Policz puste komórki w zakresie za pomocą COUNTBLANK
Zawsze, gdy trzeba policzyć puste miejsca w Excelu, COUNTBLANK jest pierwszą funkcją, którą należy wypróbować.
Na przykład, aby uzyskać liczbę pustych komórek w każdym wierszu w poniższej tabeli, wpisujemy w F2 następującą formułę:
=COUNTBLANK(A2:E2)
Ponieważ używamy względnych odniesień dla zakresu, możemy po prostu przeciągnąć formułę w dół, a odniesienia dostosują się automatycznie dla każdego wiersza, dając następujący wynik:
Jak policzyć puste komórki w Excelu za pomocą COUNTIFS lub COUNTIF
Innym sposobem zliczania pustych komórek w Excelu jest użycie funkcji COUNTIF lub COUNTIFS lub z pustym ciągiem ("") jako kryterium.
W naszym przypadku formuły przebiegałyby następująco:
=COUNTIF(B2:E2, "")
Albo
=COUNTIFS(B2:E2, "")
Jak widać na poniższym zrzucie ekranu, wyniki COUNTIFS są dokładnie takie same jak COUNTBLANK, więc to, którą formułę zastosować w tym scenariuszu, jest kwestią Twoich osobistych preferencji.
Policz puste komórki z warunkiem
W sytuacji, gdy chcemy policzyć puste komórki na podstawie jakiegoś warunku, właściwą funkcją jest COUNTIFS, ponieważ jej składnia przewiduje wiele kryteriów .
Na przykład, aby określić liczbę komórek, które mają "Jabłka" w kolumnie A i puste miejsca w kolumnie C, użyj tej formuły:
=COUNTIFS(A2:A9, "jabłka", C2:C9, "")
Albo wprowadzić warunek do predefiniowanej komórki, powiedzmy F1, i odwołać się do tej komórki jako do kryteriów:
=COUNTIFS(A2:A9, F1, C2:C9, "")
IF COUNTBLANK w Excelu
W niektórych przypadkach możesz potrzebować nie tylko policzyć puste komórki w zakresie, ale podjąć pewne działania w zależności od tego, czy są puste komórki, czy nie.
Chociaż w programie Excel nie ma wbudowanej funkcji IF COUNTBLANK, możesz łatwo stworzyć własną formułę, używając funkcji IF i COUNTBLANK razem.Oto jak:
- Sprawdź, czy liczba pustych miejsc jest równa zeru i umieść to wyrażenie w teście logicznym IF:
COUNTBLANK(B2:D2)=0 - Jeśli test logiczny zakończy się wynikiem TRUE, wypisz "Brak pustych miejsc".
- Jeśli test logiczny zakończy się FALSE, wypisz "Puste".
Kompletna formuła przyjmuje taki kształt:
=IF(COUNTBLANK(B2:D2)=0, "Bez pustych miejsc", "Puste miejsca")
W rezultacie formuła identyfikuje wszystkie wiersze, w których brakuje jednej lub więcej wartości:
Możesz też uruchomić inną funkcję w zależności od liczby pustych komórek. Na przykład, jeśli nie ma pustych komórek w zakresie B2:D2 (tj. Jeśli COUNTBLANK zwraca 0), to zsumuj wartości, w przeciwnym razie zwróć "Puste":
=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Puste miejsca")
Jak policzyć puste wiersze w programie Excel
Załóżmy, że masz tabelę, w której niektóre wiersze zawierają informacje, a inne są całkowicie puste. Pytanie brzmi - jak uzyskać liczbę wierszy, które nie zawierają niczego w nich?
Najprostszym rozwiązaniem, które przychodzi mi do głowy, jest dodanie kolumny pomocniczej i wypełnienie jej formułą Excel COUNTBLANK, która znajduje liczbę pustych komórek w każdym wierszu:
=COUNTBLANK(A2:E2)
A następnie użyj funkcji COUNTIF, aby dowiedzieć się, w ilu wierszach wszystkie komórki są puste. Ponieważ nasza tabela źródłowa zawiera 5 kolumn (od A do E), liczymy wiersze, które mają 5 pustych komórek:
=COUNTIF(F2:F8, 5))
Zamiast "twardo" kodować liczbę kolumn, możesz użyć funkcji COLUMNS, aby obliczyć ją automatycznie:
=COUNTIF(F2:F8, COLUMNS(A2:E2))
Jeśli nie chcesz zaśmiecać struktury swojego pięknie zaprojektowanego arkusza, możesz osiągnąć ten sam rezultat za pomocą dużo bardziej złożonej formuły, która jednak nie wymaga żadnych kolumn pomocniczych ani nawet wprowadzania tablic:
=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))
Pracując od środka na zewnątrz, oto co robi formuła:
- Najpierw sprawdzamy cały zakres pod kątem niepustych komórek za pomocą wyrażenia A2:E8"", a następnie zamieniamy zwrócone wartości logiczne TRUE i FALSE na 1 i 0 za pomocą podwójnego operatora jednoargumentowego (--). Wynikiem tej operacji jest dwuwymiarowa tablica jedynek (niepustych) i zer (pustych).
- Celem części ROW jest wygenerowanie pionowej tablicy numerycznej niezerowy wartości, w których liczba elementów jest równa liczbie kolumn zakresu. W naszym przypadku zakres składa się z 5 kolumn (A2:E8), więc otrzymujemy taką tablicę: {1;2;3;4;5}
- Funkcja MMULT oblicza iloczyn macierzowy powyższych tablic i daje wynik taki jak: {11;0;15;8;0;8;10}. W tej tablicy liczą się dla nas tylko wartości 0, które reprezentują wiersze, w których wszystkie komórki są puste.
- Na koniec porównujemy każdy element powyższej tablicy z zerem, zamieniamy TRUE i FALSE na 1 i 0, a następnie sumujemy elementy tej końcowej tablicy: {0;1;0;0;1;0;0}. Pamiętając, że 1 odpowiada pustym wierszom, otrzymujemy pożądany wynik.
Jeśli powyższa formuła wydaje Ci się zbyt trudna do ogarnięcia, może bardziej spodoba Ci się ta:
=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))
Tutaj używasz funkcji COUNTIF, aby znaleźć ile niepustych komórek jest w każdym wierszu, a INDIRECT "karmi" wiersze do COUNTIF jeden po drugim. Wynikiem tej operacji jest tablica taka jak {4;0;5;3;0;3;4}. Sprawdzenie dla 0, przekształca powyższą tablicę do {0;1;0;0;1;0;0}, gdzie 1 reprezentuje puste wiersze, więc musisz je po prostu dodać.
Policz prawdziwie puste komórki z wyłączeniem pustych ciągów znaków
We wszystkich poprzednich przykładach liczyliśmy puste komórki, w tym te, które tylko wydają się puste, ale w rzeczywistości zawierają puste ciągi ("") zwracane przez niektóre formuły. W przypadku, gdy chciałbyś wykluczyć z wyniku ciągi o zerowej długości, możesz użyć tej ogólnej formuły:
ROWS( zakres ) * KOLUMNY( zakres ) - COUNTA( zakres )Formuła mnoży liczbę wierszy przez liczbę kolumn, aby uzyskać całkowitą liczbę komórek w zakresie, od której odejmuje się liczbę komórek niepustych zwróconych przez COUNTA. Jak być może pamiętasz, funkcja COUNTA w Excelu traktuje puste ciągi jako komórki niepuste, więc nie będą one uwzględnione w końcowym wyniku.
Na przykład, aby określić, ile absolutnie pustych komórek znajduje się w zakresie A2:A8, oto formuła, której należy użyć:
=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)
Poniższy zrzut ekranu przedstawia wynik:
Tak wygląda liczenie pustych komórek w Excelu. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!
Dostępne pliki do pobrania
Licz puste komórki przykłady formuły
