Падручнік паказвае, як выкарыстоўваць IFERROR у Excel для выяўлення памылак і замены іх пустой ячэйкай, іншым значэннем або ўласным паведамленнем. Вы даведаецеся, як выкарыстоўваць функцыю IFERROR з Vlookup і Index Match, і як яна параўноўваецца з IF ISERROR і IFNA.

"Дайце мне месца, каб я стаяў, і я зрушу зямлю", Аднойчы сказаў Архімед. «Дайце мне формулу, і я прымусю яе вяртаць памылку», — сказаў бы карыстальнік Excel. У гэтым уроку мы не будзем разглядаць, як вяртаць памылкі ў Excel, мы лепш навучымся іх прадухіляць, каб вашы аркушы былі чыстымі, а формулы празрыстымі.

Функцыя IFERROR Excel - сінтаксіс і асноўныя спосабы выкарыстання

Функцыя IFERROR у Excel прызначана для ўлоўлівання і кіравання памылкамі ў формулах і разліках. У прыватнасці, IFERROR правярае формулу і, калі яна дае памылку, вяртае іншае значэнне, якое вы ўказваеце; у адваротным выпадку вяртае вынік формулы.

Сінтаксіс функцыі IFERROR наступны:

Дзе:

• Значэнне (абавязкова) - што правяраць на памылкі. Гэта можа быць формула, выраз, значэнне або спасылка на ячэйку.
• Value_if_error (абавязкова) - што вярнуць, калі знойдзена памылка. Гэта можа быць пусты радок (пустая ячэйка), тэкставае паведамленне, лікавае значэнне, іншая формула або разлік.

Напрыклад, пры падзеле двух слупкоў лікаў выможа атрымаць кучу розных памылак, калі адзін са слупкоў змяшчае пустыя ячэйкі, нулі або тэкст.

Каб гэтага не здарылася, выкарыстоўвайце функцыю IFERROR для выяўлення і апрацоўкі памылак так, як вы хочаце.

Калі памылка, то пустое

Пастаўце пусты радок (") у аргумент value_if_error , каб вярнуць пустую ячэйку, калі памылка знойдзена:

=IFERROR(A2/B2, "")

Калі памылка, паказаць паведамленне

Вы таксама можаце паказаць сваё ўласнае паведамленне замест стандартнага абазначэння памылкі Excel:

=IFERROR(A2/B2, "Error in calculation")

5 рэчаў, якія вы павінны ведаць пра функцыю IFERROR Excel

1. Функцыя IFERROR у Excel апрацоўвае ўсе тыпы памылак, уключаючы # DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! і #VALUE!.
2. У залежнасці ад змесціва value_if_error аргумент, КАЛІПАМЫЛКА можа замяніць памылкі вашым уласным тэкставым паведамленнем, нумарам, датай або лагічным значэннем, вынікам іншай формулы або пустым радком (пустая ячэйка).
3. Калі аргумент значэнне з'яўляецца пустой ячэйкай, яна разглядаецца як пусты радок ('''), але не памылка.
4. IFERROR быў прадстаўлены ў Excel 2007 і даступны ва ўсіх наступных версіях Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 і Excel 365.
5. Каб улоўліваць памылкі ў Excel 2003 і ранейшых версіях, выкарыстоўвайце функцыю ISERROR у спалучэнні з IF, як паказана ў гэтым прыкладзе.

Прыклады формул IFERROR

Наступныя прыкладыпаказаць, як выкарыстоўваць IFERROR ў Excel у спалучэнні з іншымі функцыямі для выканання больш складаных задач.

Excel IFERROR з Vlookup

Адзін з найбольш распаўсюджаных варыянтаў выкарыстання функцыі IFERROR паведамляе карыстальнікам, што значэнне, якое яны шукаюць, не існуе ў наборы даных. Для гэтага вы абгартаеце формулу VLOOKUP у IFERROR наступным чынам:

Калі значэння пошуку няма ў табліцы, якую вы шукаеце , звычайная формула ВПР верне памылку #N/A:

Для спакою вашых карыстальнікаў абгарніце VLOOKUP у IFERROR і пакажыце больш інфарматыўны і зручны паведамленне:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

На скрыншоце ніжэй паказана гэтая формула Iferror у Excel:

Калі вы хочаце захапіць толькі #N Памылкі /A, але не ўсе памылкі, выкарыстоўвайце функцыю IFNA замест IFERROR.

Каб атрымаць дадатковыя прыклады формул Excel IFERROR VLOOKUP, азнаёмцеся з гэтымі падручнікамі:

• Iferror з Vlookup для перахопу і апрацоўваць памылкі
• Як атрымаць N-е ўваходжанне значэння пошуку
• Як атрымаць усе ўваходжанні значэння пошуку

Укладзеныя функцыі IFERROR для выканання паслядоўных ВПР у Excel

У сітуацыях, калі вам трэба выканаць некалькі ВПР у залежнасці ад таго, удалая або няўдалая папярэдняя ВПР, вы можаце ўкласці дзве ці больш IFERROR функцыі адно ў адно.

Выкажам здагадку, што ў вас ёсць шэраг справаздач аб продажах ад рэгіянальных аддзяленняў вашагакампаніі, і вы хочаце атрымаць суму за пэўны ідэнтыфікатар замовы. З A2 у якасці значэння пошуку ў бягучым аркушы і A2:B5 у якасці дыяпазону пошуку ў 3 аркушах пошуку (Справаздача 1, Справаздача 2 і Справаздача 3), формула выглядае наступным чынам:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))

Вынік будзе выглядаць прыкладна так:

Падрабязнае тлумачэнне логікі формулы глядзіце, калі ласка, у раздзеле "Як рабіць паслядоўныя ВПР у Excel".

КАЛІПАШЫЛКА ў формулах масіва

Як вы, напэўна, ведаеце, формулы масіва ў Excel прызначаныя для выканання некалькіх вылічэнняў у рамках адной формулы. Калі вы дасце формулу масіва або выраз, які прыводзіць да масіву ў аргуменце значэнне функцыі IFERROR, ён верне масіў значэнняў для кожнай ячэйкі ў паказаным дыяпазоне. Прыклад ніжэй паказвае дэталі.

Дапусцім, у вас ёсць Усяго ў слупку B і Кошт у слупку C, і вы хочаце вылічыць Агульную колькасць . Гэта можна зрабіць з дапамогай наступнай формулы масіву, якая дзеліць кожную ячэйку ў дыяпазоне B2:B4 на адпаведную ячэйку дыяпазону C2:C4, а затым складае вынікі:

=SUM($B$2:$B$4/$C$2:$C$4)

Формула працуе нармальна, пакуль у дыяпазоне дзельніка няма нулёў або пустых вочак. Калі ёсць хаця б адно значэнне 0 або пустая ячэйка, #DIV/0! вяртаецца памылка:

Каб выправіць гэтую памылку, проста выканайце дзяленне ў функцыі IFERROR:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Што робіць формулазаключаецца ў падзеле значэння ў слупку B на значэнне ў слупку C у кожным радку (100/2, 200/5 і 0/0) і вяртанні масіва вынікаў {50; 40; #DIV/0!}. Функцыя IFERROR ловіць усе #DIV/0! памылкі і замяняе іх нулямі. Затым функцыя SUM складае значэнні ў атрыманым масіве {50; 40; 0} і выводзіць канчатковы вынік (50+40=90).

Заўвага. Калі ласка, памятайце, што формулы масіва павінны быць завершаны, націснуўшы спалучэнне клавіш Ctrl + Shift + Enter.

КАЛІ ПАМЫЛКА супраць КАЛІ ПАМЫЛКА

Цяпер, калі вы ведаеце, як лёгка выкарыстоўваць функцыю КАЛІ ПАМЫЛКА ў Excel, вы можаце задацца пытаннем, чаму некаторыя людзі ўсё яшчэ схіляюцца да выкарыстання камбінацыі КАЛІ ПАМЫЛКА. Ці ёсць у яго якія-небудзь перавагі ў параўнанні з IFERROR? Няма. У старыя дрэнныя часы Excel 2003 і ніжэй, калі IFERROR не існавала, IF ISERROR быў адзіным магчымым спосабам фіксацыі памылак. У Excel 2007 і пазнейшых версіях гэта крыху больш складаны спосаб дасягнуць таго ж выніку.

Напрыклад, каб выявіць памылкі Vlookup, вы можаце выкарыстоўваць любую з прыведзеных ніжэй формул.

У Excel 2007 - Excel 2016:

Ва ўсіх версіях Excel:

Заўважце, што ў формуле IF ISERROR VLOOKUP вы павінны выканаць VLOOKUP двойчы. На простай англійскай мове формулу можна прачытаць наступным чынам: калі Vlookup прыводзіць да памылкі, вярніце "Не знойдзена", інакш вывядзіце вынік Vlookup.

І вось сапраўдны-жыццёвы прыклад формулы Excel If Iserror Vlookup:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))

