ट्यूटोरियल इस बात पर केंद्रित है कि एक्सेल में बिना किसी रिपीट के रैंडम सैंपलिंग कैसे करें। आपको Excel 365, Excel 2021, Excel 2019 और पुराने संस्करणों के लिए समाधान मिलेंगे।

कुछ समय पहले, हमने Excel में बेतरतीब ढंग से चयन करने के कुछ अलग तरीकों का वर्णन किया था। उनमें से अधिकांश समाधान RAND और RANDBETWEEN फ़ंक्शंस पर निर्भर करते हैं, जो डुप्लीकेट नंबर उत्पन्न कर सकते हैं। नतीजतन, आपके यादृच्छिक नमूने में दोहराए जाने वाले मान हो सकते हैं। यदि आपको डुप्लिकेट के बिना एक यादृच्छिक चयन की आवश्यकता है, तो इस ट्यूटोरियल में वर्णित दृष्टिकोण का उपयोग करें।

बिना डुप्लिकेट वाली सूची से एक्सेल यादृच्छिक चयन

केवल में काम करता है एक्सेल 365 और एक्सेल 2021 जो डायनेमिक सरणियों का समर्थन करते हैं। , RANDARRAY(ROWS( data ))), SEQUENCE( n ))

जहां n वांछित चयन आकार है।

उदाहरण के लिए, A2:A10 में सूची से 5 अद्वितीय यादृच्छिक नाम प्राप्त करने के लिए, यहां उपयोग करने का सूत्र दिया गया है:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

सुविधा के लिए, आप नमूना आकार को एक में इनपुट कर सकते हैं पूर्वनिर्धारित सेल, C2 कहें, और SEQUENCE फ़ंक्शन को सेल संदर्भ प्रदान करें:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

यह सूत्र कैसे काम करता है:

यहां सूत्र के तर्क की उच्च-स्तरीय व्याख्या दी गई है: RANDARRAY फ़ंक्शन यादृच्छिक संख्याओं की एक सरणी बनाता है, SORTBY मूल मानों को उन संख्याओं के आधार पर क्रमबद्ध करता है, और INDEX उतने मान पुनर्प्राप्त करता है जितनेSEQUENCE द्वारा निर्दिष्ट।

एक विस्तृत ब्रेकडाउन नीचे दिया गया है:

ROWS फ़ंक्शन गणना करता है कि आपके डेटा सेट में कितनी पंक्तियाँ हैं और RANDARRAY फ़ंक्शन को गिनती पास करता है, इसलिए यह समान संख्या में उत्पन्न कर सकता है यादृच्छिक दशमलव:

RANDARRAY(ROWS(A2:C10))

यादृच्छिक दशमलव की इस सरणी का उपयोग सॉर्टबी फ़ंक्शन द्वारा "सॉर्ट बाय" सरणी के रूप में किया जाता है। परिणामस्वरूप, आपका मूल डेटा बेतरतीब ढंग से शफल हो जाता है।

यादृच्छिक रूप से क्रमबद्ध डेटा से, आप एक विशिष्ट आकार का एक नमूना निकालते हैं। इसके लिए, आप INDEX फ़ंक्शन को शफ़ल्ड ऐरे की आपूर्ति करते हैं और SEQUENCE फ़ंक्शन की सहायता से पहले N मानों को पुनः प्राप्त करने का अनुरोध करते हैं, जो 1 से N तक संख्याओं का अनुक्रम उत्पन्न करता है . क्योंकि मूल डेटा पहले से ही यादृच्छिक क्रम में क्रमबद्ध है, हम वास्तव में परवाह नहीं करते हैं कि किन पदों को पुनः प्राप्त करना है, केवल मात्रा मायने रखती है।

डुप्लिकेट के बिना एक्सेल में यादृच्छिक पंक्तियों का चयन करें

केवल काम करता है एक्सेल 365 और एक्सेल 2021 में जो डायनेमिक सरणियों का समर्थन करते हैं। RANDARRAY(ROWS( data ))), SEQUENCE( n ), {1,2,…})

जहां n नमूना आकार है और {1,2,…} निकालने के लिए स्तंभ संख्याएं हैं।

