Tutorial ini menjelaskan perbedaan antara fungsi SUMIF dan SUMIFS dalam hal sintaks dan penggunaannya, dan memberikan sejumlah contoh rumus untuk menjumlahkan nilai dengan beberapa kriteria AND / OR di Excel 365, 2021, 2019, 2016, 2013, 2010, dan yang lebih rendah.

Seperti yang diketahui semua orang, Microsoft Excel menyediakan berbagai fungsi untuk melakukan berbagai penghitungan dengan data. Beberapa artikel yang lalu, kami menjelajahi COUNTIF dan COUNTIFS, yang masing-masing dirancang untuk menghitung sel berdasarkan satu kondisi dan beberapa kondisi. Minggu lalu kami membahas Excel SUMIF yang menambahkan nilai yang memenuhi kriteria yang ditentukan. Sekarang saatnya untuk membahas versi jamak dariSUMIF - Excel SUMIFS yang memungkinkan penjumlahan nilai dengan beberapa kriteria.

Mereka yang akrab dengan fungsi SUMIF mungkin berpikir bahwa mengubahnya menjadi SUMIFS hanya membutuhkan tambahan "S" dan beberapa kriteria tambahan. Ini tampaknya cukup logis... tetapi "logis" tidak selalu terjadi ketika berurusan dengan Microsoft : )

Fungsi SUMIF Excel - sintaks &; penggunaan

Fungsi SUMIF digunakan untuk menjumlahkan nilai secara kondisional berdasarkan pada kriteria tunggal Kita telah membahas sintaks SUMIF secara rinci dalam artikel sebelumnya, dan berikut ini hanya penyegaran singkat.

• rentang - rentang sel yang akan dievaluasi oleh kriteria Anda, diperlukan.
• kriteria - kondisi yang harus dipenuhi, diperlukan.
• sum_range - sel yang akan dijumlahkan jika kondisi terpenuhi, opsional.

Seperti yang Anda lihat, sintaks fungsi Excel SUMIF hanya memungkinkan untuk satu kondisi saja. Dan tetap saja, kami mengatakan bahwa Excel SUMIF dapat digunakan untuk menjumlahkan nilai dengan beberapa kriteria. Bagaimana itu bisa terjadi? Dengan menambahkan hasil dari beberapa fungsi SUMIF dan dengan menggunakan rumus SUMIF dengan kriteria array, seperti yang ditunjukkan pada contoh berikut.

Fungsi Excel SUMIFS - sintaks &; penggunaan

Anda menggunakan SUMIFS di Excel untuk menemukan jumlah nilai bersyarat berdasarkan beberapa kriteria Fungsi SUMIFS diperkenalkan di Excel 2007 dan tersedia di semua versi Excel 2010, 2013, 2016, 2019, 2021, dan Excel 365 berikutnya.

Dibandingkan dengan SUMIF, sintaks SUMIFS sedikit lebih kompleks:

3 argumen pertama bersifat wajib, rentang tambahan dan kriteria terkaitnya bersifat opsional.

• sum_range - satu sel atau lebih untuk dijumlahkan, diperlukan. Ini bisa berupa sel tunggal, rentang sel, atau rentang bernama. Hanya sel dengan angka yang dijumlahkan; nilai kosong dan teks diabaikan.
• criteria_range1 - rentang pertama yang akan dievaluasi oleh kriteria terkait, diperlukan.
• kriteria1 - Anda dapat memberikan kriteria dalam bentuk angka, ekspresi logika, referensi sel, teks atau fungsi Excel lainnya. Misalnya Anda dapat menggunakan kriteria seperti 10, ">=10", A1, "ceri" atau TODAY().
• kriteria_range2, kriteria2, ... - ini adalah rentang dan kriteria tambahan yang terkait dengannya, opsional. Anda dapat menggunakan hingga 127 pasangan rentang/kriteria dalam rumus SUMIFS.

Catatan:

