Αναρωτιέστε πώς να προσθέσετε κείμενο σε ένα υπάρχον κελί στο Excel; Σε αυτό το άρθρο, θα μάθετε μερικούς πολύ απλούς τρόπους για να εισάγετε χαρακτήρες σε οποιαδήποτε θέση σε ένα κελί.

Όταν εργάζεστε με δεδομένα κειμένου στο Excel, μπορεί μερικές φορές να χρειαστεί να προσθέσετε το ίδιο κείμενο σε υπάρχοντα κελιά για να κάνετε τα πράγματα πιο σαφή. Για παράδειγμα, μπορεί να θέλετε να βάλετε κάποιο πρόθεμα στην αρχή κάθε κελιού, να εισάγετε ένα ειδικό σύμβολο στο τέλος ή να τοποθετήσετε ορισμένο κείμενο πριν από έναν τύπο.

Υποθέτω ότι όλοι γνωρίζουν πώς να το κάνουν αυτό χειροκίνητα. Αυτό το σεμινάριο θα σας διδάξει πώς να προσθέσετε γρήγορα συμβολοσειρές σε πολλαπλά κελιά χρησιμοποιώντας τύπους και να αυτοματοποιήσετε την εργασία με VBA ή ένα ειδικό Προσθήκη κειμένου εργαλείο.

Τύποι του Excel για την προσθήκη κειμένου/χαρακτήρα στο κελί

Για να προσθέσετε έναν συγκεκριμένο χαρακτήρα ή κείμενο σε ένα κελί του Excel, απλώς συνδέστε μια συμβολοσειρά και μια αναφορά κελιού χρησιμοποιώντας μία από τις παρακάτω μεθόδους.

Τελεστής συνένωσης

Ο ευκολότερος τρόπος για να προσθέσετε μια συμβολοσειρά κειμένου σε ένα κελί είναι να χρησιμοποιήσετε τον χαρακτήρα ampersand (&), ο οποίος είναι ο τελεστής συνένωσης στο Excel.

" κείμενο "&, κύτταρο

Αυτό λειτουργεί σε όλες τις εκδόσεις του Excel 2007 - Excel 365.

Συνάρτηση CONCATENATE

Το ίδιο αποτέλεσμα μπορεί να επιτευχθεί με τη βοήθεια της συνάρτησης CONCATENATE:

CONCATENATE(" κείμενο ", κύτταρο )

Η λειτουργία είναι διαθέσιμη στο Excel για το Microsoft 365, Excel 2019 - 2007.

Συνάρτηση CONCAT

Για να προσθέσετε κείμενο σε κελιά στο Excel 365, το Excel 2019 και το Excel Online, μπορείτε να χρησιμοποιήσετε τη συνάρτηση CONCAT, η οποία είναι μια σύγχρονη αντικατάσταση της CONCATENATE:

CONCAT(" κείμενο ", κύτταρο )

Σημείωση. Παρακαλείστε να προσέξετε ότι, σε όλους τους τύπους, κείμενο πρέπει να περικλείεται σε εισαγωγικά.

Αυτές είναι οι γενικές προσεγγίσεις και τα παρακάτω παραδείγματα δείχνουν πώς μπορούν να εφαρμοστούν στην πράξη.

Πώς να προσθέσετε κείμενο στην αρχή των κελιών

Για να προσθέσετε συγκεκριμένο κείμενο ή χαρακτήρα στην αρχή ενός κελιού, πρέπει να κάνετε τα εξής:

1. Στο κελί όπου θέλετε να εξάγετε το αποτέλεσμα, πληκτρολογήστε το σύμβολο της ισότητας (=).
2. Πληκτρολογήστε το επιθυμητό κείμενο μέσα στα εισαγωγικά.
3. Πληκτρολογήστε ένα σύμβολο τελείας (&).
4. Επιλέξτε το κελί στο οποίο θα προστεθεί το κείμενο και πατήστε Enter .

Εναλλακτικά, μπορείτε να παρέχετε τη συμβολοσειρά κειμένου και την αναφορά κελιού ως παραμέτρους εισόδου στη συνάρτηση CONCATENATE ή CONCAT.

Για παράδειγμα, για να προτάξετε το κείμενο " Έργο: " σε ένα όνομα έργου στο Α2, οποιοσδήποτε από τους παρακάτω τύπους θα λειτουργήσει.

Σε όλες τις εκδόσεις του Excel:

="Project:"&A2

=CONCATENATE("Project:", A2)

Στο Excel 365 και στο Excel 2019:

=CONCAT("Έργο:", A2)

Εισάγετε τον τύπο στο B2, σύρετε τον προς τα κάτω στη στήλη και θα έχετε το ίδιο κείμενο σε όλα τα κελιά.

Συμβουλή. Οι παραπάνω τύποι ενώνουν δύο συμβολοσειρές χωρίς κενά. Για να διαχωρίσετε τις τιμές με ένα κενό διάστημα, πληκτρολογήστε ένα χαρακτήρας διαστήματος στο τέλος του κειμένου που προστίθεται (π.χ. "Project: ").

Για ευκολία, μπορείτε να εισαγάγετε το κείμενο-στόχο σε ένα προκαθορισμένο κελί (E2) και προσθήκη δύο κελιών κειμένου μαζί :

Χωρίς κενά:

=$E$2&A2

=CONCATENATE($E$2, A2)

Με κενά:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Παρατηρήστε ότι η διεύθυνση του κελιού που περιέχει το προστιθέμενο κείμενο είναι κλειδωμένη με το σύμβολο $, ώστε να μην μετατοπίζεται κατά την αντιγραφή του τύπου προς τα κάτω.

Με αυτή την προσέγγιση, μπορείτε εύκολα να αλλάξετε το προστιθέμενο κείμενο σε ένα σημείο, χωρίς να χρειάζεται να ενημερώνετε κάθε τύπο.

Πώς να προσθέσετε κείμενο στο τέλος των κελιών στο Excel

Για να προσθέσετε κείμενο ή συγκεκριμένο χαρακτήρα σε ένα υπάρχον κελί, χρησιμοποιήστε ξανά τη μέθοδο της συνένωσης. Η διαφορά έγκειται στη σειρά των συνυφασμένων τιμών: μια αναφορά κελιού ακολουθείται από μια συμβολοσειρά κειμένου.

Για παράδειγμα, για να προσθέσετε τη συμβολοσειρά " -ΗΠΑ " στο τέλος του κελιού A2, αυτοί είναι οι τύποι που πρέπει να χρησιμοποιηθούν:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Εναλλακτικά, μπορείτε να εισαγάγετε το κείμενο σε κάποιο κελί και, στη συνέχεια, να ενώσετε δύο κελιά με κείμενο μεταξύ τους:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Θυμηθείτε να χρησιμοποιήσετε μια απόλυτη αναφορά για το προσαρτημένο κείμενο ($D$2), ώστε ο τύπος να αντιγραφεί σωστά σε όλη τη στήλη.

Προσθήκη χαρακτήρων στην αρχή και το τέλος μιας συμβολοσειράς

Γνωρίζοντας πώς να προθέτετε και να προσαρτάτε κείμενο σε ένα υπάρχον κελί, δεν υπάρχει τίποτα που να σας εμποδίζει να χρησιμοποιήσετε και τις δύο τεχνικές μέσα σε έναν τύπο.

Ως παράδειγμα, ας προσθέσουμε το αλφαριθμητικό " Έργο: " στην αρχή και " -ΗΠΑ " στο τέλος του υπάρχοντος κειμένου στο Α2.

="Project:"&A2&"-US"

=CONCATENATE("Project:", A2, "-US")

=CONCAT("Project:", A2, "-US")

Με την εισαγωγή των συμβολοσειρών σε ξεχωριστά κελιά, αυτό λειτουργεί εξίσου καλά:

Συνδυασμός κειμένου από δύο ή περισσότερα κελιά

Για να τοποθετήσετε τιμές από πολλαπλά κελιά σε ένα κελί, ενώστε τα αρχικά κελιά χρησιμοποιώντας τις ήδη γνωστές τεχνικές: ένα σύμβολο με τελεία και παύλα, τη συνάρτηση CONCATENATE ή CONCAT.

Για παράδειγμα, για να συνδυάσετε τιμές από τις στήλες Α και Β χρησιμοποιώντας ένα κόμμα και ένα κενό (", ") για το διαχωριστικό, εισαγάγετε έναν από τους παρακάτω τύπους στη στήλη Β2 και, στη συνέχεια, σύρετέ τον προς τα κάτω στη στήλη.

Προσθήκη κειμένου από δύο κελιά με τελεία και παύλα:

=A2&", "&B2

