이 자습서는 Excel에서 IFERROR를 사용하여 오류를 포착하고 빈 셀, 다른 값 또는 사용자 정의 메시지로 바꾸는 방법을 보여줍니다. Vlookup 및 Index Match와 함께 IFERROR 함수를 사용하는 방법과 IF ISERROR 및 IFNA를 비교하는 방법을 배웁니다.

"서 있을 자리를 주면 지구를 움직일 것입니다." 아르키메데스는 언젠가 말했다. Excel 사용자는 "공식을 주면 오류를 반환하도록 하겠습니다."라고 말합니다. 이 자습서에서는 Excel에서 오류를 반환하는 방법을 살펴보는 것이 아니라 워크시트를 깔끔하게 유지하고 수식을 투명하게 유지하기 위해 오류를 방지하는 방법을 배웁니다.

Excel IFERROR 함수 - 구문 및 기본 사용

Excel의 IFERROR 함수는 수식 및 계산에서 오류를 포착하고 관리하도록 설계되었습니다. 보다 구체적으로 IFERROR는 수식을 확인하고 오류로 평가되면 지정한 다른 값을 반환합니다. 그렇지 않으면 수식 결과를 반환합니다.

Excel IFERROR 함수의 구문은 다음과 같습니다.

여기서:

• Value (필수) - 오류를 확인할 대상입니다. 수식, 표현식, 값 또는 셀 참조가 될 수 있습니다.
• Value_if_error (필수) - 오류가 발견된 경우 반환할 내용입니다. 빈 문자열(빈 셀), 문자 메시지, 숫자 값, 다른 수식 또는 계산이 될 수 있습니다.

예를 들어 두 열의 숫자를 나눌 때열 중 하나에 빈 셀, 0 또는 텍스트가 포함된 경우 다양한 오류가 발생할 수 있습니다.

그런 일이 발생하지 않도록 하려면 IFERROR 함수를 사용하여 오류를 포착하고 처리하십시오. 원하는 방식으로.

오류인 경우 공백

value_if_error 인수에 빈 문자열(")을 제공하여 오류가 발견된 경우 빈 셀을 반환합니다.

=IFERROR(A2/B2, "")

오류가 있으면 메시지 표시

Excel의 표준 오류 표기법 대신 자신의 메시지를 표시할 수도 있습니다.

=IFERROR(A2/B2, "Error in calculation")

엑셀 IFERROR 함수에 대해 알아야 할 5가지

1. 엑셀의 IFERROR 함수는 #을 포함한 모든 오류 유형을 처리합니다. DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! 및 #VALUE!.
2. value_if_error 의 내용에 따라 인수, IFERROR는 사용자 지정 텍스트 메시지, 숫자, 날짜 또는 논리 값, 다른 수식의 결과 또는 빈 문자열(빈 셀)로 오류를 바꿀 수 있습니다.
3. 값 인수인 경우 빈 셀인 경우 다음과 같이 처리됩니다. 빈 문자열(''')이지만 오류는 아닙니다.
4. IFERROR는 Excel 2007에서 도입되었으며 Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 및 Excel의 모든 후속 버전에서 사용할 수 있습니다. 365.
5. Excel 2003 및 이전 버전에서 오류를 잡으려면 이 예제와 같이 IF와 함께 ISERROR 함수를 사용하십시오.

IFERROR 수식 예제

다음 예Excel에서 IFERROR를 다른 기능과 함께 사용하여 더 복잡한 작업을 수행하는 방법을 보여줍니다.

Vlookup을 사용한 Excel IFERROR

IFERROR 함수의 가장 일반적인 용도 중 하나는 사용자에게 검색 중인 값이 데이터 세트에 존재하지 않습니다. 이를 위해 다음과 같이 IFERROR에서 VLOOKUP 수식을 래핑합니다.

찾고 있는 테이블에 조회 값이 없는 경우 , 일반적인 Vlookup 수식은 #N/A 오류를 반환합니다.

사용자의 마음을 위해 VLOOKUP을 IFERROR로 래핑하고 보다 유익하고 사용자 친화적인 message:

=IFERROR(VLOOKUP(A2, 'Lookup table'!$A$2:$B$4, 2,FALSE), "Not found")

아래 스크린샷은 Excel의 Iferror 공식을 보여줍니다.

#N만 트랩하려는 경우 /A 오류가 있지만 모든 오류가 아닌 경우 IFERROR 대신 IFNA 함수를 사용하세요.

더 많은 Excel IFERROR VLOOKUP 수식 예제를 보려면 다음 자습서를 확인하세요.

• 트랩할 Vlookup을 사용한 Iferror 및 오류 처리
• 조회 값의 N번째 발생을 가져오는 방법
• 조회 값의 모든 발생을 가져오는 방법

Excel에서 순차적 Vlookup을 수행하는 중첩된 IFERROR 함수

이전 Vlookup의 성공 여부에 따라 여러 Vlookup을 수행해야 하는 상황에서 두 개 이상의 IFERROR를 중첩할 수 있습니다. 기능을 서로 연결합니다.

회사의 지역 지사에서 여러 판매 보고서가 있다고 가정합니다.회사에서 특정 주문 ID에 대한 금액을 받고 싶습니다. A2를 현재 시트의 조회 값으로, A2:B5를 3개의 조회 시트(보고서 1, 보고서 2 및 보고서 3)의 조회 범위로 사용하면 공식은 다음과 같습니다.

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found")))

결과는 다음과 유사합니다.

수식 논리에 대한 자세한 설명은 Excel에서 순차적 Vlookup 수행 방법을 참조하세요.

배열 수식의 IFERROR

알다시피 Excel의 배열 수식은 단일 수식 내에서 여러 계산을 수행하기 위한 것입니다. IFERROR 함수의 value 인수에 배열을 생성하는 배열 수식 또는 식을 제공하면 지정된 범위의 각 셀에 대한 값 배열이 반환됩니다. 아래 예는 세부 정보를 보여줍니다.

B열에 Total 이 있고 C열에 Price 가 있고 Total Quantity를 계산하려고 한다고 가정해 보겠습니다. . 이것은 B2:B4 범위의 각 셀을 C2:C4 범위의 해당 셀로 나눈 다음 결과를 더하는 배열 수식 을 사용하여 수행할 수 있습니다.

=SUM($B$2:$B$4/$C$2:$C$4)

제수 범위에 0 또는 빈 셀이 없는 한 수식이 제대로 작동합니다. 하나 이상의 0 값이나 빈 셀이 있으면 #DIV/0! 오류가 반환됩니다.

이 오류를 수정하려면 IFERROR 함수 내에서 나누기만 하면 됩니다.

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

공식의 역할각 행(100/2, 200/5 및 0/0)에서 열 B의 값을 열 C의 값으로 나누고 결과 배열 {50을 반환합니다. 40; #DIV/0!}. IFERROR 함수는 모든 #DIV/0을 포착합니다! 오류를 제거하고 0으로 바꿉니다. 그런 다음 SUM 함수는 결과 배열 {50; 40; 0}을 입력하고 최종 결과를 출력합니다(50+40=90).

참고. Ctrl + Shift + Enter 단축키를 눌러 배열 수식을 완성해야 한다는 점을 기억하세요.

IFERROR 대 IF ISERROR

이제 Excel에서 IFERROR 함수를 사용하는 것이 얼마나 쉬운지 알게 되었으므로 일부 사람들이 여전히 IF ISERROR 조합을 사용하는 데 관심이 있는 이유가 궁금할 것입니다. IFERROR에 비해 장점이 있습니까? 없음. IFERROR가 존재하지 않았던 Excel 2003 이하의 나쁜 옛날에는 IF ISERROR가 오류를 잡을 수 있는 유일한 방법이었습니다. Excel 2007 이상에서는 동일한 결과를 얻기 위한 좀 더 복잡한 방법일 뿐입니다.

예를 들어 Vlookup 오류를 잡으려면 아래 수식 중 하나를 사용할 수 있습니다.

Excel에서 2007 - Excel 2016:

모든 Excel 버전에서:

IF ISERROR VLOOKUP 수식에서 Vlookup을 두 번 수행해야 합니다. 일반 영어로 수식은 다음과 같이 읽을 수 있습니다. Vlookup 결과에 오류가 있으면 "찾을 수 없음"을 반환하고, 그렇지 않으면 Vlookup 결과를 출력합니다.

여기에 실제-Excel의 실제 예 If Iserror Vlookup 수식:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Not found", VLOOKUP(D2, A2:B5,2,FALSE ))

자세한 내용은 Excel에서 ISERROR 함수 사용을 참조하세요.

IFERROR 대 IFNA

Excel 2013에 도입된 IFNA는 수식 오류를 확인하는 또 하나의 기능입니다. 구문은 IFERROR의 구문과 유사합니다.

IFNA는 IFERROR와 어떤 점에서 다릅니까? IFNA 기능은 오직 #N/A 오류 를 포착하는 반면 IFERROR는 모든 오류 유형을 처리합니다.

어떤 상황에서 IFNA를 사용해야 할까요? 모든 오류를 위장하는 것이 현명하지 못한 경우. 예를 들어, 중요하거나 민감한 데이터로 작업할 때 데이터 세트의 가능한 결함에 대해 경고를 받고 싶을 수 있으며 "#" 기호가 있는 표준 Excel 오류 메시지는 생생한 시각적 표시가 될 수 있습니다.

보자 조회 값이 데이터 집합에 없을 때 나타나는 N/A 오류 대신 "찾을 수 없음" 메시지를 표시하는 수식을 만드는 방법은 무엇입니까?

Qty를 가져오고 싶다고 가정합니다. 아래 스크린샷과 같이 조회 테이블에서 요약 테이블로 이동합니다. Excel Iferror Vlookup 공식을 사용하면 심미적으로 만족스러운 결과를 얻을 수 있습니다. 조회 테이블에 레몬 이 존재하기 때문에 이는 기술적으로 올바르지 않습니다.

To catch # N/A이지만 #DIV/0 오류를 표시하려면 Excel 2013 및 Excel에서 IFNA 함수를 사용하십시오.2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Not found")

또는 Excel 2010 및 이전 버전의 IF ISNA 조합:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Not found", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

IFNA VLOOKUP 및 IF ISNA의 구문 VLOOKUP 수식은 앞에서 설명한 IFERROR VLOOKUP 및 IF ISERROR VLOOKUP과 유사합니다.

아래 스크린샷과 같이 Ifna Vlookup 수식은 조회 테이블에 없는 항목에 대해서만 "찾을 수 없음"을 반환합니다. ( 복숭아 ). Lemons 의 경우 #DIV/0! 조회 테이블에 0으로 나누기 오류가 있음을 나타냅니다.

자세한 내용은 Excel에서 IFNA 함수 사용을 참조하세요.

IFERROR 사용 모범 사례 in Excel

지금까지 IFERROR 함수가 Excel에서 오류를 잡아 빈 셀, 0 값 또는 사용자 지정 메시지로 마스킹하는 가장 쉬운 방법이라는 것을 이미 알고 있습니다. 그러나 그렇다고 해서 모든 수식을 오류 처리로 래핑해야 한다는 의미는 아닙니다. 다음과 같은 간단한 권장 사항이 균형을 유지하는 데 도움이 될 수 있습니다.

1. 이유 없이 오류를 포착하지 마십시오.
2. 공식의 가능한 가장 작은 부분을 IFERROR로 래핑합니다.
3. 특정 오류만 처리하려면 더 작은 범위의 오류 처리 기능을 사용하십시오.
   • IFNA 또는 IF ISNA는 #N/A 오류만 포착합니다.
   • ISERR은 다음을 제외한 모든 오류를 포착합니다. #N/A.

Excel에서 IFERROR 함수를 사용하여 오류를 잡아 처리하는 방법입니다. 이 문서에서 논의된 공식을 자세히 살펴보려면자습서에서 샘플 IFERROR Excel 통합 문서를 다운로드할 수 있습니다. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙겠습니다.