Упатството ќе ве научи како да најдете просек во Excel со или без формули и да ги заокружите резултатите на онолку децимали колку што сакате.

Во Microsoft Excel има неколку различни функции за пресметување на просекот за множество нумерички вредности. Покрај тоа, постои инстант начин без формула. На оваа страница, ќе најдете брз преглед на сите методи илустрирани со примери за употреба и најдобри практики. Сите функции дискутирани во ова упатство работат во која било верзија на Excel 365 преку Excel 2007.

Што е просечно?

Во секојдневниот живот, просекот е број што изразува типичната вредност во базата на податоци. На пример, ако неколку спортисти истрчале спринт на 100 метри, можеби ќе сакате да го знаете просечниот резултат - т.е. колку време се очекува повеќето спринтери да поминат за да ја завршат трката.

Во математиката, просекот е средна или централна вредност во збир од броеви, која се пресметува со делење на збирот на сите вредности со нивниот број.

Во горниот пример, под претпоставка дека првиот спортист го поминал растојанието за 10,5 секунди, на вториот му треба 10,7 секунди, а третата траеше 11,2 секунди, просечното време ќе биде 10,8 секунди:

(10,5+10,7+11,2)/3 = 10,8

Како да добиете просек во Excel без формули

Во работните листови на Excel, не треба да вршите рачни пресметки - моќните функции на Excel ќе направат сèфункција која пресметува аритметичка средина на броеви игнорирајќи ги логичките вредности.

Како да се заокружи просекот во Excel

Кога се пресметува просекот во Excel, резултатот е често број со повеќе децимални места . Во случај да сакате да прикажете помалку децимални цифри или да заокружите просек на цел број, користете едно од следните решенија.

Намали ја децималната опција

За да го заокружите само прикажаниот просек без промена на основната вредност, најбрзиот начин е да се користи командата Намали Децимална на картичката Дома , во групата Број :

Форматирај ќелии дијалог прозорец

Бројот на децимални места може да се наведе и во полето за дијалог Форматирај ќелии . За да го направите тоа, изберете ја ќелијата со формулата и притиснете Ctrl + 1 за да го отворите дијалогот Форматирај ќелии . Потоа, префрлете се на картичката Број и напишете го бројот на места што сакате да ги прикажете во полето децимални места .

Како и претходниот метод, овој се менува само форматот на приказот. Кога се однесува на просечната ќелија во други формули, оригиналната незаокружена вредност ќе се користи во сите пресметки.

За целосни детали, видете заокружени броеви со менување на форматот на ќелијата.

Заокружете го просекот со формула

За да ја заокружите самата пресметана вредност, завиткајте го вашиот просек формула во една од функциите за заокружување на Excel.

Во повеќето ситуации, би го користелеФункција ROUND која ги следи општите математички правила за заокружување. Во првиот аргумент ( број ), вметнете ја функцијата AVERAGE, AVERAGEIF или AVERAGEIFS. Во вториот аргумент ( num_цифри ), наведете го бројот на децимални места до кои треба да се заокружи просекот.

На пример, да се заокружи просекот до најблискиот цел број , формулата е:

=ROUND(AVERAGE(B3:B15), 0)

За да се заокружи просекот на едно децимално место , ова е формулата што треба да се користи:

=ROUND(AVERAGE(B3:B15), 1)

За да се заокружи просекот на две децимали , ова ќе работи:

=ROUND(AVERAGE(B3:B15), 2)

Совет. За заокружување нагоре, користете ја функцијата ROUNDUP; за заокружување - функцијата ROUNDDOWN.

Така можете да постигнете просек во Excel. Подолу има линкови до поврзаните упатства кои дискутираат за поконкретни случаи на просек, се надеваме дека ќе ви бидат корисни. Ви благодариме што прочитавте!

Вежбајте работна книга за преземање

Пресметајте просек во Excel - примери (датотека .xlsx)

>работата зад сцената и го испорача резултатот за кратко време. Пред детално да ги истражиме специјализираните функции, ајде да научиме брз и неверојатно едноставен начин без формула.

За брзо наоѓање просек без формула, користете ја статусната лента на Excel:

1. Изберете ќелиите или опсезите што сакате да ги просечете. За не-соседни селекции, користете го копчето Ctrl.
2. Погледнете ја лентата за статус на дното на прозорецот на Excel, која ги обезбедува основните информации за моментално избраните ќелии. Една од вредностите што Excel ги пресметува автоматски е просекот.

Резултатот е прикажан на сликата подолу:

Како рачно да се пресмета просекот

Во математиката, за да ја пронајдете аритметичката средина на списокот со броеви, треба да ги соберете сите вредности, а потоа да го поделите збирот со колку броеви има во списокот. Во Excel, ова може да се направи со помош на функциите SUM и COUNT, соодветно:

SUM( опсег )/COUNT( опсег )

За опсегот на броеви подолу, формулата оди на следниов начин:

=SUM(B3:B12)/COUNT(B3:B12)

Како што можете да видите, резултатот од формулата точно се совпаѓа со просечната вредност во статусната лента.

Во пракса, тешко дека некогаш ќе треба да направите рачен просек во вашите работни листови. Сепак, може да биде корисно повторно да го проверите резултатот од вашата просечна формула во случај на сомнеж.

А сега, ајде да погледнеме како можете да постигнете просек во Excel користејќи ги специјално функциитедизајнирана за таа цел.

ПРОСЕЧНА функција - пресметајте просек од броеви

Ја користите функцијата Excel AVERAGE за да добиете просек од сите броеви во наведените ќелии или опсези.

ПРОСЕК (број 1, [број2], ...)

Каде што број 1, број2 , … се нумерички вредности за кои сакате да го најдете просекот. Во една формула може да се вклучат до 255 аргументи. Аргументите може да се дадат како бројки, референци или именувани опсези.

AVERAGE е една од наједноставните и најлесни за користење функции во Excel.

За да се пресмета просекот на броеви, можете да ги напишете директно во формула или да ги наведете соодветните референци за ќелии или опсег.

На пример, за просечни 2 опсези и 1 поединечна ќелија подолу, формулата е:

=AVERAGE(B4:B6, B8:B10, B12)

Освен бројки, функцијата Excel AVERAGE може да најде просек од други нумерички вредности како што се проценти и времиња.

Формула Excel AVERAGE - белешки за употреба

Како што штотуку видовте, користењето на функцијата AVERAGE во Excel е лесно. Меѓутоа, за да добиете точен резултат, треба јасно да разберете кои вредности се вклучени во просекот, а што се игнорираат.

Вклучено:

• Ќелии со нула вредности (0)
• Логичките вредности TRUE и FALSE внесени директно во списокот со аргументи. На пример, формулата AVERAGE(TRUE, FALSE) враќа 0,5, што е средна вредност од 1 и 0.

Игнорирано:

• Празноќелии
• Текстуални низи
• Ќелии што содржат булови вредности TRUE и FALSE

За повеќе информации, погледнете Како да се користи функцијата AVERAGE во Excel.

ПРОСЕЧНА функција - просек на сите непразни ќелии

Функцијата Excel AVERAGEA е слична на AVERAGE во тоа што ја пресметува аритметичката средина на вредностите во нејзините аргументи. Разликата е во тоа што AVERAGEA ги вклучува сите непразни ќелии во една пресметка, без разлика дали тие содржат броеви, текст, логички вредности или празни низи вратени од други функции.

AVERAGEA(вредност1, [вредност2], …)

Каде што вредност1, вредност2, … се вредностите, низите, референците на ќелиите или опсезите што сакате да ги просечните. Првиот аргумент е потребен, другите (до 255) се опционални.

Формула Excel AVERAGEA - белешки за употреба

Како што беше споменато погоре, функцијата AVERAGEA обработува различни типови вредности како што се броеви, текстуални низи и логички вредности. И еве како се оценуваат:

Вклучено:

• Тексталните вредности се оценуваат како 0.
• Нулта должина ("") се оценуваат како 0.
• Буловата вредност TRUE оценува како 1 и FALSE како 0.

Игнорирано:

• Празни ќелии

На пример, под формулата враќа 1, што е просек од 2 и 0.

=AVERAGEA(2, FALSE)

Следната формула враќа 1,5, што е просек од 2 и 1.

=AVERAGEA(2, TRUE)

Сликата подолу ги прикажува формулите AVERAGE и AVERAGEA применети наист список на вредности и различни резултати што ги враќаат:

Функција AVERAGEIF - добиј просек со услов

За да го добиете просекот на сите ќелии во наведениот опсег што исполнуваат одреден услов, користете ја функцијата AVERAGEIF .

AVERAGEIF(опсег, критериуми, [просечен_опсег])

Функцијата AVERAGEIF ги има следните аргументи:

• Опсег (задолжително) - опсегот на ќелиите до тест според даден критериум.
• Критериуми (задолжително) - условот што треба да се исполни.
• Просечен_опсег (изборно) - ќелиите до просек. Ако се испушти, тогаш опсег е просечен.

Функцијата AVERAGEIF е достапна во Excel 2007 - Excel 365. Во претходните верзии, можете да изградите своја сопствена формула AVERAGE IF.

А сега, да видиме како можете да ја користите функцијата Excel AVERAGEIF за просечни ќелии врз основа на условот што ќе го наведете.

Да претпоставиме дека имате резултати за различни предмети во C3:C15 и сакате да најдете просечен резултат по математика. Ова може да се направи со следнава формула:

=AVERAGEIF(B3:B15, "math", C3:C15)

Наместо да ја „хардкодирате“ состојбата директно во формула, можете да ја напишете во посебна ќелија (F3) и да се повикате на таа ќелија во критериумите:

=AVERAGEIF(B3:B15, F3, C3:C15)

За повеќе примери на формула, погледнете ја функцијата Excel AVERAGEIF.

Функција AVERAGEIFS - просек со повеќе критериуми

За да направите просек со два или повеќе услови, користете го множинскиот пандан на AVERAGEIF -функцијата AVERAGEIFS.

AVERAGEIFS(просечен_опсег, критериум_опсег1, критериуми1, [опсег_критериуми2, критериуми2], ...)

Функцијата ја има следнава синтакса:

• Просечен_опсег ( потребно) - опсег до просек.
• Опсег_критериуми (задолжително) - опсегот што треба да се тестира според критериуми .
• Критериуми (задолжително) - состојба која одредува кои ќелии да се просечат. Може да се даде во форма на број, логички израз, текстуална вредност или референца на ќелијата.

1 до 127 опсег_критериуми / критериуми бидат доставени. Првиот пар е потребен, следните се опционални.

Во суштина, вие користите AVERAGEIFS слично како AVERAGEIF, освен што повеќе од еден услов може да се тестираат во една формула.

Претпоставувајќи дека некои студенти не полагале тестови по одредени предмети и имаат нула бодови. Имате за цел да најдете просечна оценка во одредена тема игнорирајќи ги нулите.

За да ја постигнете задачата, градите формула AVERAGEIFS со два критериуми:

• Дефинирајте го опсегот до просекот (C3 :C15).
• Наведете го опсегот за проверка во однос на првиот услов (B3:B15 - ставки).
• Искажете го првиот услов („математика“ или F3 - целната ставка е ставена во наводник ознаки или упатување на ќелијата што ја содржи ставката).
• Наведете го опсегот за проверка според вториот услов (C3:C15 - резултати).
• Изразете го вториот услов („>0“- поголема од нула).

Со составување на горенаведените компоненти заедно ја добиваме следната формула:

=AVERAGEIFS(C3:C15, B3:B15, "math", C3:C15, ">0")

Или

=AVERAGEIFS(C3:C15, B3:B15, F3, C3:C15, ">0")

Сликата подолу јасно покажува дека само две ќелии (C6 и C10) ги исполнуваат двата услови, и затоа само овие ќелии се просечни.

За повеќе информации, проверете ја функцијата Excel AVERAGEIFS.

Формулите AVERAGEIF и AVERAGEIFS - белешки за употреба

Функциите Excel AVERAGEIF и AVERAGEIFS имаат многу заедничко, особено кои вредности ги пресметајте и кои игнорираат:

• Во просечниот опсег, празните ќелии, вредностите на текстот, логичките вредности TRUE/FALSE се игнорираат.
• Во критериумите, празните ќелии се третираат како нула вредности.
• Луките со џокер како прашалник (?) и ѕвездичка (*) може да се користат во критериумите за делумно совпаѓање.
• Ако ниту една ќелија не ги исполнува сите наведени критериуми, #DIV0! се појавува грешка.

