Vraagt u zich af hoe u tekst kunt toevoegen aan een bestaande cel in Excel? In dit artikel leert u een paar heel eenvoudige manieren om tekens in te voegen op een willekeurige plaats in een cel.

Wanneer u in Excel met tekstgegevens werkt, moet u soms dezelfde tekst aan bestaande cellen toevoegen om de dingen duidelijker te maken. U wilt bijvoorbeeld een voorvoegsel aan het begin van elke cel zetten, een speciaal symbool aan het eind invoegen of bepaalde tekst vóór een formule plaatsen.

Ik neem aan dat iedereen weet hoe je dit handmatig moet doen. Deze tutorial leert je hoe je snel tekenreeksen aan meerdere cellen kunt toevoegen met behulp van formules en het werk kunt automatiseren met VBA of een speciale Tekst toevoegen gereedschap.

Excel formules om tekst/teken aan cel toe te voegen

Om een specifiek teken of tekst aan een Excel-cel toe te voegen, voegt u eenvoudigweg een tekenreeks en een celverwijzing samen met behulp van een van de volgende methoden.

Aaneenschakelingsoperator

De eenvoudigste manier om een tekststring aan een cel toe te voegen is met een ampersand-teken (&), de aaneenschakelingsoperator in Excel.

" tekst "& cel

Dit werkt in alle versies van Excel 2007 - Excel 365.

CONCATENATE functie

Hetzelfde resultaat kan worden bereikt met behulp van de functie CONCATENATE:

CONCATENATE(" tekst ", cel )

De functie is beschikbaar in Excel voor Microsoft 365, Excel 2019 - 2007.

CONCAT functie

Om tekst toe te voegen aan cellen in Excel 365, Excel 2019 en Excel Online, kunt u de functie CONCAT gebruiken, die een moderne vervanging is van CONCATENATE:

CONCAT(" tekst ", cel )

Let erop dat in alle formules, tekst moet tussen aanhalingstekens staan.

Dit zijn de algemene benaderingen, en de onderstaande voorbeelden laten zien hoe ze in de praktijk kunnen worden toegepast.

Hoe tekst toevoegen aan het begin van cellen

Om bepaalde tekst of tekens aan het begin van een cel toe te voegen, moet u het volgende doen:

1. In de cel waar u het resultaat wilt uitvoeren, typt u het gelijkteken (=).
2. Typ de gewenste tekst binnen de aanhalingstekens.
3. Typ een ampersand symbool (&).
4. Selecteer de cel waaraan de tekst moet worden toegevoegd en druk op Enter .

Als alternatief kunt u uw tekststring en celverwijzing opgeven als invoerparameters voor de functie CONCATENATE of CONCAT.

Om bijvoorbeeld de tekst " Project: " aan een projectnaam in A2, werkt elk van de onderstaande formules.

In alle Excel-versies:

="Project:"&A2

=CONCATENATE("Project:", A2)

In Excel 365 en Excel 2019:

=CONCAT("Project:", A2)

Voer de formule in B2 in, sleep hem naar beneden in de kolom, en u krijgt dezelfde tekst ingevoegd in alle cellen.

Tip. De bovenstaande formules voegen twee strings samen zonder spaties. Om waarden te scheiden met een spatie, typ je een spatie karakter aan het einde van de voorgehangen tekst (bijvoorbeeld "Project: ").

Voor het gemak kunt u de doeltekst invoeren in een vooraf gedefinieerde cel (E2) en twee tekstcellen aan elkaar toevoegen :

Zonder spaties:

=$E$2&A2

=CONCATENATE($E$2, A2)

Met spaties:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Merk op dat het adres van de cel met de ingevoegde tekst is vergrendeld met het $-teken, zodat het niet verschuift als u de formule naar beneden kopieert.

Met deze aanpak kunt u de toegevoegde tekst gemakkelijk op één plaats wijzigen, zonder dat u elke formule hoeft bij te werken.

Tekst toevoegen aan het einde van cellen in Excel

Om tekst of een specifiek teken toe te voegen aan een bestaande cel, gebruik je opnieuw de aaneenschakelingsmethode. Het verschil zit in de volgorde van de aaneengeschakelde waarden: een celverwijzing wordt gevolgd door een tekststring.

Om bijvoorbeeld de string " -US " aan het eind van cel A2, zijn dit de formules die u moet gebruiken:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

U kunt ook de tekst in een cel invoeren, en dan twee cellen met tekst samenvoegen:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Gebruik een absolute referentie voor de toegevoegde tekst ($D$2) zodat de formule correct over de kolom wordt gekopieerd.

Tekens toevoegen aan begin en einde van een tekenreeks

Als u weet hoe u tekst aan een bestaande cel kunt toevoegen, is er niets dat u ervan weerhoudt beide technieken in één formule te gebruiken.

Laten we als voorbeeld de string " Project: " aan het begin en " -US " aan het einde van de bestaande tekst in A2.

="Project:"&A2&"-US"

=CONCATENATE("Project:", A2, "-US")

=CONCAT("Project:", A2, "-US")

Met de strings in aparte cellen werkt dit even goed:

Tekst uit twee of meer cellen combineren

Om waarden van meerdere cellen in één cel te plaatsen, voegt u de oorspronkelijke cellen samen met behulp van de reeds bekende technieken: een ampersand symbool, CONCATENATE of CONCAT functie.

Om bijvoorbeeld waarden uit de kolommen A en B te combineren met een komma en een spatie (", ") als scheidingsteken, voert u een van de onderstaande formules in B2 in, en sleept u deze naar beneden in de kolom.

Voeg tekst toe van twee cellen met een ampersand:

=A2&", "&B2

Combineer tekst uit twee cellen met CONCAT of CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Bij het toevoegen van tekst uit twee kolommen Zorg ervoor dat u relatieve celverwijzingen gebruikt (zoals A2), zodat ze correct worden aangepast voor elke rij waarin de formule wordt gekopieerd.

Om te combineren tekst uit meerdere cellen In Excel 365 en Excel 2019 kunt u gebruikmaken van de TEXTJOIN-functie. De syntaxis ervan voorziet in een scheidingsteken (het eerste argument), waardoor de formulering compacter en gemakkelijker te beheren is.

Om bijvoorbeeld strings uit drie kolommen (A, B en C) toe te voegen, waarbij de waarden worden gescheiden door een komma en een spatie, is de formule:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Hoe speciaal teken toevoegen aan cel in Excel

Om een speciaal teken in een Excel-cel in te voegen, moet u de code ervan in het ASCII-systeem kennen. Zodra de code is vastgesteld, levert u deze aan de CHAR-functie om een overeenkomstig teken terug te geven. De CHAR-functie accepteert elk getal van 1 tot 255. Een lijst met afdrukbare tekencodes (waarden van 32 tot 255) vindt u hier.

Om een speciaal teken toe te voegen aan een bestaande waarde of een formule-resultaat, kunt u elke aaneenschakelingsmethode toepassen die u het beste bevalt.

Om bijvoorbeeld het handelsmerksymbool (™) toe te voegen aan tekst in A2, werkt elk van de volgende formules:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Hoe tekst toevoegen aan een formule in Excel

Om een bepaald teken of tekst aan een formule-uitkomst toe te voegen, hoeft u alleen maar een tekenreeks aan de formule zelf te koppelen.

Stel, u gebruikt deze formule om de huidige tijd op te vragen:

=TEXT(NOW(), "h:mm AM/PM")

Om uw gebruikers uit te leggen hoe laat dat is, kunt u wat tekst voor en/of na de formule plaatsen.

Tekst invoegen vóór de formule :

="Huidige tijd: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Huidige tijd: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Huidige tijd: ", TEXT(NOW(), "h:mm AM/PM"))

Tekst toevoegen na formule:

=TEXT(NOW(), "h:mm AM/PM")&" - huidige tijd"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - huidige tijd")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - huidige tijd")

Voeg aan beide zijden tekst toe aan de formule:

="Het is " &TEXT(NOW(), "h:mm AM/PM")& " hier in Gomel."

=CONCATENATE("Het is ", TEXT(NOW(), "h:mm AM/PM"), " hier in Gomel")

=CONCAT("Het is ", TEXT(NOW(), "h:mm AM/PM"), " hier in Gomel")

Hoe tekst invoegen na het N-de teken

Om een bepaalde tekst of teken op een bepaalde plaats in een cel toe te voegen, moet u de oorspronkelijke string in twee delen splitsen en de tekst ertussen plaatsen. Hier ziet u hoe:

1. Neem een substring vóór de ingevoegde tekst met behulp van de functie LINKS:

LINKS(cel, n)

Extraheer een substring na de tekst met de combinatie van RECHTS en LEN:

RIGHT(cel, LEN(cel) -n)

Voeg de twee substrings en de tekst/teken samen met een ampersand-teken.

De volledige formule heeft deze vorm:

LINKS( cel , n ) & " tekst " & RIGHT( cel , LEN( cel ) - n )

Dezelfde delen kunnen worden samengevoegd door de functie CONCATENATE of CONCAT te gebruiken:

CONCATENATE(LEFT( cel , n ), " tekst ", RECHTS( cel , LEN( cel ) - n ))

De taak kan ook worden uitgevoerd met de functie REPLACE:

VERVANGEN( cel , n+1 , 0, " tekst ")

De truc is dat de num_chars argument dat bepaalt hoeveel tekens moeten worden vervangen is ingesteld op 0, dus de formule voegt in feite het volgende in tekst op de opgegeven positie in een cel zonder iets te vervangen. De positie ( start_num argument) wordt berekend met deze uitdrukking: n+1. We voegen 1 toe aan de positie van het n-de teken omdat de tekst erna moet worden ingevoegd.

Om bijvoorbeeld een koppelteken (-) in te voegen na het 2e teken in A2, is de formule in B2:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Of

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Of

=REPLACE(A2, 2+1, 0, "-")

Sleep de formule naar beneden, en u krijgt hetzelfde teken ingevoegd in alle cellen:

Hoe tekst toevoegen voor/na een bepaald teken

Om bepaalde tekst voor of na een bepaald teken in te voegen, moet u de positie van dat teken in een tekenreeks bepalen. Dat kan met behulp van de functie ZOEKEN:

ZOEKEN(" char ", cel )

Zodra de positie is bepaald, kunt u een string toevoegen precies op die plaats door gebruik te maken van de in het bovenstaande voorbeeld besproken benaderingen.

Tekst toevoegen na specifiek teken

Om tekst in te voegen na een bepaald teken, is de algemene formule:

LINKS( cel , SEARCH(" char ", cel )) & " tekst " & RIGHT( cel , LEN( cel ) - ZOEK(" char ", cel ))

Of

CONCATENATE(LEFT( cel , SEARCH(" char ", cel )), " tekst ", RECHTS( cel , LEN( cel ) - ZOEK(" char ", cel )))

Om bijvoorbeeld de tekst (US) na een streepje in A2, is de formule:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Of

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))

Tekst invoegen vóór specifiek teken

Om wat tekst toe te voegen voor een bepaald teken, is de formule:

LINKS( cel , SEARCH(" char ", cel ) -1) & " tekst " & RIGHT( cel , LEN( cel ) - ZOEK(" char ", cel ) +1)

Of

CONCATENATE(LEFT( cel , SEARCH(" char ", cel ) - 1), " tekst ", RECHTS( cel , LEN( cel ) - ZOEK(" char ", cel ) +1))

Zoals u ziet, lijken de formules sterk op die welke tekst invoegen na een teken. Het verschil is dat we 1 aftrekken van het resultaat van de eerste ZOEKEN om de LINKS-functie te dwingen het teken waarna de tekst wordt toegevoegd weg te laten. Aan het resultaat van de tweede ZOEKEN voegen we 1 toe, zodat de RECHTS-functie dat teken zal ophalen.

Om bijvoorbeeld de tekst (US) voor een koppelteken in A2, is dit de te gebruiken formule:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Of

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Opmerkingen:

• Als de oorspronkelijke cel meerdere gebeurtenissen van een teken wordt de tekst voor/na het eerste voorkomen ingevoegd.
• De functie ZOEKEN is hoofdletterongevoelig Als u tekst wilt toevoegen voor/na een kleine of hoofdletter, gebruik dan de hoofdlettergevoelige zoekfunctie om die letter te vinden.

Hoe spatie toe te voegen tussen tekst in Excel-cel

In feite is het gewoon een specifiek geval van de twee vorige voorbeelden.

Om ruimte toe te voegen aan de dezelfde positie in alle cellen, gebruik de formule om tekst in te voegen na het n-de teken, waarbij tekst is het spatieteken (" ").

Om bijvoorbeeld een spatie in te voegen na het 10e teken in de cellen A2:A7, voert u de onderstaande formule in B2 in en sleept u deze door B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Of

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

In alle oorspronkelijke cellen is het 10e teken een dubbele punt (:), dus wordt een spatie ingevoegd precies waar we die nodig hebben:

Om een spatie in te voegen bij een ander standpunt in elke cel de formule aanpassen die tekst toevoegt voor/na een bepaald teken.

In de onderstaande voorbeeldtabel staat een dubbele punt (:) na het projectnummer, dat een variabel aantal tekens kan bevatten. Aangezien wij een spatie willen toevoegen na de dubbele punt, zoeken wij de positie ervan met de functie ZOEKEN:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Of

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Hoe dezelfde tekst toevoegen aan bestaande cellen met VBA

Als u vaak dezelfde tekst in meerdere cellen moet invoegen, kunt u de taak automatiseren met VBA.

Zet tekst aan het begin

De onderstaande macro's voegen tekst of een specifiek karakter toe aan de beginnend van alle geselecteerde cellen Beide codes berusten op dezelfde logica: controleer elke cel in het geselecteerde bereik en indien de cel niet leeg is, voeg de opgegeven tekst toe. Het verschil is waar het resultaat wordt geplaatst: de eerste code wijzigt de oorspronkelijke gegevens terwijl de tweede de resultaten in een kolom rechts van het geselecteerde bereik plaatst.

Als u weinig ervaring hebt met VBA, zal deze stap-voor-stap gids u door het proces leiden: Hoe VBA-code in Excel invoegen en uitvoeren.

Macro 1: voegt tekst toe aan de oorspronkelijke cellen

Sub PrependText() Dim cel Als Bereik Voor Elke cel In Toepassing.Selectie Als cel.Waarde "" Dan cel.Waarde = "PR-" & cel.Waarde Volgende Einde Sub

Deze code voegt de substring "PR-" in links van een bestaande tekst. Voordat u de code in uw werkblad gebruikt, moet u onze voorbeeldtekst vervangen door de tekst die u echt nodig hebt.

Macro 2: plaatst de resultaten in de aangrenzende kolom

Sub PrependText2() Dim cel Als Bereik Voor Elke cel In Toepassing.Selectie Als cel.Waarde "" Dan cel.Offset(0, 1).Waarde = "PR-" & cel.Waarde Volgende Einde Sub

Voordat u deze macro uitvoert, moet u ervoor zorgen dat er een lege kolom naar rechts van het geselecteerde bereik, anders worden de bestaande gegevens overschreven.

Tekst toevoegen aan het einde

Als u een specifieke string/teken wilt toevoegen aan de eind van alle geselecteerde cellen zullen deze codes je helpen om het werk snel gedaan te krijgen.

Macro 1: voegt tekst toe aan de oorspronkelijke cellen

Sub AppendText() Dim cel Als Bereik Voor Elke cel In Toepassing.Selectie Als cel.Waarde "" Dan cel.Waarde = cel.Waarde & "-PR" Volgende Einde Sub

Onze voorbeeldcode voegt de substring "-PR" in rechts van een bestaande tekst. U kunt dit natuurlijk veranderen in een tekst/teken naar keuze.

Macro 2: plaatst de resultaten in een andere kolom

Sub AppendText2() Dim cel Als Bereik Voor Elke cel In Toepassing.Selectie Als cel.Waarde "" Dan cel.Offset(0, 1).Waarde = cel.Waarde & "-PR" Volgende Einde Sub

Deze code plaatst de resultaten in een naburige kolom Dus, voordat u het uitvoert, zorg ervoor dat u ten minste één lege kolom heeft rechts van het geselecteerde bereik, anders worden uw bestaande gegevens overschreven.

Voeg tekst of teken toe aan meerdere cellen met Ultimate Suite

In het eerste deel van deze tutorial heb je een handvol verschillende formules geleerd om tekst aan Excel-cellen toe te voegen. Nu laat ik je zien hoe je deze taak met een paar klikken kunt uitvoeren :)

Met Ultimate Suite geïnstalleerd in uw Excel, zijn hier de te volgen stappen:

1. Selecteer uw brongegevens.
2. Op de Ablebits tabblad, in de Tekst groep, klik Toevoegen .
3. Op de Tekst toevoegen deelvenster, typ het teken/tekst dat u wilt toevoegen aan de geselecteerde cellen, en geef aan waar het moet worden ingevoegd:
   • In het begin
   • Aan het eind
   • Vóór specifieke tekst/teken
   • Na specifieke tekst/karakter
   • Na het N-de teken vanaf het begin of einde
4. Klik op de Tekst toevoegen knop. Klaar!

Laten we als voorbeeld de tekenreeks "PR-" invoegen na het teken "-" in de cellen A2:A7. Hiervoor configureren we de volgende instellingen:

Even later krijgen we het gewenste resultaat:

Dit zijn de beste manieren om tekens en tekstreeksen toe te voegen in Excel. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!

Beschikbare downloads

Tekst toevoegen aan cel in Excel - formulevoorbeelden (.xlsm-bestand)

Ultimate Suite - proefversie (.exe bestand)