Soovite teada, kuidas Excelis olemasolevasse lahtrisse teksti lisada? Selles artiklis saate teada mõned väga lihtsad viisid, kuidas sisestada tähemärke lahtri mis tahes positsioonile.

Kui töötate Excelis tekstiandmetega, võib mõnikord olla vaja lisada olemasolevatesse lahtritesse sama teksti, et muuta asjad selgemaks. Näiteks võite soovida panna iga lahtri algusesse mingi eesliite, lisada lõppu erisümboli või paigutada teatud teksti enne valemit.

Ma arvan, et kõik teavad, kuidas seda käsitsi teha. See õpetus õpetab teile, kuidas kiiresti lisada stringid mitmesse lahtrisse valemite abil ja automatiseerida töö VBA või spetsiaalse Teksti lisamine tööriist.

Exceli valemid teksti/märgi lisamiseks lahtrisse

Konkreetse tähemärgi või teksti lisamiseks Exceli lahtrisse liita lihtsalt string ja lahtriviide, kasutades ühte järgmistest meetoditest.

Konkateerimisoperaator

Lihtsaim viis teksti stringi lisamiseks lahtrisse on kasutada ampersandi märki (&), mis on Exceli liitmisoperaator.

" tekst "& rakk

See töötab kõigis Excel 2007 - Excel 365 versioonides.

CONCATENATE funktsioon

Sama tulemuse saab saavutada funktsiooni CONCATENATE abil:

CONCATENATE(" tekst ", rakk )

Funktsioon on saadaval Excelis Microsoft 365, Excel 2019 - 2007.

CONCAT funktsioon

Teksti lisamiseks lahtritesse Excel 365, Excel 2019 ja Excel Online'is saate kasutada funktsiooni CONCAT, mis on CONCATENATE kaasaegne asendaja:

CONCAT(" tekst ", rakk )

Märkus. Palun pöörake tähelepanu sellele, et kõikides valemites, tekst tuleks sulgeda jutumärkidesse.

Need on üldised lähenemisviisid ja allpool esitatud näited näitavad, kuidas neid praktikas rakendada.

Kuidas lisada teksti lahtrite algusesse

Teatud teksti või tähemärgi lisamiseks lahtri algusesse tuleb teha järgmist:

1. Kirjutage sellesse lahtrisse, kuhu soovite tulemust väljastada, võrdusmärki (=).
2. Kirjutage soovitud tekst jutumärkide sisse.
3. Kirjutage ampersandi sümbol (&).
4. Valige lahter, kuhu tekst lisatakse, ja vajutage Enter .

Alternatiivina võite anda oma tekstistringi ja lahtriviite CONCATENATE või CONCAT funktsiooni sisendparameetrina.

Näiteks, et lisada tekst " Projekt: " projekti nimele A2, töötab mis tahes allpool esitatud valemiga.

Kõikides Exceli versioonides:

="Projekt:"&A2

=CONCATENATE("Projekt:", A2)

Excel 365 ja Excel 2019:

=CONCAT("Projekt:", A2)

Sisestage valem B2-sse, lohistage see veergu ja te saate sama teksti sisestatud kõikidesse lahtritesse.

Vihje. Ülaltoodud valemid ühendavad kaks stringi ilma tühikuta. Väärtuste eraldamiseks tühikuga kirjutage a tühiku märk eeltäidetud teksti lõpus (nt "Projekt: ").

Mugavuse huvides saate sisestada sihtteksti etteantud lahtrisse (E2) ja lisada kaks tekstirakku kokku :

Ilma tühikuta:

=$E$2&A2

=CONCATENATE($E$2, A2)

Ruumidega:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Pange tähele, et eelkirjeldatud teksti sisaldava lahtri aadress on lukustatud $-märgiga, nii et see ei nihkuks valemi kopeerimisel alla.

Selle lähenemisviisi abil saate lisatud teksti hõlpsasti muuta ühes kohas, ilma et peaksite iga valemit uuendama.

Kuidas lisada teksti Exceli lahtrite lõppu

Teksti või konkreetse tähemärgi lisamiseks olemasolevasse lahtrisse kasutage taas aheldamise meetodit. Erinevus seisneb aheldatud väärtuste järjekorras: lahtriviidale järgneb tekstirida.

Näiteks, et lisada string " -USA " lahtri A2 lõppu, on need kasutatavad valemid:

=A2&"-USA"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Teise võimalusena võite sisestada teksti mõnda lahtrisse ja seejärel liita kaks lahtrit tekstiga kokku:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Ärge unustage kasutada lisatud teksti jaoks absoluutset viidet ($D$2), et valemit saaks õigesti üle veeru kopeerida.

Tähemärkide lisamine stringi algusesse ja lõppu

Teades, kuidas teksti olemasolevasse lahtrisse ette ja juurde lisada, ei ole midagi, mis takistaks teil mõlema tehnika kasutamist ühes valemis.

Lisame näiteks stringi " Projekt: " algusesse ja " -USA " A2 olemasoleva teksti lõppu.

="Project:"&A2&"-US"

=CONCATENATE("Projekt:", A2, "-US")

=CONCAT("Projekt:", A2, "-US")

Kui stringid sisestatakse eraldi lahtritesse, toimib see võrdselt hästi:

Kahe või enama lahtri teksti ühendamine

Mitme lahtri väärtuste paigutamiseks ühte lahtrisse ühendage algsed lahtrid, kasutades juba tuttavaid tehnikaid: ampersandi sümbolit, CONCATENATE või CONCAT funktsiooni.

Näiteks, et kombineerida väärtusi veergudest A ja B, kasutades eraldusjoonena koma ja tühikut (", "), sisestage üks allpool esitatud valemitest veergu B2 ja lohistage see seejärel veerus alla.

Lisage tekst kahest lahtrist kahepoolse eraldusjoonega:

=A2&", "&B2

Ühendage kahe lahtri tekst CONCAT või CONCATENATE abil:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Kui lisate tekst kahest veerust , kasutage kindlasti suhtelisi lahtriviiteid (näiteks A2), et need kohanduksid õigesti iga rea puhul, kuhu valem kopeeritakse.

Kombineerida tekst mitmest lahtrist Excel 365-s ja Excel 2019-s saate kasutada funktsiooni TEXTJOIN. Selle süntaks näeb ette eraldaja (esimene argument), mis muudab vormi kompaktsemaks ja lihtsamaks.

Näiteks kolme veeru (A, B ja C) stringide lisamiseks, eraldades väärtused koma ja tühikuga, on valem järgmine:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Kuidas lisada Exceli lahtrisse erimärk

Erimärgi sisestamiseks Exceli lahtrisse on vaja teada selle koodi ASCII-süsteemis. Kui kood on kindlaks tehtud, tuleb see esitada funktsioonile CHAR, et tagastada vastav märk. Funktsioon CHAR võtab vastu mis tahes arvu vahemikus 1 kuni 255. Trükitavate märkide koodide loetelu (väärtused vahemikus 32 kuni 255) leiate siit.

Erimärgi lisamiseks olemasolevale väärtusele või valemi tulemusele saate kasutada mis tahes aheldamismeetodit, mis teile kõige paremini meeldib.

Näiteks kaubamärgi sümboli (™) lisamiseks tekstile A2 töötab ükskõik milline järgmistest valemitest:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Kuidas lisada teksti Exceli valemile

Teatud tähemärgi või teksti lisamiseks valemi tulemusele liita lihtsalt string koos valemiga.

Oletame, et kasutate seda valemit praeguse aja tagastamiseks:

=TEXT(NOW(), "h:mm AM/PM")

Selleks, et selgitada kasutajatele, mis kellaaeg see on, võite paigutada teksti enne ja/või pärast valemit.

Teksti sisestamine enne valemit :

="Praegune kellaaeg: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Praegune kellaaeg: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Praegune kellaaeg: ", TEXT(NOW(), "h:mm AM/PM"))

Lisage tekst pärast valemit:

=TEXT(NOW(), "h:mm AM/PM")&" - praegune kellaaeg"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - praegune kellaaeg")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - praegune kellaaeg")

Lisage tekst valemile mõlemale poole:

="Praegu on " &TEXT(NOW(), "h:mm AM/PM")& " siin Gomelis"

=CONCATENATE("See on ", TEXT(NOW(), "h:mm AM/PM"), " siin Gomelis")

=CONCAT("Praegu on ", TEXT(NOW(), "h:mm AM/PM"), " siin Gomelis")

Kuidas sisestada teksti pärast N-ndat märki

Et lisada teatud teksti või märki teatud positsioonile lahtrisse, tuleb algne string jagada kaheks osaks ja paigutada tekst nende vahele. Siin on, kuidas:

1. Eemaldage sisestatud tekstile eelnev alajaotus funktsiooni LEFT abil:

LEFT(cell, n)

Ekstraheeri tekstile järgnev alamjada, kasutades kombinatsiooni RIGHT ja LEN:

RIGHT(lahter, LEN(lahter) -n)

Ühendage kaks alajaotust ja tekst/märk kokku, kasutades ampersandi sümbolit.

Täielik valem on sellisel kujul:

LEFT( rakk , n ) & " tekst " & RIGHT( rakk , LEN( rakk ) - n )

Samu osi saab ühendada, kasutades funktsiooni CONCATENATE või CONCAT:

CONCATENATE(LEFT( rakk , n ), " tekst ", RIGHT( rakk , LEN( rakk ) - n ))

Ülesannet saab täita ka funktsiooni REPLACE abil:

REPLACE( rakk , n+1 , 0, " tekst ")

Trikk on selles, et num_chars argument, mis määrab, mitu märki asendada, on seatud 0, nii et valem tegelikult sisestab tekst määratud positsioonil lahtris ilma midagi asendamata. Positsioon ( start_num argument) arvutatakse selle väljendi abil: n+1. Me lisame n-ndale märgile 1, sest tekst tuleks sisestada pärast seda.

Näiteks, et lisada sidekriips (-) pärast A2 2. märki, on valem B2:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Või

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Või

=REPLACE(A2, 2+1, 0, "-")

Lohistage valemit allapoole ja te saate sama tähemärgi sisestatud kõikidesse lahtritesse:

Kuidas lisada teksti enne/pärast konkreetset märki

Selleks, et sisestada teatud teksti enne või pärast teatud märki, tuleb määrata selle tähemärgi asukoht stringis. Seda saab teha funktsiooni SEARCH abil:

SEARCH(" char ", rakk )

Kui positsioon on kindlaks määratud, saate lisada stringi täpselt sellesse kohta, kasutades ülaltoodud näites käsitletud lähenemisviise.

Teksti lisamine pärast konkreetset märki

Teksti lisamiseks pärast antud märki on üldine valem:

LEFT( rakk , SEARCH(" char ", rakk )) & " tekst " & RIGHT( rakk , LEN( rakk ) - SEARCH(" char ", rakk ))

Või

CONCATENATE(LEFT( rakk , SEARCH(" char ", rakk )), " tekst ", RIGHT( rakk , LEN( rakk ) - SEARCH(" char ", rakk )))

Näiteks teksti sisestamiseks (USA) pärast sidekriipsu A2, valem on:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Või

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))))

Teksti sisestamine enne konkreetset märki

Teksti lisamiseks enne teatud märki on valem:

LEFT( rakk , SEARCH(" char ", rakk ) -1) & " tekst " & RIGHT( rakk , LEN( rakk ) - SEARCH(" char ", rakk ) +1)

Või

CONCATENATE(LEFT( rakk , SEARCH(" char ", rakk ) - 1), " tekst ", RIGHT( rakk , LEN( rakk ) - SEARCH(" char ", rakk ) +1))

Nagu näete, on valemid väga sarnased nendega, mis sisestavad teksti pärast märki. Erinevus seisneb selles, et me lahutame esimese OTSIMISE tulemusest 1, et sundida funktsiooni LEFT jätma välja märki, mille järel tekst lisatakse. Teise OTSIMISE tulemusele lisame 1, et funktsioon RIGHT saaks selle märgi kätte.

Näiteks teksti paigutamiseks (USA) enne sidekriipsu A2, siis tuleb kasutada seda valemit:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Või

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)))

Märkused:

• Kui algne lahter sisaldab mitu esinemist tähemärki, lisatakse tekst enne/pärast esimest esinemist.
• Funktsioon SEARCH on suur- ja väiketähelepanuta ja ei suuda eristada väikseid ja suuri tähemärke. Kui soovite lisada teksti enne/järgmisel väikse või suure tähe, siis kasutage selle tähe leidmiseks suur- ja väiketähte arvestavat funktsiooni FIND.

Kuidas lisada ruumi teksti vahel Exceli lahtrisse

Tegelikult on see vaid kahe eelneva näite erijuhtum.

Ruumi lisamiseks aadressil sama positsioon kõikides lahtrites, kasutage valemit, et sisestada tekst pärast n-ndat märki, kus tekst on tühiku märk (" ").

Näiteks, et sisestada tühik pärast 10. märki lahtritesse A2:A7, sisestage allpool olev valem lahtrisse B2 ja lohistage see läbi lahtri B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Või

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Kõigis algsetes lahtrites on 10. märk koolon (:), seega sisestatakse tühik täpselt sinna, kus seda vajame:

Tühiku sisestamiseks aadressil erinev positsioon igas lahtris kohandada valemit, mis lisab teksti enne/pärast konkreetset märki.

Alljärgnevas näidistabelis on pärast projekti numbrit, mis võib sisaldada muutuvat arvu tähemärke, paigutatud koolon (:). Kuna me soovime kooloni järel lisada tühiku, otsime selle koha üles, kasutades funktsiooni SEARCH:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Või

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))))

Kuidas lisada sama teksti olemasolevatele lahtritele VBA abil

Kui teil on sageli vaja sisestada sama teksti mitmesse lahtrisse, saate selle ülesande VBA abil automatiseerida.

Teksti algusesse lisamine

Allpool toodud makrode abil saab lisada teksti või konkreetse tähemärgi algus kõigi valitud lahtrite kohta Mõlemad koodid tuginevad samale loogikale: kontrollitakse iga lahtrit valitud vahemikus ja kui lahter ei ole tühi, lisatakse etteantud tekst. Erinevus seisneb selles, kuhu tulemus paigutatakse: esimene kood muudab algseid andmeid, teine aga paigutab tulemused valitud vahemikust paremale jäävasse veergu.

Kui teil on VBAga vähe kogemusi, siis juhendab see samm-sammult: Kuidas sisestada ja käivitada VBA-koodi Excelis.

Makro 1: lisab teksti algsetesse lahtritesse

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

See kood lisab olemasolevast tekstist vasakule alajaotuse "PR-". Enne koodi kasutamist oma töölehel asendage kindlasti meie näidistekst sellega, mida te tegelikult vajate.

Makro 2: paigutab tulemused kõrvalolevasse veergu.

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Enne selle makro käivitamist veenduge, et on olemas tühi veerg paremal valitud vahemikus, vastasel juhul kirjutatakse olemasolevad andmed üle.

Teksti lisamine lõppu

Kui soovite lisada konkreetse stringi/tähemärgi kohta lõpp kõigi valitud lahtrite kohta , need koodid aitavad teil töö kiiresti ära teha.

Makro 1: lisab teksti algsetele lahtritele

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Meie näidiskood lisab olemasoleva teksti paremale küljele alajaotuse "-PR". Loomulikult saate seda muuta mis tahes tekstiks/märgiks, mida vajate.

Makro 2: paigutab tulemused teise veergu

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

See kood paigutab tulemused naabersammas Enne selle käivitamist veenduge, et valitud vahemikust paremal on vähemalt üks tühi veerg, sest vastasel juhul kirjutatakse olemasolevad andmed üle.

Teksti või tähemärgi lisamine mitmesse lahtrisse Ultimate Suite'iga

Selle õpetuse esimeses osas olete õppinud käputäis erinevaid valemeid teksti lisamiseks Exceli lahtritesse. Nüüd näitan teile, kuidas seda ülesannet paari klõpsuga täita :)

Kui Ultimate Suite on installitud Excelisse, on järgmised sammud:

1. Valige oma lähteandmed.
2. On Ablebits vahekaardil Tekst rühma, klõpsake Lisa .
3. On Teksti lisamine paanile, sisestage märk/tekst, mida soovite valitud lahtritesse lisada, ja määrake, kuhu see tuleks sisestada:
   • Alguses
   • Lõpus
   • Enne konkreetset teksti/märki
   • Pärast konkreetset teksti/märki
   • Pärast N-ndat märki algusest või lõpust
4. Klõpsake nuppu Teksti lisamine nuppu. Valmis!

Näitena sisestame lahtritesse A2:A7 pärast märki "-" stringi "PR-". Selleks seadistame järgmised seaded:

Hetk hiljem saame soovitud tulemuse:

Need on parimad viisid tähemärkide ja tekstisõnade lisamiseks Excelis. Tänan teid lugemast ja loodan, et näeme teid järgmisel nädalal meie blogis!

Saadaolevad allalaadimised

Teksti lisamine Exceli lahtrisse - valemite näited (.xlsm fail)

Ultimate Suite - prooviversioon (.exe fail)