• Agar rumus SUMIFS berfungsi dengan benar, semua criteria_range argumen harus memiliki dimensi yang sama dengan sum_range , yaitu jumlah baris dan kolom yang sama.
• Fungsi SUMIFS bekerja dengan logika AND, artinya sel dalam rentang penjumlahan dijumlahkan hanya jika memenuhi semua kriteria yang ditentukan, yaitu semua kriteria benar untuk sel tersebut.

Rumus dasar SUMIFS

Dan sekarang, mari kita lihat rumus SUMIFS Excel dengan dua kondisi. Misalkan, Anda memiliki tabel yang mencantumkan kiriman buah dari pemasok yang berbeda. Anda memiliki nama buah di kolom A, nama pemasok di kolom B, dan kuantitas di kolom C. Apa yang Anda inginkan adalah menemukan jumlah jumlah yang berkaitan dengan buah dan pemasok tertentu, misalnya semua apel yang dipasok oleh Pete.

Ketika kamu sedang mempelajari sesuatu yang baru, ada baiknya kamu memulai dengan hal-hal yang sederhana. Jadi, untuk memulainya, mari kita definisikan semua argumen untuk rumus SUMIFS kita:

• sum_range - C2:C9
• kriteria_range1 - A2:A9
• kriteria1 - "apel"
• kriteria_range2 - B2:B9
• kriteria2 - "Pete"

Sekarang kumpulkan parameter di atas, dan Anda akan mendapatkan rumus SUMIFS berikut:

=SUMIFS(C2:C9, A2:A9, "apel", B2:B9, "Pete")

Untuk menyempurnakan rumusnya lebih lanjut, Anda dapat mengganti kriteria teks "apel" dan "Pete" dengan referensi sel. Dalam hal ini, Anda tidak perlu mengubah rumus untuk menghitung kuantitas buah lain dari pemasok yang berbeda:

=SUMIFS(C2:C9, A2:A9, F1, B2:B9, F2)

Catatan. Baik fungsi SUMIF dan SUMIFS pada dasarnya tidak peka huruf besar / kecil. Untuk membuatnya mengenali kasus teks, silakan lihat Rumus SUMIF dan SUMIFS peka huruf besar / kecil di Excel.

SUMIF vs SUMIFS di Excel

Karena tujuan tutorial ini adalah untuk mencakup semua cara yang mungkin untuk menjumlahkan nilai dengan beberapa kondisi, kita akan membahas contoh rumus dengan kedua fungsi - Excel SUMIFS dan SUMIF dengan beberapa kriteria. Untuk menggunakannya dengan benar, kamu perlu memahami dengan jelas kesamaan dari kedua fungsi ini dan perbedaannya.

Meskipun bagian yang umum sudah jelas (tujuan dan parameter yang sama), namun perbedaannya tidak begitu jelas, meskipun sangat esensial.

Ada 4 perbedaan utama antara SUMIF dan SUMIFS:

1. Jumlah kondisi SUMIF bisa mengevaluasi hanya satu kondisi pada satu waktu, sementara SUMIFS bisa memeriksa beberapa kriteria.
2. Sintaksis Dengan SUMIF, maka sum_range adalah argumen terakhir dan opsional - jika tidak didefinisikan, nilai-nilai dalam rentang argumen dijumlahkan. Dengan SUMIFS, sum_range adalah argumen pertama dan wajib.
3. Ukuran rentang. Dalam rumus SUMIF, sum_range tidak harus memiliki ukuran dan bentuk yang sama seperti rentang selama Anda memiliki sel kiri atas kanan. Di Excel SUMIFS, setiap criteria_range harus berisi jumlah baris dan kolom yang sama dengan sum_range argumen.

   Contohnya, SUMIF(A2:A9,F1,C2:C18) akan mengembalikan hasil yang benar karena sel paling kiri dalam sum_range Jadi, Excel akan melakukan koreksi secara otomatis dan menyertakan kolom dan baris sebanyak-banyaknya dalam sum_range seperti yang ada di rentang .

   Rumus SUMIFS dengan range yang ukurannya tidak sama akan menghasilkan error #VALUE!

4. Ketersediaan SUMIF tersedia di semua versi Excel, dari 365 hingga 2000. SUMIFS tersedia di Excel 2007 dan yang lebih tinggi.

Baiklah, cukup strategi (yaitu teori), mari kita masuk ke dalam taktik (yaitu contoh rumus : )

Cara menggunakan SUMIFS di Excel - contoh rumus

Beberapa saat yang lalu, kita telah membahas rumus SUMIFS sederhana dengan dua kriteria teks. Dengan cara yang sama, Anda dapat menggunakan SUMIFS Excel dengan beberapa kriteria yang dinyatakan dengan angka, tanggal, ekspresi logika, dan fungsi Excel lainnya.

Contoh 1. Excel SUMIFS dengan operator perbandingan

Dalam tabel pemasok buah kita, misalkan, Anda ingin menjumlahkan semua pengiriman oleh Mike dengan Qty. 200 atau lebih. Untuk melakukan ini, Anda menggunakan operator perbandingan "lebih besar dari atau sama dengan" (>=) dalam kriteria2 dan mendapatkan rumus SUMIFS berikut:

=SUMIFS(C2:C9,B2:B9,"Mike",C2:C9,">=200")

Catatan Harap perhatikan bahwa dalam rumus SUMIFS Excel, ekspresi logis dengan operator perbandingan harus selalu diapit oleh tanda kutip ganda ("").

Kami membahas semua kemungkinan operator perbandingan secara detail saat membahas fungsi SUMIF Excel, operator yang sama dapat digunakan dalam kriteria SUMIFS. Misalnya, rumus berikut dengan mengembalikan jumlah semua nilai dalam sel C2: C9 yang lebih besar dari atau sama dengan 200 dan kurang dari atau sama dengan 300.

=SUMIFS(C2:C9, C2:C9,">=200", C2:C9,"<=300")

Contoh 2. Menggunakan Excel SUMIFS dengan tanggal

Jika Anda ingin menjumlahkan nilai dengan beberapa kriteria berdasarkan tanggal saat ini, gunakan fungsi TODAY () dalam kriteria SUMIFS Anda, seperti yang ditunjukkan di bawah ini. Rumus berikut ini menjumlahkan nilai di kolom D jika tanggal yang sesuai di kolom C jatuh dalam 7 hari terakhir, termasuk hari ini:

=SUMIFS(D2:D10, C2:C10,">="&TODAY()-7, C2:C10,"<="&TODAY())

Catatan. Saat Anda menggunakan fungsi Excel lain bersama dengan operator logika dalam kriteria, Anda harus menggunakan ampersand (&) untuk menggabungkan string, misalnya "<="&TODAY().

Dengan cara yang sama, Anda dapat menggunakan fungsi SUMIF Excel untuk menjumlahkan nilai dalam rentang tanggal tertentu. Misalnya, rumus SUMIFS berikut menambahkan nilai dalam sel C2: C9 jika tanggal di kolom B jatuh antara 1-Okt-2014 dan 31-Okt-2014, inklusif.

=SUMIFS(C2:C9, B2:B9, ">=10/1/2014", B2:B9, "<=10/31/2014")

Hasil yang sama dapat dicapai dengan menghitung selisih dari dua fungsi SUMIF, seperti yang ditunjukkan dalam contoh ini - Cara menggunakan SUMIF untuk menjumlahkan nilai dalam rentang tanggal tertentu. Namun, Excel SUMIFS jauh lebih mudah dan lebih mudah dipahami, bukan?

Contoh 3. Excel SUMIFS dengan sel kosong dan tidak kosong

Ketika menganalisis laporan dan data lainnya, Anda mungkin sering perlu menjumlahkan nilai yang berhubungan dengan sel kosong atau tidak kosong.

Jumlahkan nilai dalam sel C2:C10 jika sel yang sesuai dalam kolom A dan B benar-benar kosong. "" Jumlahkan nilai yang sesuai dengan sel kosong "secara visual" termasuk yang berisi string kosong yang dikembalikan oleh beberapa fungsi Excel lainnya (misalnya, sel dengan rumus seperti). =SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Jumlahkan nilai dalam sel C2: C10 dengan kondisi yang sama seperti rumus di atas, tetapi termasuk string kosong. Sel yang tidak kosong "" Jumlahkan nilai yang berhubungan dengan sel yang tidak kosong, termasuk string dengan panjang nol. =SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Jumlahkan nilai di sel C2:C10 jika sel yang sesuai di kolom A dan B tidak kosong, termasuk sel dengan string kosong. SUM-SUMIF

atau

SUM / LEN Jumlahkan nilai yang berhubungan dengan sel yang tidak kosong, tidak termasuk string dengan panjang nol. =SUM(C2:C10) - SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

=SUM((C2:C10) * (LEN(A2:A10)>0)*(LEN(B2:B10)>0))

Jumlahkan nilai di sel C2:C10 jika sel yang sesuai di kolom A dan B tidak kosong, sel dengan string panjang nol tidak disertakan.

Dan sekarang, mari kita lihat bagaimana kamu bisa menggunakan rumus SUMIFS dengan kriteria "blank" dan "non-blank" pada data real.

Misalkan, Anda memiliki tanggal pesanan di kolom B, tanggal pengiriman di kolom C dan Qty. di kolom D. Bagaimana Anda menemukan total produk yang belum dikirim? Artinya, Anda ingin mengetahui jumlah nilai yang sesuai dengan sel yang tidak kosong di kolom B dan sel kosong di kolom C.

Solusinya adalah menggunakan rumus SUMIFS dengan 2 kriteria:

=SUMIFS(D2:D10, B2:B10,"", C2:C10,"=")

Menggunakan Excel SUMIF dengan beberapa kriteria OR

Seperti yang disebutkan di awal tutorial ini, fungsi SUMIFS dirancang dengan logika AND. Tetapi bagaimana jika Anda perlu menjumlahkan nilai dengan beberapa kriteria OR, yaitu ketika setidaknya salah satu kondisi terpenuhi?

Contoh 1. SUMIF + SUMIF

Solusi paling sederhana adalah menjumlahkan hasil yang dikembalikan oleh beberapa fungsi SUMIF. Misalnya, rumus berikut ini mendemonstrasikan cara menemukan total produk yang dikirimkan oleh Mike dan John:

=SUMIF(C2:C9, "Mike",D2:D9) + SUMIF(C2:C9, "John",D2:D9)

Seperti yang Anda lihat, fungsi SUMIF pertama menambahkan jumlah yang sesuai dengan "Mike", fungsi SUMIF lainnya mengembalikan jumlah yang berkaitan dengan "John" dan kemudian Anda menambahkan 2 angka ini.

Contoh 2. SUM & SUMIF dengan argumen larik

Solusi di atas sangat sederhana dan dapat menyelesaikan pekerjaan dengan cepat ketika hanya ada beberapa kriteria. Tetapi rumus SUMIF + SUMIF dapat bertambah besar jika Anda ingin menjumlahkan nilai dengan beberapa kondisi OR. Dalam hal ini, pendekatan yang lebih baik adalah menggunakan rumus kriteria larik Mari kita periksa pendekatan ini sekarang.

Anda bisa mulai dengan membuat daftar semua kondisi Anda yang dipisahkan dengan koma dan kemudian mengapit daftar yang dipisahkan koma yang dihasilkan dalam {kurung kurung}, yang secara teknis disebut larik.

Dalam contoh sebelumnya, jika Anda ingin menjumlahkan produk yang dikirimkan oleh John, Mike dan Pete, kriteria larik Anda akan terlihat seperti {"John", "Mike", "Pete"}. Dan fungsi SUMIF lengkapnya adalah SUMIF(C2:C9, {"John", "Mike", "Pete"} ,D2:D9) .

Argumen array yang terdiri dari 3 nilai memaksa rumus SUMIF Anda untuk mengembalikan tiga hasil terpisah, tetapi karena kita menulis rumus dalam satu sel, rumus ini hanya akan mengembalikan hasil pertama saja - yaitu total produk yang dikirimkan oleh John. Untuk membuat pendekatan kriteria array ini berfungsi, Anda harus menggunakan satu trik kecil lagi - lampirkan rumus SUMIF Anda dalam fungsi SUM, seperti ini:

=SUM(SUMIF(C2:C9, {"John", "Mike", "Pete"} , D2:D9))

Seperti yang Anda lihat, kriteria larik membuat rumusnya jauh lebih ringkas dibandingkan dengan SUMIF + SUMIF, dan memungkinkan Anda menambahkan nilai sebanyak yang Anda suka dalam larik.

Pendekatan ini bekerja dengan angka maupun dengan nilai teks. Misalnya, jika alih-alih nama pemasok di kolom C, Anda memiliki ID pemasok seperti 1, 2, 3, dsb., maka rumus SUMIF Anda akan terlihat mirip dengan ini:

=SUM(SUMIF(C2:C9, {1,2,3} , D2:D9))

Tidak seperti nilai teks, angka tidak perlu diapit oleh tanda kutip ganda dalam argumen array.

Contoh 3. SUMPRODUCT &; SUMIF

Jika, cara yang Anda sukai adalah mencantumkan kriteria dalam beberapa sel daripada menentukannya secara langsung dalam rumus, Anda dapat menggunakan SUMIF bersama dengan fungsi SUMPRODUCT yang mengalikan komponen dalam larik yang diberikan, dan mengembalikan jumlah produk tersebut.

=SUMPRODUCT(SUMIF(C2:C9, G2:G4, D2:D9))

Di mana G2:G4 adalah sel yang berisi kriteria Anda, nama pemasok dalam kasus kami, seperti yang diilustrasikan pada gambar di bawah.

Tetapi tentu saja, tidak ada yang menghalangi Anda untuk mencantumkan nilai dalam kriteria larik fungsi SUMIF Anda jika Anda menginginkannya:

=SUMPRODUCT(SUMIF(C2:C9, {"Mike", "John", "Pete"}, D2:D9))

Hasil yang dikembalikan oleh kedua rumus akan identik dengan apa yang Anda lihat di tangkapan layar:

Excel SUMIFS dengan beberapa kriteria OR

Jika Anda ingin menjumlahkan nilai bersyarat di Excel tidak hanya dengan beberapa kondisi OR, tetapi dengan beberapa set kondisi, Anda harus menggunakan SUMIFS, bukan SUMIF. Rumusnya akan sangat mirip dengan apa yang baru saja kita bahas.

Seperti biasa, sebuah contoh mungkin bisa membantu untuk mengilustrasikan poinnya dengan lebih baik. Dalam tabel pemasok buah kita, mari kita tambahkan Tanggal Pengiriman (kolom E) dan temukan jumlah total yang dikirimkan oleh Mike, John dan Pete pada bulan Oktober.

Contoh 1. SUMIFS + SUMIFS

Formula yang dihasilkan oleh pendekatan ini mencakup banyak pengulangan dan terlihat tidak praktis, tetapi mudah dimengerti dan, yang paling penting, berhasil : )

