Tha an oideachadh a’ sealltainn mar a chleachdas tu IFERROR ann an Excel gus mearachdan a ghlacadh agus cealla bàn, luach eile no teachdaireachd àbhaisteach a chuir nan àite. Ionnsaichidh tu mar a chleachdas tu an gnìomh IFERROR le Vlookup agus Index Match, agus mar a nì thu coimeas ri IF ISERROR agus IFNA.

"Thoir dhomh an t-àite airson seasamh, agus gluaisidh mi an talamh," Thuirt Archimedes aon uair. “Thoir foirmle dhomh, agus bheir mi mearachd air ais," thuirt neach-cleachdaidh Excel. San oideachadh seo, cha bhith sinn a’ coimhead air mar a thilleas tu mearachdan ann an Excel, b’ fheàrr leinn ionnsachadh mar a chuireas tu casg orra gus na duilleagan-obrach agad a chumail glan is na foirmlean agad follaiseach.

Gnìomh Excel IFERROR - co-chòrdadh agus cleachdaidhean bunaiteach

Tha an gnìomh IFERROR ann an Excel air a dhealbhadh gus mearachdan ann am foirmlean agus àireamhachadh a ghlacadh agus a stiùireadh. Nas mionaidiche, bidh IFERROR a 'sgrùdadh foirmle, agus ma nì e measadh gu mearachd, tillidh e luach eile a shònraicheas tu; air neo, tillidh e toradh na foirmle.

Tha co-chòrdadh gnìomh Excel IFERROR mar a leanas:

Càite:

• 9>Luach (riatanach) - dè a nì thu sgrùdadh airson mearachdan. Faodaidh e a bhith na fhoirmle, abairt, luach, no iomradh cealla.
• Luach_if_error (riatanach) - dè a thilleadh ma lorgar mearachd. Faodaidh e a bhith na shreang falamh (ceall bàn), teachdaireachd teacsa, luach àireamhach, foirmle no àireamhachadh eile.

Mar eisimpleir, nuair a bhios tu a’ roinneadh dà cholbh àireamhan, bidh thudh'fhaoidte gum faigh thu dòrlach de mhearachdan eadar-dhealaichte ma tha ceallan falamh, neamhan no teacsa ann an aon de na colbhan.

Gus casg a chur air sin, cleachd an gnìomh IFERROR gus mearachdan a ghlacadh agus a làimhseachadh mar a tha thu ag iarraidh.

Ma tha mearachd ann, an sin bàn

Sola sreang fhalamh (") dhan argamaid value_if_error gus ceal bàn a thilleadh ma lorgar mearachd:

=IFERROR(A2/B2, "")

Ma tha mearachd ann, seall teachdaireachd

Faodaidh tu cuideachd do theachdaireachd fhèin a thaisbeanadh an àite comharradh mearachd àbhaisteach Excel:

=IFERROR(A2/B2, "Error in calculation")

5 rudan air am bu chòir fios a bhith agad mu ghnìomh Excel IFERROR

1. Bidh an gnìomh IFERROR ann an Excel a' làimhseachadh a h-uile seòrsa mearachd a' gabhail a-steach # DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF!, agus #VALUE!.
2. A rèir susbaint na value_if_error argamaid, faodaidh IFERROR an teachdaireachd teacsa àbhaisteach agad, an àireamh, an ceann-latha no an luach loidsigeach agad, toradh foirmle eile, no sreang falamh (ceall bàn) a chur an àite mhearachdan.
3. Ma tha an argamaid luach is cealla falamh a th’ ann, thathas ga làimhseachadh mar sreang falamh (''') ach chan e mearachd.
4. Chaidh IFERROR a thoirt a-steach ann an Excel 2007 agus tha e ri fhaighinn anns a h-uile tionndadh às dèidh sin de Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021, agus Excel 365.
5. Gus mearachdan a ghlacadh ann an Excel 2003 agus tionndaidhean nas tràithe, cleachd an gnìomh ISERROR an co-bhonn ri IF, mar a chithear san eisimpleir seo.

eisimpleirean foirmle IFERROR

Na h-eisimpleirean a leanasseall mar a chleachdas tu IFERROR ann an Excel an co-bhonn ri gnìomhan eile gus gnìomhan nas iom-fhillte a choileanadh.

Excel IFERROR le Vlookup

'S e aon de na cleachdaidhean as cumanta a th' aig gnìomh IFERROR innse dhan luchd-cleachdaidh gu bheil an chan eil an luach a tha iad a’ lorg ann san t-seata dàta. Airson seo, còmhdaichidh tu foirmle VLOOKUP ann an IFERROR mar seo:

Mura bheil an luach lorg sa chlàr air a bheil thu a' coimhead , bheireadh foirmle Vlookup cunbhalach a’ mhearachd #N/A air ais:

Airson inntinn an neach-cleachdaidh agad, paisg VLOOKUP ann an IFERROR agus seallaidh e sealladh nas fiosrachail agus nas fhasa a chleachdadh. teachdaireachd:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

Tha an dealbh gu h-ìosal a’ sealltainn na foirmle Iferror seo ann an Excel:

Ma tha thu airson dìreach #N a ghlacadh /A Mearachdan ach chan eil a h-uile mearachd, cleachd an gnìomh IFNA an àite IFERROR.

Airson barrachd eisimpleirean foirmle Excel IFERROR VLOOKUP, thoir sùil air na clasaichean seo:

• Iferror with Vlookup gus a ghlacadh agus làimhseachadh mhearachdan
• Mar a gheibh thu an Nth tachartas de luach lorg
• Mar a gheibh thu a h-uile tachartas de luach lorg

Gnìomhan neadachaidh IFERROR gus Vlookups sreathach a dhèanamh ann an Excel

Ann an suidheachaidhean nuair a dh’ fheumas tu iomadh Vlookups a dhèanamh a rèir an do shoirbhich leis an Vlookup a bh’ ann roimhe no nach do shoirbhich leat, faodaidh tu dhà no barrachd a neadachadh IFERROR gnìomhan aon gu fear eile.

A’ gabhail ris gu bheil grunn aithisgean reic agad o mheuran roinneil na buidhne agadcompanaidh, agus tha thu airson suim fhaighinn airson ID òrdugh sònraichte. Le A2 mar an luach sgrùdaidh anns an duilleag làithreach, agus A2: B5 mar an raon sgrùdaidh ann an 3 duilleagan sgrùdaidh (Aithisg 1, Aithisg 2 agus Aithisg 3), tha am foirmle a’ dol mar a leanas:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))

Seallaidh an toradh rudeigin coltach ri seo:

Airson mìneachadh mionaideach air loidsig na foirmle, faic Mar a nì thu Vlookups sreath ann an Excel.

IFERROR ann am foirmlean rèite

Mar is dòcha gu bheil fios agad, tha foirmlean rèite ann an Excel an dùil grunn àireamhachadh a dhèanamh taobh a-staigh aon fhoirmle. Ma bheir thu seachad foirmle no abairt rèite a dh’ adhbhraicheas sreath san argamaid luach den ghnìomh IFERROR, thilleadh e sreath de luachan airson gach cealla san raon ainmichte. Tha an eisimpleir gu h-ìosal a' sealltainn an fhiosrachaidh.

Can abair, tha Iomlan agad ann an colbh B agus Prìs ann an colbh C, agus tha thu airson Àireamh Iomlan obrachadh a-mach . Faodar seo a dhèanamh le bhith a’ cleachdadh na foirmle eagar a leanas, a tha a’ roinn gach cealla san raon B2: B4 leis a’ chill fhreagarrach den raon C2:C4, agus an uairsin a’ cur suas na toraidhean:

=SUM($B$2:$B$4/$C$2:$C$4)

Tha am foirmle ag obair gu math fhad ‘s nach eil neoni no ceallan falamh aig an raon roinneadh. Ma tha co-dhiù aon luach 0 no cealla bàn, an #DIV/0! tha mearachd air a thilleadh:

Gus a’ mhearachd sin a cheartachadh, dìreach dèan an roinneadh taobh a-staigh gnìomh IFERROR:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Dè nì am foirmleis e luach ann an colbh B a roinn le luach ann an colbh C anns gach sreath (100/2, 200/5 agus 0/0) agus an sreath de thoraidhean {50 a thilleadh; 40; #DIV/0!}. Bidh an gnìomh IFERROR a’ glacadh a h-uile #DIV/0! mhearachdan agus cuiridh e neoni nan àite. Agus an uairsin, bidh an gnìomh SUM a’ cur suas na luachan anns an raon {50; 40; 0} agus a’ toirt a-mach an toradh deireannach (50+40=90).

Nota. Cuimhnich gum bu chòir foirmlean rèite a lìonadh le putadh air a’ gheàrr-liosta Ctrl + Shift + Enter.

IFERROR vs. IF ISERROR

A-nis gu bheil fios agad dè cho furasta 's a tha e an gnìomh IFERROR a chleachdadh ann an Excel, is dòcha gum bi e iongantach carson a tha cuid de dhaoine fhathast a' leantainn gu bhith a' cleachdadh a' chothlamadh IF ISERROR. A bheil buannachdan sam bith aige an taca ri IFERROR? Chan eil gin. Anns na seann làithean de Excel 2003 agus nas ìsle nuair nach robh IFERROR ann, b 'e ISERROR an aon dòigh air mearachdan a ghlacadh. Ann an Excel 2007 agus nas fhaide air adhart, chan eil ann ach dòigh beagan nas iom-fhillte air an aon toradh a choileanadh.

Mar eisimpleir, gus mearachdan Vlookup a ghlacadh, faodaidh tu aon de na foirmlean gu h-ìosal a chleachdadh.

Ann an Excel 2007 - Excel 2016:

Anns a h-uile tionndadh Excel:

Thoir an aire gum feum thu Vlookup a dhèanamh dà thuras san fhoirmle IF ISERROR VLOOKUP. Ann am Beurla shìmplidh, faodar am foirmle a leughadh mar a leanas: Ma thig mearachd air Vlookup, till "Cha deach a lorg", no cuir a-mach toradh Vlookup.

Agus seo fìor-eisimpleir beatha de fhoirmle Excel If Iserror Vlookup:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))

Airson tuilleadh fiosrachaidh, faic A’ cleachdadh gnìomh ISERROR ann an Excel.

IFERROR vs. IFNA

Air a thoirt a-steach le Excel 2013, tha aon ghnìomh eile aig IFNA gus foirmle a dhearbhadh airson mhearachdan. Tha an co-chàradh aige coltach ris an fhear aig IFERROR:

Dè an dòigh anns a bheil IFNA diofraichte bho IFERROR? Bidh gnìomh IFNA a' glacadh a-mhàin #N/A mhearachdan fhad 's a làimhsicheas IFERROR a h-uile seòrsa mearachd.

Dè na suidheachaidhean 's dòcha gu bheil thu airson IFNA a chleachdadh? Nuair a tha e neo-ghlic a h-uile mearachd fhalach. Mar eisimpleir, nuair a bhios tu ag obair le dàta cudromach no mothachail, is dòcha gum bi thu airson fios fhaighinn mu sgàinidhean a dh’ fhaodadh a bhith san t-seata dàta agad, agus dh’ fhaodadh teachdaireachdan mearachd àbhaisteach Excel leis an t-samhla “#” a bhith nan comharran lèirsinneach beòthail.

Chì sinn mar a nì thu foirmle a sheallas an teachdaireachd “Cha deach a lorg” an àite a’ mhearachd N/A, a nochdas nuair nach eil an luach sgrùdaidh an làthair san t-seata dàta, ach a bheir sin nad aire do mhearachdan Excel eile.

A’ smaoineachadh gu bheil thu airson Qty a tharraing. bhon chlàr sgrùdaidh chun chlàr geàrr-chunntas mar a chithear san dealbh gu h-ìosal. Le bhith a’ cleachdadh foirmle Excel Iferror Vlookup bheireadh sin toradh a tha tlachdmhor a thaobh bòidhchead, a tha ceàrr gu teicnigeach leis gu bheil Lemons ann sa chlàr sgrùdaidh:

Gus # a ghlacadh N/A ach seall am mearachd #DIV/0, cleachd an gnìomh IFNA ann an Excel 2013 agus Excel2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")

No, am measgachadh IF ISNA ann an Excel 2010 agus tionndaidhean nas tràithe:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

Co-chòrdadh an IFNA VLOOKUP agus IF ISNA Tha foirmlean VLOOKUP coltach ri foirmlean IFERROR VLOOKUP agus IF ISERROR VLOOKUP air an deach beachdachadh na bu tràithe.

Mar a chithear san dealbh-sgrìn gu h-ìosal, tha foirmle Ifna Vlookup a' tilleadh "Cha deach a lorg" a-mhàin airson an rud nach eil an làthair sa chlàr lorg. ( Peaches ). Airson Lemons , tha e a’ sealltainn #DIV/0! a’ nochdadh gu bheil mearachd sgaraidh le neoni anns a’ chlàr sgrùdaidh againn:

Airson tuilleadh fiosrachaidh, faic A’ cleachdadh gnìomh IFNA ann an Excel.

Na cleachdaidhean as fheàrr airson a bhith a’ cleachdadh IFERROR ann an Excel

Le seo tha fios agad mu thràth gur e gnìomh IFERROR an dòigh as fhasa air mearachdan a ghlacadh ann an Excel agus am falach le ceallan bàn, luachan neoni, no teachdaireachdan àbhaisteach dhut fhèin. Ach, chan eil sin a’ ciallachadh gum bu chòir dhut gach foirmle a phasgadh le làimhseachadh mhearachdan. 'S dòcha gun cuidich na molaidhean sìmplidh a leanas thu gus an cothromachadh a chumail.

1. Na glac mearachdan gun adhbhar.
2. Slap am pàirt as lugha de dh'fhoirmle ann an IFERROR.
3. Gus dìreach mearachdan sònraichte a làimhseachadh, cleachd gnìomh làimhseachadh mhearachdan le raon nas lugha:
   • IFNA no IF ISNA gus dìreach # N/A mhearachdan a ghlacadh.
   • ISERR gus a h-uile mearachd a ghlacadh ach a-mhàin #N/A.

Seo mar a chleachdas tu an gnìomh IFERROR ann an Excel gus mearachdan a ghlacadh agus a làimhseachadh. Airson sùil nas mionaidiche a thoirt air na foirmlean air an deach beachdachadh an seooideachadh, tha fàilte oirbh an sampall againn leabhar-obrach IFERROR Excel a luchdachadh sìos. Tha mi a' toirt taing dhut airson an leughadh agus an dòchas ur faicinn air ar blog an ath sheachdain.