Das Tutorial konzentriert sich darauf, wie man in Excel eine Zufallsstichprobe ohne Wiederholungen erstellt. Sie finden Lösungen für Excel 365, Excel 2021, Excel 2019 und frühere Versionen.

Vor einiger Zeit haben wir verschiedene Möglichkeiten der Zufallsauswahl in Excel beschrieben. Die meisten dieser Lösungen beruhen auf den Funktionen RAND und RANDBETWEEN, die doppelte Zahlen erzeugen können. Folglich kann Ihre Zufallsstichprobe sich wiederholende Werte enthalten. Wenn Sie eine Zufallsauswahl ohne Duplikate benötigen, dann verwenden Sie die in diesem Tutorial beschriebenen Ansätze.

Excel-Zufallsauswahl aus einer Liste ohne Duplikate

Funktioniert nur in Excel 365 und Excel 2021, die dynamische Arrays unterstützen.

Um eine Zufallsauswahl aus einer Liste ohne Wiederholungen zu treffen, verwenden Sie diese allgemeine Formel:

Wo n ist die gewünschte Auswahlgröße.

Um zum Beispiel 5 zufällige Namen aus der Liste A2:A10 zu erhalten, ist folgende Formel zu verwenden:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Der Einfachheit halber können Sie den Stichprobenumfang in eine vordefinierte Zelle, z. B. C2, eingeben und den Zellbezug an die Funktion SEQUENCE übergeben:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Wie diese Formel funktioniert:

Hier eine kurze Erklärung der Logik der Formel: Die Funktion RANDARRAY erstellt ein Array mit Zufallszahlen, SORTBY sortiert die ursprünglichen Werte nach diesen Zahlen und INDEX ruft so viele Werte ab, wie durch SEQUENCE angegeben.

Eine detaillierte Aufschlüsselung folgt weiter unten:

Die Funktion ROWS zählt, wie viele Zeilen Ihr Datensatz enthält, und übergibt die Anzahl an die Funktion RANDARRAY, damit diese die gleiche Anzahl an zufälligen Dezimalzahlen erzeugen kann:

RANDARRAY(ROWS(A2:C10))

Dieses Array mit zufälligen Dezimalzahlen wird von der Funktion SORTBY als Array "Sortieren nach" verwendet, wodurch Ihre ursprünglichen Daten zufällig gemischt werden.

Aus den zufällig sortierten Daten extrahieren Sie eine Stichprobe eines bestimmten Umfangs. Dazu übergeben Sie das gemischte Array an die Funktion INDEX und fordern die Abfrage der ersten N Werte mit Hilfe der Funktion SEQUENCE, die eine Folge von Zahlen von 1 bis N Da die Originaldaten bereits in zufälliger Reihenfolge sortiert sind, ist es nicht wichtig, welche Positionen abgerufen werden, sondern nur die Menge.

Zufällige Zeilen in Excel ohne Duplikate auswählen

Funktioniert nur in Excel 365 und Excel 2021, die dynamische Arrays unterstützen.

Um zufällige Zeilen ohne Wiederholungen auszuwählen, erstellen Sie eine Formel auf diese Weise:

Wo n ist der Stichprobenumfang und {1,2,...} sind die zu extrahierenden Spaltennummern.

Lassen Sie uns als Beispiel zufällige Zeilen aus A2:C10 ohne doppelte Einträge auswählen, basierend auf dem Stichprobenumfang in F1. Da unsere Daten in 3 Spalten vorliegen, geben wir diese Array-Konstante in die Formel ein: {1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

Und erhalten das folgende Ergebnis:

Wie diese Formel funktioniert:

Die Formel funktioniert nach genau der gleichen Logik wie die vorherige. Eine kleine Änderung, die einen großen Unterschied macht, ist, dass Sie sowohl die zeilen_nummer und spalte_num Argumente für die Funktion INDEX: zeilen_nummer wird von SEQUENCE geliefert und spalte_num durch die Array-Konstante.

Wie man in Excel 2010 eine Zufallsstichprobe zieht - 2019

Da nur Excel für Microsoft 365 und Excel 2021 dynamische Arrays unterstützen, funktionieren die in den vorherigen Beispielen verwendeten dynamischen Array-Funktionen nur in Excel 365. Für andere Versionen müssen Sie eine andere Lösung finden.

Angenommen, Sie möchten eine zufällige Auswahl aus der Liste in A2:A10 treffen, so können Sie dies mit 2 separaten Formeln tun:

1. Generieren Sie Zufallszahlen mit der Rand-Formel, in unserem Fall geben Sie sie in B2 ein und kopieren sie dann nach B10:

   =RAND()

2. Extrahieren Sie den ersten Zufallswert mit der folgenden Formel, die Sie in E2 eingeben:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Kopieren Sie die obige Formel in so viele Zellen, wie Sie zufällige Werte auswählen wollen. In diesem Beispiel wollen wir 4 Namen, also kopieren wir die Formel von E2 bis E5.

Unsere Zufallsstichprobe ohne Duplikate sieht wie folgt aus:

Wie diese Formel funktioniert:

Wie im ersten Beispiel verwenden Sie die INDEX-Funktion, um Werte aus Spalte A auf der Grundlage von zufälligen Zeilennummern abzurufen. Der Unterschied besteht darin, wie Sie diese Nummern erhalten:

Die Funktion RAND füllt den Bereich B2:B10 mit zufälligen Dezimalzahlen.

Die Funktion RANK.EQ berechnet den Rang einer Zufallszahl in einer bestimmten Zeile. In E2 zum Beispiel ordnet RANK.EQ(B2, $B$2:$B$10) die Zahl in B2 gegen alle Zahlen in B2:B10 ein. Beim Kopieren nach E3 ändert sich die relative Referenz B2 in B3 und gibt den Rang der Zahl in B3 zurück usw.

Die Funktion COUNTIF ermittelt, wie viele Vorkommen einer bestimmten Zahl in den oben genannten Zellen vorhanden sind. In E2 prüft COUNTIF($B$2:B2, B2) beispielsweise nur eine Zelle - B2 selbst - und gibt 1 zurück. In E5 ändert sich die Formel in COUNTIF($B$2:B5, B5) und gibt 2 zurück, da B5 denselben Wert wie B2 enthält (bitte beachten Sie, dass dies nur zur besseren Erläuterung der Logik der Formel dient; bei einem kleinen Datensatz ist die Wahrscheinlichkeit, dass mandoppelte Zufallszahlen sind nahe Null).

Als Ergebnis liefert COUNTIF für das erste Auftreten die Zahl 1, von der Sie 1 abziehen, um die ursprüngliche Rangfolge beizubehalten. Für das zweite Auftreten liefert COUNTIF die Zahl 2. Indem Sie 1 abziehen, erhöhen Sie die Rangfolge um 1 und verhindern so doppelte Rangfolgen.

Für B2 beispielsweise liefert RANK.EQ den Wert 1. Da dies das erste Vorkommen ist, liefert COUNTIF ebenfalls den Wert 1. RANK.EQ + COUNTIF ergibt 2. Und - 1 stellt den Wert 1 wieder her.

Sehen wir uns nun an, was im Falle des zweiten Vorkommens passiert. Für B5 liefert RANK.EQ ebenfalls 1, während COUNTIF 2 liefert. Addiert man diese Werte, erhält man 3, von denen man 1 abzieht. Als Endergebnis erhält man 2, was den Rang der Zahl in B5 darstellt.

Der Rang geht an den zeilen_nummer Argument der Funktion INDEX und wählt den Wert aus der entsprechenden Zeile (die spalte_num Das ist der Grund, warum es so wichtig ist, eine doppelte Rangfolge zu vermeiden. Ohne die Funktion COUNTIF würde RANK.EQ sowohl für B2 als auch für B5 den Wert 1 liefern, so dass INDEX den Wert der ersten Zeile (Andrew) zweimal zurückgeben würde.

Wie kann man verhindern, dass sich die Excel-Zufallsstichprobe ändert?

Da alle Zufallsfunktionen in Excel wie RAND, RANDBETWEEN und RANDARRAY flüchtig sind, werden sie bei jeder Änderung auf dem Arbeitsblatt neu berechnet. Das hat zur Folge, dass sich Ihre Zufallsstichprobe ständig ändert. Um dies zu verhindern, verwenden Sie die Funktion Einfügen Spezial> Werte, um Formeln durch statische Werte zu ersetzen. Führen Sie dazu die folgenden Schritte aus:

1. Markieren Sie alle Zellen mit Ihrer Formel (jede Formel, die die Funktionen RAND, RANDBETWEEN oder RANDARRAY enthält) und drücken Sie Strg + C, um sie zu kopieren.
2. Klicken Sie mit der rechten Maustaste auf den ausgewählten Bereich und dann auf Einfügen Spezial > Werte Alternativ können Sie auch die Tastenkombination Umschalt + F10 und dann V drücken, um die oben genannte Funktion zu aktivieren.

Die detaillierten Schritte finden Sie unter Konvertieren von Formeln in Werte in Excel.

Excel-Zufallsauswahl: Zeilen, Spalten oder Zellen

Funktioniert in allen Versionen von Excel 365 bis Excel 2010.

Wenn Sie unsere Ultimate Suite in Ihrem Excel installiert haben, können Sie Stichproben mit einem Mausklick statt mit einer Formel erstellen, und zwar folgendermaßen

1. Auf der Ablebits Tools Registerkarte, klicken Sie auf Randomisieren > Zufällig auswählen .
2. Wählen Sie den Bereich aus, aus dem Sie eine Probe entnehmen möchten.
3. Gehen Sie im Fenster des Add-Ins wie folgt vor:
   • Wählen Sie, ob Sie zufällige Zeilen, Spalten oder Zellen auswählen möchten.
   • Definieren Sie den Stichprobenumfang: Das kann ein Prozentsatz oder eine Zahl sein.
   • Klicken Sie auf die Wählen Sie Taste.

Das war's! Wie in der Abbildung unten zu sehen ist, wird eine Zufallsstichprobe direkt in Ihrem Datensatz ausgewählt. Wenn Sie sie irgendwo hin kopieren möchten, drücken Sie einfach die Tastenkombination zum Kopieren (Strg + C).

So wählt man in Excel eine Zufallsstichprobe ohne Duplikate aus. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Verfügbare Downloads

Zufallsstichprobe ohne Duplikate - Formelbeispiele (.xlsx-Datei)

Ultimate Suite 14 Tage voll funktionsfähige Version (.exe-Datei)