Чудите се как да добавите текст към съществуваща клетка в Excel? В тази статия ще научите няколко много прости начина за вмъкване на символи на всяко място в клетка.

Когато работите с текстови данни в Excel, понякога може да се наложи да добавите един и същ текст към съществуващи клетки, за да направите нещата по-ясни. Например може да искате да поставите някакъв префикс в началото на всяка клетка, да вмъкнете специален символ в края или да поставите определен текст преди формула.

Предполагам, че всеки знае как да направи това ръчно. Този урок ще ви научи как бързо да добавяте низове към няколко клетки, като използвате формули и автоматизирате работата с VBA или специален Добавяне на текст инструмент.

Формули на Excel за добавяне на текст/символ към клетка

За да добавите определен символ или текст към клетка на Excel, просто конкатенирайте низ и референция към клетка, като използвате един от следните методи.

Оператор за конкатенация

Най-лесният начин за добавяне на текстов низ към клетка е да използвате символа амперсанд (&), който е операторът за конкатенация в Excel.

" текст "& клетка

Това работи във всички версии на Excel 2007 - Excel 365.

Функция CONCATENATE

Същият резултат може да се постигне с помощта на функцията CONCATENATE:

CONCATENATE(" текст ", клетка )

Функцията е налична в Excel за Microsoft 365, Excel 2019 - 2007.

Функция CONCAT

За добавяне на текст към клетки в Excel 365, Excel 2019 и Excel Online можете да използвате функцията CONCAT, която е съвременен заместител на CONCATENATE:

CONCAT(" текст ", клетка )

Забележка: Моля, обърнете внимание, че във всички формули, текст трябва да се поставят в кавички.

Това са общите подходи, а примерите по-долу показват как да ги приложите на практика.

Как да добавяте текст в началото на клетките

За да добавите определен текст или символ в началото на клетка, трябва да направите следното:

1. В клетката, в която искате да изведете резултата, въведете знака за равенство (=).
2. Въведете желания текст в кавичките.
3. Въведете символа амперсанд (&).
4. Изберете клетката, в която ще се добави текстът, и натиснете Enter .

Като алтернатива можете да предоставите текстовия низ и препратката към клетката като входни параметри на функцията CONCATENATE или CONCAT.

Например, за да добавите текста " Проект: " към името на проекта в A2, всяка от посочените по-долу формули ще работи.

Във всички версии на Excel:

="Проект:"&A2

=CONCATENATE("Проект:", A2)

В Excel 365 и Excel 2019:

=CONCAT("Проект:", A2)

Въведете формулата в B2, плъзнете я надолу по колоната и във всички клетки ще бъде вмъкнат един и същ текст.

Съвет. Горните формули обединяват два низа без интервали. За да разделите стойностите с бял интервал, въведете символа символът интервал в края на предварително добавения текст (например "Проект: ").

За удобство можете да въведете целевия текст в предварително определена клетка (E2) и добавяне на две текстови клетки заедно :

Без интервали:

=$E$2&A2

=CONCATENATE($E$2, A2)

С интервали:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Обърнете внимание, че адресът на клетката, съдържаща добавения текст, е заключен със знака $, така че да не се измества при копиране на формулата надолу.

При този подход можете лесно да променяте добавения текст на едно място, без да се налага да актуализирате всяка формула.

Как да добавяте текст в края на клетките в Excel

За да добавите текст или конкретен символ към съществуваща клетка, отново използвайте метода на конкатенация. Разликата е в реда на конкатенираните стойности: след препратка към клетка следва текстов низ.

Например, за да добавите символа " -US " в края на клетка А2, това са формулите, които трябва да използвате:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Можете също така да въведете текста в някоя клетка и след това да съедините две клетки с текст:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Не забравяйте да използвате абсолютна референция за добавения текст ($D$2), за да може формулата да се копира правилно в колоната.

Добавяне на символи в началото и края на низ

Тъй като знаете как да добавяте и добавяте текст към съществуваща клетка, нищо не ви пречи да използвате и двете техники в една формула.

Като пример, нека добавим символа " Проект: " в началото и " -US " в края на съществуващия текст в A2.

="Project:"&A2&"-US"

=CONCATENATE("Проект:", A2, "-US")

=CONCAT("Проект:", A2, "-US")

При въвеждане на низовете в отделни клетки това работи също толкова добре:

Комбиниране на текст от две или повече клетки

За да поставите стойности от няколко клетки в една клетка, конкатенирайте оригиналните клетки, като използвате познатите вече техники: символ амперсенд, функцията CONCATENATE или CONCAT.

Например, за да комбинирате стойности от колони A и B, като използвате запетая и интервал (", ") за разделител, въведете една от следните формули в B2 и след това я плъзнете надолу по колоната.

Добавяне на текст от две клетки с амперсанд:

=A2&", "&B2

Комбинирайте текст от две клетки с помощта на CONCAT или CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

При добавяне на текст от две колони , не забравяйте да използвате относителни препратки към клетките (например A2), за да се коригират правилно за всеки ред, в който се копира формулата.

Да комбинирате текст от няколко клетки в Excel 365 и Excel 2019 можете да използвате функцията TEXTJOIN. Нейният синтаксис предвижда разделител (първият аргумент), което прави формуляра по-компактен и по-лесен за управление.

Например за добавяне на низове от три колони (A, B и C), като стойностите се разделят със запетая и интервал, формулата е:

=TEXTJOIN(", ", TRUE, A2, B2, C2)

Как да добавите специален символ към клетка в Excel

За да вмъкнете специален символ в клетка на Excel, трябва да знаете неговия код в системата ASCII. След като установите кода, подайте го на функцията CHAR, за да върне съответния символ. Функцията CHAR приема всяко число от 1 до 255. Списък с кодове на печатни символи (стойности от 32 до 255) можете да намерите тук.

За да добавите специален символ към съществуваща стойност или резултат от формула, можете да приложите който и да е метод за конкатенация, който ви харесва най-добре.

Например за добавяне на символа за търговска марка (™) към текст в A2 ще работи всяка от следните формули:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153))

Как да добавяте текст към формула в Excel

За да добавите определен символ или текст към резултата от формула, просто конкатенирайте низ със самата формула.

Да речем, че използвате тази формула, за да върнете текущото време:

=TEXT(NOW(), "h:mm AM/PM")

За да обясните на потребителите колко е часът, можете да поставите текст преди и/или след формулата.

Вмъкване на текст преди формулата :

="Текущо време: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Текущо време: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Текущо време: ", TEXT(NOW(), "h:mm AM/PM"))

Добавяне на текст след формулата:

=TEXT(NOW(), "h:mm AM/PM")&" - текущо време"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - текущо време")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - текущо време")

Добавете текст към формулата от двете страни:

="Днес е " &TEXT(NOW(), "h:mm AM/PM")& " тук, в Гомел"

=CONCATENATE("Сега е ", TEXT(NOW(), "h:mm AM/PM"), " тук, в Гомел")

=CONCAT("Сега е ", TEXT(NOW(), "h:mm AM/PM"), " тук, в Гомел")

Как да вмъкнете текст след N-тия символ

За да добавите определен текст или символ на определена позиция в клетка, трябва да разделите оригиналния низ на две части и да поставите текста между тях. Ето как:

1. Извличане на подниз, предхождащ вмъкнатия текст, с помощта на функцията LEFT:

LEFT(клетка, n)

Извличане на подниз след текста с помощта на комбинацията от RIGHT и LEN:

RIGHT (клетка, LEN (клетка) -n)

Конкатенирайте двата подниза и текста/символа, като използвате символа амперсанд.

Пълната формула има следния вид:

ЛЯВО( клетка , n ) & " текст " & RIGHT( клетка , LEN( клетка ) - n )

Едни и същи части могат да бъдат обединени с помощта на функцията CONCATENATE или CONCAT:

CONCATENATE(LEFT( клетка , n ), " текст ", RIGHT( клетка , LEN( клетка ) - n ))

Задачата може да бъде изпълнена и с помощта на функцията REPLACE:

REPLACE( клетка , n+1 , 0, " текст ")

Трикът е, че num_chars който определя колко символа да се заменят, е 0, така че формулата всъщност вмъква текст на посочената позиция в клетката, без да заменя нищо. Позицията ( start_num аргумент) се изчислява с помощта на този израз: n+1. Добавяме 1 към позицията на n-тия символ, тъй като текстът трябва да се вмъкне след него.

Например, за да вмъкнете дефис (-) след втория символ в A2, формулата в B2 е:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Или

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Или

=REPLACE(A2, 2+1, 0, "-")

Плъзнете формулата надолу и във всички клетки ще бъде вмъкнат един и същ символ:

Как да добавяте текст преди/след определен символ

За да вмъкнете определен текст преди или след даден символ, трябва да определите позицията на този символ в низ. Това може да стане с помощта на функцията SEARCH:

SEARCH(" char ", клетка )

След като позицията е определена, можете да добавите низ точно на това място, като използвате подходите, разгледани в горния пример.

Добавяне на текст след определен символ

За вмъкване на някакъв текст след даден символ общата формула е:

ЛЯВО( клетка , SEARCH(" char ", клетка )) & " текст " & RIGHT( клетка , LEN( клетка ) - SEARCH(" char ", клетка ))

Или

CONCATENATE(LEFT( клетка , SEARCH(" char ", клетка )), " текст ", RIGHT( клетка , LEN( клетка ) - SEARCH(" char ", клетка )))

Например, за да вмъкнете текста (САЩ) след тирето в A2 формулата е:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Или

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))

Вмъкване на текст преди определен символ

За да добавите текст преди определен символ, формулата е:

ЛЯВО( клетка , SEARCH(" char ", клетка ) -1) & " текст " & RIGHT( клетка , LEN( клетка ) - SEARCH(" char ", клетка ) +1)

Или

CONCATENATE(LEFT( клетка , SEARCH(" char ", клетка ) - 1), " текст ", RIGHT( клетка , LEN( клетка ) - SEARCH(" char ", клетка ) +1))

Както виждате, формулите са много подобни на тези, които вмъкват текст след символ. Разликата е, че изваждаме 1 от резултата на първото търсене, за да принудим функцията LEFT да пропусне символа, след който се добавя текстът. Към резултата на второто търсене добавяме 1, така че функцията RIGHT да вземе този символ.

Например, за да поставите текста (САЩ) преди тирето в A2, трябва да се използва тази формула:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Или

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1))

Забележки:

• Ако оригиналната клетка съдържа множество случаи на даден символ, текстът ще бъде вмъкнат преди/след първата му поява.
• Функцията SEARCH е без значение на размера на буквите Ако искате да добавите текст преди/след малка или главна буква, използвайте функцията FIND, за да откриете тази буква.

Как да добавите място между текста в клетка на Excel

Всъщност това е просто специфичен случай на двата предишни примера.

Добавяне на място в същата позиция във всички клетки, използвайте формулата, за да вмъкнете текст след n-тия символ, където текст е символът интервал (" ").

Например, за да вмъкнете интервал след 10-ия символ в клетките A2:A7, въведете следната формула в B2 и я плъзнете през B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Или

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

Във всички оригинални клетки десетият символ е двоеточие (:), така че интервалът е вмъкнат точно там, където ни е необходим:

Вмъкване на място в различна позиция във всяка клетка настройте формулата, която добавя текст преди/след определен символ.

В примерната таблица по-долу двоеточието (:) е разположено след номера на проекта, който може да съдържа различен брой знаци. Тъй като искаме да добавим интервал след двоеточието, намираме позицията му с помощта на функцията SEARCH:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Или

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Как да добавяте един и същ текст към съществуващи клетки с VBA

Ако често ви се налага да вмъквате един и същ текст в няколко клетки, можете да автоматизирате задачата с VBA.

Добавяне на текст в началото

Макросите по-долу добавят текст или определен символ към начало на всички избрани клетки И двата кода разчитат на една и съща логика: проверяват всяка клетка в избрания диапазон и ако клетката не е празна, добавят предварително определения текст. Разликата е в мястото, където се поставя резултатът: първият код прави промени в оригиналните данни, докато вторият поставя резултатите в колона вдясно от избрания диапазон.

Ако имате малко опит с VBA, това ръководство стъпка по стъпка ще ви запознае с процеса: Как да вмъкнете и стартирате VBA код в Excel.

Макрос 1: добавя текст към оригиналните клетки

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = "PR-" & cell.Value Next End Sub

Този код вмъква подниз "PR-" вляво от съществуващ текст. Преди да използвате кода в работния си лист, не забравяйте да замените нашия примерен текст с този, който наистина ви е необходим.

Макрос 2: поставя резултатите в съседната колона

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = "PR-" & cell.Value Next End Sub

Преди да стартирате този макрос, уверете се, че има празна колона вдясно на избрания диапазон, в противен случай съществуващите данни ще бъдат презаписани.

Добавяне на текст в края

Ако искате да добавите определен низ/символ към край на всички избрани клетки , тези кодове ще ви помогнат да свършите работата бързо.

Макрос 1: добавя текст към оригиналните клетки

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Value = cell.Value & "-PR" Next End Sub

Нашият примерен код вмъква подниз "-PR" вдясно от съществуващ текст. Естествено, можете да го промените на какъвто текст/символ ви е необходим.

Макрос 2: поставя резултатите в друга колона

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value "" Then cell.Offset(0, 1).Value = cell.Value & "-PR" Next End Sub

Този код поставя резултатите в съседна колона . Затова, преди да го стартирате, се уверете, че имате поне една празна колона вдясно от избрания диапазон, в противен случай съществуващите данни ще бъдат презаписани.

Добавяне на текст или символ към няколко клетки с Ultimate Suite

В първата част на този урок научихте няколко различни формули за добавяне на текст към клетките на Excel. Сега ще ви покажа как да изпълните задачата с няколко кликвания :)

След като инсталирате Ultimate Suite в Excel, следвайте следните стъпки:

1. Изберете изходните си данни.
2. На Ablebits в раздела Текст група, щракнете върху Добавяне на .
3. На Добавяне на текст въведете символа/текста, който искате да добавите към избраните клетки, и посочете къде да бъде вмъкнат:
   • В началото
   • В края
   • Преди определен текст/символ
   • След определен текст/символ
   • След N-тия символ от началото или края
4. Щракнете върху Добавяне на текст бутон. Готово!

Като пример нека вмъкнем символа "PR-" след символа "-" в клетките A2:A7. За целта конфигурираме следните настройки:

Миг по-късно получаваме желания резултат:

Това са най-добрите начини за добавяне на символи и текстови низове в Excel. Благодаря ви за четенето и се надявам да се видим в нашия блог следващата седмица!

Налични изтегляния

Добавяне на текст към клетка в Excel - примери за формули (.xlsm файл)

Ultimate Suite - пробна версия (.exe файл)