Для атрымання дадатковай інфармацыі гл. Выкарыстанне функцыі ISERROR у Excel.

IFERROR супраць IFNA

IFNA, прадстаўленая ў Excel 2013, з'яўляецца яшчэ адной функцыяй для праверкі формулы на наяўнасць памылак. Яго сінтаксіс падобны да IFNA:

Чым IFNA адрозніваецца ад IFERROR? Функцыя IFNA выяўляе толькі памылкі #N/A , у той час як IFERROR апрацоўвае ўсе тыпы памылак.

У якіх сітуацыях вы можаце выкарыстоўваць IFNA? Калі неразумна маскіраваць усе памылкі. Напрыклад, калі вы працуеце з важнымі або канфідэнцыйнымі дадзенымі, вам можа спатрэбіцца папярэджанне аб магчымых памылках у вашым наборы даных, а стандартныя паведамленні пра памылкі Excel з сімвалам "#" могуць быць яркімі візуальнымі індыкатарамі.

Давайце паглядзім. як вы можаце стварыць формулу, якая адлюстроўвае паведамленне "Не знойдзена" замест памылкі N/A, якая з'яўляецца, калі значэння пошуку няма ў наборы даных, але звяртае вашу ўвагу на іншыя памылкі Excel.

Выкажам здагадку, што вы хочаце атрымаць Qty. з табліцы пошуку ў зводную табліцу, як паказана на скрыншоце ніжэй. Выкарыстанне формулы Excel Iferror Vlookup дало б эстэтычна прыемны вынік, што тэхнічна няправільна, таму што Лімоны існуюць у табліцы пошуку:

Каб злавіць # Н/Д, але адлюстроўваецца памылка #DIV/0, выкарыстоўвайце функцыю IFNA ў Excel 2013 і Excel2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")

Або камбінацыя IF ISNA ў Excel 2010 і больш ранніх версіях:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

Сінтаксіс IFNA VLOOKUP і IF ISNA Формулы VLOOKUP падобныя на формулы IFERROR VLOOKUP і IF ISERROR VLOOKUP, якія абмяркоўваліся раней.

Як паказана на скрыншоце ніжэй, формула Ifna VLOOKUP вяртае «Не знойдзена» толькі для элемента, якога няма ў табліцы пошуку. ( Персікі ). Для лімонаў паказваецца #DIV/0! паказвае, што наша табліца пошуку змяшчае памылку дзялення на нуль:

Для атрымання дадатковай інфармацыі, калі ласка, гл. Выкарыстанне функцыі IFNA ў Excel.

Лепшыя практыкі выкарыстання IFERROR у Excel

Да гэтага часу вы ўжо ведаеце, што функцыя IFERROR - гэта самы просты спосаб выявіць памылкі ў Excel і замаскіраваць іх пустымі ячэйкамі, нулявымі значэннямі або ўласнымі паведамленнямі. Аднак гэта не значыць, што вы павінны абгарнуць кожную формулу апрацоўкай памылак. Наступныя простыя рэкамендацыі могуць дапамагчы вам захаваць баланс.

1. Не ловіце памылкі без прычыны.
2. Аберніце найменшую магчымую частку формулы ў IFERROR.
3. Каб апрацоўваць толькі пэўныя памылкі, выкарыстоўвайце функцыю апрацоўкі памылак з меншым аб'ёмам:
   • IFNA або IF ISNA, каб улоўліваць толькі памылкі #N/A.
   • ISERR, каб улоўліваць усе памылкі, акрамя #N/A.

Вось як вы выкарыстоўваеце функцыю IFERROR у Excel для ўлоўлівання і апрацоўкі памылак. Каб больш уважліва паглядзець на формулы, якія абмяркоўваюцца ў гэтымпадручнік, вы можаце загрузіць наш узор кнігі Excel IFERROR. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні.