Zaujíma vás, ako pridať text do existujúcej bunky v programe Excel? V tomto článku sa dozviete niekoľko naozaj jednoduchých spôsobov, ako vložiť znaky na ľubovoľné miesto v bunke.

Pri práci s textovými údajmi v aplikácii Excel môžete niekedy potrebovať pridať rovnaký text do existujúcich buniek, aby boli veci jasnejšie. Napríklad môžete chcieť na začiatok každej bunky umiestniť nejakú predponu, na koniec vložiť špeciálny symbol alebo umiestniť určitý text pred vzorec.

Hádam každý vie, ako to urobiť ručne. Tento návod vás naučí, ako rýchlo pridať reťazce do viacerých buniek pomocou vzorcov a automatizovať prácu pomocou VBA alebo špeciálneho Pridať text nástroj.

Vzorce programu Excel na pridanie textu/znaku do bunky

Ak chcete do bunky programu Excel pridať konkrétny znak alebo text, jednoducho spojte reťazec a odkaz na bunku pomocou jednej z nasledujúcich metód.

Operátor konkatenácie

Najjednoduchší spôsob pridania textového reťazca do bunky je použitie znaku ampersand (&), ktorý je v programe Excel operátorom spájania.

" text "& bunka

Funguje to vo všetkých verziách programu Excel 2007 - Excel 365.

Funkcia CONCATENATE

Rovnaký výsledok možno dosiahnuť pomocou funkcie CONCATENATE:

CONCATENATE(" text ", bunka )

Funkcia je k dispozícii v aplikáciách Excel pre Microsoft 365, Excel 2019 - 2007.

Funkcia CONCAT

Na pridávanie textu do buniek v aplikáciách Excel 365, Excel 2019 a Excel Online môžete použiť funkciu CONCAT, ktorá je modernou náhradou funkcie CONCATENATE:

CONCAT(" text ", bunka )

Poznámka: Dbajte na to, že vo všetkých vzorcoch, text by mali byť uvedené v úvodzovkách.

Toto sú všeobecné prístupy a na nasledujúcich príkladoch je uvedené, ako ich uplatniť v praxi.

Ako pridať text na začiatok buniek

Ak chcete pridať určitý text alebo znak na začiatok bunky, postupujte takto:

1. Do bunky, do ktorej chcete vypísať výsledok, zadajte znak rovnosti (=).
2. Zadajte požadovaný text do úvodzoviek.
3. Zadajte symbol ampersand (&).
4. Vyberte bunku, do ktorej sa má text pridať, a stlačte kláves Enter .

Prípadne môžete textový reťazec a odkaz na bunku zadať ako vstupné parametre funkcie CONCATENATE alebo CONCAT.

Ak chcete napríklad predradiť text " Projekt: " k názvu projektu v A2, bude fungovať ktorýkoľvek z nižšie uvedených vzorcov.

Vo všetkých verziách programu Excel:

="Projekt:"&A2

=CONCATENATE("Projekt:", A2)

V aplikáciách Excel 365 a Excel 2019:

=CONCAT("Projekt:", A2)

Zadajte vzorec do bunky B2, potiahnite ho dole stĺpcom a do všetkých buniek sa vloží rovnaký text.

Tip. Vyššie uvedené vzorce spájajú dva reťazce bez medzier. Ak chcete hodnoty oddeliť bielou medzerou, zadajte a priestorový znak na konci pridaného textu (napr. "Projekt: ").

Pre väčšie pohodlie môžete cieľový text zadať do preddefinovanej bunky (E2) a pridať dve textové bunky k sebe :

Bez medzier:

=$E$2&A2

=CONCATENATE($E$2, A2)

S medzerami:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Všimnite si, že adresa bunky obsahujúcej predvyplnený text je uzamknutá znakom $, aby sa pri kopírovaní vzorca nadol neposunula.

Vďaka tomuto prístupu môžete jednoducho zmeniť pridaný text na jednom mieste bez toho, aby ste museli aktualizovať každý vzorec.

Ako pridať text na koniec buniek v programe Excel

Ak chcete do existujúcej bunky pridať text alebo konkrétny znak, opäť použite metódu konkatenácie. Rozdiel je v poradí konkatenovaných hodnôt: za odkazom na bunku nasleduje textový reťazec.

Ak chcete napríklad pridať reťazec " -US " na koniec bunky A2, použite tieto vzorce:

