Хочете дізнатися, як додати текст в існуючу комірку в Excel? У цій статті ви дізнаєтеся кілька дійсно простих способів вставки символів в будь-яку позицію в комірці.

При роботі з текстовими даними в Excel іноді може виникнути необхідність додати однаковий текст в існуючі комірки, щоб зробити їх більш зрозумілими. Наприклад, ви можете поставити якийсь префікс на початку кожної комірки, вставити спеціальний символ в кінці або розмістити певний текст перед формулою.

Як це зробити вручну, напевно, знають всі. Цей урок навчить вас швидко додавати рядки в кілька комірок за допомогою формул і автоматизувати цю роботу за допомогою VBA або спеціального редактора. Додати текст інструмент.

Формули Excel для додавання тексту/символу в комірку

Щоб додати певний символ або текст до комірки Excel, просто об'єднайте рядок і посилання на комірку одним із наведених нижче способів.

Оператор конкатенації

Найпростіший спосіб додавання текстового рядка в комірку - це використання символу амперсанду (&), який є оператором конкатенації в Excel.

" текст "І я не хочу, щоб ви знали, що я тут"; клітина

Це працює у всіх версіях Excel 2007 - Excel 365.

Функція CONCATENATE

Такого ж результату можна досягти за допомогою функції CONCATENATE:

CONCATENATE(" текст ", клітина )

Функція доступна в Excel для Microsoft 365, Excel 2019 - 2007.

Функція CONCAT

Для додавання тексту в клітинки в Excel 365, Excel 2019 і Excel Online можна використовувати функцію КОНКРЕТ, яка є сучасною заміною СЦЕПИТЬ:

CONCAT(" текст ", клітина )

Примітка. Просимо звернути увагу, що у всіх формулах, текст слід брати в лапки.

Це загальні підходи, а наведені нижче приклади показують, як їх застосовувати на практиці.

Як додати текст на початок комірок

Щоб додати певний текст або символ на початок комірки, потрібно зробити ось що:

1. У комірці, де потрібно вивести результат, введіть знак рівності (=).
2. Введіть потрібний текст всередині лапок.
3. Введіть символ амперсанду (&).
4. Виділіть комірку, в яку необхідно додати текст, і натисніть клавішу Enter .

Крім того, ви можете ввести текстовий рядок і посилання на комірку в якості вхідних параметрів для функції CONCATENATE або CONCAT.

Наприклад, підготувати текст " Проект: " до назви проекту в А2, буде працювати будь-яка з наведених нижче формул.

У всіх версіях Excel:

="Проект:"&A2

=CONCATENATE("Project:", A2)

В Excel 365 та Excel 2019:

=CONCAT("Проект:", A2)

Введіть формулу в комірку B2, перетягніть її вниз по стовпчику, і ви отримаєте однаковий текст, вставлений в усі комірки.

Порада. Наведені вище формули з'єднують два рядки без пробілів. Щоб відокремити значення пробілом, введіть a символ пробілу в кінці підготовленого тексту (наприклад, "Проект: ").

Для зручності можна ввести цільовий текст в заздалегідь визначену комірку (Е2) і додавання двох текстових комірок разом :

Без пробілів:

=$E$2&A2

=CONCATENATE($E$2, A2)

З пробілами:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Зверніть увагу, що адреса комірки, яка містить вставлений текст, фіксується знаком $, щоб вона не зміщувалася при копіюванні формули вниз.

При такому підході можна легко змінити доданий текст в одному місці, без необхідності оновлювати кожну формулу.

Як додати текст в кінець комірок в Excel

Щоб додати текст або певний символ до існуючої комірки, знову використовуйте метод конкатенації. Різниця полягає в порядку значень, що конкатенуються: за посиланням на комірку слідує текстовий рядок.

Наприклад, щоб додати рядок " -США " до кінця комірки А2, це формули, які слід використовувати:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Крім того, ви можете ввести текст в якусь комірку, а потім з'єднати дві комірки з текстом разом:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Будь ласка, не забудьте використовувати абсолютне посилання для доданого тексту ($D$2), щоб формула правильно копіювалася по колонці.

Додавання символів на початок і кінець рядка

Знаючи, як вставляти і додавати текст в існуючу комірку, ніщо не завадить вам використовувати обидва прийоми в одній формулі.

Як приклад, додамо рядок " Проект: " на початок і " -США " в кінці існуючого тексту на аркуші А2.

="Project:"&A2&"-US"

=CONCATENATE("Project:", A2, "-US")

=CONCAT("Project:", A2, "-US")

При введенні рядків в окремі комірки це працює однаково добре:

Об'єднання тексту з двох і більше комірок

Щоб помістити значення з декількох комірок в одну комірку, об'єднайте вихідні комірки, використовуючи вже знайомі прийоми: символ амперсанда, функцію CONCATENATE або CONCAT.

Наприклад, щоб об'єднати значення зі стовпців А і В, використовуючи кому і пробіл (", ") в якості роздільника, введіть одну з наведених нижче формул в стовпець В2, а потім перетягніть її вниз по стовпцю.

Додати текст з двох клітинок за допомогою амперсанду:

=A2&", "&B2

Об'єднати текст з двох клітинок за допомогою CONCAT або CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

При додаванні текст з двох колонок обов'язково використовуйте відносні посилання на комірки (наприклад, A2), щоб вони коректно підлаштовувалися під кожен рядок, куди копіюється формула.

Об'єднати текст з декількох комірок в Excel 365 та Excel 2019 можна використовувати функцію TEXTJOIN, синтаксис якої передбачає наявність роздільника (першого аргументу), що робить формулу компактнішою та простішою в управлінні.

Наприклад, для додавання рядків з трьох стовпців (A, B і C), розділяючи значення комою і пробілом, формула має вигляд:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Як додати спеціальний символ до комірки в Excel

Щоб вставити спеціальний символ в комірку Excel, необхідно знати його код в системі ASCII. Після того, як код встановлений, передайте його функції CHAR для повернення відповідного символу. Функція CHAR приймає будь-яке число від 1 до 255. Список кодів символів, що виводяться на друк (значення від 32 до 255), можна знайти тут.

Щоб додати спеціальний символ до існуючого значення або результату формули, ви можете застосувати будь-який метод конкатенації, який вам найбільше подобається.

Наприклад, для додавання знака для товарів і послуг (™) до тексту формату А2 підійде будь-яка з наведених нижче формул:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Як додати текст до формули в Excel

Щоб додати певний символ або текст до результату формули, просто об'єднайте рядок з самою формулою.

Припустимо, ви використовуєте цю формулу для повернення поточного часу:

=TEXT(NOW(), "h:mm AM/PM")

Щоб пояснити користувачам, який зараз час, можна розмістити текст до та/або після формули.

Вставка тексту перед формулою :

="Поточний час: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Поточний час: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Поточний час: ", TEXT(NOW(), "h:mm AM/PM"))

Додайте текст після формули:

=TEXT(NOW(), "h:mm AM/PM")&" - поточний час"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - поточний час")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - поточний час")

Додайте текст до формули з обох сторін:

="Це " &TEXT(NOW(), "h:mm AM/PM")& "тут, в Гомелі"

=CONCATENATE("Це ", TEXT(NOW(), "h:mm AM/PM"), "тут в Гомелі")

=CONCAT("Це ", TEXT(NOW(), "h:mm AM/PM"), "тут в Гомелі")

Як вставити текст після N-го символу

Щоб додати певний текст або символ на певну позицію в комірці, потрібно розділити вихідний рядок на дві частини і помістити текст між ними. Ось як це робиться:

1. Витягнути підрядок, що передує вставленому тексту, за допомогою функції LEFT:

LEFT(комірка, n)

Виділіть підрядок, що слідує за текстом, використовуючи комбінацію клавіш RIGHT і LEN:

RIGHT(комірка, LEN(комірка) -n)

Об'єднайте два підрядки та текст/символ за допомогою символу амперсанду.

Повна формула має такий вигляд:

LEFT( клітина , n ) & " текст " & RIGHT( клітина , LEN( клітина ) - n )

Однакові деталі можуть бути з'єднані між собою за допомогою функції CONCATENATE або CONCAT:

CONCATENATE(LEFT( клітина , n ), " текст ", RIGHT( клітина , LEN( клітина ) - n ))

Завдання також можна виконати за допомогою функції REPLACE:

REPLACE( клітина , n+1 , 0, " текст ")

Хитрість полягає в тому, що num_chars аргумент, що визначає, скільки символів замінити, встановлюється рівним 0, тому формула фактично вставляє текст на вказану позицію в комірці, нічого не замінюючи. Позиція ( start_num аргумент) обчислюється за таким виразом: n+1. До позиції n-го символу ми додаємо 1, тому що текст повинен бути вставлений після нього.

Наприклад, щоб вставити дефіс (-) після 2-го символу в А2, формула в В2 буде такою:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Або

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Або

=REPLACE(A2, 2+1, 0, "-")

Перетягніть формулу вниз, і в усі клітинки буде вставлено однаковий символ:

Як додати текст до/після певного символу

Щоб вставити певний текст до або після певного символу, потрібно визначити позицію цього символу в рядку. Це можна зробити за допомогою функції ПОИСК:

SEARCH(" char - символ ", клітина )

Після того, як позиція визначена, можна додати рядок точно в це місце, використовуючи підходи, розглянуті в наведеному вище прикладі.

Додавання тексту після певного символу

Для того, щоб вставити текст після заданого символу, використовується загальна формула:

LEFT( клітина , SEARCH(" char - символ ", клітина )) & " текст " & RIGHT( клітина , LEN( клітина ) - ПОШУК(" char - символ ", клітина ))

Або

CONCATENATE(LEFT( клітина , SEARCH(" char - символ ", клітина )), " текст ", RIGHT( клітина , LEN( клітина ) - ПОШУК(" char - символ ", клітина )))

Наприклад, щоб вставити текст (США) через дефіс в А2 - формула:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Або

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2)))

Вставка тексту перед певним символом

Для додавання тексту перед певним символом використовується формула:

LEFT( клітина , SEARCH(" char - символ ", клітина ) -1) & " текст " & RIGHT( клітина , LEN( клітина ) - ПОШУК(" char - символ ", клітина ) +1)

Або

CONCATENATE(LEFT( клітина , SEARCH(" char - символ ", клітина ) - 1), " текст ", RIGHT( клітина , LEN( клітина ) - ПОШУК(" char - символ ", клітина ) +1))

Як бачите, формули дуже схожі на ті, що вставляють текст після символу. Різниця в тому, що від результату першого ПОИСК ми віднімаємо 1, щоб змусити функцію LEFT пропустити символ, після якого додається текст. До результату другого ПОИСК ми додаємо 1, щоб функція RIGHT взяла цей символ.

Наприклад, для розміщення тексту (США) перед дефісом в А2, то слід використовувати саме цю формулу:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Або

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Нотатки:

• Якщо вихідна комірка містить неодноразові випадки символу, текст буде вставлено до/після першого входження.
• Функція ПОШУК - це нечутливий до регістру і не може розрізняти малі та великі літери. Якщо ви хочете додати текст до/після малої або великої літери, використовуйте функцію пошуку з урахуванням регістру, щоб знайти цю літеру.

Як додати пробіл між текстом в комірці Excel

По суті, це лише окремий випадок двох попередніх прикладів.

Щоб додати місця на та ж позиція у всіх комірках вставити текст після n-го символу за формулою, де текст символ пробілу (" ").