उदाहरण के तौर पर, एफ1 में नमूना आकार के आधार पर डुप्लिकेट प्रविष्टियों के बिना ए2:सी10 से यादृच्छिक पंक्तियों का चयन करें। जैसा कि हमारा डेटा 3 कॉलम में है, हम इस सरणी को सूत्र में स्थिर रखते हैं:{1,2,3

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

और निम्न परिणाम प्राप्त करें:

यह सूत्र कैसे काम करता है:

सूत्र ठीक उसी तर्क के साथ काम करता है जैसा पिछले वाले ने किया था। एक छोटा परिवर्तन जो एक बड़ा अंतर बनाता है वह यह है कि आप INDEX फ़ंक्शन के लिए row_num और column_num दोनों तर्क निर्दिष्ट करते हैं: row_num SEQUENCE द्वारा आपूर्ति की जाती है और column_num सरणी स्थिरांक द्वारा।

Excel 2010 - 2019

में यादृच्छिक नमूनाकरण कैसे करें

क्योंकि Microsoft 365 और Excel 2021 के लिए केवल Excel गतिशील सरणियों का समर्थन करता है, इसमें उपयोग किए जाने वाले गतिशील सरणी फ़ंक्शन पिछले उदाहरण केवल Excel 365 में काम करते हैं। अन्य संस्करणों के लिए, आपको एक अलग समाधान निकालना होगा।

मान लें कि आप A2:A10 में सूची से एक यादृच्छिक चयन चाहते हैं। यह 2 अलग-अलग सूत्रों के साथ किया जा सकता है:

1. रैंड सूत्र के साथ यादृच्छिक संख्या उत्पन्न करें। हमारे मामले में, हम इसे B2 में दर्ज करते हैं, और फिर B10 में कॉपी करते हैं:

   =RAND()

2. नीचे दिए गए सूत्र के साथ पहला यादृच्छिक मान निकालें, जिसे आप E2 में दर्ज करते हैं:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. उपरोक्त सूत्र को उतने से कक्षों में कॉपी करें जितने यादृच्छिक मान आप चुनना चाहते हैं। इस उदाहरण में, हमें 4 नाम चाहिए, इसलिए हम सूत्र को E2 से E5 तक कॉपी करते हैं।

हो गया! डुप्लिकेट के बिना हमारा यादृच्छिक नमूना इस प्रकार दिखता है:

यह फ़ॉर्मूला कैसे काम करता है:

पहले उदाहरण की तरह, आप इसका उपयोग करते हैं यादृच्छिक पंक्ति के आधार पर स्तंभ A से मान प्राप्त करने के लिए INDEX फ़ंक्शननंबर। अंतर यह है कि आप उन नंबरों को कैसे प्राप्त करते हैं:

रैंड फ़ंक्शन श्रेणी B2:B10 को यादृच्छिक दशमलव से भरता है।

RANK.EQ फ़ंक्शन किसी दिए गए में यादृच्छिक संख्या के रैंक की गणना करता है पंक्ति। उदाहरण के लिए, E2 में, RANK.EQ(B2, $B$2:$B$10) B2:B10 में सभी संख्याओं के विरुद्ध B2 में संख्या को रैंक करता है। जब E3 में कॉपी किया जाता है, तो सापेक्ष संदर्भ B2 B3 में बदल जाता है और B3 में संख्या का रैंक लौटाता है, और इसी तरह आगे भी। उदाहरण के लिए, E2 में, COUNTIF($B$2:B2, B2) केवल एक सेल - B2 की जाँच करता है, और 1 लौटाता है। E5 में, सूत्र COUNTIF($B$2:B5, B5) में बदल जाता है और 2 लौटाता है, क्योंकि B5 में B2 के समान मान हैं (कृपया ध्यान दें, यह केवल सूत्र के तर्क को बेहतर ढंग से समझाने के लिए है; एक छोटे डेटासेट पर, डुप्लिकेट यादृच्छिक संख्या प्राप्त करने की संभावना शून्य के करीब है)।

परिणाम के रूप में, सभी के लिए पहली घटनाएं, COUNTIF 1 लौटाता है, जिसमें से आप मूल रैंकिंग बनाए रखने के लिए 1 घटाते हैं। दूसरी घटनाओं के लिए, COUNTIF 2 लौटाता है। 1 घटाकर आप रैंकिंग को 1 से बढ़ाते हैं, इस प्रकार डुप्लीकेट रैंक को रोकते हैं। रिटर्न 1. RANK.EQ + COUNTIF 2 देता है। और - 1 रैंक 1 को पुनर्स्थापित करता है।

अब, देखें कि दूसरी घटना के मामले में क्या होता है। B5 के लिए, RANK.EQ भी 1 देता है जबकि COUNTIF 2 देता है। इन्हें जोड़ने पर मिलता है3, जिसमें से आप 1 घटाते हैं। अंतिम परिणाम के रूप में, आपको 2 मिलता है, जो B5 में संख्या के रैंक का प्रतिनिधित्व करता है।

रैंक INDEX फ़ंक्शन के row_num तर्क पर जाता है , और यह संबंधित पंक्ति से मान चुनता है ( column_num तर्क छोड़ा गया है, इसलिए यह 1 के लिए डिफ़ॉल्ट है)। यही कारण है कि डुप्लीकेट रैंकिंग से बचना इतना महत्वपूर्ण है। यदि यह COUNTIF फ़ंक्शन के लिए नहीं होता, तो RANK.EQ B2 और B5 दोनों के लिए 1 उत्पन्न करेगा, जिससे INDEX पहली पंक्ति (एंड्रयू) से दो बार मान लौटाएगा।

एक्सेल रैंडम सैंपल को बदलने से कैसे रोकें

चूंकि एक्सेल में रैंड, रैंडबेटवीन और रैंडाराय जैसे सभी रैंडमाइजिंग फ़ंक्शन अस्थिर हैं, वे वर्कशीट पर हर बदलाव के साथ पुनर्गणना करते हैं। नतीजतन, आपका यादृच्छिक नमूना लगातार बदलता रहेगा। ऐसा होने से रोकने के लिए, पेस्ट स्पेशल > सूत्रों को स्थिर मानों से बदलने के लिए मान सुविधा। इसके लिए, इन चरणों को पूरा करें:

1. अपने सूत्र के साथ सभी कक्षों का चयन करें (कोई भी सूत्र जिसमें RAND, RANDBETWEEN या RANDARRAY फ़ंक्शन हो) और उन्हें कॉपी करने के लिए Ctrl + C दबाएं।
2. चयनित श्रेणी पर राइट क्लिक करें और विशेष पेस्ट करें > मान क्लिक करें। वैकल्पिक रूप से, Shift + F10 दबाएं और फिर V दबाएं, जो उपर्युक्त सुविधा के लिए शॉर्टकट है।

विस्तृत चरणों के लिए, कृपया एक्सेल में सूत्रों को मूल्यों में कैसे परिवर्तित करें देखें।

एक्सेल यादृच्छिक चयन: पंक्तियाँ, कॉलमया सेल

एक्सेल 2010 के माध्यम से एक्सेल 365 के सभी संस्करणों में काम करता है।

अगर आपके एक्सेल में हमारा अल्टीमेट सूट स्थापित है, तो आप एक सूत्र के बजाय माउस क्लिक करें। इसका तरीका यहां दिया गया है:

1. Ablebits Tools टैब पर, यादृच्छिक करें > यादृच्छिक रूप से चुनें क्लिक करें।
2. चुनें वह सीमा जिससे आप एक नमूना चुनना चाहते हैं।
3. ऐड-इन के फलक पर, निम्न कार्य करें:
   • चुनें कि क्या आप यादृच्छिक पंक्तियों, स्तंभों, या कक्षों का चयन करना चाहते हैं।<14
   • नमूने के आकार को परिभाषित करें: जो प्रतिशत या संख्या हो सकती है।
   • चयन करें बटन पर क्लिक करें।

यह यह! जैसा कि नीचे दी गई छवि में दिखाया गया है, एक यादृच्छिक नमूना सीधे आपके डेटा सेट में चुना जाता है। यदि आप इसे कहीं कॉपी करना चाहते हैं, तो बस एक नियमित कॉपी शॉर्टकट (Ctrl + C) दबाएं।

इसी तरह एक्सेल में बिना डुप्लीकेट के रैंडम सैंपल का चयन किया जाता है। मैं आपको पढ़ने के लिए धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह हमारे ब्लॉग पर आपसे मुलाकात होगी!

डाउनलोड उपलब्ध हैं

डुप्लिकेट के बिना यादृच्छिक नमूना - सूत्र उदाहरण (.xlsx फ़ाइल)

अल्टीमेट सुइट 14-दिवसीय पूर्ण-कार्यात्मक संस्करण (.exe फ़ाइल)