Συνδυασμός κειμένου από δύο κελιά με CONCAT ή CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Κατά την προσθήκη κείμενο από δύο στήλες , βεβαιωθείτε ότι χρησιμοποιείτε σχετικές αναφορές κελιών (όπως A2), ώστε να προσαρμόζονται σωστά για κάθε γραμμή όπου αντιγράφεται ο τύπος.

Για να συνδυάσετε κείμενο από πολλαπλά κελιά στο Excel 365 και το Excel 2019, μπορείτε να αξιοποιήσετε τη συνάρτηση TEXTJOIN. Η σύνταξή της προβλέπει έναν διαχωριστή (το πρώτο όρισμα), ο οποίος καθιστά τον τύπο πιο συμπαγή και ευκολότερο στη διαχείριση.

Για παράδειγμα, για να προσθέσετε συμβολοσειρές από τρεις στήλες (A, B και C), διαχωρίζοντας τις τιμές με κόμμα και κενό, ο τύπος είναι:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Πώς να προσθέσετε ειδικό χαρακτήρα σε κελί στο Excel

Για να εισαγάγετε έναν ειδικό χαρακτήρα σε ένα κελί του Excel, πρέπει να γνωρίζετε τον κωδικό του στο σύστημα ASCII. Μόλις καθοριστεί ο κωδικός, δώστε τον στη συνάρτηση CHAR για να επιστρέψει έναν αντίστοιχο χαρακτήρα. Η συνάρτηση CHAR δέχεται οποιονδήποτε αριθμό από το 1 έως το 255. Μια λίστα με τους εκτυπώσιμους κωδικούς χαρακτήρων (τιμές από 32 έως 255) μπορείτε να βρείτε εδώ.

Για να προσθέσετε έναν ειδικό χαρακτήρα σε μια υπάρχουσα τιμή ή σε ένα αποτέλεσμα τύπου, μπορείτε να εφαρμόσετε οποιαδήποτε μέθοδο συνένωσης που σας αρέσει περισσότερο.

Για παράδειγμα, για να προσθέσετε το σύμβολο του εμπορικού σήματος (™) στο κείμενο στο Α2, οποιοσδήποτε από τους ακόλουθους τύπους θα λειτουργήσει:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Πώς να προσθέσετε κείμενο στον τύπο του Excel

Για να προσθέσετε έναν συγκεκριμένο χαρακτήρα ή κείμενο σε ένα αποτέλεσμα ενός τύπου, απλώς συνδέστε μια συμβολοσειρά με τον ίδιο τον τύπο.

Ας υποθέσουμε ότι χρησιμοποιείτε αυτόν τον τύπο για να επιστρέψετε την τρέχουσα ώρα:

=TEXT(NOW(), "h:mm AM/PM")

Για να εξηγήσετε στους χρήστες σας τι ώρα είναι, μπορείτε να τοποθετήσετε κάποιο κείμενο πριν ή/και μετά τον τύπο.

Εισαγωγή κειμένου πριν από τον τύπο :

="Τρέχουσα ώρα: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Τρέχουσα ώρα: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Τρέχουσα ώρα: ", TEXT(NOW(), "h:mm AM/PM"))

Προσθέστε κείμενο μετά τον τύπο:

=TEXT(NOW(), "h:mm AM/PM")&" - τρέχουσα ώρα"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - τρέχουσα ώρα")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - τρέχουσα ώρα")

Προσθέστε κείμενο στον τύπο και στις δύο πλευρές:

="Είναι " &TEXT(NOW(), "h:mm AM/PM")& " εδώ στο Γκόμελ"

=CONCATENATE("Είναι ", TEXT(NOW(), "h:mm AM/PM"), " εδώ στο Gomel")

=CONCAT("Είναι ", TEXT(NOW(), "h:mm AM/PM"), " εδώ στο Gomel")

Πώς να εισαγάγετε κείμενο μετά τον Nοστό χαρακτήρα

Για να προσθέσετε ένα συγκεκριμένο κείμενο ή χαρακτήρα σε μια συγκεκριμένη θέση σε ένα κελί, πρέπει να χωρίσετε την αρχική συμβολοσειρά σε δύο μέρη και να τοποθετήσετε το κείμενο ανάμεσά τους. Ακούστε πώς:

1. Εξάγετε μια υποπερίοδο που προηγείται του εισαγόμενου κειμένου με τη βοήθεια της συνάρτησης LEFT:

LEFT(cell, n)

Εξάγετε μια υποπερίοδο μετά το κείμενο χρησιμοποιώντας το συνδυασμό των RIGHT και LEN:

