Zajímá vás, jak přidat text do existující buňky v aplikaci Excel? V tomto článku se dozvíte několik opravdu jednoduchých způsobů, jak vložit znaky na libovolné místo v buňce.

Při práci s textovými daty v aplikaci Excel můžete někdy potřebovat přidat stejný text do existujících buněk, aby bylo vše přehlednější. Například můžete chtít na začátek každé buňky vložit nějakou předponu, na konec vložit speciální symbol nebo umístit určitý text před vzorec.

Asi každý ví, jak to udělat ručně. Tento návod vás naučí, jak rychle přidávat řetězce do více buněk pomocí vzorců a automatizovat práci pomocí VBA nebo speciálního programu. Přidat text nástroj.

Vzorce aplikace Excel pro přidání textu/znaku do buňky

Chcete-li do buňky aplikace Excel přidat určitý znak nebo text, jednoduše spojte řetězec a odkaz na buňku pomocí jedné z následujících metod.

Operátor konkatenace

Nejjednodušší způsob, jak přidat textový řetězec do buňky, je použít znak ampersand (&), což je v aplikaci Excel operátor spojování.

" text "& buňka

Tato funkce funguje ve všech verzích aplikace Excel 2007 - Excel 365.

Funkce CONCATENATE

Stejného výsledku lze dosáhnout pomocí funkce CONCATENATE:

CONCATENATE(" text ", buňka )

Funkce je k dispozici v aplikaci Excel pro Microsoft 365, Excel 2019 - 2007.

Funkce CONCAT

K přidávání textu do buněk v aplikacích Excel 365, Excel 2019 a Excel Online můžete použít funkci CONCAT, která je moderní náhradou funkce CONCATENATE:

CONCAT(" text ", buňka )

Poznámka: Upozorňujeme, že ve všech vzorcích, text by měly být uvedeny v uvozovkách.

Jedná se o obecné přístupy a níže uvedené příklady ukazují, jak je použít v praxi.

Jak přidat text na začátek buněk

Chcete-li přidat určitý text nebo znak na začátek buňky, postupujte takto:

1. Do buňky, do které chcete vypsat výsledek, napište znaménko rovnosti (=).
2. Zadejte požadovaný text do uvozovek.
3. Zadejte symbol ampersand (&).
4. Vyberte buňku, do které má být text přidán, a stiskněte klávesu Enter .

Alternativně můžete zadat textový řetězec a odkaz na buňku jako vstupní parametry funkce CONCATENATE nebo CONCAT.

Například pro předřazení textu " Projekt: " k názvu projektu v A2, bude fungovat kterýkoli z níže uvedených vzorců.

Ve všech verzích aplikace Excel:

="Projekt:"&A2

=CONCATENATE("Projekt:", A2)

V aplikacích Excel 365 a Excel 2019:

=CONCAT("Projekt:", A2)

Zadejte vzorec do B2, přetáhněte jej dolů do sloupce a do všech buněk bude vložen stejný text.

Tip: Výše uvedené vzorce spojují dva řetězce bez mezer. Chcete-li hodnoty oddělit bílým znakem, zadejte a prostorový znak na konci předřazeného textu (např. "Projekt: ").

Pro větší pohodlí můžete zadat cílový text do předem definované buňky (E2) a. přidat dvě textové buňky k sobě :

Bez mezer:

=$E$2&A2

=CONCATENATE($E$2, A2)

S mezerami:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Všimněte si, že adresa buňky obsahující předřazený text je uzamčena znakem $, aby se při kopírování vzorce dolů neposunula.

Díky tomuto přístupu můžete snadno změnit přidaný text na jednom místě, aniž byste museli aktualizovat každý vzorec.

Jak přidat text na konec buněk v aplikaci Excel

Chcete-li k existující buňce připojit text nebo určitý znak, použijte opět metodu spojování. Rozdíl je v pořadí spojovaných hodnot: za odkazem na buňku následuje textový řetězec.

Chcete-li například přidat řetězec " -US " na konec buňky A2, použijete tyto vzorce:

=A2&"-USA"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Případně můžete zadat text do některé buňky a poté spojit dvě buňky s textem dohromady:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Nezapomeňte použít absolutní odkaz na připojený text ($D$2), aby se vzorec správně zkopíroval do celého sloupce.

Přidání znaků na začátek a konec řetězce

Pokud víte, jak předpřipojit a připojit text k existující buňce, nic vám nebrání použít obě techniky v rámci jednoho vzorce.

Jako příklad přidejme řetězec " Projekt: " na začátek a " -US " na konec stávajícího textu v A2.

="Project:"&A2&"-US"

=CONCATENATE("Projekt:", A2, "-US")

=CONCAT("Projekt:", A2, "-US")

Při zadávání řetězců do samostatných buněk to funguje stejně dobře:

Kombinovat text ze dvou nebo více buněk

Chcete-li umístit hodnoty z více buněk do jedné buňky, spojte původní buňky pomocí již známých technik: symbolu ampersand, funkce CONCATENATE nebo CONCAT.

Chcete-li například spojit hodnoty ze sloupců A a B pomocí čárky a mezery (", ") jako oddělovače, zadejte do sloupce B2 jeden z níže uvedených vzorců a poté jej přetáhněte dolů.

Přidání textu ze dvou buněk pomocí ampersandu:

=A2&", "&B2

Spojte text ze dvou buněk pomocí CONCAT nebo CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Při přidávání text ze dvou sloupců , nezapomeňte použít relativní odkazy na buňky (např. A2), aby se správně přizpůsobily každému řádku, do kterého je vzorec zkopírován.

Kombinace text z více buněk v aplikacích Excel 365 a Excel 2019 můžete využít funkci TEXTJOIN. Její syntaxe obsahuje oddělovač (první argument), díky němuž je formulář kompaktnější a lépe se spravuje.

Například pro sčítání řetězců ze tří sloupců (A, B a C), přičemž hodnoty jsou odděleny čárkou a mezerou, je vzorec následující:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Jak přidat speciální znak do buňky v aplikaci Excel

Chcete-li do buňky aplikace Excel vložit speciální znak, musíte znát jeho kód v systému ASCII. Jakmile kód zjistíte, zadejte jej funkci CHAR, která vrátí odpovídající znak. Funkce CHAR přijímá libovolné číslo od 1 do 255. Seznam kódů tisknutelných znaků (hodnoty od 32 do 255) naleznete zde.

Chcete-li přidat speciální znak k existující hodnotě nebo výsledku vzorce, můžete použít libovolnou metodu zřetězení, která vám nejlépe vyhovuje.

Chcete-li například přidat symbol ochranné známky (™) do textu v poli A2, můžete použít kterýkoli z následujících vzorců:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Jak přidat text do vzorce v aplikaci Excel

Chcete-li do výsledku vzorce přidat určitý znak nebo text, stačí řetězec spojit se samotným vzorcem.

Řekněme, že tento vzorec používáte k vrácení aktuálního času:

=TEXT(NOW(), "h:mm AM/PM")

Chcete-li uživatelům vysvětlit, kolik je hodin, můžete před vzorec nebo za něj umístit nějaký text.

Vložení textu před vzorec :

="Aktuální čas: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Aktuální čas: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Aktuální čas: ", TEXT(NOW(), "h:mm AM/PM"))

Přidání textu za vzorec:

=TEXT(NOW(), "h:mm AM/PM")&" - aktuální čas"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - aktuální čas")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - aktuální čas")

Přidejte text do vzorce na obou stranách:

="Je " &TEXT(NOW(), "h:mm AM/PM")& " zde v Gomelu"

=CONCATENATE("Je ", TEXT(NOW(), "h:mm AM/PM"), " zde v Gomelu")

=CONCAT("Je ", TEXT(NOW(), "h:mm AM/PM"), " zde v Gomelu")

Jak vložit text za N-tý znak

Chcete-li přidat určitý text nebo znak na určité místo v buňce, musíte původní řetězec rozdělit na dvě části a text umístit mezi ně. Zde je uveden postup:

1. Výběr podřetězce před vloženým textem pomocí funkce LEFT:

LEFT(buňka, n)

Výpis podřetězce následujícího za textem pomocí kombinace RIGHT a LEN:

RIGHT(buňka, LEN(buňka) -n)

Spojte oba podřetězce a text/znak pomocí symbolu ampersand.

Úplný vzorec má tento tvar:

LEVÝ( buňka , n ) & " text " & RIGHT( buňka , LEN( buňka ) - n )

Stejné části lze spojit pomocí funkce CONCATENATE nebo CONCAT:

CONCATENATE(LEFT( buňka , n ), " text ", RIGHT( buňka , LEN( buňka ) - n ))

Tento úkol lze provést také pomocí funkce REPLACE:

REPLACE( buňka , n+1 , 0, " text ")

Trik spočívá v tom, že num_chars argument, který určuje, kolik znaků se má nahradit, je nastaven na 0, takže vzorec skutečně vloží text na zadanou pozici v buňce, aniž by cokoli nahradil. Pozice ( start_num argument) se vypočítá pomocí tohoto výrazu: n+1. K pozici n-tého znaku přičteme 1, protože text má být vložen až za něj.

Například pro vložení pomlčky (-) za 2. znak v A2 je vzorec v B2 následující:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Nebo

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Nebo

=REPLACE(A2, 2+1, 0, "-")

Přetáhněte vzorec dolů a do všech buněk se vloží stejný znak:

Jak přidat text před/za určitý znak

Chcete-li vložit určitý text před nebo za určitý znak, musíte určit pozici tohoto znaku v řetězci. To lze provést pomocí funkce HLEDAT:

HLEDAT(" znak ", buňka )

Jakmile je pozice určena, můžete přidat řetězec přesně na toto místo pomocí přístupů popsaných ve výše uvedeném příkladu.

Přidání textu za určitý znak

Chcete-li vložit nějaký text za daný znak, použijete obecný vzorec:

LEVÝ( buňka , HLEDAT(" znak ", buňka )) & " text " & RIGHT( buňka , LEN( buňka ) - HLEDAT(" znak ", buňka ))

Nebo

CONCATENATE(LEFT( buňka , HLEDAT(" znak ", buňka )), " text ", RIGHT( buňka , LEN( buňka ) - HLEDAT(" znak ", buňka )))

Chcete-li například vložit text (USA) za pomlčkou v A2 je vzorec:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Nebo

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2)))

Vložení textu před určitý znak

Chcete-li přidat nějaký text před určitý znak, vzorec je:

LEVÝ( buňka , HLEDAT(" znak ", buňka ) -1) & " text " & RIGHT( buňka , LEN( buňka ) - HLEDAT(" znak ", buňka ) +1)

Nebo

CONCATENATE(LEFT( buňka , HLEDAT(" znak ", buňka ) - 1), " text ", RIGHT( buňka , LEN( buňka ) - HLEDAT(" znak ", buňka ) +1))

Jak vidíte, vzorce jsou velmi podobné vzorcům, které vkládají text za znak. Rozdíl je v tom, že od výsledku prvního HLEDÁNÍ odečteme 1, abychom donutili funkci LEFT vynechat znak, za který je text přidán. K výsledku druhého HLEDÁNÍ přičteme 1, aby funkce RIGHT tento znak načetla.

Chcete-li například umístit text (USA) před pomlčkou v A2, je třeba použít tento vzorec:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Nebo

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)))

Poznámky:

• Pokud původní buňka obsahuje více výskytů znaku, bude text vložen před/za první výskyt.
• Funkce HLEDAT je rozlišování velkých a malých písmen a nedokáže rozlišit malá a velká písmena. Pokud chcete přidat text před/za malé nebo velké písmeno, použijte k vyhledání daného písmene funkci FIND, která rozlišuje malá a velká písmena.

Jak přidat mezeru mezi text v buňce aplikace Excel

Ve skutečnosti se jedná pouze o specifický případ dvou předchozích příkladů.

Přidání místa na stejná pozice ve všech buňkách, použijte vzorec pro vložení textu za n-tý znak, kde text je znak mezery (" ").