Наприклад, щоб вставити пробіл після 10-го символу в комірках A2:A7, введіть наведену нижче формулу в комірку B2 і перетягніть її через B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Або

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

У всіх вихідних комірках 10-й символ - двокрапка (:), тому пробіл вставляється саме там, де він нам потрібен:

Щоб вставити пробіл за адресою інша позиція в кожній комірці налаштуйте формулу, яка додає текст до/після певного символу.

У наведеному нижче прикладі таблиці двокрапка (:) стоїть після номера проекту, який може містити змінну кількість символів. Оскільки ми хочемо додати пробіл після двокрапки, ми знаходимо її положення за допомогою функції ПОШУК:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Або

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2)))

Як додати однаковий текст в існуючі комірки з допомогою VBA

Якщо вам часто потрібно вставляти один і той же текст в декілька комірок, ви можете автоматизувати завдання за допомогою VBA.

Підготувати текст до початку

Наведені нижче макроси додають текст або певний символ до початок всіх виділених комірок Обидва коди працюють за однаковою логікою: перевіряють кожну комірку у виділеному діапазоні і, якщо комірка не порожня, додають вказаний текст. Різниця полягає в тому, де розміщується результат: перший код вносить зміни у вихідні дані, а другий - розміщує результат у стовпчику праворуч від виділеного діапазону.

Якщо у вас мало досвіду роботи з VBA, цей покроковий посібник допоможе вам розібратися з цим процесом: Як вставити і запустити код VBA в Excel.

Макрос 1: додає текст у вихідні комірки

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Цей код вставляє підрядок "PR-" зліва від існуючого тексту. Перед використанням коду на своєму робочому аркуші обов'язково замініть наш зразок тексту на той, який вам дійсно потрібен.

Макрос 2: поміщає результати в сусідній стовпчик

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Перед запуском цього макросу переконайтесь, що є порожній стовпчик праворуч обраного діапазону, інакше існуючі дані будуть перезаписані.

Доповнити текст до кінця

Якщо ви хочете додати певний рядок/символ до кінець всіх виділених комірок Ці коди допоможуть вам швидко виконати роботу.

Макрос 1: додає текст у вихідні комірки

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Наш приклад коду вставляє підрядок "-PR" праворуч від існуючого тексту. Звичайно, ви можете змінити його на будь-який потрібний вам текст/символ.

Макрос 2: поміщає результати в іншу колонку

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Цей код поміщає результати в сусідня колонка Тому, перш ніж запускати його, переконайтеся, що праворуч від обраного діапазону є принаймні один порожній стовпець, інакше наявні дані будуть замінені.

Додавання тексту або символів до кількох клітинок за допомогою Ultimate Suite

У першій частині цього уроку ви вивчили кілька різних формул для додавання тексту в клітинки Excel. Зараз я покажу вам, як виконати це завдання кількома клацаннями миші :)

Після встановлення Ultimate Suite у вашому Excel виконайте наступні кроки:

1. Виберіть вихідні дані.
2. Про це йдеться на Аблебіти у вкладці Текст групу, натисніть Додати .
3. Про це йдеться на Додати текст введіть символ/текст, який ви бажаєте додати до виділених клітинок, та вкажіть, куди його слід вставити:
   • На початку
   • Наприкінці
   • Перед певним текстом/символом
   • Після певного тексту/символу
   • Після N-го символу з початку або кінця
4. Натисніть на кнопку Додати текст кнопку. Готово!

Як приклад, вставимо рядок "PR-" після символу "-" в комірках А2:А7. Для цього налаштуємо наступні параметри:

За мить отримуємо бажаний результат:

Це найкращі способи додавання символів і текстових рядків в Excel. Дякую за прочитання і сподіваюся побачити вас на нашому блозі наступного тижня!

Доступні для завантаження

Додавання тексту в комірку в Excel - приклади формул (файл .xlsm)

Ultimate Suite - пробна версія (файл .exe)