Šajā pamācībā ir parādīts, kā lietot IFERROR programmā Excel, lai konstatētu kļūdas un aizstātu tās ar tukšu šūnu, citu vērtību vai pielāgotu ziņojumu. Jūs uzzināsiet, kā lietot funkciju IFERROR ar Vlookup un Index Match un kā to salīdzināt ar IF ISERROR un IFNA.

"Dodiet man vietu, kur stāvēt, un es izkustināšu zemi," reiz teica Arhimeds. "Dodiet man formulu, un es liksim tai atgriezt kļūdu," teiktu kāds Excel lietotājs. Šajā pamācībā mēs neapskatīsim, kā Excel programmā atgriezt kļūdas, bet gan mācīsimies, kā tās novērst, lai darblapas būtu tīras un formulas pārskatāmas.

Excel IFERROR funkcija - sintakse un galvenie lietojumi

Excel funkcija IFERROR ir paredzēta kļūdu izķeršanai un pārvaldīšanai formulās un aprēķinos. Precīzāk, IFERROR pārbauda formulu un, ja tā ir kļūdaina, atgriež citu norādīto vērtību; pretējā gadījumā atgriež formulas rezultātu.

Excel funkcijas IFERROR sintakse ir šāda:

Kur:

• Vērtība (obligāts) - ko pārbaudīt, lai atrastu kļūdas. Tā var būt formula, izteiksme, vērtība vai šūnas atsauce.
• Value_if_error (obligāts) - kas jāatgriež, ja tiek atrasta kļūda. Tā var būt tukša virkne (tukša šūna), teksta ziņojums, skaitliska vērtība, cita formula vai aprēķins.

Piemēram, dalot divas skaitļu kolonnas, var rasties vairākas dažādas kļūdas, ja vienā no kolonnām ir tukšas šūnas, nulles vai teksts.

Lai to novērstu, izmantojiet funkciju IFERROR, lai pārtvertu un apstrādātu kļūdas, kā vēlaties.

Ja kļūda, tad tukšs

Ierakstiet tukšu virkni (") value_if_error argumentu, lai atgrieztu tukšu šūnu, ja tiek atrasta kļūda:

=IFERROR(A2/B2, "")

Ja ir kļūda, parādiet ziņojumu

Varat arī parādīt savu ziņojumu, nevis Excel standarta kļūdas pierakstu:

=IFERROR(A2/B2, "Kļūda aprēķinā")

5 lietas, kas jāzina par Excel IFERROR funkciju

1. IFERROR funkcija programmā Excel apstrādā visus kļūdu veidus, tostarp #DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! un #VALUE!.
2. Atkarībā no satura value_if_error argumentu IFERROR var aizstāt kļūdas ar jūsu pielāgotu teksta ziņojumu, skaitli, datumu vai loģisku vērtību, citas formulas rezultātu vai tukšu virkni (tukšu šūnu).
3. Ja vērtība arguments ir tukša šūna, tas tiek uzskatīts par tukšu virkni (''''), bet ne par kļūdu.
4. IFERROR tika ieviesta programmā Excel 2007, un tā ir pieejama visās turpmākajās Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 un Excel 365 versijās.
5. Lai programmā Excel 2003 un agrākajās versijās fiksētu kļūdas, izmantojiet funkciju ISERROR kopā ar IF, kā parādīts šajā piemērā.

IFERROR formulas piemēri

Turpmākajos piemēros parādīts, kā programmā Excel lietot IFERROR kopā ar citām funkcijām, lai veiktu sarežģītākus uzdevumus.

Excel IFERROR ar Vlookup

Viens no visbiežāk izmantotajiem IFERROR funkciju lietojumiem ir informēt lietotājus, ka meklējamā vērtība datu kopā neeksistē. Šim nolūkam VLOOKUP formulu ietin IFERROR šādā veidā:

Ja meklēšanas vērtība neatrodas meklējamā tabulā, parastā Vlookup formula atgriezīs kļūdu #N/A:

Lai lietotāji būtu mierīgāki, ietiniet VLOOKUP ar IFERROR un parādiet informatīvāku un lietotājam draudzīgāku ziņojumu:

=IFERROR(VLOOKUP(A2, 'Lookup tabula'!$A$2:$B$4, 2,FALSE), "Nav atrasts")

Tālāk redzamajā ekrānšāviņas attēlā ir parādīta šī Iferror formula programmā Excel:

Ja vēlaties izķert tikai #N/A kļūdas, bet ne visas kļūdas, IFERROR vietā izmantojiet funkciju IFNA.

Vairāk Excel IFERROR VLOOKUP formulas piemēru skatiet šajās pamācībās:

• Iferror ar Vlookup, lai izķertu un apstrādātu kļūdas
• Kā iegūt meklēšanas vērtības N-o atkārtojumu
• Kā iegūt visus meklēšanas vērtības atkārtojumus

Iespraustās IFERROR funkcijas, lai veiktu secīgu Vlookups programmā Excel

Situācijās, kad nepieciešams veikt vairākas Vlookup, pamatojoties uz to, vai iepriekšējā Vlookup ir vai nav izdevusies, var ievietot divas vai vairākas IFERROR funkcijas vienu otrā.

Pieņemsim, ka jums ir vairāki pārdošanas pārskati no jūsu uzņēmuma reģionālajām filiālēm un jūs vēlaties iegūt summu par noteiktu pasūtījuma ID. Izmantojot A2 kā meklēšanas vērtību pašreizējā lapā un A2:B5 kā meklēšanas diapazonu 3 meklēšanas lapās (1. pārskats, 2. pārskats un 3. pārskats), formula ir šāda:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0), "nav atrasts")))))

Rezultāts būs līdzīgs šim:

Sīkāku formulas loģikas skaidrojumu skatiet sadaļā Kā veikt secīgus Vlookups programmā Excel.

IFERROR masīva formulās

Kā jūs droši vien zināt, masīva formulas programmā Excel ir paredzētas vairāku aprēķinu veikšanai vienā formulā. Ja sniedzat masīva formulu vai izteiksmi, kuras rezultāts ir masīvs. vērtība funkcijas IFERROR argumentu, tā atgrieztu vērtību masīvu katrai šūnai norādītajā diapazonā. Tālāk dotajā piemērā parādīta sīkāka informācija.

Teiksim, jums ir Kopā B slejā un Cena C slejā, un jūs vēlaties aprēķināt Kopējais daudzums . To var izdarīt, izmantojot šādu masīva formula, kas sadala katru šūnu diapazonā B2:B4 ar attiecīgo šūnu diapazonā C2:C4 un tad saskaita rezultātus:

=SUM($B$2:$B$4/$C$2:$C$4)

Formula darbojas pareizi, ja vien dalītāja diapazonā nav nullīšu vai tukšu šūnu. Ja ir vismaz viena 0 vērtība vai tukša šūna, tiek atgriezta #DIV/0! kļūda:

Lai labotu šo kļūdu, vienkārši veiciet dalīšanu ar funkciju IFERROR:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Formulas uzdevums ir dalīt vērtību B slejā ar vērtību C slejā katrā rindā (100/2, 200/5 un 0/0) un atgriezt rezultātu masīvu {50; 40; #DIV/0!}. Funkcija IFERROR noķer visas #DIV/0! kļūdas un aizstāj tās ar nullēm. Un tad funkcija SUM saskaita iegūtā masīva {50; 40; 0} vērtības un izvada galīgo rezultātu (50+40=90).

Lūdzu, atcerieties, ka masīva formulas jāaizpilda, nospiežot īsceļu kombināciju Ctrl + Shift + Enter.

IFERROR vs IF ISERROR

Tagad, kad zināt, cik vienkārši ir izmantot funkciju IFERROR programmā Excel, jūs, iespējams, brīnīsieties, kāpēc daži cilvēki joprojām sliecas izmantot kombināciju IF ISERROR. Vai tai ir kādas priekšrocības salīdzinājumā ar IFERROR? Nekādas. Vecajos sliktajos Excel 2003 un jaunākajos laikos, kad IFERROR nepastāvēja, IF ISERROR bija vienīgais iespējamais kļūdu slazds. 2007. gada un jaunākajos Excel versijās tas ir tikai nedaudz sarežģītāks veids, kāsasniegt tādu pašu rezultātu.

Piemēram, lai novērstu Vlookup kļūdas, varat izmantot kādu no tālāk minētajām formulām.

programmā Excel 2007 - Excel 2016:

Visās Excel versijās:

Ievērojiet, ka IF ISERROR VLOOKUP formulā Vlookup ir jāveic divas reizes. Vienkāršā angļu valodā formulu var lasīt šādi: Ja Vlookup rezultātā rodas kļūda, atgrieziet "Not found", pretējā gadījumā izvadiet Vlookup rezultātu.

Un šeit ir reāls Excel If Iserror Vlookup formulas piemērs:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)), "Nav atrasts", VLOOKUP(D2, A2:B5,2,FALSE ))

Lai iegūtu vairāk informācijas, skatiet tēmu Funkcijas ISERROR lietošana programmā Excel.

IFERROR pret IFNA

IFNA ir vēl viena funkcija, kas ieviesta programmā Excel 2013, lai pārbaudītu, vai formulā nav kļūdu. Tās sintakse ir līdzīga IFERROR sintaksei:

Ar ko IFNA atšķiras no IFERROR? IFNA funkcija aiztur tikai #N/A kļūdas bet IFERROR apstrādā visus kļūdu tipus.

Kādās situācijās var būt nepieciešams izmantot IFNA? Ja nav prātīgi slēpt visas kļūdas. Piemēram, strādājot ar svarīgiem vai sensitīviem datiem, jūs, iespējams, vēlaties, lai jūs brīdinātu par iespējamām kļūdām datu kopā, un standarta Excel kļūdu ziņojumi ar simbolu "#" varētu būt spilgti vizuāli rādītāji.

Aplūkosim, kā izveidot formulu, kas N/A kļūdas vietā, kura tiek parādīta, ja meklēšanas vērtība nav atrodama datu kopā, parāda ziņojumu "Nav atrasts", bet pievērš jūsu uzmanību citām Excel kļūdām.

Pieņemsim, ka vēlaties pārnest Qty. no uzmeklēšanas tabulas uz kopsavilkuma tabulu, kā parādīts ekrānšā attēlā. Izmantojot Excel Iferror Vlookup formulu, tiktu iegūts estētiski patīkams rezultāts, kas tehniski ir nepareizs, jo Citroni pastāv meklēšanas tabulā:

Lai atpazītu #N/A, bet parādītu kļūdu #DIV/0, programmā Excel 2013 un Excel 2016 izmantojiet funkciju IFNA:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Nav atrasts")

Vai kombinācija IF ISNA programmā Excel 2010 un agrākajās versijās:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)), "Nav atrasts", VLOOKUP(F3,$A$3:$D$6,4,FALSE)).

IFNA VLOOKUP un IF ISNA VLOOKUP formulu sintakse ir līdzīga iepriekš aplūkotajām IFERROR VLOOKUP un IF ISERROR VLOOKUP formulām.

Kā redzams zemāk redzamajā ekrānšāviņas attēlā, Ifna Vlookup formula atgriež rezultātu "Nav atrasts" tikai tad, ja vienība nav atrodama meklēšanas tabulā ( Persiki ). Citroni , tiek parādīts #DIV/0!, kas norāda, ka mūsu meklēšanas tabulā ir dalīšanas ar nulli kļūda:

Lai iegūtu sīkāku informāciju, skatiet sadaļu IFNA funkcijas lietošana programmā Excel.

Labākā prakse, kā lietot IFERROR programmā Excel

Jūs jau zināt, ka funkcija IFERROR ir visvienkāršākais veids, kā programmā Excel konstatēt kļūdas un maskēt tās ar tukšām šūnām, nulles vērtībām vai pielāgotiem ziņojumiem. Tomēr tas nenozīmē, ka jums katra formula ir jāapstrādā ar kļūdu apstrādi. Turpmākie vienkāršie ieteikumi var palīdzēt saglabāt līdzsvaru.

1. Nepieļaujiet kļūdas bez iemesla.
2. Iespējami mazāko formulas daļu ietin IFERROR.
3. Lai apstrādātu tikai konkrētas kļūdas, izmantojiet kļūdu apstrādes funkciju ar mazāku darbības jomu:
   • IFNA vai IF ISNA, lai atpazītu tikai #N/A kļūdas.
   • ISERR, lai pārtvertu visas kļūdas, izņemot #N/A.

Tas ir veids, kā jūs izmantojat funkciju IFERROR programmā Excel, lai izķertu un apstrādātu kļūdas. Lai tuvāk aplūkotu šajā pamācībā aplūkotās formulas, aicinām lejupielādēt mūsu parauga IFERROR Excel darbgrāmatu. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā.