Excel'de mevcut bir hücreye nasıl metin ekleyeceğinizi mi merak ediyorsunuz? Bu makalede, bir hücredeki herhangi bir konuma karakter eklemenin gerçekten basit birkaç yolunu öğreneceksiniz.

Excel'de metin verileriyle çalışırken, bazen işleri daha net hale getirmek için mevcut hücrelere aynı metni eklemeniz gerekebilir. Örneğin, her hücrenin başına bir önek koymak, sonuna özel bir sembol eklemek veya bir formülden önce belirli bir metin yerleştirmek isteyebilirsiniz.

Sanırım herkes bunu manuel olarak nasıl yapacağını biliyor. Bu eğitim size formülleri kullanarak birden fazla hücreye dizeleri nasıl hızlı bir şekilde ekleyeceğinizi ve işi VBA veya özel bir Metin Ekle Alet.

Hücreye metin/karakter eklemek için Excel formülleri

Bir Excel hücresine belirli bir karakter veya metin eklemek için, aşağıdaki yöntemlerden birini kullanarak bir dize ile bir hücre başvurusunu birleştirmeniz yeterlidir.

Birleştirme operatörü

Bir hücreye metin dizesi eklemenin en kolay yolu, Excel'de birleştirme işleci olan ve işareti karakterini (&) kullanmaktır.

" Metin "& hücre

Bu, Excel 2007 - Excel 365'in tüm sürümlerinde çalışır.

CONCATENATE işlevi

Aynı sonuç CONCATENATE fonksiyonu yardımıyla da elde edilebilir:

CONCATENATE(" Metin ", hücre )

İşlev, Microsoft 365, Excel 2019 - 2007 için Excel'de kullanılabilir.

CONCAT işlevi

Excel 365, Excel 2019 ve Excel Online'da hücrelere metin eklemek için CONCATENATE işlevinin modern bir alternatifi olan CONCAT işlevini kullanabilirsiniz:

CONCAT(" Metin ", hücre )

Not: Lütfen tüm formüllerde şuna dikkat edin, Metin tırnak işareti içine alınmalıdır.

Bunlar genel yaklaşımlardır ve aşağıdaki örnekler bunların pratikte nasıl uygulanacağını göstermektedir.

Hücrelerin başına metin ekleme

Bir hücrenin başına belirli bir metin veya karakter eklemek için yapmanız gerekenler şunlardır:

1. Sonucun çıktısını almak istediğiniz hücreye eşittir işaretini (=) yazın.
2. Tırnak işaretlerinin içine istediğiniz metni yazın.
3. Bir ve işareti sembolü (&) yazın.
4. Metnin ekleneceği hücreyi seçin ve Enter tuşuna basın.

Alternatif olarak, metin dizenizi ve hücre referansınızı CONCATENATE veya CONCAT işlevine giriş parametreleri olarak sağlayabilirsiniz.

Örneğin, metnin önüne " Proje: " öğesini A2'deki bir proje adına eklerseniz, aşağıdaki formüllerden herhangi biri çalışacaktır.

Tüm Excel sürümlerinde:

="Proje:"&A2

=CONCATENATE("Proje:", A2)

Excel 365 ve Excel 2019'da:

=CONCAT("Proje:", A2)

Formülü B2'ye girin, sütunda aşağı sürükleyin ve tüm hücrelere aynı metni ekleyeceksiniz.

İpucu: Yukarıdaki formüller iki dizeyi boşluksuz olarak birleştirir. Değerleri boşluk ile ayırmak için boşluk karakteri eklenen metnin sonunda (örneğin "Proje: ").

Kolaylık sağlamak için, hedef metni önceden tanımlanmış bir hücreye (E2) girebilir ve iki metin hücresini birbirine ekleme :

Boşluksuz:

=$E$2&A2

=CONCATENATE($E$2, A2)

Boşluklu:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Lütfen eklenen metni içeren hücrenin adresinin $ işaretiyle kilitlendiğine dikkat edin, böylece formül aşağı kopyalanırken kaymaz.

Bu yaklaşımla, her formülü güncellemek zorunda kalmadan eklenen metni tek bir yerde kolayca değiştirebilirsiniz.

Excel'de hücrelerin sonuna metin ekleme

Mevcut bir hücreye metin veya belirli bir karakter eklemek için yine birleştirme yöntemini kullanın. Aradaki fark, birleştirilen değerlerin sırasıdır: bir hücre referansının ardından bir metin dizesi gelir.

Örneğin, dizeyi eklemek için " -ABD " öğesini A2 hücresinin sonuna eklerseniz, kullanılacak formüller şunlardır:

=A2&"-ABD"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Alternatif olarak, metni bir hücreye girebilir ve ardından metin içeren iki hücreyi birleştirebilirsiniz:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Formülün sütun boyunca doğru şekilde kopyalanması için lütfen eklenen metin ($D$2) için mutlak bir referans kullanmayı unutmayın.

Dizenin başına ve sonuna karakter ekleme

Metni mevcut bir hücreye nasıl ekleyeceğinizi ve önceden ekleyeceğinizi bildiğinizden, her iki tekniği de tek bir formül içinde kullanmanızı engelleyecek hiçbir şey yoktur.

Örnek olarak, " Proje: " ibaresini başa ve " -ABD " ifadesini A2'deki mevcut metnin sonuna ekleyiniz.

="Project:"&A2&"-US"

=CONCATENATE("Project:", A2, "-US")

=CONCAT("Project:", A2, "-US")

Dizeler ayrı hücrelere girildiğinde, bu eşit derecede iyi çalışır:

İki veya daha fazla hücredeki metni birleştirme

Birden fazla hücredeki değerleri tek bir hücreye yerleştirmek için, zaten bilinen teknikleri kullanarak orijinal hücreleri birleştirin: ve işareti sembolü, CONCATENATE veya CONCAT işlevi.

Örneğin, sınırlayıcı olarak virgül ve boşluk (", ") kullanarak A ve B sütunlarındaki değerleri birleştirmek için, B2'ye aşağıdaki formüllerden birini girin ve ardından sütundan aşağı sürükleyin.

İki hücreden ve işareti ile metin ekleyin:

=A2&", "&B2

İki hücredeki metni CONCAT veya CONCATENATE ile birleştirin:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Ekleme yaparken iki sütundan metin formülün kopyalandığı her satır için doğru şekilde ayarlanabilmesi için göreli hücre referansları (A2 gibi) kullandığınızdan emin olun.

Birleştirmek için birden çok hücreden metin Excel 365 ve Excel 2019'da TEXTJOIN işlevinden yararlanabilirsiniz. Sözdizimi, formülü daha kompakt ve yönetimi daha kolay hale getiren bir sınırlayıcı (ilk bağımsız değişken) sağlar.

Örneğin, değerleri virgül ve boşlukla ayırarak üç sütundan (A, B ve C) dizeler eklemek için formül şöyledir:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Excel'de hücreye özel karakter nasıl eklenir

Bir Excel hücresine özel bir karakter eklemek için, ASCII sistemindeki kodunu bilmeniz gerekir. Kod belirlendikten sonra, karşılık gelen bir karakter döndürmek için CHAR işlevine verin. CHAR işlevi 1'den 255'e kadar herhangi bir sayıyı kabul eder. Yazdırılabilir karakter kodlarının bir listesi (32'den 255'e kadar değerler) burada bulunabilir.

Mevcut bir değere veya formül sonucuna özel bir karakter eklemek için, en çok sevdiğiniz birleştirme yöntemini uygulayabilirsiniz.

Örneğin, A2'deki metne ticari marka sembolü (™) eklemek için aşağıdaki formüllerden herhangi biri çalışacaktır:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Excel'de formüle nasıl metin eklenir

Bir formül sonucuna belirli bir karakter veya metin eklemek için, formülün kendisiyle bir dizeyi birleştirmeniz yeterlidir.

Diyelim ki, bu formülü geçerli saati döndürmek için kullanıyorsunuz:

=TEXT(NOW(), "h:mm AM/PM")

Kullanıcılarınıza saatin kaç olduğunu açıklamak için formülden önce ve/veya sonra bazı metinler yerleştirebilirsiniz.

Formülden önce metin ekleme :

="Geçerli saat: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Geçerli saat: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Geçerli saat: ", TEXT(NOW(), "h:mm AM/PM"))

Formülden sonra metin ekleyin:

=TEXT(NOW(), "h:mm AM/PM")&" - geçerli saat"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - geçerli saat")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - geçerli saat")

Her iki taraftaki formüle metin ekleyin:

="It's " &TEXT(NOW(), "h:mm AM/PM")& " here in Gomel"

=CONCATENATE("It's ", TEXT(NOW(), "h:mm AM/PM"), " here in Gomel")

=CONCAT("It's ", TEXT(NOW(), "h:mm AM/PM"), " here in Gomel")

N'inci karakterden sonra metin nasıl eklenir

Bir hücrede belirli bir konuma belirli bir metin veya karakter eklemek için, orijinal dizeyi iki parçaya bölmeniz ve metni arasına yerleştirmeniz gerekir. İşte nasıl yapılacağı:

1. LEFT fonksiyonu yardımıyla eklenen metinden önce gelen bir alt dizeyi çıkarın:

LEFT(hücre, n)

RIGHT ve LEN kombinasyonunu kullanarak metni takip eden bir alt dizeyi çıkarın:

RIGHT(hücre, LEN(hücre) -n)

İki alt dizeyi ve metni/karakteri bir ve işareti sembolü kullanarak birleştirin.

Formülün tamamı şu şekildedir:

SOL( hücre , n ) & " Metin " & SAĞ( hücre , LEN( hücre ) - n )

Aynı parçalar CONCATENATE veya CONCAT işlevi kullanılarak birleştirilebilir:

CONCATENATE(LEFT( hücre , n ), " Metin ", SAĞ( hücre , LEN( hücre ) - n ))

Bu görev REPLACE fonksiyonu kullanılarak da gerçekleştirilebilir:

REPLACE( hücre , n+1 , 0, " Metin ")

İşin püf noktası num_chars kaç karakterin değiştirileceğini tanımlayan bağımsız değişken 0 olarak ayarlanmıştır, bu nedenle formül aslında Metin herhangi bir şeyi değiştirmeden bir hücrede belirtilen konumda konum ( start_num argümanı) şu ifade kullanılarak hesaplanır: n+1. n. karakterin konumuna 1 ekleriz çünkü metin ondan sonra eklenmelidir.

Örneğin, A2'deki 2. karakterden sonra bir kısa çizgi (-) eklemek için B2'deki formül şöyledir:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Ya da

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Ya da

=REPLACE(A2, 2+1, 0, "-")

Formülü aşağı sürüklediğinizde, tüm hücrelere aynı karakter eklenmiş olacaktır:

Belirli bir karakterden önce/sonra metin ekleme

Belirli bir karakterden önce veya sonra belirli bir metin eklemek için, o karakterin bir dize içindeki konumunu belirlemeniz gerekir. Bu, ARAMA işlevi yardımıyla yapılabilir:

ARA(" char ", hücre )

Konum belirlendikten sonra, yukarıdaki örnekte tartışılan yaklaşımları kullanarak tam olarak o yere bir dize ekleyebilirsiniz.

Belirli karakterden sonra metin ekleme

Belirli bir karakterden sonra bir metin eklemek için genel formül şöyledir:

SOL( hücre , SEARCH(" char ", hücre )) & " Metin " & SAĞ( hücre , LEN( hücre ) - ARA(" char ", hücre ))

Ya da

CONCATENATE(LEFT( hücre , SEARCH(" char ", hücre )), " Metin ", SAĞ( hücre , LEN( hücre ) - ARA(" char ", hücre )))

Örneğin, metni eklemek için (ABD) A2'de bir tire işaretinden sonra formül şöyledir:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Ya da

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))

Belirli karakterden önce metin ekleme

Belirli bir karakterden önce bir metin eklemek için formül şöyledir:

SOL( hücre , SEARCH(" char ", hücre ) -1) & " Metin " & SAĞ( hücre , LEN( hücre ) - ARA(" char ", hücre ) +1)

Ya da

CONCATENATE(LEFT( hücre , SEARCH(" char ", hücre ) - 1), " Metin ", SAĞ( hücre , LEN( hücre ) - ARA(" char ", hücre ) +1))

Gördüğünüz gibi, formüller bir karakterden sonra metin ekleyen formüllere çok benziyor. Aradaki fark, LEFT fonksiyonunu metnin eklendiği karakteri dışarıda bırakmaya zorlamak için ilk SEARCH sonucundan 1 çıkarıyoruz. İkinci SEARCH sonucuna 1 ekliyoruz, böylece RIGHT fonksiyonu bu karakteri getirecek.

Örneğin, metni yerleştirmek için (ABD) A2'de bir kısa çizgiden önce, kullanılacak formül budur:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Ya da

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Notlar:

• Orijinal hücre aşağıdakileri içeriyorsa çoklu oluşumlar karakterinin ilk geçtiği yerden önce/sonra metin eklenecektir.
• ARAMA işlevi büyük/küçük harf duyarsız ve küçük ve büyük harfleri ayırt edemez. Küçük veya büyük bir harften önce/sonra metin eklemek istiyorsanız, o harfi bulmak için büyük/küçük harfe duyarlı BUL işlevini kullanın.

Excel hücresinde metin arasına nasıl boşluk eklenir

Aslında, bu sadece önceki iki örneğin özel bir durumudur.

Boşluk eklemek için aynı pozisyon tüm hücrelerde, n. karakterden sonra metin eklemek için formülü kullanın, burada Metin boşluk karakteridir (" ").