Chcete-li například vložit mezeru za 10. znak v buňkách A2:A7, zadejte následující vzorec do buňky B2 a přetáhněte jej přes B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Nebo

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Ve všech původních buňkách je desátým znakem dvojtečka (:), takže mezera je vložena přesně tam, kde ji potřebujeme:

Vložení mezery u jiná poloha v každé buňce upravte vzorec, který přidá text před/za určitý znak.

V ukázkové tabulce níže je za číslem projektu, které může obsahovat různý počet znaků, umístěna dvojtečka (:). Protože chceme za dvojtečku přidat mezeru, vyhledáme její pozici pomocí funkce HLEDAT:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Nebo

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2)))

Jak přidat stejný text do existujících buněk pomocí VBA

Pokud často potřebujete vložit stejný text do více buněk, můžete tuto úlohu automatizovat pomocí VBA.

Připojení textu na začátek

Níže uvedená makra přidávají text nebo určitý znak do pole začátek všech vybraných buněk . Oba kódy se opírají o stejnou logiku: kontrolují každou buňku ve vybraném rozsahu, a pokud není prázdná, předvyplní zadaný text. Rozdíl je v tom, kam se výsledek umístí: první kód provede změny v původních datech, zatímco druhý umístí výsledek do sloupce napravo od vybraného rozsahu.

Pokud máte s VBA jen malé zkušenosti, tento průvodce vás krok za krokem provede celým procesem: Jak vložit a spustit kód VBA v aplikaci Excel.

Makro 1: přidá text do původních buněk

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Tento kód vloží podřetězec "PR-" vlevo od existujícího textu. Před použitím kódu v pracovním listu se ujistěte, že jste náš ukázkový text nahradili textem, který skutečně potřebujete.

Makro 2: umístí výsledky do sousedního sloupce

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Před spuštěním tohoto makra se ujistěte, že je prázdný sloupec vpravo vybraného rozsahu, jinak budou stávající data přepsána.

Připojení textu na konec

Pokud chcete přidat určitý řetězec/znak do pole konec všech vybraných buněk , tyto kódy vám pomohou rychle dokončit práci.

Makro 1: připojí text k původním buňkám

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Náš ukázkový kód vloží podřetězec "-PR" napravo od existujícího textu. Samozřejmě jej můžete změnit na jakýkoli text/znak, který potřebujete.

Makro 2: umístí výsledky do jiného sloupce

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Tento kód umístí výsledky do sousední sloupec . Před spuštěním se tedy ujistěte, že máte vpravo od vybraného rozsahu alespoň jeden prázdný sloupec, jinak budou vaše stávající data přepsána.

Přidání textu nebo znaku do více buněk pomocí sady Ultimate Suite

V první části tohoto návodu jste se seznámili s několika různými vzorci pro přidávání textu do buněk Excelu. Nyní vám ukážu, jak tento úkol provést pomocí několika kliknutí :)

Pokud máte v aplikaci Excel nainstalovanou sadu Ultimate Suite, postupujte podle následujících kroků:

1. Vyberte zdrojová data.
2. Na Ablebits na kartě Text klikněte na tlačítko Přidat .
3. Na Přidat text zadejte znak/text, který chcete přidat do vybraných buněk, a určete, kam má být vložen:
   • Na začátku
   • Na konci
   • Před konkrétním textem/znakem
   • Za konkrétním textem/znakem
   • Po N-tém znaku od začátku nebo konce
4. Klikněte na Přidat text Hotovo!

Jako příklad vložíme řetězec "PR-" za znak "-" do buněk A2:A7. Za tímto účelem nakonfigurujeme následující nastavení:

O chvíli později získáme požadovaný výsledek:

Toto jsou nejlepší způsoby, jak přidávat znaky a textové řetězce v aplikaci Excel. Děkuji vám za přečtení a doufám, že se uvidíme na našem blogu příští týden!

Dostupné soubory ke stažení

Přidání textu do buňky v aplikaci Excel - příklady vzorců (.xlsm soubor)

Ultimate Suite - zkušební verze (.exe soubor)