Edukien taula
Tutorialak IFERROR Excel-en nola erabili erakusten du erroreak atzemateko eta gelaxka huts batekin, beste balio batekin edo mezu pertsonalizatu batekin ordezkatzeko. IFERROR funtzioa Vlookup eta Index Match-ekin nola erabiltzen den ikasiko duzu, eta IF ISERROR eta IFNArekin nola alderatzen den.
"Emaidazu zutik egoteko lekua, eta lurra mugituko dut". Esan zuen behin Arkimedesek. "Eman formula bat, eta errore bat itzuliko diot", esango luke Excel erabiltzaile batek. Tutorial honetan, ez dugu Excel-en erroreak nola itzuli aztertuko, nahiago dugu horiek nola saihesten ikasi zure lan-orriak garbi eta zure formulak garden mantentzeko.
Excel IFERROR funtzioa - sintaxia eta oinarrizko erabilerak
Excel-en IFERROR funtzioa formuletan eta kalkuluetan akatsak harrapatzeko eta kudeatzeko diseinatuta dago. Zehatzago esanda, IFERROR formula bat egiaztatzen du, eta errore bat ebaluatzen badu, zuk zehazten duzun beste balio bat itzultzen du; bestela, formularen emaitza itzultzen du.
Excel IFERROR funtzioaren sintaxia hau da:
IFERROR(balioa, balioa_baldin_errorea)Non:
- Balioa (beharrezkoa) - zer egiaztatu errorerik. Formula, adierazpen, balio edo gelaxka-erreferentzia bat izan daiteke.
- Value_if_error (beharrezkoa) - zer itzuli behar den errore bat aurkitzen bada. Kate huts bat (gelaxka hutsa), testu-mezua, zenbakizko balioa, beste formula bat edo kalkulu bat izan daiteke.
Adibidez, bi zenbaki-zutabe zatitzean,akats ugari sor ditzake zutabeetako batek gelaxka hutsak, zeroak edo testuak baditu.
Hori gerta ez dadin, erabili IFERROR funtzioa akatsak atzemateko eta kudeatzeko. nahi duzun moduan.
Errorea bada, hutsik
Eman kate huts bat ("") value_if_error argumentuari gelaxka huts bat itzultzeko errore bat aurkitzen bada:
=IFERROR(A2/B2, "")
Errorea bada, erakutsi mezu bat
Excel-en errore estandarraren idazkeraren ordez zure mezua ere bistaratu dezakezu:
=IFERROR(A2/B2, "Error in calculation")
Excel IFERROR funtzioari buruz jakin behar dituzun 5 gauza
- Excel-en IFERROR funtzioak errore mota guztiak kudeatzen ditu # barne DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! eta #VALUE!.
- value_if_error ren edukiaren arabera argumentua, IFERROR erroreak zure testu-mezu pertsonalizatuarekin, zenbakiarekin, datarekin edo balio logikoarekin, beste formula baten emaitzarekin edo kate huts batekin (gelaxka hutsarekin) ordezkatu ditzake.
- balioa argumentua bada. gelaxka huts bat da, honela tratatzen da kate huts bat ('''), baina ez errore bat.
- IFERROR Excel 2007-n sartu zen eta hurrengo bertsio guztietan dago eskuragarri Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 eta Excel-en. 365.
- Excel 2003 eta aurreko bertsioetan akatsak harrapatzeko, erabili ISERROR funtzioa IFrekin batera, adibide honetan erakusten den bezala.
IFERROR formula adibideak
Ondoko adibideakerakutsi nola erabili IFERROR Excel-en beste funtzio batzuekin batera zeregin konplexuagoak egiteko.
Excel IFERROR Vlookup-ekin
IFERROR funtzioaren erabilera ohikoenetako bat erabiltzaileei esatea da bilatzen ari diren balioa ez dago datu multzoan. Horretarako, BLOOKUP formula bat IFERROR-en bilduko duzu honela:
IFERROR(VLOOKUP( …),"Ez da aurkitu")Bilaketa-balioa bilatzen ari zaren taulan ez badago , Vlookup formula arrunt batek #N/A errorea itzuliko luke:
Zure erabiltzaileen gogorako, bildu VLOOKUP IFERROR-en eta bistaratu informazio gehiago eta erabilerrazagoa. mezua:
=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")
Beheko pantaila-argazkiak Excel-en Iferror formula hau erakusten du:
#N bakarrik harrapatu nahi baduzu /A erroreak baina ez akats guztiak, erabili IFNA funtzioa IFERROR-en ordez.
Excel IFERROR VLOOKUP formula adibide gehiago lortzeko, begiratu tutorial hauek:
- Vlookup-ekin akatsa harrapatzeko. eta kudeatu erroreak
- Nola lortu bilaketa-balioaren N. agerraldia
- Nola lortu bilaketa-balioaren agerraldi guztiak
Habiaratutako IFERROR funtzioak Excel-en Vlookups sekuentzialak egiteko
Vlookup anitz egin behar dituzun egoeretan, aurreko Vlookupek arrakasta izan edo huts egin duenaren arabera, IFERROR bi edo gehiago habia ditzakezu. elkarren artean funtzionatzen du.
Demagun zure eskualdeko sukurtsaletako salmenta-txosten batzuk dituzula.enpresa, eta eskaera ID jakin baterako kopuru bat lortu nahi duzu. A2 uneko orriko bilaketa-balio gisa eta A2:B5 bilaketa-barrutia 3 bilaketa-orritan (1. txostena, 2. txostena eta 3. txostena), formula honela doa:
=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))
Emaitza honen antzekoa izango da:
Formularen logikaren azalpen zehatza lortzeko, ikus Nola egin Vlookups sekuentzialak Excel-en.
IFERROR matrize-formuletan
Ziurrenik dakizuenez, Excel-eko matrize-formulak formula bakarrean hainbat kalkulu egiteko daude. IFERROR funtzioaren balioa argumentuan array-formula edo adierazpen bat ematen baduzu, zehaztutako barrutian gelaxka bakoitzeko balio-matrize bat itzuliko luke. Beheko adibideak erakusten ditu xehetasunak.
Demagun, Guztira duzula B zutabean eta Prezioa C zutabean, eta Kopuru osoa kalkulatu nahi duzula. . Hau egin daiteke array-formula hau erabiliz, , B2:B4 barrutiko gelaxka bakoitza C2:C4 barrutiari dagokion gelaxkarekin banatzen duena, eta, ondoren, emaitzak batzen ditu:
=SUM($B$2:$B$4/$C$2:$C$4)
Formulak ondo funtzionatzen du zatitzaileen barrutiak zero edo gelaxka hutsik ez baditu. Gutxienez 0 balio edo gelaxka huts bat badago, #DIV/0! errorea itzultzen da:
Errore hori konpontzeko, egin zatiketa IFERROR funtzioaren barruan:
=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))
Formulak zer egiten duenerrenkada bakoitzean B zutabeko balio bat C zutabeko balio batekin zatitzea da (100/2, 200/5 eta 0/0) eta emaitzen array {50; 40; #DIV/0!}. IFERROR funtzioak #DIV/0 guztiak harrapatzen ditu! erroreak eta zeroekin ordezkatzen ditu. Eta gero, SUM funtzioak ondoriozko matrizeko balioak gehitzen ditu {50; 40; 0} eta azken emaitza ateratzen du (50+40=90).
Oharra. Gogoratu matrizearen formulak Ctrl + Shift + Sartu lasterbidea sakatuz osatu behar direla.
IFERROR vs. IF ISERROR
Orain IFERROR funtzioa Excel-en erabiltzea zein erraza den dakizuenez, baliteke norbaitek zergatik jarraitzen duten makurtzen IF ISERROR konbinazioa erabiltzera. Ba al du abantailarik IFERROR-ekin alderatuta? Bat ere ez. Excel 2003-ren garai txarretan eta IFERROR existitzen ez zenean, IF ERROR zen akatsak harrapatzeko modu posible bakarra. Excel 2007-n eta geroago, emaitza bera lortzeko modu apur bat konplexuagoa da.
Adibidez, Vlookup akatsak atzemateko, beheko formula hauetakoren bat erabil dezakezu.
Excel-en 2007 - Excel 2016:
IFERROR(VLOOKUP( … ), "Ez da aurkitu")Excel bertsio guztietan:
IF(ISERROR(VLOOKUP(…)), "Ez da aurkitu ", VLOOKUP(…))Ohartu IF ERROREA VLOOKUP formulan, bi aldiz bilatu behar duzula. Ingeles arruntean, formula honela irakur daiteke: Vlookup-ek errorea ematen badu, itzuli "Not found", bestela atera Vlookup emaitza.
Eta hona hemen benetako-Excel-en bizitzaren adibidea Iserror Vlookup formula:
=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))
Informazio gehiago lortzeko, ikusi ISERROR funtzioa Excel-en erabiltzea.
IFERROR vs. IFNA
Excel 2013-rekin aurkeztuta, IFNA funtzio bat gehiago da akatsak dauden formula egiaztatzeko. Haren sintaxia IFERROR-renaren antzekoa da:
IFNA(value, value_if_na)Zertan desberdintzen da IFNA IFERROR-ekin? IFNA funtzioak #N/A erroreak bakarrik harrapatzen ditu bitartean IFERROR akats mota guztiak kudeatzen ditu.
Zein egoeratan erabili nahi zenuke IFNA? Akats guztiak mozorrotzea zentzugabea denean. Adibidez, datu garrantzitsu edo sentikorrekin lan egiten duzunean, baliteke datu multzoan izan daitezkeen akatsen berri ematea eta "#" ikurra duten Excel errore-mezu estandarrak adierazle bisual biziak izan daitezke.
Ikus dezagun. nola egin dezakezun formula bat "Ez aurkitu" mezua N/A errorearen ordez bistaratzen duen formula bat, bilaketa-balioa datu-multzoan ez dagoenean agertzen dena, baina Excel-eko beste akats batzuk zure arreta ekartzen dituenean.
Kut. tira nahi duzula demagun. bilaketa-taulatik laburpen-taulara beheko pantaila-argazkian erakusten den moduan. Excel Iferror Vlookup formula erabiltzeak emaitza estetiko atsegina izango luke, teknikoki okerra dena, Limoiak bilaketa-taulan daudelako:
# harrapatzeko. N/A baina erakutsi #DIV/0 errorea, erabili IFNA funtzioa Excel 2013 eta Excel-en2016:
=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")
Edo, IF ISNA konbinazioa Excel 2010 eta aurreko bertsioetan:
=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))
IFNA VLOOKUP eta IF ISNA-ren sintaxia VLOOKUP formulak IFERROR VLOOKUP eta IF ISERROR VLOOKUP-en antzekoak dira.
Beheko pantaila-argazkian erakusten den bezala, Ifna Blookup formulak "Ez aurkitu" itzultzen du bilaketa-taulan ez dagoen elementuarentzat soilik. ( Mertxika ). Limoiak rentzat, #DIV/0 erakusten du! Gure bilaketa-taulak zeroren arteko zatiketa errorea duela adieraziz:
Xehetasun gehiago lortzeko, ikusi IFNA funtzioa Excel-en erabiltzea.
IFERROR erabiltzeko praktika onenak Excel-en
Oraindik badakizu IFERROR funtzioa Excel-en akatsak atzemateko eta gelaxka hutsekin, zero balioekin edo zure mezu pertsonalizatuekin ezkutatzeko modurik errazena dela. Hala ere, horrek ez du esan nahi formula guztiak erroreen kudeaketarekin bildu behar dituzunik. Ondorengo gomendio sinple hauek oreka mantentzen lagun zaitzake.
- Ez harrapatu erroreak arrazoirik gabe.
- Itzuli formula baten ahalik eta zatirik txikiena IFERROR-en.
- Errore zehatzak soilik kudeatzeko, erabili eremu txikiagoko erroreak kudeatzeko funtzio bat:
- IFNA edo IF ISNA #N/A erroreak soilik atzemateko.
- ISERR akats guztiak atzemateko izan ezik. #N/A.
Horrela erabiltzen duzu IFERROR funtzioa Excel-en akatsak harrapatzeko eta kudeatzeko. Honetan eztabaidatutako formulak gertutik ikustekotutoriala, ongi etorria zara gure lagina IFERROR Excel lan-koadernoa deskargatzera. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut.
