Sie fragen sich, wie Sie in Excel Text in eine bestehende Zelle einfügen können? In diesem Artikel lernen Sie einige wirklich einfache Möglichkeiten kennen, um Zeichen an beliebiger Stelle in eine Zelle einzufügen.

Wenn Sie in Excel mit Textdaten arbeiten, müssen Sie manchmal denselben Text in vorhandene Zellen einfügen, um die Dinge klarer zu machen, z. B. ein Präfix am Anfang jeder Zelle, ein spezielles Symbol am Ende oder einen bestimmten Text vor einer Formel zu platzieren.

In diesem Tutorial lernen Sie, wie Sie mithilfe von Formeln schnell Zeichenketten zu mehreren Zellen hinzufügen und die Arbeit mit VBA oder einem speziellen Programm automatisieren können. Text hinzufügen Werkzeug.

Excel-Formeln zum Hinzufügen von Text/Zeichen in Zellen

Um einer Excel-Zelle ein bestimmtes Zeichen oder einen Text hinzuzufügen, verketten Sie einfach eine Zeichenfolge und einen Zellverweis mit einer der folgenden Methoden.

Verkettungsoperator

Die einfachste Art, einer Zelle eine Textzeichenfolge hinzuzufügen, ist die Verwendung eines kaufmännischen Und-Zeichens (&), das in Excel als Verkettungsoperator dient.

" Text "& Zelle

Dies funktioniert in allen Versionen von Excel 2007 - Excel 365.

CONCATENATE-Funktion

Das gleiche Ergebnis kann mit Hilfe der Funktion CONCATENATE erzielt werden:

CONCATENATE(" Text ", Zelle )

Die Funktion ist in Excel für Microsoft 365, Excel 2019 - 2007 verfügbar.

CONCAT-Funktion

Um Text zu Zellen in Excel 365, Excel 2019 und Excel Online hinzuzufügen, können Sie die Funktion CONCAT verwenden, die ein moderner Ersatz für CONCATENATE ist:

CONCAT(" Text ", Zelle )

Hinweis: Bitte beachten Sie, dass in allen Formeln, Text sollte in Anführungszeichen gesetzt werden.

Dies sind die allgemeinen Ansätze, und die folgenden Beispiele zeigen, wie sie in der Praxis angewendet werden können.

Hinzufügen von Text am Anfang von Zellen

Um einen bestimmten Text oder ein bestimmtes Zeichen an den Anfang einer Zelle zu setzen, müssen Sie Folgendes tun:

1. Geben Sie in der Zelle, in der Sie das Ergebnis ausgeben möchten, das Gleichheitszeichen (=) ein.
2. Geben Sie den gewünschten Text innerhalb der Anführungszeichen ein.
3. Geben Sie ein kaufmännisches Und-Symbol (&) ein.
4. Wählen Sie die Zelle aus, in die der Text eingefügt werden soll, und drücken Sie die Eingabetaste.

Alternativ können Sie Ihre Textzeichenfolge und den Zellbezug als Eingabeparameter für die Funktionen CONCATENATE oder CONCAT verwenden.

Zum Beispiel, um den Text voranzustellen " Projekt: "zu einem Projektnamen in A2 hinzufügen, funktioniert jede der folgenden Formeln.

In allen Excel-Versionen:

="Projekt:"&A2

=CONCATENATE("Projekt:", A2)

In Excel 365 und Excel 2019:

=CONCAT("Projekt:", A2)

Geben Sie die Formel in B2 ein, ziehen Sie sie in der Spalte nach unten, und schon haben Sie in allen Zellen den gleichen Text eingefügt.

Tipp: Die obigen Formeln verbinden zwei Zeichenfolgen ohne Leerzeichen. Um Werte durch ein Leerzeichen zu trennen, geben Sie ein Leerzeichen am Ende des vorangestellten Textes (z. B. "Projekt: ").

Der Einfachheit halber können Sie den Zieltext in eine vordefinierte Zelle (E2) eingeben und zwei Textzellen zusammenfügen :

Ohne Leerzeichen:

=$E$2&A2

=VERKETTUNG($E$2, A2)

Mit Leerzeichen:

=$E$2&" "&A2

=VERKETTUNG($E$2, " ", A2)

Bitte beachten Sie, dass die Adresse der Zelle, die den vorangestellten Text enthält, mit dem $-Zeichen gesperrt ist, damit sie sich beim Kopieren der Formel nicht nach unten verschiebt.

Auf diese Weise können Sie den hinzugefügten Text einfach an einer Stelle ändern, ohne jede Formel aktualisieren zu müssen.

Hinzufügen von Text an das Ende von Zellen in Excel

Um Text oder ein bestimmtes Zeichen an eine bestehende Zelle anzuhängen, verwenden Sie wieder die Methode der Verkettung. Der Unterschied liegt in der Reihenfolge der verketteten Werte: Auf einen Zellbezug folgt eine Textzeichenfolge.

Um zum Beispiel die Zeichenfolge " -US " am Ende von Zelle A2 einfügen, sind dies die zu verwendenden Formeln:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Alternativ können Sie den Text auch in eine Zelle eingeben und dann zwei Zellen mit Text miteinander verbinden:

=A2&$D$2

=VERKETTUNG(A2, $D$2)

Bitte denken Sie daran, einen absoluten Bezug für den angehängten Text ($D$2) zu verwenden, damit die Formel korrekt in die Spalte kopiert werden kann.

Hinzufügen von Zeichen am Anfang und Ende einer Zeichenkette

Wenn Sie wissen, wie man Text an eine bestehende Zelle anfügt und vorangestellt wird, spricht nichts dagegen, beide Techniken in einer Formel zu verwenden.

Als Beispiel fügen wir die Zeichenfolge " Projekt: " an den Anfang und " -US " an das Ende des bestehenden Textes in A2.

="Project:"&A2&"-US"

=CONCATENATE("Projekt:", A2, "-US")

=CONCAT("Projekt:", A2, "-US")

Wenn die Zeichenfolgen in getrennten Zellen eingegeben werden, funktioniert dies ebenso gut:

Kombinieren von Text aus zwei oder mehr Zellen

Um Werte aus mehreren Zellen in einer Zelle zu platzieren, verketten Sie die ursprünglichen Zellen mit Hilfe der bereits bekannten Techniken: ein kaufmännisches Und-Symbol, die Funktion CONCATENATE oder CONCAT.

Um beispielsweise Werte aus den Spalten A und B zu kombinieren, indem Sie ein Komma und ein Leerzeichen (", ") als Trennzeichen verwenden, geben Sie eine der folgenden Formeln in B2 ein und ziehen Sie sie dann nach unten in die Spalte.

Fügen Sie Text aus zwei Zellen mit einem kaufmännischen Und ein:

=A2&", "&B2

Kombinieren Sie Text aus zwei Zellen mit CONCAT oder CONCATENATE:

=VERKETTUNG(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

Beim Hinzufügen von Text aus zwei Spalten Achten Sie darauf, relative Zellbezüge (wie A2) zu verwenden, damit sie für jede Zeile, in die die Formel kopiert wird, korrekt angepasst werden.

Zum Kombinieren Text aus mehreren Zellen In Excel 365 und Excel 2019 können Sie die Funktion TEXTJOIN nutzen, deren Syntax ein Trennzeichen (das erste Argument) vorsieht, wodurch das Formular kompakter und einfacher zu verwalten ist.

Um z. B. Zeichenketten aus drei Spalten (A, B und C) zu addieren, wobei die Werte durch ein Komma und ein Leerzeichen getrennt werden, lautet die Formel:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Hinzufügen von Sonderzeichen zu Zellen in Excel

Um ein Sonderzeichen in eine Excel-Zelle einzufügen, müssen Sie seinen Code im ASCII-System kennen. Sobald der Code feststeht, geben Sie ihn an die Funktion CHAR weiter, um ein entsprechendes Zeichen zurückzugeben. Die Funktion CHAR akzeptiert jede Zahl von 1 bis 255. Eine Liste der druckbaren Zeichencodes (Werte von 32 bis 255) finden Sie hier.

Um ein Sonderzeichen zu einem vorhandenen Wert oder einem Formelergebnis hinzuzufügen, können Sie eine beliebige Verkettungsmethode anwenden, die Ihnen am besten gefällt.

Um z. B. das Markensymbol (™) zu Text in A2 hinzuzufügen, können Sie eine der folgenden Formeln verwenden:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Hinzufügen von Text zu einer Formel in Excel

Um ein bestimmtes Zeichen oder einen Text zu einem Formelergebnis hinzuzufügen, verketten Sie einfach eine Zeichenfolge mit der Formel selbst.

Angenommen, Sie verwenden diese Formel, um die aktuelle Zeit zu ermitteln:

=TEXT(NOW(), "h:mm AM/PM")

Um Ihren Benutzern zu erklären, wie spät es ist, können Sie vor und/oder nach der Formel einen Text einfügen.

Text vor der Formel einfügen :

="Aktuelle Uhrzeit: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Aktuelle Zeit: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Aktuelle Zeit: ", TEXT(NOW(), "h:mm AM/PM"))

Text nach der Formel hinzufügen:

=TEXT(NOW(), "h:mm AM/PM")&" - aktuelle Zeit"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - aktuelle Zeit")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - aktuelle Zeit")

Fügen Sie der Formel auf beiden Seiten Text hinzu:

="Es ist " &TEXT(NOW(), "h:mm AM/PM")& " hier in Gomel"

=CONCATENATE("Es ist ", TEXT(NOW(), "h:mm AM/PM"), " hier in Gomel")

=CONCAT("Es ist ", TEXT(NOW(), "h:mm AM/PM"), " hier in Gomel")

Einfügen von Text nach dem N-ten Zeichen

Um einen bestimmten Text oder ein bestimmtes Zeichen an einer bestimmten Stelle in einer Zelle einzufügen, müssen Sie die ursprüngliche Zeichenfolge in zwei Teile aufteilen und den Text dazwischen platzieren. So geht's:

1. Extrahieren Sie mit Hilfe der Funktion LEFT eine Teilzeichenkette, die dem eingefügten Text vorausgeht:

LEFT(Zelle, n)

Extrahieren einer Teilzeichenkette, die dem Text folgt, unter Verwendung der Kombination von RIGHT und LEN:

RIGHT(Zelle, LEN(Zelle) -n)

Verketten Sie die beiden Teilzeichenfolgen und den Text/das Zeichen mit einem kaufmännischen Und-Symbol.

Die vollständige Formel sieht so aus:

LINKS( Zelle , n ) & " Text " & RIGHT( Zelle , LEN( Zelle ) - n )

Gleiche Teile können mit Hilfe der Funktionen CONCATENATE oder CONCAT zusammengefügt werden:

CONCATENATE(LEFT( Zelle , n ), " Text ", RIGHT( Zelle , LEN( Zelle ) - n ))

Diese Aufgabe kann auch mit Hilfe der Funktion REPLACE erledigt werden:

REPLACE( Zelle , n+1 , 0, " Text ")

Der Trick ist, dass die num_chars Argument, das festlegt, wie viele Zeichen ersetzt werden sollen, ist auf 0 gesetzt, so dass die Formel tatsächlich Folgendes einfügt Text an der angegebenen Position in einer Zelle, ohne etwas zu ersetzen. Die Position ( start_num Argument) wird mit diesem Ausdruck berechnet: n+1. Wir addieren 1 zur Position des n-ten Zeichens, weil der Text danach eingefügt werden soll.

Um zum Beispiel einen Bindestrich (-) nach dem 2. Zeichen in A2 einzufügen, lautet die Formel in B2:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Oder

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Oder

=REPLACE(A2, 2+1, 0, "-")

Ziehen Sie die Formel nach unten, so dass in allen Zellen das gleiche Zeichen eingefügt wird:

Hinzufügen von Text vor/nach einem bestimmten Zeichen

Um einen bestimmten Text vor oder nach einem bestimmten Zeichen einzufügen, müssen Sie die Position dieses Zeichens in einer Zeichenkette bestimmen, was mit Hilfe der Funktion SEARCH möglich ist:

SEARCH(" char ", Zelle )

Sobald die Position bestimmt ist, können Sie eine Zeichenkette genau an dieser Stelle einfügen, indem Sie die im obigen Beispiel beschriebenen Ansätze verwenden.

Text nach einem bestimmten Zeichen hinzufügen

Um einen Text nach einem bestimmten Zeichen einzufügen, lautet die allgemeine Formel:

LINKS( Zelle , SEARCH(" char ", Zelle )) & " Text " & RIGHT( Zelle , LEN( Zelle ) - SEARCH(" char ", Zelle ))

Oder

CONCATENATE(LEFT( Zelle , SEARCH(" char ", Zelle )), " Text ", RIGHT( Zelle , LEN( Zelle ) - SEARCH(" char ", Zelle )))

Zum Beispiel, um den Text einzufügen (US) nach einem Bindestrich in A2, lautet die Formel:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Oder

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2)))

Text vor einem bestimmten Zeichen einfügen

Um einen Text vor einem bestimmten Zeichen einzufügen, lautet die Formel:

LINKS( Zelle , SEARCH(" char ", Zelle ) -1) & " Text " & RIGHT( Zelle , LEN( Zelle ) - SEARCH(" char ", Zelle ) +1)

Oder

CONCATENATE(LEFT( Zelle , SEARCH(" char ", Zelle ) - 1), " Text ", RIGHT( Zelle , LEN( Zelle ) - SEARCH(" char ", Zelle ) +1))

Wie Sie sehen, sind die Formeln denen, die Text nach einem Zeichen einfügen, sehr ähnlich. Der Unterschied besteht darin, dass wir 1 vom Ergebnis der ersten SUCHE subtrahieren, um die Funktion LINKS zu zwingen, das Zeichen, nach dem der Text eingefügt wird, wegzulassen. Zum Ergebnis der zweiten SUCHE addieren wir 1, damit die Funktion RECHTS dieses Zeichen holt.

Zum Beispiel, um den Text zu platzieren (US) vor einem Bindestrich in A2, so ist diese Formel zu verwenden:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Oder

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Anmerkungen:

• Wenn die Originalzelle Folgendes enthält mehrfaches Vorkommen eines Zeichens, wird der Text vor/nach dem ersten Vorkommen eingefügt.
• Die Funktion SEARCH ist Groß- und Kleinschreibung wird nicht berücksichtigt Wenn Sie Text vor oder nach einem Klein- oder Großbuchstaben einfügen möchten, verwenden Sie die Funktion FINDEN, die die Groß- und Kleinschreibung berücksichtigt, um diesen Buchstaben zu finden.

Leerzeichen zwischen Text in Excel-Zellen einfügen

Tatsächlich handelt es sich nur um einen Sonderfall der beiden vorangegangenen Beispiele.

So fügen Sie Platz an der gleiche Position in allen Zellen die Formel verwenden, um den Text nach dem n-ten Zeichen einzufügen, wobei Text ist das Leerzeichen (" ").

Um zum Beispiel ein Leerzeichen nach dem 10. Zeichen in den Zellen A2:A7 einzufügen, geben Sie die folgende Formel in B2 ein und ziehen Sie sie durch B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Oder

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

In allen ursprünglichen Zellen ist das 10. Zeichen ein Doppelpunkt (:), so dass ein Leerzeichen genau an der Stelle eingefügt wird, an der wir es brauchen:

So fügen Sie ein Leerzeichen an einer andere Position Passen Sie in jeder Zelle die Formel an, die Text vor/nach einem bestimmten Zeichen einfügt.

In der Beispieltabelle unten steht nach der Projektnummer, die eine variable Anzahl von Zeichen enthalten kann, ein Doppelpunkt (:). Da wir nach dem Doppelpunkt ein Leerzeichen einfügen wollen, suchen wir seine Position mit der Funktion SEARCH:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Oder

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2)))

Hinzufügen desselben Textes zu vorhandenen Zellen mit VBA

Wenn Sie häufig denselben Text in mehrere Zellen einfügen müssen, können Sie diese Aufgabe mit VBA automatisieren.

Text am Anfang vorangestellt

Die folgenden Makros fügen Text oder ein bestimmtes Zeichen in die Anfang aller ausgewählten Zellen Beide Codes beruhen auf derselben Logik: jede Zelle im ausgewählten Bereich wird überprüft, und wenn die Zelle nicht leer ist, wird der angegebene Text vorangestellt. Der Unterschied besteht darin, wo das Ergebnis platziert wird: der erste Code ändert die ursprünglichen Daten, während der zweite die Ergebnisse in einer Spalte rechts vom ausgewählten Bereich platziert.

Wenn Sie nur wenig Erfahrung mit VBA haben, wird Sie diese Anleitung Schritt für Schritt durch den Prozess führen: Einfügen und Ausführen von VBA-Code in Excel.

Makro 1: fügt Text zu den ursprünglichen Zellen hinzu

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Dieser Code fügt die Teilzeichenkette "PR-" links von einem vorhandenen Text ein. Bevor Sie den Code in Ihrem Arbeitsblatt verwenden, sollten Sie unseren Beispieltext durch den tatsächlich benötigten Text ersetzen.

Makro 2: platziert die Ergebnisse in der nebenstehenden Spalte

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Vergewissern Sie sich vor der Ausführung dieses Makros, dass es eine leere Spalte auf der rechten Seite des ausgewählten Bereichs, andernfalls werden die vorhandenen Daten überschrieben.

Text an das Ende anhängen

Wenn Sie eine bestimmte Zeichenkette/ein bestimmtes Zeichen in die Ende aller ausgewählten Zellen Diese Codes werden Ihnen helfen, die Arbeit schnell zu erledigen.

Makro 1: fügt Text an die ursprünglichen Zellen an

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Unser Beispielcode fügt die Teilzeichenkette "-PR" rechts von einem vorhandenen Text ein. Natürlich können Sie sie in jeden beliebigen Text/Zeichen ändern.

Makro 2: platziert die Ergebnisse in einer anderen Spalte

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Dieser Code legt die Ergebnisse in einer benachbarte Spalte Vergewissern Sie sich also vor der Ausführung, dass sich rechts vom ausgewählten Bereich mindestens eine leere Spalte befindet, da sonst Ihre vorhandenen Daten überschrieben werden.

Hinzufügen von Text oder Zeichen zu mehreren Zellen mit Ultimate Suite

Im ersten Teil dieses Tutorials haben Sie eine Handvoll verschiedener Formeln kennengelernt, mit denen Sie Text in Excel-Zellen einfügen können. Jetzt zeige ich Ihnen, wie Sie diese Aufgabe mit ein paar Klicks erledigen können :)

Wenn Ultimate Suite in Ihrem Excel installiert ist, gehen Sie wie folgt vor:

1. Wählen Sie Ihre Quelldaten aus.
2. Auf der Ablebits auf der Registerkarte Text Gruppe, klicken Sie auf hinzufügen .
3. Auf der Text hinzufügen geben Sie das Zeichen/den Text ein, das/den Sie in die ausgewählten Zellen einfügen möchten, und geben Sie an, wo es/er eingefügt werden soll:
   • Zu Beginn
   • Am Ende
   • Vor einem bestimmten Text/Zeichen
   • Nach einem bestimmten Text/Zeichen
   • Nach dem N-ten Zeichen vom Anfang oder Ende
4. Klicken Sie auf die Text hinzufügen Taste. Erledigt!

Als Beispiel fügen wir die Zeichenfolge "PR-" nach dem "-"-Zeichen in die Zellen A2:A7 ein und konfigurieren dazu die folgenden Einstellungen:

Einen Moment später erhalten wir das gewünschte Ergebnis:

Dies sind die besten Möglichkeiten, um Zeichen und Textstrings in Excel hinzuzufügen. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Verfügbare Downloads

Text zu einer Zelle in Excel hinzufügen - Formelbeispiele (.xlsm-Datei)

Ultimate Suite - Testversion (.exe-Datei)