=SUMIFS(D2:D9,C2:C9, "Mike", E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014") +

SUMIFS(D2:D9, C2:C9, "John", E2:E9, ">=10/1/2014", E2:E9, "<=10/31/2014") +

SUMIFS(D2:D9, C2:C9, "Pete", E2:E9, ">=10/1/2014" ,E2:E9, "<=10/31/2014")

Seperti yang Anda lihat, Anda menulis fungsi SUMIFS terpisah untuk masing-masing pemasok dan menyertakan dua kondisi - sama dengan atau lebih besar dari Okt-1 (">=10/1/2014",) dan kurang dari atau sama dengan 31 Oktober ("<=10/31/2014"), dan kemudian Anda menjumlahkan hasilnya.

Contoh 2. SUM & SUMIFS dengan argumen larik

Saya sudah mencoba menjelaskan esensi dari pendekatan ini dalam contoh SUMIF, jadi sekarang kita cukup menyalin rumus tersebut, mengubah urutan argumen (seperti yang Anda ingat bahwa ini berbeda dalam SUMIF dan SUMIFS) dan menambahkan kriteria tambahan. Rumus yang dihasilkan lebih ringkas daripada SUMIFS + SUMIFS:

=SUM(SUMIFS(D2:D9,C2:C9, {"Mike", "John", "Pete"}, E2:E9,">=10/1/2014", E2:E9, "<=10/31/2014"))

Hasil yang dikembalikan oleh rumus ini persis sama seperti yang Anda lihat pada gambar di atas.

Contoh 3. SUMPRODUCT &; SUMIFS

Seperti yang Anda ingat, pendekatan SUMPRODUCT berbeda dari dua pendekatan sebelumnya dengan cara Anda memasukkan setiap kriteria Anda dalam sel terpisah daripada menentukannya secara langsung dalam rumus. Jika ada beberapa set kriteria, fungsi SUMPRODUCT tidak akan cukup dan Anda harus menggunakan ISNUMBER dan MATCH juga.

Jadi, dengan asumsi bahwa Nama Persediaan ada di sel H1: H3, Tanggal Mulai ada di sel H4 dan Tanggal Akhir di sel H5, rumus SUMPRODUCT kami mengambil bentuk berikut:

=SUMPRODUCT(--(E2:E9>=H4), --(E2:E9<=H5), --(ISNUMBER(MATCH(C2:C9, H1:H3,0))), D2:D9)

Banyak orang bertanya-tanya mengapa menggunakan tanda hubung ganda (--) dalam rumus SUMPRODUCT. Intinya adalah bahwa Excel SUMPRODUCT mengabaikan semua kecuali nilai numerik, sedangkan operator perbandingan dalam rumus kami mengembalikan nilai Boolean (TRUE / FALSE), yang non-numerik. Untuk mengubah nilai Boolean ini menjadi 1 dan 0, Anda menggunakan tanda minus ganda, yang secara teknis disebut operator unary ganda. Paksaan unary pertamaTRUE / FALSE ke -1 / 0, masing-masing. Unary kedua meniadakan nilai, yaitu membalikkan tanda, mengubahnya menjadi +1 dan 0, yang dapat dipahami oleh fungsi SUMPRODUCT.

Saya harap penjelasan di atas masuk akal. Dan bahkan jika tidak, ingat saja aturan praktis ini - gunakan operator unary ganda (--) saat Anda menggunakan operator perbandingan dalam rumus SUMPRODUCT Anda.

Menggunakan SUM Excel dalam rumus array

Seperti yang Anda ingat, Microsoft mengimplementasikan fungsi SUMIFS di Excel 2007. Jika seseorang masih menggunakan Excel 2003, 2000 atau sebelumnya, Anda harus menggunakan rumus array SUM untuk menambahkan nilai dengan beberapa kriteria AND. Secara alami, pendekatan ini juga berfungsi di versi modern Excel 2013 - 2007, dan dapat dianggap sebagai padanan kuno dari fungsi SUMIFS.

Dalam rumus SUMIF yang dibahas di atas, Anda telah menggunakan argumen array, tetapi rumus array adalah sesuatu yang berbeda.

Contoh 1. Jumlahkan dengan beberapa kriteria AND di Excel 2003 dan sebelumnya

Mari kita kembali ke contoh pertama di mana kita menemukan jumlah jumlah yang berkaitan dengan buah dan pemasok tertentu:

Seperti yang sudah Anda ketahui, tugas ini mudah diselesaikan dengan menggunakan rumus SUMIFS biasa:

=SUMIFS(C2:C9, A2:A9, "apel", B2:B9, "Pete")

Dan sekarang, mari kita lihat bagaimana tugas yang sama dapat dipenuhi dalam versi Excel "bebas SUMIFS" awal. Pertama, Anda menuliskan semua kondisi yang harus dipenuhi dalam bentuk range = "condition". Dalam contoh ini, kita memiliki dua pasangan range/kondisi:

Kondisi 1: A2:A9="apel"

Kondisi 2: B2:B9="Pete"

Kemudian, Anda menulis rumus SUM yang "mengalikan" semua pasangan rentang / kondisi Anda, masing-masing diapit dalam tanda kurung. Pengali terakhir adalah rentang jumlah, C2: C9 dalam kasus kami:

=SUM((A2:A9="apel") * ( B2:B9="Pete") * ( C2:C9))

Seperti yang diilustrasikan pada gambar di bawah ini, rumus tersebut berfungsi dengan sempurna di versi Excel 2013 terbaru.

Catatan. Ketika memasukkan rumus array apa pun, Anda harus menekan Ctrl + Shift + Enter . Setelah Anda melakukan ini, rumus Anda akan diapit dalam {kurung kurung keriting}, yang merupakan indikasi visual bahwa rumus array dimasukkan dengan benar. Jika Anda mencoba mengetikkan kawat gigi secara manual, rumus Anda akan diubah menjadi string teks, dan tidak akan berfungsi.

Contoh 2. Rumus larik SUM dalam versi Excel modern

Bahkan dalam versi modern Excel, kekuatan fungsi SUM tidak boleh diremehkan. Rumus array SUM bukan hanya senam pikiran, tetapi memiliki nilai praktis, seperti yang ditunjukkan dalam contoh berikut.

Misalkan, Anda memiliki dua kolom, B dan C, dan Anda perlu menghitung berapa kali kolom C lebih besar dari kolom B, ketika nilai di kolom C lebih besar atau sama dengan 10. Solusi langsung yang muncul di benak Anda adalah menggunakan rumus array SUM:

=SUM((C1:C10>=10) * (C1:C10>B1:B10))

Tidak melihat aplikasi praktis dari rumus di atas? Pikirkan tentang hal itu dengan cara lain : )

Misalkan, Anda memiliki daftar pesanan seperti yang ditunjukkan pada gambar di bawah ini dan Anda ingin mengetahui berapa banyak produk yang belum dikirim secara penuh pada tanggal tertentu. Diterjemahkan ke dalam bahasa Excel, kami memiliki kondisi berikut:

Kondisi 1: Nilai dalam kolom B (Item yang dipesan) lebih besar dari 0

Kondisi 2: Nilai di kolom C (Delivered) kurang dari kolom B

Kondisi 3: Tanggal di kolom D (Tanggal jatuh tempo) kurang dari 11/1/2014.

Menyatukan ketiga pasangan range/kondisi tersebut, Anda mendapatkan rumus berikut ini:

=SUM((B2:B10>=0)*(B2:B10>C2:C10)*(D2:D10

Nah, contoh-contoh rumus yang dibahas dalam tutorial ini hanya menggores permukaan dari apa yang sebenarnya bisa dilakukan oleh fungsi SUMIFS dan SUMIF Excel. Tapi mudah-mudahan, mereka telah membantu mengarahkan Anda ke arah yang benar dan sekarang Anda dapat menjumlahkan nilai dalam buku kerja Excel Anda tidak peduli berapa banyak kondisi rumit yang harus Anda pertimbangkan.