Örneğin, A2:A7 hücrelerindeki 10. karakterden sonra bir boşluk eklemek için, aşağıdaki formülü B2'ye girin ve B7'ye sürükleyin:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Ya da

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Tüm orijinal hücrelerde 10. karakter iki nokta üst üste (:) olduğundan, tam ihtiyacımız olan yere bir boşluk eklenir:

Bir alana boşluk eklemek için farklı pozisyon her hücrede, belirli bir karakterden önce/sonra metin ekleyen formülü ayarlayın.

Aşağıdaki örnek tabloda, değişken sayıda karakter içerebilen proje numarasından sonra iki nokta üst üste (:) işareti yer almaktadır. İki nokta üst üste işaretinden sonra bir boşluk eklemek istediğimizden, ARA işlevini kullanarak konumunu belirleriz:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Ya da

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))

VBA ile mevcut hücrelere aynı metin nasıl eklenir

Sık sık aynı metni birden fazla hücreye eklemeniz gerekiyorsa, görevi VBA ile otomatikleştirebilirsiniz.

Metni başlangıca ekleme

Aşağıdaki makrolar, metin veya belirli bir karakteri başlangıç seçilen tüm hücrelerin Her iki kod da aynı mantığa dayanır: seçilen aralıktaki her hücreyi kontrol edin ve hücre boş değilse, belirtilen metni ekleyin. Aradaki fark, sonucun nereye yerleştirildiğidir: ilk kod orijinal verilerde değişiklik yaparken, ikincisi sonuçları seçilen aralığın sağındaki bir sütuna yerleştirir.

VBA konusunda çok az deneyiminiz varsa, bu adım adım kılavuz size süreç boyunca yol gösterecektir: Excel'de VBA kodu nasıl eklenir ve çalıştırılır.

Makro 1: orijinal hücrelere metin ekler

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Bu kod, mevcut bir metnin soluna "PR-" alt dizesini ekler. Kodu çalışma sayfanızda kullanmadan önce, örnek metnimizi gerçekten ihtiyacınız olan metinle değiştirdiğinizden emin olun.

Makro 2: sonuçları bitişik sütuna yerleştirir

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Bu makroyu çalıştırmadan önce, aşağıdakilerin olduğundan emin olun sağda boş bir sütun seçili aralığın üzerine yazılır, aksi takdirde mevcut verilerin üzerine yazılır.

Metni sona ekle

Belirli bir dize/karakter eklemek istiyorsanız son seçilen tüm hücrelerin bu kodlar işinizi hızlı bir şekilde halletmenize yardımcı olacaktır.

Makro 1: metni orijinal hücrelere ekler

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Örnek kodumuz mevcut bir metnin sağına "-PR" alt dizesini ekler. Doğal olarak, bunu ihtiyacınız olan herhangi bir metin/karakterle değiştirebilirsiniz.

Makro 2: Sonuçları başka bir sütuna yerleştirir

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Bu kod, sonuçları bir komşu sütun Bu nedenle, çalıştırmadan önce, seçilen aralığın sağında en az bir boş sütun olduğundan emin olun, aksi takdirde mevcut verilerinizin üzerine yazılacaktır.

Ultimate Suite ile birden çok hücreye metin veya karakter ekleyin

Bu eğitimin ilk bölümünde, Excel hücrelerine metin eklemek için bir avuç farklı formül öğrendiniz. Şimdi, size birkaç tıklama ile görevi nasıl gerçekleştireceğinizi göstereyim :)

Excel'inizde Ultimate Suite yüklüyken izlemeniz gereken adımlar şunlardır:

1. Kaynak verilerinizi seçin.
2. Üzerinde Ablebits sekmesinde Metin grubunu seçin, tıklayın Ekle .
3. Üzerinde Metin Ekle bölmesinde, seçili hücrelere eklemek istediğiniz karakteri/metni yazın ve nereye ekleneceğini belirtin:
   • Başlangıçta
   • Sonunda
   • Belirli bir metin/karakterden önce
   • Belirli bir metin/karakterden sonra
   • Baştan veya sondan N. karakterden sonra
4. Tıklayınız Metin Ekle Düğme. Bitti!

Örnek olarak, A2:A7 hücrelerindeki "-" karakterinden sonra "PR-" dizesini ekleyelim. Bunun için aşağıdaki ayarları yapılandırıyoruz:

Bir dakika sonra, istediğimiz sonucu elde ederiz:

Bunlar Excel'de karakter ve metin dizeleri eklemenin en iyi yollarıdır. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

Mevcut indirmeler

Excel'de hücreye metin ekleme - formül örnekleri (.xlsm dosyası)

Ultimate Suite - deneme sürümü (.exe dosyası)