В учебном пособии рассматривается синтаксис и основные способы использования функции COUNTBLANK для подсчета количества пустых ячеек в Excel.

В нескольких недавних постах мы обсуждали различные способы определения пустых ячеек и выделения пустых ячеек в Excel. Однако в некоторых ситуациях вы можете захотеть узнать, сколько ячеек не содержат ничего. В Microsoft Excel для этого тоже есть специальная функция. В этом руководстве мы покажем вам самые быстрые и удобные методы получения количества пустых ячеек в диапазоне, а также абсолютно пустых ячеек.ряды.

Функция Excel COUNTBLANK

Функция COUNTBLANK в Excel предназначена для подсчета пустых ячеек в указанном диапазоне. Она относится к категории статистических функций и доступна во всех версиях Excel для Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 и Excel 2007.

Синтаксис этой функции очень прост и требует только одного аргумента:

Где ассортимент это диапазон ячеек, в которых необходимо подсчитать пробелы.

Вот пример формулы COUNTBLANK в Excel в ее простейшей форме:

=COUNTBLANK(A2:D2)

Формула, введенная в E2 и скопированная вниз в E7, определяет количество пустых ячеек в столбцах с A по D в каждой строке и возвращает эти результаты:

Совет. Посчитать непустой ячейки в Excel, используйте функцию COUNTA.

Функция COUNTBLANK - 3 вещи, которые нужно помнить

Чтобы эффективно использовать формулу Excel для подсчета пустых ячеек, важно понимать, какие ячейки функция COUNTBLANK считает "пустыми".

1. Ячейки, содержащие любой текст, числа, даты, логические значения, пробелы или ошибки, не учитываются.
2. Клетки, содержащие нули считаются незаполненными и не учитываются.
3. Ячейки, содержащие формулы, которые возвращают пустые строки ("") считаются пустыми и учитываются.

Глядя на скриншот выше, обратите внимание, что ячейка A7, содержащая формулу, которая возвращает пустую строку, учитывается дважды:

• COUNTBLANK рассматривает строку нулевой длины как пустую ячейку, поскольку она отображается пустой.
• COUNTA рассматривает строку нулевой длины как непустую ячейку, поскольку она на самом деле содержит формулу.

Это может показаться немного нелогичным, но Excel действительно работает таким образом :)

Как подсчитать пустые ячейки в Excel - примеры формул

COUNTBLANK - самый удобный, но не единственный способ подсчета пустых ячеек в Excel. Следующие примеры демонстрируют несколько других методов и объясняют, какую формулу лучше использовать в том или ином сценарии.

Подсчет пустых ячеек в диапазоне с помощью COUNTBLANK

Если вам нужно подсчитать пробелы в Excel, первой функцией, которую следует попробовать, является COUNTBLANK.

Например, чтобы получить количество пустых ячеек в каждой строке в таблице ниже, мы вводим следующую формулу в F2:

=COUNTBLANK(A2:E2)

Поскольку мы используем относительные ссылки для диапазона, мы можем просто перетащить формулу вниз, и ссылки будут автоматически корректироваться для каждой строки, получая следующий результат:

Как подсчитать пустые ячейки в Excel с помощью COUNTIFS или COUNTIF

Другой способ подсчета пустых ячеек в Excel - использовать функцию COUNTIF или COUNTIFS или с пустой строкой ("") в качестве критерия.

В нашем случае формулы будут выглядеть следующим образом:

=COUNTIF(B2:E2, "")

Или

=COUNTIFS(B2:E2, "")

Как вы можете видеть на скриншоте ниже, результаты COUNTIFS точно такие же, как и COUNTBLANK, поэтому какую формулу использовать в данном сценарии - это вопрос ваших личных предпочтений.

Подсчет пустых ячеек с условием

В ситуации, когда вы хотите подсчитать пустые ячейки на основе некоторого условия, COUNTIFS является подходящей функцией, так как ее синтаксис предусматривает следующее многочисленные критерии .

Например, чтобы определить количество ячеек, имеющих "Яблоки" в столбце A и пробелы в столбце C, используйте эту формулу:

=COUNTIFS(A2:A9, "яблоки", C2:C9, "")

Или введите условие в заранее определенную ячейку, например F1, и ссылайтесь на эту ячейку как на критерий:

=COUNTIFS(A2:A9, F1, C2:C9, "")

IF COUNTBLANK в Excel

В некоторых случаях вам может понадобиться не просто подсчитать пустые ячейки в диапазоне, а предпринять определенные действия в зависимости от того, есть ли пустые ячейки или нет.

Хотя в Excel нет встроенной функции IF COUNTBLANK, вы можете легко создать свою собственную формулу, используя функции IF и COUNTBLANK вместе. Вот как это сделать:

• Проверьте, равен ли счетчик пробелов нулю, и поместите это выражение в логический тест IF:

  COUNTBLANK(B2:D2)=0

• Если логический тест выдает значение TRUE, выведите "No blanks".
• Если логический тест выдает значение FALSE, выведите "Blanks".

Полная формула имеет такую форму:

=IF(COUNTBLANK(B2:D2)=0, "Без пробелов", "Пробелы")

В результате формула определяет все строки, в которых отсутствует одно или несколько значений:

Например, если в диапазоне B2:D2 нет пустых ячеек (т.е. COUNTBLANK возвращает 0), то суммируйте значения, иначе верните "Пустые":

=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Пустые")

Как подсчитать пустые строки в Excel

Предположим, у вас есть таблица, в которой некоторые строки содержат информацию, а другие строки абсолютно пустые. Вопрос в том, как получить количество строк, в которых ничего не содержится?

Самое простое решение, которое приходит на ум, - добавить вспомогательный столбец и заполнить его формулой Excel COUNTBLANK, которая определяет количество пустых ячеек в каждой строке:

=COUNTBLANK(A2:E2)

Затем с помощью функции COUNTIF выясните, в скольких строках все ячейки пустые. Поскольку наша исходная таблица содержит 5 столбцов (от A до E), мы подсчитаем строки, в которых есть 5 пустых ячеек:

=COUNTIF(F2:F8, 5))

Вместо того чтобы "жестко кодировать" количество столбцов, вы можете использовать функцию COLUMNS для его автоматического расчета:

=COUNTIF(F2:F8, COLUMNS(A2:E2))

Если вы не хотите уродовать структуру вашего красиво оформленного рабочего листа, вы можете добиться того же результата с помощью гораздо более сложной формулы, которая, однако, не требует ни вспомогательных столбцов, ни даже ввода массива:

=SUM(--(MMULT(--(A2:E8""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0)))

Работает изнутри наружу, вот что делает формула:

• Сначала вы проверяете весь диапазон на наличие незаполненных ячеек с помощью выражения вида A2:E8"", а затем преобразуете возвращаемые логические значения TRUE и FALSE в 1 и 0 с помощью двойного унарного оператора (--). Результатом этой операции является двумерный массив единиц (незаполненных) и нулей (пустых).
• Целью части ROW является генерация вертикального массива числовых данных. ненулевой значений, в котором количество элементов равно количеству столбцов диапазона. В нашем случае диапазон состоит из 5 столбцов (A2:E8), поэтому мы получаем такой массив: {1;2;3;4;5}
• Функция MMULT вычисляет матричное произведение указанных выше массивов и выдает результат вида: {11;0;15;8;0;8;10}. В этом массиве для нас важны только значения 0, которые представляют строки, где все ячейки пустые.
• Наконец, вы сравниваете каждый элемент вышеуказанного массива с нулем, переводите TRUE и FALSE в 1 и 0, а затем суммируете элементы этого конечного массива: {0;1;0;0;0;1;0;0;0}. Помня, что 1 соответствует пустым строкам, вы получаете желаемый результат.

Если приведенная выше формула кажется вам слишком сложной для понимания, возможно, вам больше понравится эта:

=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), ""&"")=0))

Здесь вы используете функцию COUNTIF для определения количества непустых ячеек в каждом ряду, а INDIRECT "подает" строки в COUNTIF по одной. Результатом этой операции является массив вида {4;0;5;3;0;3;4}. Проверка на 0 преобразует вышеприведенный массив в {0;1;0;0;0;1;0;0;0}, где 1 представляет собой пустые строки, поэтому вам нужно просто сложить их.

Подсчет действительно пустых ячеек, исключая пустые строки

Во всех предыдущих примерах мы считали пустые ячейки, включая те, которые только кажутся пустыми, но на самом деле содержат пустые строки (""), возвращаемые некоторыми формулами. Если вы хотите исключить строки нулевой длины из результата, вы можете использовать эту общую формулу:

Формула умножает количество строк на количество столбцов, чтобы получить общее количество ячеек в диапазоне, из которого вычитается количество незаполненных ячеек, возвращенных функцией COUNTA. Как вы помните, функция COUNTA в Excel считает пустые строки незаполненными ячейками, поэтому они не будут включены в конечный результат.

Например, чтобы определить количество абсолютно пустых ячеек в диапазоне A2:A8, можно воспользоваться следующей формулой:

=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)

На скриншоте ниже показан результат:

Вот как считать пустые ячейки в Excel. Я благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе!

Доступные загрузки

Подсчет пустых ячеек формула примеры