RIGHT(cell, LEN(cell) -n)

Συνδυάστε τις δύο υποομάδες και το κείμενο/χαρακτήρα χρησιμοποιώντας ένα σύμβολο ampersand.

Ο πλήρης τύπος έχει την εξής μορφή:

LEFT( κύτταρο , n ) & " κείμενο " & RIGHT( κύτταρο , LEN( κύτταρο ) - n )

Τα ίδια μέρη μπορούν να ενωθούν μεταξύ τους με τη χρήση της συνάρτησης CONCATENATE ή CONCAT:

CONCATENATE(LEFT( κύτταρο , n ), " κείμενο ", RIGHT( κύτταρο , LEN( κύτταρο ) - n ))

Η εργασία μπορεί επίσης να πραγματοποιηθεί με τη χρήση της συνάρτησης REPLACE:

REPLACE( κύτταρο , n+1 , 0, " κείμενο ")

Το κόλπο είναι ότι η num_chars το όρισμα που ορίζει πόσοι χαρακτήρες θα αντικατασταθούν έχει οριστεί σε 0, οπότε ο τύπος εισάγει στην πραγματικότητα κείμενο στην καθορισμένη θέση σε ένα κελί χωρίς να αντικαταστήσει τίποτα. Η θέση ( start_num όρισμα) υπολογίζεται με την ακόλουθη έκφραση: n+1. Προσθέτουμε 1 στη θέση του n-οστού χαρακτήρα επειδή το κείμενο πρέπει να εισαχθεί μετά από αυτόν.

Για παράδειγμα, για να εισαγάγετε μια παύλα (-) μετά τον 2ο χαρακτήρα στο Α2, ο τύπος στο Β2 είναι:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Ή

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Ή

=REPLACE(A2, 2+1, 0, "-")

Σύρετε τον τύπο προς τα κάτω και θα έχετε τον ίδιο χαρακτήρα σε όλα τα κελιά:

Πώς να προσθέσετε κείμενο πριν/μετά από έναν συγκεκριμένο χαρακτήρα

Για να εισαγάγετε συγκεκριμένο κείμενο πριν ή μετά από έναν συγκεκριμένο χαρακτήρα, πρέπει να προσδιορίσετε τη θέση αυτού του χαρακτήρα σε μια συμβολοσειρά. Αυτό μπορεί να γίνει με τη βοήθεια της λειτουργίας SEARCH:

SEARCH(" char ", κύτταρο )

Μόλις καθοριστεί η θέση, μπορείτε να προσθέσετε μια συμβολοσειρά ακριβώς σε αυτό το σημείο χρησιμοποιώντας τις προσεγγίσεις που συζητήθηκαν στο παραπάνω παράδειγμα.

Προσθήκη κειμένου μετά από συγκεκριμένο χαρακτήρα

Για να εισαγάγετε κάποιο κείμενο μετά από έναν συγκεκριμένο χαρακτήρα, ο γενικός τύπος είναι:

LEFT( κύτταρο , SEARCH(" char ", κύτταρο )) & " κείμενο " & RIGHT( κύτταρο , LEN( κύτταρο ) - SEARCH(" char ", κύτταρο ))

Ή

CONCATENATE(LEFT( κύτταρο , SEARCH(" char ", κύτταρο )), " κείμενο ", RIGHT( κύτταρο , LEN( κύτταρο ) - SEARCH(" char ", κύτταρο )))

Για παράδειγμα, για να εισαγάγετε το κείμενο (ΗΠΑ) μετά από μια παύλα στο Α2, ο τύπος είναι:

=LEFT(A2, SEARCH("-", A2)) &?"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Ή

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))))

Εισαγωγή κειμένου πριν από συγκεκριμένο χαρακτήρα

Για να προσθέσετε κάποιο κείμενο πριν από έναν συγκεκριμένο χαρακτήρα, ο τύπος είναι:

LEFT( κύτταρο , SEARCH(" char ", κύτταρο ) -1) & " κείμενο " & RIGHT( κύτταρο , LEN( κύτταρο ) - SEARCH(" char ", κύτταρο ) +1)

Ή

CONCATENATE(LEFT( κύτταρο , SEARCH(" char ", κύτταρο ) - 1), " κείμενο ", RIGHT( κύτταρο , LEN( κύτταρο ) - SEARCH(" char ", κύτταρο ) +1))

Όπως βλέπετε, οι τύποι μοιάζουν πολύ με εκείνους που εισάγουν κείμενο μετά από έναν χαρακτήρα. Η διαφορά είναι ότι αφαιρούμε 1 από το αποτέλεσμα της πρώτης ΑΝΑΖΗΤΗΣΗΣ για να αναγκάσουμε τη συνάρτηση ΑΡΙΣΤΕΡΑ να αφήσει εκτός τον χαρακτήρα μετά τον οποίο προστίθεται το κείμενο. Στο αποτέλεσμα της δεύτερης ΑΝΑΖΗΤΗΣΗΣ προσθέτουμε 1, ώστε η συνάρτηση ΔΕΞΙΑ να πάρει αυτόν τον χαρακτήρα.

Για παράδειγμα, για να τοποθετήσετε το κείμενο (ΗΠΑ) πριν από μια παύλα στο Α2, αυτός είναι ο τύπος που πρέπει να χρησιμοποιήσετε:

=LEFT(A2, SEARCH("-", A2) -1) &?"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Ή

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)))

Σημειώσεις:

• Εάν το αρχικό κελί περιέχει πολλαπλά περιστατικά ενός χαρακτήρα, το κείμενο θα εισαχθεί πριν/μετά την πρώτη εμφάνιση.
• Η λειτουργία SEARCH είναι case-insensitive και δεν μπορεί να διακρίνει πεζούς και κεφαλαίους χαρακτήρες. Αν σκοπεύετε να προσθέσετε κείμενο πριν/μετά από ένα πεζό ή κεφαλαίο γράμμα, τότε χρησιμοποιήστε τη λειτουργία FIND που διακρίνει την πεζότητα για να εντοπίσετε το γράμμα αυτό.

Πώς να προσθέσετε χώρο μεταξύ του κειμένου στο κελί του Excel

Στην πραγματικότητα, πρόκειται απλώς για μια ειδική περίπτωση των δύο προηγούμενων παραδειγμάτων.

Για να προσθέσετε χώρο στο ίδια θέση σε όλα τα κελιά, χρησιμοποιήστε τον τύπο για να εισαγάγετε κείμενο μετά τον nοστό χαρακτήρα, όπου κείμενο είναι ο χαρακτήρας διαστήματος (" ").

Για παράδειγμα, για να εισαγάγετε ένα κενό μετά τον 10ο χαρακτήρα στα κελιά Α2:Α7, εισαγάγετε τον παρακάτω τύπο στο Β2 και σύρετέ τον μέσω του Β7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Ή

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Σε όλα τα αρχικά κελιά, ο 10ος χαρακτήρας είναι μια άνω και κάτω τελεία (:), οπότε ένα κενό εισάγεται ακριβώς εκεί που το χρειαζόμαστε:

Για να εισαγάγετε κενό σε ένα διαφορετική θέση σε κάθε κελί, προσαρμόστε τον τύπο που προσθέτει κείμενο πριν/μετά από έναν συγκεκριμένο χαρακτήρα.

Στον πίνακα του παρακάτω δείγματος, μια άνω και κάτω τελεία (:) βρίσκεται μετά τον αριθμό έργου, ο οποίος μπορεί να περιέχει μεταβλητό αριθμό χαρακτήρων. Καθώς θέλουμε να προσθέσουμε ένα κενό μετά την άνω και κάτω τελεία, εντοπίζουμε τη θέση της με τη λειτουργία SEARCH:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Ή

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))))

Πώς να προσθέσετε το ίδιο κείμενο σε υπάρχοντα κελιά με την VBA

Αν χρειάζεται συχνά να εισάγετε το ίδιο κείμενο σε πολλά κελιά, μπορείτε να αυτοματοποιήσετε την εργασία με τη VBA.

Προσθήκη κειμένου στην αρχή

Οι παρακάτω μακροεντολές προσθέτουν κείμενο ή έναν συγκεκριμένο χαρακτήρα στο αρχή όλων των επιλεγμένων κελιών Και οι δύο κώδικες βασίζονται στην ίδια λογική: ελέγξτε κάθε κελί στην επιλεγμένη περιοχή και αν το κελί δεν είναι κενό, προσθέστε το καθορισμένο κείμενο. Η διαφορά είναι πού τοποθετείται το αποτέλεσμα: ο πρώτος κώδικας κάνει αλλαγές στα αρχικά δεδομένα, ενώ ο δεύτερος τοποθετεί τα αποτελέσματα σε μια στήλη στα δεξιά της επιλεγμένης περιοχής.

Αν έχετε μικρή εμπειρία με το VBA, αυτός ο οδηγός βήμα προς βήμα θα σας καθοδηγήσει στη διαδικασία: Πώς να εισάγετε και να εκτελείτε κώδικα VBA στο Excel.

Μακροεντολή 1: προσθέτει κείμενο στα αρχικά κελιά

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Αυτός ο κώδικας εισάγει την υποσειρά "PR-" στα αριστερά ενός υπάρχοντος κειμένου. Πριν χρησιμοποιήσετε τον κώδικα στο φύλλο εργασίας σας, φροντίστε να αντικαταστήσετε το κείμενο του δείγματός μας με αυτό που πραγματικά χρειάζεστε.

Μακροεντολή 2: τοποθετεί τα αποτελέσματα στη διπλανή στήλη

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Πριν εκτελέσετε αυτή τη μακροεντολή, βεβαιωθείτε ότι υπάρχει μια κενή στήλη στα δεξιά του επιλεγμένου εύρους, διαφορετικά τα υπάρχοντα δεδομένα θα αντικατασταθούν.

Προσθήκη κειμένου στο τέλος

Αν θέλετε να προσθέσετε μια συγκεκριμένη συμβολοσειρά/χαρακτήρα στο αρχείο τέλος όλων των επιλεγμένων κελιών , αυτοί οι κωδικοί θα σας βοηθήσουν να κάνετε γρήγορα τη δουλειά σας.

Μακροεντολή 1: προσθέτει κείμενο στα αρχικά κελιά

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Ο κώδικας του παραδείγματός μας εισάγει την υποσέλιδο "-PR" στα δεξιά ενός υπάρχοντος κειμένου. Φυσικά, μπορείτε να το αλλάξετε σε οποιοδήποτε κείμενο/χαρακτήρα χρειάζεστε.

Μακροεντολή 2: τοποθετεί τα αποτελέσματα σε άλλη στήλη

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Αυτός ο κώδικας τοποθετεί τα αποτελέσματα σε ένα γειτονική στήλη Έτσι, πριν την εκτελέσετε, βεβαιωθείτε ότι έχετε τουλάχιστον μια κενή στήλη στα δεξιά του επιλεγμένου εύρους, διαφορετικά τα υπάρχοντα δεδομένα σας θα αντικατασταθούν.

Προσθήκη κειμένου ή χαρακτήρα σε πολλαπλά κελιά με την Ultimate Suite

Στο πρώτο μέρος αυτού του σεμιναρίου, μάθατε μια χούφτα διαφορετικών τύπων για να προσθέσετε κείμενο σε κελιά του Excel. Τώρα, επιτρέψτε μου να σας δείξω πώς να ολοκληρώσετε την εργασία με μερικά κλικ :)

Με εγκατεστημένο το Ultimate Suite στο Excel, ακολουθούν τα βήματα που πρέπει να ακολουθήσετε:

1. Επιλέξτε τα δεδομένα της πηγής σας.
2. Στο Ablebits στην καρτέλα Κείμενο ομάδα, κάντε κλικ στο Προσθέστε .
3. Στο Προσθήκη κειμένου πληκτρολογήστε τον χαρακτήρα/το κείμενο που θέλετε να προσθέσετε στα επιλεγμένα κελιά και καθορίστε το σημείο στο οποίο θα εισαχθεί:
   • Στην αρχή
   • Στο τέλος
   • Πριν από συγκεκριμένο κείμενο/χαρακτήρα
   • Μετά από συγκεκριμένο κείμενο/χαρακτήρα
   • Μετά τον Ν-οστό χαρακτήρα από την αρχή ή το τέλος
4. Κάντε κλικ στο Προσθήκη κειμένου κουμπί. Έγινε!

Ως παράδειγμα, ας εισάγουμε τη συμβολοσειρά "PR-" μετά τον χαρακτήρα "-" στα κελιά A2:A7. Για το σκοπό αυτό, διαμορφώνουμε τις ακόλουθες ρυθμίσεις:

Λίγο αργότερα, έχουμε το επιθυμητό αποτέλεσμα:

Αυτοί είναι οι καλύτεροι τρόποι για να προσθέσετε χαρακτήρες και συμβολοσειρές κειμένου στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Προσθήκη κειμένου σε κελί στο Excel - παραδείγματα τύπων (.xlsm αρχείο)

Ultimate Suite - δοκιμαστική έκδοση (.exe αρχείο)