=A2&"-USA"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Prípadne môžete text zadať do niektorej bunky a potom spojiť dve bunky s textom:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Nezabudnite použiť absolútny odkaz na pripojený text ($D$2), aby sa vzorec správne skopíroval do celého stĺpca.

Pridanie znakov na začiatok a koniec reťazca

Ak viete, ako predvyplniť a doplniť text do existujúcej bunky, nič vám nebráni použiť obe techniky v rámci jedného vzorca.

Ako príklad pridáme reťazec " Projekt: " na začiatok a " -US " na koniec existujúceho textu v A2.

="Project:"&A2&"-US"

=CONCATENATE("Projekt:", A2, "-US")

=CONCAT("Projekt:", A2, "-US")

Pri zadávaní reťazcov v samostatných bunkách to funguje rovnako dobre:

Kombinácia textu z dvoch alebo viacerých buniek

Ak chcete umiestniť hodnoty z viacerých buniek do jednej bunky, spojte pôvodné bunky pomocou už známych techník: symbol ampersand, funkcia CONCATENATE alebo CONCAT.

Ak chcete napríklad spojiť hodnoty zo stĺpcov A a B pomocou čiarky a medzery (", ") ako oddeľovača, zadajte do stĺpca B2 jeden z nasledujúcich vzorcov a potom ho potiahnite nadol.

Pridanie textu z dvoch buniek pomocou ampersandu:

=A2&", "&B2

Spojte text z dvoch buniek pomocou funkcie CONCAT alebo CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Pri pridávaní text z dvoch stĺpcov , nezabudnite použiť relatívne odkazy na bunky (napríklad A2), aby sa správne prispôsobili každému riadku, do ktorého sa vzorec kopíruje.

Kombinovať text z viacerých buniek v aplikáciách Excel 365 a Excel 2019 môžete využiť funkciu TEXTJOIN. Jej syntax poskytuje oddeľovač (prvý argument), vďaka čomu je formulár kompaktnejší a ľahšie sa spravuje.

Ak chcete napríklad sčítať reťazce z troch stĺpcov (A, B a C) a oddeliť hodnoty čiarkou a medzerou, vzorec je:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Ako pridať špeciálny znak do bunky v programe Excel

Ak chcete vložiť špeciálny znak do bunky programu Excel, musíte poznať jeho kód v systéme ASCII. Po zistení kódu ho zadajte funkcii CHAR, ktorá vráti príslušný znak. Funkcia CHAR akceptuje ľubovoľné číslo od 1 do 255. Zoznam kódov tlačiteľných znakov (hodnoty od 32 do 255) nájdete tu.

Ak chcete pridať špeciálny znak k existujúcej hodnote alebo výsledku vzorca, môžete použiť ľubovoľnú metódu spájania, ktorá vám najviac vyhovuje.

Ak chcete napríklad pridať symbol ochrannej známky (™) do textu v A2, môžete použiť ktorýkoľvek z nasledujúcich vzorcov:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Ako pridať text do vzorca v programe Excel

Ak chcete do výsledku vzorca pridať určitý znak alebo text, stačí reťazec spojiť so samotným vzorcom.

Povedzme, že tento vzorec používate na vrátenie aktuálneho času:

=TEXT(NOW(), "h:mm AM/PM")

Ak chcete používateľom vysvetliť, o aký čas ide, môžete pred a/alebo za vzorec umiestniť text.

Vloženie textu pred vzorec :

="Aktuálny čas:"&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Aktuálny čas: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Aktuálny čas: ", TEXT(NOW(), "h:mm AM/PM")

Pridanie textu za vzorec:

=TEXT(NOW(), "h:mm AM/PM")&" - aktuálny čas"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - aktuálny čas")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - aktuálny čas")

Pridanie textu do vzorca na oboch stranách:

="Je " &TEXT(NOW(), "h:mm AM/PM")& " tu v Gomeli"

=CONCATENATE("Je ", TEXT(NOW(), "h:mm AM/PM"), " tu v Gomeli")

=CONCAT("Je ", TEXT(NOW(), "h:mm AM/PM"), " tu v Gomeli")

Ako vložiť text po N-tom znaku

Ak chcete pridať určitý text alebo znak na určité miesto v bunke, musíte pôvodný reťazec rozdeliť na dve časti a text umiestniť medzi ne. Tu je uvedený postup:

1. Výber podreťazca pred vloženým textom pomocou funkcie LEFT:

LEFT(bunka, n)

Výber podreťazca nasledujúceho za textom pomocou kombinácie RIGHT a LEN:

RIGHT(bunka, LEN(bunka) -n)

Spojte dva podreťazce a text/znak pomocou symbolu ampersand.

Úplný vzorec má tento tvar:

LEFT( bunka , n ) & " text " & RIGHT( bunka , LEN( bunka ) - n )

Rovnaké časti možno spojiť pomocou funkcie CONCATENATE alebo CONCAT:

CONCATENATE(LEFT( bunka , n ), " text ", RIGHT( bunka , LEN( bunka ) - n ))

Túto úlohu možno vykonať aj pomocou funkcie REPLACE:

REPLACE( bunka , n+1 , 0, " text ")

Trik spočíva v tom, že num_chars argument, ktorý určuje, koľko znakov sa má nahradiť, je nastavený na 0, takže vzorec v skutočnosti vloží text na zadanú pozíciu v bunke bez nahradenia čohokoľvek. start_num argument) sa vypočíta pomocou tohto výrazu: n+1. K pozícii n-tého znaku pripočítame 1, pretože text má byť vložený za ním.

Ak chcete napríklad vložiť pomlčku (-) za 2. znak v A2, vzorec v B2 je:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Alebo

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Alebo

=REPLACE(A2, 2+1, 0, "-")

Potiahnite vzorec nadol a do všetkých buniek sa vloží rovnaký znak:

Ako pridať text pred/za konkrétny znak

Ak chcete vložiť určitý text pred alebo za konkrétny znak, musíte určiť pozíciu tohto znaku v reťazci. To môžete urobiť pomocou funkcie SEARCH:

HĽADAŤ(" znak ", bunka )

Po určení pozície môžete pridať reťazec presne na toto miesto pomocou prístupov uvedených vo vyššie uvedenom príklade.

Pridanie textu za konkrétny znak

Ak chcete vložiť nejaký text za daný znak, všeobecný vzorec je:

LEFT( bunka , SEARCH(" znak ", bunka )) & " text " & RIGHT( bunka , LEN( bunka ) - VYHĽADAŤ(" znak ", bunka ))

Alebo

CONCATENATE(LEFT( bunka , SEARCH(" znak ", bunka )), " text ", RIGHT( bunka , LEN( bunka ) - VYHĽADAŤ(" znak ", bunka )))

Ak chcete napríklad vložiť text (USA) za pomlčkou v A2 je vzorec:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Alebo

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))

Vloženie textu pred konkrétny znak

Ak chcete pridať text pred určitý znak, vzorec je:

LEFT( bunka , SEARCH(" znak ", bunka ) -1) & " text " & RIGHT( bunka , LEN( bunka ) - VYHĽADAŤ(" znak ", bunka ) +1)

Alebo

CONCATENATE(LEFT( bunka , SEARCH(" znak ", bunka ) - 1), " text ", RIGHT( bunka , LEN( bunka ) - VYHĽADAŤ(" znak ", bunka ) +1))

Ako vidíte, vzorce sú veľmi podobné tým, ktoré vkladajú text za znak. Rozdiel je v tom, že od výsledku prvého HLEDANIA odčítame 1, aby sme prinútili funkciu LEFT vynechať znak, za ktorý sa pridáva text. K výsledku druhého HLEDANIA pripočítame 1, aby funkcia RIGHT načítala tento znak.

Ak chcete napríklad umiestniť text (USA) pred pomlčkou v A2, je potrebné použiť tento vzorec:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Alebo

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Poznámky:

• Ak pôvodná bunka obsahuje viacnásobný výskyt znaku, text sa vloží pred/za prvý výskyt.
• Funkcia SEARCH je rozlišovanie veľkých a malých písmen a nedokáže rozlišovať malé a veľké písmená. Ak chcete pridať text pred/za malé alebo veľké písmeno, použite na vyhľadanie daného písmena funkciu FIND, ktorá rozlišuje malé a veľké písmená.

Ako pridať medzeru medzi text v bunke programu Excel

V skutočnosti je to len špecifický prípad dvoch predchádzajúcich príkladov.

Pridanie priestoru na rovnaká pozícia vo všetkých bunkách použite vzorec na vloženie textu za n-ty znak, kde text je znak medzery (" ").

Ak chcete napríklad vložiť medzeru za 10. znak v bunkách A2:A7, zadajte nasledujúci vzorec do bunky B2 a pretiahnite ho cez B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Alebo

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Vo všetkých pôvodných bunkách je desiatym znakom dvojbodka (:), takže medzera sa vloží presne tam, kde ju potrebujeme:

Vloženie medzery pri iná poloha v každej bunke upravte vzorec, ktorý pridáva text pred/za konkrétny znak.

Vo vzorovej tabuľke nižšie je za číslom projektu, ktoré môže obsahovať rôzny počet znakov, umiestnená dvojbodka (:). Keďže za dvojbodku chceme pridať medzeru, jej pozíciu vyhľadáme pomocou funkcie SEARCH:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Alebo

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Ako pridať rovnaký text do existujúcich buniek pomocou VBA

Ak často potrebujete vložiť rovnaký text do viacerých buniek, môžete túto úlohu automatizovať pomocou VBA.

Predpísanie textu na začiatok

Nižšie uvedené makrá pridávajú text alebo konkrétny znak do začiatok všetkých vybraných buniek Oba kódy sa spoliehajú na rovnakú logiku: skontrolujú každú bunku vo vybranom rozsahu a ak bunka nie je prázdna, predvyplnia zadaný text. Rozdiel je v tom, kam sa výsledok umiestni: prvý kód vykoná zmeny v pôvodných údajoch, zatiaľ čo druhý umiestni výsledky do stĺpca napravo od vybraného rozsahu.

Ak máte s VBA málo skúseností, tento sprievodca vás krok za krokom prevedie týmto postupom: Ako vložiť a spustiť kód VBA v programe Excel.

Makro 1: pridáva text do pôvodných buniek

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Tento kód vloží podreťazec "PR-" na ľavú stranu existujúceho textu. Pred použitím kódu vo vašom pracovnom hárku sa uistite, že ste náš vzorový text nahradili tým, ktorý skutočne potrebujete.

Makro 2: umiestni výsledky do susedného stĺpca

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Pred spustením tohto makra sa uistite, že je prázdny stĺpec vpravo vybraného rozsahu, inak sa existujúce údaje prepíšu.

Pridanie textu na koniec

Ak chcete pridať konkrétny reťazec/znak do koniec všetkých vybraných buniek , tieto kódy vám pomôžu rýchlo vykonať prácu.

Makro 1: pridá text do pôvodných buniek

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Náš vzorový kód vloží podreťazec "-PR" napravo od existujúceho textu. Samozrejme, môžete ho zmeniť na akýkoľvek text/znak, ktorý potrebujete.

Makro 2: umiestni výsledky do iného stĺpca

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Tento kód umiestni výsledky do susedný stĺpec Pred spustením sa teda uistite, že máte vpravo od vybraného rozsahu aspoň jeden prázdny stĺpec, inak sa vaše existujúce údaje prepíšu.

Pridanie textu alebo znaku do viacerých buniek pomocou balíka Ultimate Suite

V prvej časti tohto návodu ste sa naučili niekoľko rôznych vzorcov na pridávanie textu do buniek programu Excel. Teraz vám ukážem, ako túto úlohu splniť pomocou niekoľkých kliknutí :)

Po nainštalovaní balíka Ultimate Suite v aplikácii Excel postupujte podľa nasledujúcich krokov:

1. Vyberte zdrojové údaje.
2. Na Ablebits na karte Text kliknite na položku Pridať .
3. Na Pridať text zadajte znak/text, ktorý chcete pridať do vybraných buniek, a určte, kam sa má vložiť:
   • Na začiatku
   • Na konci
   • Pred konkrétnym textom/znakom
   • Za konkrétnym textom/znakom
   • Po N-tom znaku od začiatku alebo konca
4. Kliknite na tlačidlo Pridať text Hotovo!

Ako príklad vložíme reťazec "PR-" za znak "-" do buniek A2:A7. Na tento účel nakonfigurujeme nasledujúce nastavenia:

O chvíľu neskôr dostaneme požadovaný výsledok:

Toto sú najlepšie spôsoby pridávania znakov a textových reťazcov v programe Excel. Ďakujem vám za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!

Dostupné súbory na stiahnutie

Pridanie textu do bunky v programe Excel - príklady vzorcov (.xlsm súbor)

Ultimate Suite - skúšobná verzia (.exe súbor)