Das Tutorial stellt die neue Excel-Funktion XMATCH vor und zeigt, wie sie besser als MATCH für die Lösung einiger gängiger Aufgaben geeignet ist.

In Excel 365 wurde die Funktion XMATCH hinzugefügt, um die Funktion MATCH abzulösen. Bevor Sie jedoch damit beginnen, Ihre bestehenden Formeln zu aktualisieren, sollten Sie alle Vorteile der neuen Funktion kennen und wissen, wie sie sich von der alten Funktion unterscheidet.

Zusammenfassend lässt sich sagen, dass die Funktion XMATCH der Funktion MATCH entspricht, aber flexibler und robuster ist: Sie kann sowohl in vertikalen als auch in horizontalen Feldern nachschlagen, von Anfang bis Ende oder von Ende bis Anfang suchen, exakte, ungefähre und teilweise Übereinstimmungen finden und einen schnelleren binären Suchalgorithmus verwenden.

Excel XMATCH-Funktion

Die Funktion XMATCH in Excel gibt die relative Position eines Wertes in einem Array oder einem Zellbereich zurück.

Sie hat die folgende Syntax:

Wo:

Nachschlagen_Wert (erforderlich) - der Wert, nach dem gesucht wird.

Nachschlagen_Array (erforderlich) - das Feld oder der Bereich von Zellen, in dem gesucht werden soll.

Spiel_Modus (optional) - gibt an, welche Art von Übereinstimmung verwendet werden soll:

• 0 oder weggelassen (Standard) - exakte Übereinstimmung
• -1 - exakte Übereinstimmung oder der nächstkleinere Wert
• 1 - genaue Übereinstimmung oder der nächstgrößere Wert
• 2 - Platzhalterübereinstimmung (*, ?)

Suche_Modus (optional) - gibt die Suchrichtung und den Algorithmus an:

• 1 oder weggelassen (Standard) - Suche vom ersten bis zum letzten.
• -1 - Suche in umgekehrter Reihenfolge vom letzten zum ersten.
• 2 - Binäre Suche aufsteigend, erforderlich lookup_array in aufsteigender Reihenfolge sortiert werden.
• -2 - Binäre Suche absteigend. benötigt lookup_array in absteigender Reihenfolge sortiert werden.

Die binäre Suche ist ein schnellerer Algorithmus, der effizient mit sortierten Arrays arbeitet. Weitere Informationen finden Sie unter Suchmodus.

Welche Excel-Version verfügt über XMATCH?

Die Funktion XMATCH ist nur in Excel für Microsoft 365 und Excel 2021 verfügbar. In Excel 2019, Excel 2016 und früheren Versionen wird diese Funktion nicht unterstützt.

Grundlegende XMATCH-Formel in Excel

Um eine allgemeine Vorstellung davon zu bekommen, wozu die Funktion fähig ist, wollen wir eine XMATCH-Formel in ihrer einfachsten Form erstellen, indem wir nur die ersten beiden erforderlichen Argumente definieren und die optionalen auf ihren Standardwerten belassen.

Angenommen, Sie haben eine Liste von Ozeanen, die nach ihrer Größe geordnet sind (C2:C6), und Sie möchten den Rang eines bestimmten Ozeans ermitteln. Indisch als Nachschlagewert und die gesamte Namensliste als Nachschlagefeld:

=XMATCH("Indisch", C2:C6)

Um die Formel flexibler zu gestalten, geben Sie den Ozean, der Sie interessiert, in eine Zelle ein, z. B. F1:

=XMATCH(F1, C2:C6)

Als Ergebnis erhalten Sie eine XMATCH-Formel zum Nachschlagen in einer vertikale Anordnung Die Ausgabe ist die relative Position des Nachschlagewertes im Array, die in unserem Fall dem Rang des Ozeans entspricht:

Eine ähnliche Formel funktioniert perfekt für eine horizontale Anordnung Alles, was Sie tun müssen, ist die Einstellung der lookup_array Hinweis:

=XMATCH(B5, B1:F1)

Excel XMATCH-Funktion - was ist zu beachten?

Um XMATCH effektiv in Ihren Arbeitsblättern einzusetzen und unerwartete Ergebnisse zu vermeiden, beachten Sie bitte diese 3 einfachen Fakten:

• Wenn es zwei oder mehr Vorkommen des Nachschlagewertes im Nachschlagearray gibt, wird die Position des erstes Spiel wird zurückgegeben, wenn die Suchmodus auf 1 gesetzt oder weggelassen wird. Mit Suchmodus auf -1 gesetzt, sucht die Funktion in umgekehrter Reihenfolge und gibt die Position des letztes Spiel wie in diesem Beispiel gezeigt.
• Wenn der Nachschlagewert wird nicht gefunden tritt ein #N/A-Fehler auf.
• Die XMATCH-Funktion ist Groß- und Kleinschreibung wird nicht berücksichtigt Um zwischen Klein- und Großbuchstaben zu unterscheiden, verwenden Sie diese case-sensitive XMATCH-Formel.

Wie man XMATCH in Excel verwendet - Formelbeispiele

Die folgenden Beispiele sollen Ihnen helfen, die Funktion XMATCH und ihre praktische Anwendung besser zu verstehen.

Genaue Übereinstimmung vs. ungefähre Übereinstimmung

Das Abgleichverhalten von XMATCH wird durch die optionale match_mode Argument:

• 0 oder weggelassen (Standard) - die Formel sucht nur nach exakten Übereinstimmungen. Wird keine exakte Übereinstimmung gefunden, wird ein #N/A-Fehler zurückgegeben.
• -1 - die Formel sucht zuerst nach der exakten Übereinstimmung und dann nach dem nächst kleineren Element.
• 1 - die Formel sucht zuerst nach exakten Übereinstimmungen und dann nach dem nächstgrößeren Element.

Und nun wollen wir sehen, wie sich verschiedene Abgleichsmodi auf das Ergebnis der Formel auswirken. Angenommen, Sie wollen herausfinden, wo ein bestimmtes Gebiet, sagen wir 80.000.000 km2, unter allen Ozeanen liegt.

Genaue Übereinstimmung

Wenn Sie 0 für match_mode erhalten Sie einen #N/A-Fehler, da die Formel keinen Wert finden kann, der genau dem Nachschlagewert entspricht:

=XMATCH(80000000, C2:C6, 0)

Nächster kleinster Posten

Wenn Sie -1 für match_mode gibt die Formel 3 zurück, da die nächste Übereinstimmung, die kleiner als der Suchwert ist, 70.560.000 ist, und dies ist das 3. Element im Suchfeld:

=XMATCH(80000000, C2:C6, -1)

Nächstgrößere Position

Wenn Sie 1 für match_mode wird die Formel 2 ausgeben, da die nächste Übereinstimmung, die größer als der Suchwert ist, 85.133.000 ist, was das zweite Element im Suchfeld ist:

=XMATCH(80000000, C2:C6, -1)

Das folgende Bild zeigt alle Ergebnisse:

Wie man in Excel einen Teil des Textes mit Platzhaltern abgleicht

Die XMATCH-Funktion verfügt über einen speziellen Übereinstimmungsmodus für Wildcards: Die match_mode Argument auf 2 gesetzt.

Im Modus der Platzhalterübereinstimmung akzeptiert eine XMATCH-Formel die folgenden Platzhalterzeichen:

• Fragezeichen (?) für die Übereinstimmung mit einem beliebigen einzelnen Zeichen.
• Sternchen (*) für eine beliebige Folge von Zeichen.

Bitte beachten Sie, dass Wildcards nur mit Text, nicht mit Zahlen funktionieren.

Um zum Beispiel die Position des ersten Eintrags zu finden, der mit "Süd" beginnt, lautet die Formel:

=XMATCH("Süd*", B2:B6, 2)

Sie können Ihren Platzhalterausdruck auch in eine Zelle, z. B. F1, eingeben und den Zellbezug für die lookup_value Argument:

=XMATCH(F1, B2:B6, 2)

Bei den meisten Excel-Funktionen verwenden Sie die Tilde (~), um das Sternchen (~*) oder das Fragezeichen (~?) nicht als Platzhalter zu behandeln. Bei XMATCH ist die Tilde nicht erforderlich. Wenn Sie den Modus für die Platzhalterübereinstimmung nicht definieren, geht XMATCH davon aus, dass ? und * reguläre Zeichen sind.

Die folgende Formel sucht zum Beispiel im Bereich A2:A7 genau nach dem Sternchenzeichen:

=XMATCH("*", A2:A7)

XMATCH Rückwärtssuche, um die letzte Übereinstimmung zu finden

Falls es mehrere Vorkommen des Nachschlagewertes im Nachschlagearray gibt, müssen Sie manchmal die Position des letztes Vorkommen .

Die Suchrichtung wird durch das 4. Argument von XMATCH namens Suchmodus Um in umgekehrter Reihenfolge zu suchen, d.h. von unten nach oben in einer vertikalen Anordnung und von rechts nach links in einer horizontalen Anordnung, Suchmodus sollte auf -1 gesetzt werden.

In diesem Beispiel soll die Position des letzten Datensatzes für einen bestimmten Suchwert zurückgegeben werden (siehe Screenshot unten). Dazu sind die Argumente wie folgt festzulegen:

• Nachschlagen_Wert - der Zielverkäufer in H1
• Nachschlagen_Array - Namen von Verkäufern in C2:C10
• Spiel_Modus 0 ist oder weggelassen wird (exakte Übereinstimmung)
• Suche_Modus ist -1 (vom letzten zum ersten)

Setzt man die vier Argumente zusammen, erhält man diese Formel:

=XMATCH(H1, C2:C10, 0, -1)

Gibt die Nummer des letzten von Laura getätigten Verkaufs zurück:

Wie vergleicht man zwei Spalten in Excel auf Übereinstimmung?

Um zwei Listen auf Übereinstimmungen zu vergleichen, können Sie die Funktion XMATCH zusammen mit IF und ISNA verwenden:

Um zum Beispiel die Liste 2 in B2:B10 mit der Liste 1 in A2:A10 zu vergleichen, sieht die Formel folgendermaßen aus:

=IF(ISNA(XMATCH(B2:B10, A2:A9)), "", "Übereinstimmung in Liste 1")

In diesem Beispiel identifizieren wir nur Übereinstimmungen, daher ist die wert_wenn_true Argument der IF-Funktion ist eine leere Zeichenkette ("").

Geben Sie die obige Formel in die oberste Zelle (in unserem Fall C2) ein, drücken Sie die Eingabetaste, und die Formel wird automatisch in die anderen Zellen übertragen (dies wird als Spill Range bezeichnet):

Wie diese Formel funktioniert

Im Kern der Formel sucht die Funktion XMATCH nach einem Wert aus Liste 2 in Liste 1. Wenn ein Wert gefunden wird, wird seine relative Position zurückgegeben, andernfalls ein #N/A-Fehler. In unserem Fall ist das Ergebnis von XMATCH das folgende Array:

{#N/A;#N/A;2;#N/A;4;#N/A;#N/A;8;#N/A}

Dieses Array wird an die ISNA-Funktion "gefüttert", um auf #N/A-Fehler geprüft zu werden. Für jeden #N/A-Fehler gibt ISNA TRUE zurück; für jeden anderen Wert - FALSE. Als Ergebnis wird das folgende Array von logischen Werten erzeugt, wobei TRUE's für Nicht-Übereinstimmungen und FALSE's für Übereinstimmungen stehen:

{WAHR;WAHR;FALSCH;WAHR;FALSCH;WAHR;WAHR;WAHR;FALSCH;WAHR}

Das obige Array geht an den logischen Test der IF-Funktion. Je nachdem, wie Sie die letzten beiden Argumente konfiguriert haben, wird die Formel den entsprechenden Text ausgeben. In unserem Fall ist es eine leere Zeichenkette ("") für Nichtübereinstimmungen ( wert_wenn_true ) und "Übereinstimmung in Liste 1" für Übereinstimmungen ( wert_wenn_false ).

Hinweis: Diese Formel funktioniert nur in Excel 365 und Excel 2021, die dynamische Arrays unterstützen. Wenn Sie Excel 2019, Excel 2016 oder eine frühere Version verwenden, sehen Sie sich bitte andere Lösungen an: Wie man zwei Spalten in Excel vergleicht.

INDEX XMATCH in Excel

XMATCH kann in Kombination mit der INDEX-Funktion verwendet werden, um einen Wert aus einer anderen Spalte abzurufen, die mit dem Nachschlagewert verknüpft ist, genau wie die INDEX MATCH-Formel. Der allgemeine Ansatz ist wie folgt:

Die Logik ist sehr geradlinig und leicht nachvollziehbar:

Die XMATCH-Funktion berechnet die relative Position des Lookup-Werts im Lookup-Array und übergibt sie an die zeilen_zahl Basierend auf der Zeilennummer gibt die Funktion INDEX einen Wert aus einer beliebigen Spalte zurück, die Sie angeben.

Um zum Beispiel die Fläche des Ozeans in E1 zu ermitteln, können Sie diese Formel verwenden:

=INDEX(B2:B6, XMATCH(E1, A2:A6))

INDEX XMATCH XMATCH zur Durchführung einer 2-dimensionalen Suche

Um gleichzeitig in Spalten und Zeilen nachzuschlagen, verwenden Sie INDEX zusammen mit zwei XMATCH-Funktionen, wobei die erste XMATCH-Funktion die Zeilennummer und die zweite die Spaltennummer abfragt:

Die Formel ist ähnlich wie bei INDEX MATCH MATCH, außer dass Sie das match_mode Argument, da es standardmäßig auf exakte Übereinstimmung eingestellt ist.

Um zum Beispiel eine Verkaufszahl für einen bestimmten Artikel (G1) in einem bestimmten Monat (G2) abzurufen, lautet die Formel:

=INDEX(B2:D8, XMATCH(G1, A2:A8), XMATCH(G2, B1:D1))

B2:D8 sind Datenzellen ohne Zeilen- und Spaltenüberschriften, A2:A8 ist eine Liste von Elementen und B1:D1 sind Monatsnamen.

Groß- und Kleinschreibung beachtende XMATCH-Formel

Wie bereits erwähnt, unterscheidet die Excel-Funktion XMATCH nicht zwischen Groß- und Kleinschreibung. Um die Unterscheidung von Groß- und Kleinschreibung zu erzwingen, verwenden Sie XMATCH in Kombination mit der Funktion EXACT:

Zur Suche in umgekehrte Reihenfolge vom Letzten zum Ersten:

Das folgende Beispiel zeigt diese allgemeine Formel in Aktion. Angenommen, Sie haben eine Liste von Produkt-IDs in B2:B11, bei denen die Groß-/Kleinschreibung beachtet werden muss. Sie möchten die relative Position des Artikels in E1 finden. Eine Formel in E2, bei der die Groß-/Kleinschreibung beachtet wird, ist so einfach wie folgt:

=XMATCH(TRUE, EXACT(B2:B11, E1))

Wie diese Formel funktioniert:

Die Funktion EXACT vergleicht den Nachschlagewert mit jedem Element im Nachschlage-Array. Wenn die verglichenen Werte exakt gleich sind, einschließlich der Groß- und Kleinschreibung, gibt die Funktion TRUE zurück, andernfalls FALSE. Dieses Array logischer Werte (wobei TRUE für exakte Übereinstimmungen steht) wird in die lookup_array Und da der Suchwert TRUE ist, gibt die XMATCH-Funktion die Position der ersten gefundenen exakten Übereinstimmung oder der letzten exakten Übereinstimmung zurück, je nachdem, wie Sie die Suchmodus Argument.

XMATCH vs. MATCH in Excel

XMATCH wurde als leistungsfähigerer und vielseitigerer Ersatz für MATCH entwickelt, so dass die beiden Funktionen viele Gemeinsamkeiten aufweisen. Es gibt jedoch auch wesentliche Unterschiede.

Unterschiedliches Standardverhalten

Die MATCH-Funktion ist standardmäßig auf exakte Übereinstimmung oder das nächstkleinere Element ( Spielart auf 1 gesetzt oder weggelassen).

Die XMATCH-Funktion ist standardmäßig auf exakte Übereinstimmung ( match_mode auf 0 gesetzt oder weggelassen).

Unterschiedliches Verhalten bei annähernder Übereinstimmung

Wenn die match_mode / Spielart wird auf 1 gesetzt:

• MATCH sucht nach exakten Übereinstimmungen oder dem nächstkleineren Wert, wobei das Lookup-Array in aufsteigender Reihenfolge sortiert sein muss.
• XMATCH sucht nach exakten Übereinstimmungen oder nach der nächstgrößeren Übereinstimmung, ohne dass eine Sortierung erforderlich ist.

Wenn die match_mode / Spielart Argument auf -1 gesetzt wird:

• MATCH sucht nach exakten Übereinstimmungen oder nach der nächstgrößeren Übereinstimmung, wobei das Lookup-Array in absteigender Reihenfolge sortiert werden muss.
• XMATCH sucht nach exakten Übereinstimmungen oder nach der nächstkleineren Übereinstimmung, ohne dass eine Sortierung erforderlich ist.

Wildcard-Suche

Um mit XMATCH partielle Übereinstimmungen zu finden, müssen Sie die Option match_mode Argument auf 2.

Die MATCH-Funktion verfügt nicht über eine spezielle Option für den Wildcard-Übereinstimmungsmodus. In den meisten Fällen wird man sie für eine exakte Übereinstimmung konfigurieren ( Spielart auf 0 gesetzt), was auch für Platzhaltersuchen funktioniert.

Suchmodus

Wie die neue Funktion XLOOKUP hat auch XMATCH eine spezielle Suchmodus Argument, das Ihnen erlaubt, die Richtung der Suche :

• 1 oder weggelassen (Standard) - Suche von Anfang bis Ende.
• -1 - Rückwärtssuche von letzter zu erster Stelle.

Und wählen Sie eine binärer Suchalgorithmus die sehr schnell und effizient ist auf sortierte Daten .

• 2 - Binäre Suche nach aufsteigend sortierten Daten.
• -2 - Binäre Suche auf absteigend sortierten Daten.

Binäre Suche , auch genannt Halbintervallsuche oder logarithmische Suche ist ein spezieller Algorithmus, der die Position eines Nachschlagewerts in einem Array durch Vergleich mit dem mittleren Element des Arrays ermittelt. Eine binäre Suche ist viel schneller als eine normale Suche, funktioniert aber nur bei sortierten Listen korrekt und kann bei unsortierten Daten falsche Ergebnisse liefern, die auf den ersten Blick ganz normal aussehen.

Die Syntax von MATCH sieht das Argument Suchmodus überhaupt nicht vor.

XMATCH verarbeitet Arrays nativ

Im Gegensatz zu ihrem Vorgänger wurde die XMATCH-Funktion für das dynamische Excel entwickelt und kann mit Arrays umgehen, ohne dass Sie die Tastenkombination Strg + Umschalt + Eingabetaste drücken müssen. Dies erleichtert die Erstellung und Bearbeitung von Formeln, insbesondere wenn Sie mehrere Funktionen zusammen verwenden. Vergleichen Sie einfach die folgenden Lösungen:

• Groß- und Kleinschreibung beachtende Formel: XMATCH
• Vergleich zweier Spalten oder Listen auf Übereinstimmungen: XMATCH

XMATCH und MATCH Verfügbarkeit

XMATCH ist eine neue Funktion, die nur in Excel für Microsoft 365 und Excel 2021 verfügbar ist.

Die MATCH-Funktion ist in jeder Version von Excel 365 bis Excel 2007 verfügbar.

So funktioniert die XMATCH-Funktion in Excel. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Übungsheft zum Herunterladen

Excel XMATCH-Formelbeispiele (.xlsx-Datei)