Ingin tahu cara menambahkan teks ke sel yang ada di Excel? Pada artikel ini, Anda akan mempelajari beberapa cara yang sangat sederhana untuk menyisipkan karakter di posisi mana pun dalam sel.

Saat bekerja dengan data teks di Excel, terkadang Anda mungkin perlu menambahkan teks yang sama ke sel yang ada untuk memperjelas. Misalnya, Anda mungkin ingin meletakkan beberapa awalan di awal setiap sel, menyisipkan simbol khusus di akhir, atau menempatkan teks tertentu sebelum rumus.

Tutorial ini akan mengajarkan Anda cara cepat menambahkan string ke beberapa sel menggunakan rumus dan mengotomatiskan pekerjaan dengan VBA atau Tambahkan Teks alat.

Rumus Excel untuk menambahkan teks / karakter ke sel

Untuk menambahkan karakter atau teks tertentu ke sel Excel, cukup gabungkan string dan referensi sel dengan menggunakan salah satu metode berikut.

Operator penggabungan

Cara termudah untuk menambahkan string teks ke sel adalah dengan menggunakan karakter ampersand (&), yang merupakan operator penggabungan di Excel.

" teks "& sel

Ini berfungsi di semua versi Excel 2007 - Excel 365.

Fungsi CONCATENATE

Hasil yang sama dapat dicapai dengan bantuan fungsi CONCATENATE:

CONCATENATE(" teks ", sel )

Fungsi ini tersedia di Excel untuk Microsoft 365, Excel 2019 - 2007.

Fungsi CONCAT

Untuk menambahkan teks ke sel di Excel 365, Excel 2019, dan Excel Online, Anda dapat menggunakan fungsi CONCAT, yang merupakan pengganti modern dari CONCATENATE:

CONCAT(" teks ", sel )

Catatan Harap perhatikan bahwa, dalam semua rumus, teks harus diapit dalam tanda kutip.

Ini adalah pendekatan umum, dan contoh-contoh di bawah ini menunjukkan cara menerapkannya dalam praktik.

Cara menambahkan teks ke awal sel

Untuk menambahkan teks atau karakter tertentu ke awal sel, inilah yang perlu Anda lakukan:

1. Di sel tempat Anda ingin menampilkan hasilnya, ketik tanda sama dengan (=).
2. Ketik teks yang diinginkan di dalam tanda kutip.
3. Ketik simbol ampersand (&).
4. Pilih sel yang akan ditambahkan teks, dan tekan Enter .

Alternatifnya, kamu bisa menyediakan string teks dan referensi cellmu sebagai parameter input ke fungsi CONCATENATE atau CONCAT.

Contohnya, untuk menambahkan teks " Proyek: " ke nama proyek di A2, salah satu rumus di bawah ini akan berfungsi.

Di semua versi Excel:

= "Proyek:" &A2

=CONCATENATE ("Proyek:", A2)

Di Excel 365 dan Excel 2019:

=CONCAT("Proyek:", A2)

Masukkan rumus di B2, seret ke bawah kolom, dan Anda akan memiliki teks yang sama yang disisipkan di semua sel.

Tip. Rumus di atas menggabungkan dua string tanpa spasi. Untuk memisahkan nilai dengan spasi, ketik a karakter ruang di akhir teks yang ditambahkan sebelumnya (misalnya, "Project: ").

Untuk kenyamanan, Anda bisa memasukkan teks target dalam sel yang sudah ditentukan sebelumnya (E2) dan menambahkan dua sel teks bersama-sama :

Tanpa spasi:

=$E$2&A2

=CONCATENATE($E$2, A2)

Dengan spasi:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Harap perhatikan bahwa alamat sel yang berisi teks yang ditambahkan sebelumnya dikunci dengan tanda $, sehingga tidak akan bergeser saat menyalin rumus ke bawah.

Dengan pendekatan ini, Anda dapat dengan mudah mengubah teks yang ditambahkan di satu tempat, tanpa harus memperbarui setiap formula.

Bagaimana cara menambahkan teks ke akhir sel di Excel

Untuk menambahkan teks atau karakter tertentu ke sel yang sudah ada, gunakan kembali metode penggabungan. Perbedaannya terletak pada urutan nilai yang digabungkan: referensi sel diikuti oleh string teks.

Contohnya, untuk menambahkan string " -AS " ke akhir sel A2, ini adalah rumus yang digunakan:

= A2 & amp; "-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Alternatifnya, Anda bisa memasukkan teks di beberapa sel, lalu menggabungkan dua sel dengan teks bersama-sama:

=A2 & amp; $D$2

=CONCATENATE(A2, $D$2)

Harap ingat untuk menggunakan referensi absolut untuk teks yang ditambahkan ($ D $ 2) agar rumus dapat disalin dengan benar di seluruh kolom.

Menambahkan karakter ke awal dan akhir string

Mengetahui cara menambahkan dan menambahkan teks ke sel yang sudah ada, tidak ada yang akan mencegah Anda menggunakan kedua teknik tersebut dalam satu rumus.

Sebagai contoh, mari kita tambahkan string " Proyek: " ke awal dan " -AS " ke akhir teks yang ada di A2.

="Project:"&A2&"-US"

=CONCATENATE("Proyek:", A2, "-US")

=CONCAT("Proyek:", A2, "-US")

Dengan input string dalam sel terpisah, ini bekerja sama baiknya:

Menggabungkan teks dari dua sel atau lebih

Untuk menempatkan nilai dari beberapa sel ke dalam satu sel, gabungkan sel asli dengan menggunakan teknik yang sudah dikenal: simbol ampersand, fungsi CONCATENATE atau CONCAT.

Misalnya, untuk menggabungkan nilai dari kolom A dan B dengan menggunakan koma dan spasi (", ") untuk pembatas, masukkan salah satu rumus di bawah ini di B2, lalu seret ke bawah kolom.

Menambahkan teks dari dua sel dengan ampersand:

=A2&", "&B2

Gabungkan teks dari dua sel dengan CONCAT atau CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Ketika menambahkan teks dari dua kolom pastikan untuk menggunakan referensi sel relatif (seperti A2), sehingga mereka menyesuaikan dengan benar untuk setiap baris di mana rumus disalin.

Untuk menggabungkan teks dari beberapa sel di Excel 365 dan Excel 2019, Anda dapat memanfaatkan fungsi TEXTJOIN. Sintaksnya menyediakan pembatas (argumen pertama), yang membuat formular lebih ringkas dan lebih mudah dikelola.

Misalnya, untuk menambahkan string dari tiga kolom (A, B dan C), memisahkan nilai dengan koma dan spasi, rumusnya adalah:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Bagaimana cara menambahkan karakter khusus ke sel di Excel

Untuk menyisipkan karakter khusus dalam sel Excel, Anda perlu mengetahui kodenya dalam sistem ASCII. Setelah kode dibuat, berikan ke fungsi CHAR untuk mengembalikan karakter yang sesuai. Fungsi CHAR menerima nomor apa pun dari 1 hingga 255. Daftar kode karakter yang dapat dicetak (nilai dari 32 hingga 255) dapat ditemukan di sini.

Untuk menambahkan karakter khusus ke nilai yang ada atau hasil rumus, Anda dapat menerapkan metode penggabungan apa pun yang paling Anda sukai.

Contohnya, untuk menambahkan simbol merek dagang (™) ke teks di A2, salah satu rumus berikut akan berfungsi:

=A2 & amp; CHAR (153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Bagaimana cara menambahkan teks ke rumus di Excel

Untuk menambahkan karakter atau teks tertentu ke hasil rumus, cukup gabungkan string dengan rumus itu sendiri.

Katakanlah, Anda menggunakan rumus ini untuk mengembalikan waktu saat ini:

=TEXT(NOW(), "h:mm AM/PM")

Untuk menjelaskan kepada pengguna Anda jam berapa saat itu, Anda dapat menempatkan beberapa teks sebelum dan/atau sesudah rumus.

Sisipkan teks sebelum rumus :

="Waktu saat ini: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Waktu saat ini: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Waktu saat ini: ", TEXT(NOW(), "h:mm AM/PM"))

Tambahkan teks setelah formula:

=TEXT(NOW(), "h:mm AM/PM")&" - waktu saat ini"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - waktu saat ini")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - waktu saat ini")

Tambahkan teks ke formula di kedua sisi:

="It's " &TEXT(NOW(), "h:mm AM/PM")& " di sini di Gomel"

=CONCATENATE("It's ", TEXT(NOW(), "h:mm AM/PM"), " here here in Gomel")

=CONCAT("It's ", TEXT(NOW(), "h:mm AM/PM"), " di sini di Gomel")

Cara menyisipkan teks setelah karakter ke-N

Untuk menambahkan teks atau karakter tertentu pada posisi tertentu dalam sel, Anda perlu membagi string asli menjadi dua bagian dan menempatkan teks di antaranya. Begini caranya:

1. Ekstrak substring sebelum teks yang disisipkan dengan bantuan fungsi LEFT:

KIRI (sel, n)

Ekstrak substring yang mengikuti teks menggunakan kombinasi RIGHT dan LEN:

KANAN(sel, LEN(sel) -n)

Gabungkan dua substring dan teks/karakter menggunakan simbol ampersand.

Rumus lengkapnya mengambil bentuk ini:

KIRI( sel , n ) &; " teks " & RIGHT( sel , LEN( sel ) - n )

Bagian yang sama dapat digabungkan bersama dengan menggunakan fungsi CONCATENATE atau CONCAT:

CONCATENATE(KIRI( sel , n ), " teks ", KANAN( sel , LEN( sel ) - n ))

Tugas ini juga bisa diselesaikan dengan menggunakan fungsi REPLACE:

REPLACE ( sel , n+1 , 0, " teks ")

Triknya adalah bahwa num_chars yang mendefinisikan berapa banyak karakter yang akan diganti diatur ke 0, sehingga rumus sebenarnya menyisipkan teks pada posisi tertentu dalam sel tanpa mengganti apa pun. Posisi ( start_num dihitung menggunakan ekspresi ini: n+1. Kita menambahkan 1 ke posisi karakter ke-n karena teks harus disisipkan setelahnya.

Misalnya, untuk menyisipkan tanda hubung (-) setelah karakter ke-2 di A2, rumus di B2 adalah:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Atau

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Atau

=REPLACE(A2, 2+1, 0, "-")

Seret rumus ke bawah, dan Anda akan memiliki karakter yang sama yang disisipkan di semua sel:

Cara menambahkan teks sebelum/sesudah karakter tertentu

Untuk menyisipkan teks tertentu sebelum atau sesudah karakter tertentu, Anda perlu menentukan posisi karakter itu dalam string. Ini dapat dilakukan dengan bantuan fungsi SEARCH:

CARI (" char ", sel )

Setelah posisinya ditentukan, Anda dapat menambahkan string tepat di tempat itu dengan menggunakan pendekatan yang dibahas dalam contoh di atas.

Tambahkan teks setelah karakter tertentu

Untuk menyisipkan beberapa teks setelah karakter tertentu, rumus umumnya adalah:

KIRI( sel , CARI (" char ", sel )) & " teks " & RIGHT( sel , LEN( sel ) - CARI (" char ", sel ))

Atau

CONCATENATE(KIRI( sel , CARI (" char ", sel )), " teks ", KANAN( sel , LEN( sel ) - CARI (" char ", sel )))

Contohnya, untuk menyisipkan teks (AS) setelah tanda hubung di A2, rumusnya adalah:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Atau

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2)))

Menyisipkan teks sebelum karakter tertentu

Untuk menambahkan beberapa teks sebelum karakter tertentu, rumusnya adalah:

KIRI( sel , CARI (" char ", sel ) -1) & " teks " & RIGHT( sel , LEN( sel ) - CARI (" char ", sel ) +1)

Atau

CONCATENATE(KIRI( sel , CARI (" char ", sel ) - 1), " teks ", KANAN( sel , LEN( sel ) - CARI (" char ", sel ) +1))

Seperti yang Anda lihat, rumusnya sangat mirip dengan rumus yang menyisipkan teks setelah karakter. Perbedaannya adalah kita mengurangi 1 dari hasil SEARCH pertama untuk memaksa fungsi LEFT meninggalkan karakter setelah teks ditambahkan. Untuk hasil SEARCH kedua, kita menambahkan 1, sehingga fungsi RIGHT akan mengambil karakter itu.

Contohnya, untuk menempatkan teks (AS) sebelum tanda hubung di A2, inilah rumus yang digunakan:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Atau

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Catatan:

• Jika sel asli berisi beberapa kejadian dari suatu karakter, teks akan disisipkan sebelum/sesudah kejadian pertama.
• Fungsi SEARCH adalah tidak peka huruf besar-kecil dan tidak dapat membedakan karakter huruf kecil dan huruf besar. Jika Anda bertujuan untuk menambahkan teks sebelum/sesudah huruf kecil atau huruf besar, maka gunakan fungsi FIND case-sensitive untuk menemukan huruf tersebut.

Bagaimana menambahkan spasi di antara teks di sel Excel

Sebenarnya, ini hanyalah kasus spesifik dari dua contoh sebelumnya.

Untuk menambahkan ruang pada posisi yang sama di semua sel, gunakan rumus untuk menyisipkan teks setelah karakter ke-n, di mana teks adalah karakter spasi (" ").

Misalnya, untuk menyisipkan spasi setelah karakter ke-10 di sel A2: A7, masukkan rumus di bawah ini di B2 dan seret melalui B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Atau

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Dalam semua sel asli, karakter ke-10 adalah titik dua (:), jadi spasi disisipkan tepat di tempat yang kita perlukan:

Untuk menyisipkan spasi pada posisi yang berbeda di setiap sel, sesuaikan rumus yang menambahkan teks sebelum/sesudah karakter tertentu.

Dalam tabel contoh di bawah ini, titik dua (:) diposisikan setelah nomor proyek, yang mungkin berisi sejumlah karakter variabel. Karena kita ingin menambahkan spasi setelah titik dua, kita cari posisinya dengan menggunakan fungsi SEARCH:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Atau

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2)))

Cara menambahkan teks yang sama ke sel yang ada dengan VBA

Jika Anda sering kali perlu menyisipkan teks yang sama di beberapa sel, Anda dapat mengotomatiskan tugas tersebut dengan VBA.

Menambahkan teks ke awal

Makro di bawah ini menambahkan teks atau karakter tertentu ke dimulai dari semua sel yang dipilih Kedua kode mengandalkan logika yang sama: periksa setiap sel dalam rentang yang dipilih dan jika sel tidak kosong, tambahkan teks yang ditentukan. Perbedaannya adalah di mana hasilnya ditempatkan: kode pertama membuat perubahan pada data asli sedangkan kode kedua menempatkan hasilnya di kolom di sebelah kanan rentang yang dipilih.

Jika Anda memiliki sedikit pengalaman dengan VBA, panduan langkah demi langkah ini akan memandu Anda melalui proses: Cara memasukkan dan menjalankan kode VBA di Excel.

Makro 1: menambahkan teks ke sel asli

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Kode ini menyisipkan substring "PR-" di sebelah kiri teks yang sudah ada. Sebelum menggunakan kode di lembar kerja Anda, pastikan untuk mengganti teks contoh kami dengan yang benar-benar Anda butuhkan.

Makro 2: menempatkan hasil di kolom yang berdekatan

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Sebelum menjalankan makro ini, pastikan ada kolom kosong di sebelah kanan dari rentang yang dipilih, jika tidak, data yang ada akan ditimpa.

Menambahkan teks ke akhir

Jika Anda ingin menambahkan string/karakter tertentu ke akhir dari semua sel yang dipilih , kode-kode ini akan membantu Anda menyelesaikan pekerjaan dengan cepat.

Makro 1: menambahkan teks ke sel asli

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Contoh kode kami menyisipkan substring "-PR" di sebelah kanan teks yang sudah ada. Tentu saja, Anda dapat mengubahnya menjadi teks/karakter apa pun yang Anda butuhkan.

Makro 2: menempatkan hasilnya di kolom lain

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Kode ini menempatkan hasilnya dalam sebuah kolom tetangga Jadi, sebelum Anda menjalankannya, pastikan Anda memiliki setidaknya satu kolom kosong di sebelah kanan rentang yang dipilih, jika tidak, data Anda yang ada akan ditimpa.

Tambahkan teks atau karakter ke beberapa sel dengan Ultimate Suite

Di bagian pertama tutorial ini, Anda telah mempelajari beberapa rumus berbeda untuk menambahkan teks ke sel Excel. Sekarang, izinkan saya menunjukkan kepada Anda cara menyelesaikan tugas dengan beberapa klik :)

Dengan Ultimate Suite terinstal di Excel Anda, berikut adalah langkah-langkah yang harus diikuti:

1. Pilih sumber data Anda.
2. Pada Ablebits tab, di tab Teks kelompok, klik Tambahkan .
3. Pada Tambahkan Teks panel, ketik karakter/teks yang ingin Anda tambahkan ke sel yang dipilih, dan tentukan di mana karakter/teks tersebut harus disisipkan:
   • Pada awalnya
   • Pada akhirnya
   • Sebelum teks/karakter tertentu
   • Setelah teks/karakter tertentu
   • Setelah karakter ke-N dari awal atau akhir
4. Klik Tambahkan Teks tombol. Selesai!

Sebagai contoh, mari kita sisipkan string "PR-" setelah karakter "-" di sel A2: A7. Untuk ini, kami mengonfigurasi pengaturan berikut:

Sesaat kemudian, kita mendapatkan hasil yang diinginkan:

Ini adalah cara terbaik untuk menambahkan karakter dan string teks di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Tambahkan teks ke sel di Excel - contoh rumus (file .xlsm)

Ultimate Suite - versi percobaan (file .exe)