Az oktatóanyag bemutatja, hogyan használhatja az IFERROR funkciót az Excelben a hibák elkapására és azok üres cellával, másik értékkel vagy egyéni üzenettel való helyettesítésére. Megtanulja, hogyan használja az IFERROR funkciót a Vlookup és az Index Match funkcióval, és hogyan hasonlítja össze az IF ISERROR és az IFNA funkcióval.

"Adj nekem egy helyet, ahol állhatok, és megmozgatom a földet" - mondta egyszer Arkhimédész. "Adj nekem egy képletet, és ráveszem, hogy hibát adjon vissza" - mondaná egy Excel-felhasználó. Ebben a bemutatóban nem azt fogjuk megvizsgálni, hogyan adjunk vissza hibákat az Excelben, inkább azt szeretnénk megtanulni, hogyan előzzük meg őket, hogy a munkalapok tiszták és a képletek átláthatóak maradjanak.

Excel IFERROR funkció - szintaxis és alapvető felhasználások

Az Excel IFERROR függvénye a képletekben és számításokban előforduló hibák felderítésére és kezelésére szolgál. Pontosabban, az IFERROR ellenőrzi a képletet, és ha az hibát mutat, akkor egy másik megadott értéket ad vissza, egyébként pedig a képlet eredményét adja vissza.

Az Excel IFERROR függvény szintaxisa a következő:

Hol:

• Érték (kötelező) - a hibaellenőrzés tárgya. Lehet képlet, kifejezés, érték vagy cellahivatkozás.
• Value_if_error (kötelező) - mit adjon vissza, ha hibát talál. Lehet üres karakterlánc (üres cella), szöveges üzenet, numerikus érték, másik képlet vagy számítás.

Például két számoszlop osztásakor egy csomó különböző hibát kaphat, ha az egyik oszlop üres cellákat, nullákat vagy szöveget tartalmaz.

Ennek megakadályozására használd az IFERROR függvényt a hibák felfogására és kezelésére a kívánt módon.

Ha hiba, akkor üres

Adjon meg egy üres karakterláncot (") a value_if_error argumentummal egy üres cellát ad vissza, ha hibát talál:

=IFERROR(A2/B2, "")

Ha hiba, akkor üzenetet jelenít meg

Az Excel szabványos hiba jelölése helyett saját üzenetet is megjeleníthet:

=IFERROR(A2/B2, "Számítási hiba")

5 dolog, amit tudnia kell az Excel IFERROR funkcióról

1. Az Excel IFERROR függvénye az összes hibatípust kezeli, beleértve a #DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! és #VALUE! típusokat.
2. A tartalomtól függően a value_if_error argumentummal az IFERROR a hibákat egyéni szöveges üzenettel, számmal, dátummal vagy logikai értékkel, egy másik képlet eredményével vagy üres karakterlánccal (üres cellával) helyettesítheti.
3. Ha a érték argumentum egy üres cella, üres karakterláncként ('''') kezeli, de nem hiba.
4. Az IFERROR az Excel 2007-ben került bevezetésre, és az Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 és Excel 365 minden későbbi verziójában elérhető.
5. Az Excel 2003 és korábbi verziókban a hibák csapdába ejtéséhez használja az ISERROR függvényt az IF függvénnyel kombinálva, ahogy ez a példában látható.

IFERROR formula példák

A következő példák azt mutatják, hogyan használhatja az IFERROR-t az Excelben más függvényekkel kombinálva összetettebb feladatok elvégzésére.

Excel IFERROR a Vlookup segítségével

Az IFERROR függvény egyik leggyakoribb felhasználási módja az, hogy a felhasználóknak jelezze, hogy a keresett érték nem létezik az adathalmazban. Ehhez a VLOOKUP képletet IFERROR-ba csomagoljuk a következőképpen:

Ha a keresési érték nem szerepel a keresett táblázatban, akkor a hagyományos Vlookup formula #N/A hibát ad vissza:

A felhasználók nyugalma érdekében csomagolja a VLOOKUP-ot IFERROR-ba, és jelenítsen meg egy informatívabb és felhasználóbarátabb üzenetet:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

Az alábbi képernyőkép mutatja ezt az Iferror képletet az Excelben:

Ha csak az #N/A hibákat szeretné rögzíteni, de nem az összes hibát, akkor az IFERROR helyett használja az IFNA funkciót.

További Excel IFERROR VLOOKUP képlet példákért tekintse meg ezeket a bemutatókat:

• Iferror a Vlookup-pal a hibák csapdázásához és kezeléséhez
• Hogyan kapjuk meg a keresési érték N-edik előfordulását?
• Hogyan kapjuk meg a keresési érték összes előfordulását?

Beágyazott IFERROR függvények a szekvenciális Vlookupok elvégzéséhez az Excelben

Olyan helyzetekben, amikor több Vlookupot kell végrehajtania annak alapján, hogy az előző Vlookup sikeres vagy sikertelen volt-e, két vagy több IFERROR függvényt egymásba ágyazhat.

Tegyük fel, hogy vállalatod regionális fiókjainak számos értékesítési jelentésével rendelkezel, és egy bizonyos rendelésazonosítóhoz tartozó összeget szeretnél megkapni. A2-vel, mint keresési értékkel az aktuális lapon, és A2:B5-tel, mint keresési tartományt 3 keresési lapon (1. jelentés, 2. jelentés és 3. jelentés), a képlet a következőképpen néz ki:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0), "nem található"))))

Az eredmény valahogy így fog kinézni:

A képlet logikájának részletes magyarázatát lásd a Hogyan készítsünk szekvenciális Vlookupokat az Excelben?

IFERROR tömbi képletekben

Amint azt valószínűleg tudja, az Excelben a tömbképletek arra szolgálnak, hogy egyetlen képleten belül több számítást végezzenek. Ha olyan tömbképletet vagy kifejezést ad meg, amely egy tömböt eredményez az érték argumentumát az IFERROR függvényben, akkor a megadott tartomány minden egyes cellájához egy értéktömböt ad vissza. Az alábbi példa mutatja a részleteket.

Tegyük fel, hogy Összesen a B oszlopban és Ár a C oszlopban, és ki akarja számítani Teljes mennyiség Ez a következő módon történhet tömbi képlet, amely a B2:B4 tartomány minden egyes celláját elosztja a C2:C4 tartomány megfelelő cellájával, majd az eredményeket összeadja:

=SUM($B$2:$B$4/$C$2:$C$4)

A képlet addig működik, amíg az osztótartomány nem tartalmaz nullákat vagy üres cellákat. Ha legalább egy 0 érték vagy üres cella van, akkor a #DIV/0! hiba jelenik meg:

A hiba kijavításához egyszerűen végezze el az osztást az IFERROR függvényen belül:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

A képlet minden sorban (100/2, 200/5 és 0/0) elosztja a B oszlopban lévő értéket a C oszlopban lévő értékkel, és visszaadja az eredmények tömbjét {50; 40; #DIV/0!}. Az IFERROR függvény minden #DIV/0! hibát elkap, és nullával helyettesíti őket. Ezután a SUM függvény összeadja a kapott tömb {50; 40; 0} értékeit, és kiadja a végeredményt (50+40=90).

Megjegyzés: Ne feledje, hogy a tömbképleteket a Ctrl + Shift + Enter billentyűkombinációval kell befejezni.

IFERROR vs. IF ISERROR

Most, hogy már tudja, milyen egyszerű az IFERROR függvény használata az Excelben, talán elgondolkodik azon, hogy egyesek miért hajlanak még mindig az IF ISERROR kombináció használatára. Van-e bármilyen előnye az IFERROR-hoz képest? Nincs. Az Excel 2003-as és annál alacsonyabb szintű rossz régi időkben, amikor az IFERROR nem létezett, az IF ISERROR volt az egyetlen lehetséges módja a hibák csapdázásának. Az Excel 2007-ben és későbbiekben ez csak egy kicsit bonyolultabb módja annak, hogyugyanazt az eredményt érik el.

Például a Vlookup hibák elkapásához az alábbi képletek bármelyikét használhatja.

Excel 2007 - Excel 2016:

Minden Excel-verzióban:

Vegye észre, hogy az IF ISERROR VLOOKUP képletben kétszer kell Vlookup-ot végrehajtani. Egyszerűbben a képlet a következőképpen olvasható: Ha a Vlookup hibát eredményez, adja vissza a "Nem talált" értéket, egyébként adja ki a Vlookup eredményét.

És itt egy valós példa egy Excel If Iserror Vlookup képletre:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)), "Nem található", VLOOKUP(D2, A2:B5,2,FALSE ))

További információért lásd: Az ISERROR függvény használata az Excelben.

IFERROR vs. IFNA

Az Excel 2013-ban bevezetett IFNA egy újabb funkció a képletek hibaellenőrzésére. Szintaxisa hasonló az IFERROR-éhoz:

Miben különbözik az IFNA az IFERROR funkciótól? Az IFNA funkció a következőket fogja el csak #N/A hibák míg az IFERROR az összes hibatípust kezeli.

Milyen helyzetekben érdemes használni az IFNA-t? Amikor nem célszerű minden hibát elrejteni. Például, amikor fontos vagy érzékeny adatokkal dolgozol, figyelmeztetni szeretnél az adathalmaz lehetséges hibáira, és a standard Excel hibaüzenetek a "#" szimbólummal élénk vizuális jelzők lehetnek.

Lássuk, hogyan készíthetünk olyan képletet, amely a "Nem található" üzenetet jeleníti meg az N/A hiba helyett, amely akkor jelenik meg, ha a keresési érték nincs jelen az adathalmazban, de más Excel-hibákra hívja fel a figyelmet.

Tegyük fel, hogy az alábbi képernyőképen látható módon a keresőtáblából az összesítő táblázatba szeretné átvinni a Qty.-t. Az Excel Iferror Vlookup képletének használata esztétikus eredményt adna, ami technikailag helytelen, mert Citromok léteznek a keresőtáblában:

A #N/A elkapásához, de a #DIV/0 hiba megjelenítéséhez használja az IFNA funkciót az Excel 2013 és az Excel 2016 programokban:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Nem található")

Vagy az IF ISNA kombináció az Excel 2010 és korábbi verziókban:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)), "Nem található", VLOOKUP(F3,$A$3:$D$6,4,FALSE)))

Az IFNA VLOOKUP és IF ISNA VLOOKUP formulák szintaxisa hasonló a korábban tárgyalt IFERROR VLOOKUP és IF ISERROR VLOOKUP formulákhoz.

Amint az alábbi képernyőképen látható, az Ifna Vlookup formula csak a keresési táblázatban nem szereplő elem esetében adja vissza a "Nem talált" választ ( Barackok ). Citromok a #DIV/0! jelzi, hogy a keresőtáblánk nullával való osztás hibát tartalmaz:

További részletekért lásd az IFNA funkció használata Excelben.

Legjobb gyakorlatok az IFERROR használatához Excelben

Mostanra már tudja, hogy az IFERROR függvény a legegyszerűbb módja annak, hogy az Excelben hibákat észleljen, és azokat üres cellákkal, nulla értékekkel vagy saját, egyéni üzenetekkel elfedje. Ez azonban nem jelenti azt, hogy minden egyes képletet hibakezeléssel kell körbetekernie. A következő egyszerű ajánlások segíthetnek az egyensúly megtartásában.

1. Ne ejtsen hibákat ok nélkül.
2. A képlet lehető legkisebb részének IFERROR-ba csomagolása.
3. Ha csak bizonyos hibákat szeretne kezelni, használjon egy kisebb hatókörű hibakezelő függvényt:
   • IFNA vagy IF ISNA, hogy csak az #N/A hibákat kapja el.
   • ISERR a #N/A kivételével minden hiba elhárítására.

Így használja az IFERROR függvényt az Excelben a hibák csapdázására és kezelésére. Ha közelebbről meg szeretné nézni az ebben a bemutatóban tárgyalt képleteket, szívesen letölti az IFERROR Excel-mintamunkát. Köszönöm, hogy elolvasta, és remélem, hogy jövő héten találkozunk a blogunkon.