AVERAGEIF наспроти AVERAGEIFS - разлики

Во однос на функционалноста, најсуштинската разлика е тоа што AVERAGEIF може да се справи само со еден услов додека AVERAGEIFS еден или повеќе критериуми. Исто така, постојат неколку технички разлики поврзани со просечен_опсег .

• Со AVERAGEIF, просечен_опсег е последниот и изборен аргумент. Во формулите AVERAGEIFS, тој е првиот и потребен аргумент.
• Со AVERAGEIF, просечен_опсег не мора нужно да биде со иста големина како опсег бидејќи вистинските ќелии што треба да се просечат се одредуваат со големината на аргументот опсег - горната лева ќелија од просечен_опсег се зема како почетна точка, и онолку ќелии се просечни колку што се вклучени во аргументот опсег . AVERAGEIFS бара секој опсег_критериуми да биде со иста големина и облик како просечен_опсег , инаку #VALUE! се појавува грешка.

ПРОСЕК АКО ИЛИ формула во Excel

Бидејќи функцијата Excel AVERAGEIFS секогаш работи со логиката И (сите критериуми мора да бидат ВИСТИНИ), ќе мора да конструирате свој формула до просечни ќелии со логиката ИЛИ (секој поединечен критериум мора да биде ТОЧЕН).

Еве ја генеричката формула за просек ако ќелијата е X или Y.

AVERAGE(IF(ISNUMBER(MATCH( опсег , { критериум 1 , критериум 2 ,...}, 0)), просечен_опсег ))

Сега, ајде да видиме како функционира во пракса . Во табелата подолу, да претпоставиме дека сакате да најдете просечен резултат од два предмети, Биологија и Хемија , кои се внесени во ќелиите F3 и F4. Ова може да се направи со следнава формула за низа:

=AVERAGE(IF(ISNUMBER(MATCH(B3:B15, {"biology", "chemistry"}, 0)), C3:C15))

Преведено на човечки јазик, формулата вели: просечни ќелии во C3:C15 ако соодветната ќелија во B3:B15 е или „ Биологија“ или „Хемија“.

Наместо тврдокодираните критериуми, можете да користите референца за опсег (F3:F4 во нашиот случај):

=AVERAGE(IF(ISNUMBER(MATCH(B3:B15, F3:F4, 0)), C3:C15))

За формулата да работи правилно,Ве молиме не заборавајте да притиснете Ctrl + Shift + Enter во Excel 2019 и пониско. Во динамична низа Excel (365 и 2021), ќе биде доволен обичен хит Enter:

Како функционира оваа формула:

За нашите љубопитни и внимателни читатели кои сакаат не само да користите формула, но да разберете што прават, еве детално објаснување за логиката.

Во суштината на формулата, функцијата IF одредува кои вредности во опсегот на изворот одговараат на кој било од наведените критериуми и поминува тие вредности на функцијата AVERAGE. Еве како:

Функцијата MATCH ги користи имињата на предметите во B3:B15 како вредности за пребарување и ја споредува секоја од тие вредности со низата за пребарување во F3:F4 (нашите целни субјекти). Третиот аргумент ( match_type ) е поставен на 0 за да бара точно совпаѓање:

MATCH(B3:B15, F3:F4, 0)

Кога ќе се најде совпаѓање, MATCH ја враќа својата релативна позиција во низата за пребарување , инаку #N/A грешка:

{1;2;1;#N/A;1;#N/A;2;#N/A;1;2;2;1;#N/A}

Функцијата ISNUMBER ги претвора броевите во TRUE и грешките во FALSE:

{TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE}

Оваа низа оди на логичкиот тест на IF. Во целосна форма, логичкиот тест треба да биде напишан вака:

IF(ISNUMBER(MATCH(B3:B15, F3:F4, 0))=TRUE

Заради краткотрајност, го испуштаме =TRUE делот бидејќи е имплициран.

Од поставувајќи го аргументот value_if_true на C3:C15, и кажувате на функцијата IF да ги замени TRUE's со вистинските вредности од C3:C15:

{89;78;75;FALSE;64;FALSE;62;FALSE;78;56;93;88;FALSE}

Оваа последна низа е предадена над ПРОСЕК