Kíváncsi, hogyan adhat szöveget egy meglévő cellához az Excelben? Ebben a cikkben megtanulhat néhány nagyon egyszerű módszert arra, hogy karaktereket illesszen be egy cella bármelyik pozíciójába.

Amikor szöveges adatokkal dolgozik az Excelben, néha szükség lehet arra, hogy ugyanazt a szöveget hozzáadja a meglévő cellákhoz, hogy a dolgokat egyértelműbbé tegye. Például előfordulhat, hogy minden egyes cella elejére valamilyen előtagot szeretne tenni, a végére egy speciális szimbólumot illeszteni, vagy bizonyos szöveget egy képlet elé helyezni.

Gondolom, mindenki tudja, hogyan kell ezt manuálisan elvégezni. Ez a bemutató megtanítja, hogyan lehet gyorsan karakterláncokat hozzáadni több cellához képletek segítségével, és hogyan automatizálhatja a munkát a VBA vagy egy speciális program segítségével. Szöveg hozzáadása eszköz.

Excel képletek szöveg/karakter hozzáadásához a cellához

Egy adott karakter vagy szöveg hozzáadásához egy Excel-cellához egyszerűen kapcsoljon össze egy karakterláncot és egy cellahivatkozást az alábbi módszerek egyikével.

Összekapcsolási operátor

A legegyszerűbb módja annak, hogy egy szöveges karakterláncot adjon hozzá egy cellához, az erősítőjel karakter (&) használata, amely az Excelben az összekapcsolási operátor.

" szöveg "& sejt

Ez az Excel 2007 - Excel 365 összes verziójában működik.

CONCATENATE funkció

Ugyanez az eredmény érhető el a CONCATENATE függvény segítségével:

CONCATENATE(" szöveg ", sejt )

A funkció elérhető az Excel for Microsoft 365, Excel 2019 - 2007 programokban.

CONCAT funkció

Az Excel 365, Excel 2019 és Excel Online programokban a cellákhoz szöveg hozzáadásához használhatja a CONCAT függvényt, amely a CONCATENATE modern helyettesítője:

CONCAT(" szöveg ", sejt )

Megjegyzés: Kérjük, figyeljen arra, hogy minden képletben, szöveg idézőjelbe kell tenni.

Ezek az általános megközelítések, és az alábbi példák azt mutatják, hogyan lehet őket a gyakorlatban alkalmazni.

Szöveg hozzáadása a cellák elejére

Ha bizonyos szöveget vagy karaktert szeretne hozzáadni egy cella elejére, a következőket kell tennie:

1. Írja be az egyenlőségjelet (=) abba a cellába, ahol az eredményt ki akarja adni.
2. Írja be a kívánt szöveget az idézőjelek közé.
3. Írja be az erősítőjelet (&).
4. Válassza ki azt a cellát, amelybe a szöveget hozzá kell adni, és nyomja meg az Enter billentyűt.

Alternatívaként a CONCATENATE vagy CONCAT függvény bemeneti paramétereként megadhatja a szöveges karakterláncot és a cellahivatkozást.

Például a " Projekt: " az A2-ben lévő projektnévhez, az alábbi képletek bármelyike működni fog.

Minden Excel-verzióban:

="Projekt:"&A2

=CONCATENATE("Projekt:", A2)

Az Excel 365 és az Excel 2019 programban:

=CONCAT("Projekt:", A2)

Írja be a képletet a B2-be, húzza lefelé az oszlopban, és minden cellába ugyanazt a szöveget fogja beilleszteni.

Tipp. A fenti képletek két karakterláncot kötnek össze szóköz nélkül. Ha az értékeket szóközzel szeretné elválasztani, írjon be egy szóköz karakter a beillesztett szöveg végén (pl. "Projekt: ").

Az egyszerűség kedvéért a célszöveget egy előre meghatározott cellába (E2) is beírhatja, és két szöveges cellát ad össze :

Szóközök nélkül:

=$E$2&A2

=CONCATENATE($E$2, A2)

Térközökkel:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Vegye észre, hogy az előzetesen beillesztett szöveget tartalmazó cella címe a $ jellel van lezárva, így nem fog elmozdulni, amikor a képletet lemásoljuk.

Ezzel a megközelítéssel könnyen módosíthatja a hozzáadott szöveget egy helyen, anélkül, hogy minden képletet frissítenie kellene.

Hogyan adhat szöveget az Excel cellák végéhez

Ha szöveget vagy egy adott karaktert szeretne egy meglévő cellához csatolni, ismét használja az összekapcsolási módszert. A különbség az összekapcsolt értékek sorrendjében van: a cellahivatkozást egy szöveges karakterlánc követi.

Például a " -US " az A2 cella végére, ezeket a képleteket kell használni:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Alternatív megoldásként beírhatja a szöveget valamelyik cellába, majd összekapcsolhatja a két cellát a szöveggel:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Ne feledje, hogy abszolút hivatkozást használjon a csatolt szöveghez ($D$2), hogy a képlet helyesen másolja át az oszlopot.

Karakterek hozzáadása egy karakterlánc elejéhez és végéhez

Mivel tudja, hogyan kell szöveget előzetesen beilleszteni és hozzáadni egy meglévő cellához, semmi sem akadályozza meg, hogy mindkét technikát egy képleten belül használja.

Példaként adjuk hozzá a karakterláncot " Projekt: " az elejére és " -US " a meglévő A2 szöveg végére.

="Project:"&A2&"-US"

=CONCATENATE("Project:", A2, "-US")

=CONCAT("Projekt:", A2, "-US")

Ha a karakterláncokat külön cellákban adjuk meg, ez ugyanilyen jól működik:

Két vagy több cellából származó szöveg kombinálása

Több cellából származó értékek egy cellába helyezéséhez az eredeti cellákat a már ismert technikák segítségével kapcsolja össze: az erősítőjel szimbólum, a CONCATENATE vagy a CONCAT függvény segítségével.

Ha például az A és B oszlopok értékeit vesszővel és szóközzel (", ") akarja összekapcsolni, írja be az alábbi képletek egyikét a B2 oszlopba, majd húzza lefelé az oszlopban.

Szöveg hozzáadása két cellából egy végződésjel segítségével:

=A2&", "&B2

Két cellából származó szöveg kombinálása a CONCAT vagy a CONCATENATE segítségével:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Amikor hozzáadjuk szöveg két oszlopból , ügyeljen arra, hogy relatív cellahivatkozásokat használjon (például A2), így azok minden olyan sorban, ahová a képletet másolja, helyesen alkalmazkodnak.

Kombinálni szöveg több cellából az Excel 365-ben és az Excel 2019-ben kihasználhatja a TEXTJOIN függvényt. Szintaxisa rendelkezik egy elválasztójelről (az első argumentum), ami tömörebbé és könnyebben kezelhetővé teszi a formulát.

Például három oszlop (A, B és C) karakterláncainak összeadásához, az értékeket vesszővel és szóközzel elválasztva, a képlet a következő:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Hogyan adjunk speciális karaktert az Excel cellához

Ahhoz, hogy egy speciális karaktert beilleszthessen egy Excel-cellába, ismernie kell annak kódját az ASCII-rendszerben. Ha a kód megvan, adja meg a CHAR függvénynek, hogy a megfelelő karaktert adja vissza. A CHAR függvény 1 és 255 közötti bármely számot elfogad. A nyomtatható karakterkódok listája (32 és 255 közötti értékek) itt található.

Ha egy meglévő értékhez vagy képlet eredményéhez különleges karaktert szeretne hozzáadni, akkor bármelyik tetszőlegesen választott összekapcsolási módszert alkalmazhatja.

Ha például a védjegy szimbólumot (™) szeretné hozzáadni az A2-ben lévő szöveghez, a következő képletek bármelyike használható:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Hogyan adjunk hozzá szöveget az Excel képletéhez

Ha egy bizonyos karaktert vagy szöveget szeretne hozzáadni egy képlet eredményéhez, egyszerűen kapcsoljon össze egy karakterláncot magával a képlettel.

Tegyük fel, hogy ezt a képletet használja az aktuális idő visszaadására:

=TEXT(NOW(), "h:mm AM/PM")

Hogy elmagyarázza a felhasználóknak, hogy mennyi az idő, a képlet előtt és/vagy után elhelyezhet némi szöveget.

Szöveg beillesztése a képlet előtt :

="Aktuális idő: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Aktuális idő: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Aktuális idő: ", TEXT(NOW(), "h:mm AM/PM"))

Szöveg hozzáadása a képlet után:

=TEXT(NOW(), "h:mm AM/PM")&" - aktuális idő"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - aktuális idő")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - aktuális idő")

Szöveg hozzáadása a képlethez mindkét oldalon:

="Itt van " &TEXT(NOW(), "h:mm AM/PM")& " itt Gomelben"

=CONCATENATE("Itt van ", TEXT(NOW(), "h:mm AM/PM"), " itt Gomelben")

=CONCAT("Itt van ", TEXT(NOW(), "h:mm AM/PM"), " Gomelben")

Hogyan illesszünk be szöveget az N-edik karakter után

Ahhoz, hogy egy adott szöveget vagy karaktert egy adott cellában egy bizonyos pozícióba helyezzünk, az eredeti karakterláncot két részre kell osztanunk, és a szöveget a két rész közé kell helyeznünk. Íme, hogyan:

1. A beillesztett szöveg előtti részlánc kivonása a LEFT függvény segítségével:

LEFT(cella, n)

A szöveget követő részlánc kivonása a RIGHT és a LEN kombinációjával:

RIGHT(cell, LEN(cell) -n)

A két részsztringet és a szöveget/karaktert egy erősítőjel segítségével kapcsolja össze.

A teljes képlet a következő formát ölti:

LEFT( sejt , n ) & " szöveg " & RIGHT( sejt , LEN( sejt ) - n )

Az azonos részek a CONCATENATE vagy CONCAT függvény használatával egyesíthetők:

CONCATENATE(LEFT( sejt , n ), " szöveg ", RIGHT( sejt , LEN( sejt ) - n ))

A feladat a REPLACE funkció használatával is elvégezhető:

REPLACE( sejt , n+1 , 0, " szöveg ")

A trükk az, hogy a num_chars argumentum, amely meghatározza, hogy hány karaktert kell helyettesíteni, 0-ra van állítva, így a képlet ténylegesen beilleszti a szöveg a megadott cellapozícióban anélkül, hogy bármit is helyettesítene. A pozíció ( start_num argumentum) kiszámítása a következő kifejezéssel történik: n+1. Az n-edik karakter pozíciójához 1-et adunk hozzá, mert a szöveget utána kell beilleszteni.

Például, ha az A2-ben a 2. karakter után kötőjelet (-) szeretnénk beilleszteni, a B2-ben a következő képletet kell használni:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Vagy

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Vagy

=REPLACE(A2, 2+1, 0, "-")

Húzza lefelé a képletet, és minden cellába ugyanazt a karaktert fogja beilleszteni:

Hogyan adhatsz hozzá szöveget egy adott karakter előtt/után

Ahhoz, hogy bizonyos szöveget egy adott karakter elé vagy után illesszen be, meg kell határoznia az adott karakter pozícióját a karakterláncban. Ezt a SEARCH funkció segítségével teheti meg:

SEARCH(" char ", sejt )

Miután a pozíciót meghatároztuk, a fenti példában ismertetett megközelítésekkel pontosan az adott helyre adhatunk hozzá egy karakterláncot.

Szöveg hozzáadása egy adott karakter után

Ha egy adott karakter után be akarunk illeszteni egy szöveget, az általános képlet a következő:

LEFT( sejt , SEARCH(" char ", sejt )) & " szöveg " & RIGHT( sejt , LEN( sejt ) - SEARCH(" char ", sejt ))

Vagy

CONCATENATE(LEFT( sejt , SEARCH(" char ", sejt )), " szöveg ", RIGHT( sejt , LEN( sejt ) - SEARCH(" char ", sejt )))

Például a következő szöveg beillesztéséhez (US) kötőjel után az A2-ben, a képlet a következő:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Vagy

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2)))))

Szöveg beszúrása egy adott karakter előtt

Ha egy bizonyos karakter előtt szeretne szöveget hozzáadni, a képlet a következő:

LEFT( sejt , SEARCH(" char ", sejt ) -1) & " szöveg " & RIGHT( sejt , LEN( sejt ) - SEARCH(" char ", sejt ) +1)

Vagy

CONCATENATE(LEFT( sejt , SEARCH(" char ", sejt ) - 1), " szöveg ", RIGHT( sejt , LEN( sejt ) - SEARCH(" char ", sejt ) +1))

Amint látja, a képletek nagyon hasonlóak azokhoz, amelyek szöveget illesztenek be egy karakter után. A különbség az, hogy az első SEARCH eredményéből kivonunk 1-et, hogy a LEFT függvény kihagyja a karaktert, amely után a szöveget hozzáadjuk. A második SEARCH eredményéhez hozzáadunk 1-et, hogy a RIGHT függvény megkapja ezt a karaktert.

Például a szöveg elhelyezéséhez (US) kötőjel előtt az A2-ben, ezt a képletet kell használni:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Vagy

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)))

Megjegyzések:

• Ha az eredeti cella tartalmaz többszörös előfordulás karaktert, a szöveg az első előfordulás előtt/után kerül beillesztésre.
• A SEARCH funkció case-insensitive és nem képes megkülönböztetni a kis- és nagybetűket. Ha egy kis- vagy nagybetű előtt/után szeretne szöveget beilleszteni, akkor használja a nagybetű-érzékeny FIND funkciót az adott betű megkereséséhez.

Hogyan adjunk helyet az Excel-cellában lévő szöveg között

Valójában ez csak egy speciális esete az előző két példának.

Hely hozzáadása a ugyanaz a pozíció az összes cellában, a képlet segítségével illessze be a szöveget az n-edik karakter után, ahol szöveg a szóköz karakter (" ").

Ha például az A2:A7 cellákban a 10. karakter után szóközt szeretne beilleszteni, írja be az alábbi képletet a B2 cellába, és húzza át a B7 cellán:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Vagy

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Az összes eredeti cellában a 10. karakter egy kettőspont (:), így a szóköz pontosan oda kerül, ahol szükségünk van rá:

A szóköz beillesztése egy más pozíció minden egyes cellában állítsa be azt a képletet, amely szöveget ad hozzá egy adott karakter előtt/után.

Az alábbi mintatáblázatban a projekt száma után egy kettőspont (:) található, amely változó számú karaktert tartalmazhat. Mivel a kettőspont után egy szóközt szeretnénk hozzáadni, a SEARCH funkcióval keressük meg a pozícióját:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Vagy

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2)))))

Hogyan lehet ugyanazt a szöveget hozzáadni a meglévő cellákhoz a VBA segítségével?

Ha gyakran kell ugyanazt a szöveget több cellába beillesztenie, a feladatot automatizálhatja a VBA segítségével.

Szöveg beillesztése az elejére

Az alábbi makrók szöveget vagy egy adott karaktert adnak hozzá a kezdete az összes kiválasztott cella Mindkét kód ugyanarra a logikára épül: ellenőrizni kell a kijelölt tartomány minden egyes celláját, és ha a cella nem üres, akkor a megadott szöveget elő kell írni. A különbség az eredmény elhelyezésében van: az első kód módosítja az eredeti adatokat, míg a második a kijelölt tartománytól jobbra lévő oszlopba helyezi az eredményeket.

Ha kevés tapasztalattal rendelkezik a VBA-val kapcsolatban, ez a lépésről lépésre bemutatott útmutató végigvezeti Önt a folyamaton: Hogyan illesszünk be és futtassunk VBA-kódot az Excelben.

1. makró: szöveget ad az eredeti cellákhoz

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Ez a kód beilleszti a "PR-" részláncot egy meglévő szöveg bal oldalára. Mielőtt használná a kódot a munkalapján, mindenképpen cserélje ki a mintaszöveget a valóban szükségesre.

2. makró: az eredményeket a szomszédos oszlopba helyezi.

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

A makró futtatása előtt győződjön meg róla, hogy van egy üres oszlop a jobb oldalon a kiválasztott tartományban, különben a meglévő adatok felülíródnak.

Szöveg hozzáadása a végére

Ha egy adott karakterláncot/karaktert szeretne hozzáadni a vége az összes kiválasztott cella , ezek a kódok segítenek abban, hogy a munkát gyorsan elvégezze.

1. makró: szöveg hozzáadása az eredeti cellákhoz

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

A példakódunk a "-PR" részláncot illeszti be egy meglévő szöveg jobb oldalára. Természetesen bármilyen szövegre/karakterre módosíthatja, amire csak szüksége van.

2. makró: az eredményeket egy másik oszlopba helyezi

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Ez a kód az eredményeket egy szomszédos oszlop Mielőtt tehát futtatná, győződjön meg róla, hogy a kiválasztott tartomány jobb oldalán legalább egy üres oszlop van, különben a meglévő adatok felülíródnak.

Szöveg vagy karakter hozzáadása több cellához az Ultimate Suite segítségével

A bemutató első részében megtanultál egy maroknyi különböző képletet, amelyekkel szöveget adhatsz hozzá Excel-cellákhoz. Most megmutatom, hogyan lehet a feladatot néhány kattintással elvégezni :)

Ha az Ultimate Suite telepítve van az Excelben, az alábbi lépéseket kell követnie:

1. Válassza ki a forrásadatokat.
2. A Ablebits lapon, a Szöveg csoport, kattintson a Add .
3. A Szöveg hozzáadása ablaktáblába írja be a kiválasztott cellákba beilleszteni kívánt karaktert/szöveget, és adja meg, hogy hova kell beilleszteni:
   • Az elején
   • A végén
   • Egy adott szöveg/karakter előtt
   • Egy adott szöveg/karakter után
   • Az elejétől vagy végétől számított N-edik karakter után
4. Kattintson a Szöveg hozzáadása Kész!

Példaként szúrjuk be a "PR-" karakterláncot a "-" karakter után az A2:A7 cellákba. Ehhez a következő beállításokat kell megadni:

Egy pillanattal később megkapjuk a kívánt eredményt:

Ezek a legjobb módjai a karakterek és szöveges karakterláncok hozzáadásának az Excelben. Köszönöm, hogy elolvastad, és remélem, jövő héten találkozunk a blogon!

Elérhető letöltések

Szöveg hozzáadása az Excel cellához - képletpéldák (.xlsm fájl)

Ultimate Suite - próbaverzió (.exe fájl)