Mafunzo yanalenga jinsi ya kufanya sampuli nasibu katika Excel bila marudio. Utapata suluhu za Excel 365, Excel 2021, Excel 2019 na matoleo ya awali.

Muda mfupi uliopita, tulielezea njia chache tofauti za kuchagua bila mpangilio katika Excel. Nyingi za suluhu hizo zinategemea vitendaji vya RAND na RANDBETWEEN, ambavyo vinaweza kutoa nambari rudufu. Kwa hivyo, sampuli yako nasibu inaweza kuwa na maadili yanayojirudia. Ikiwa unahitaji uteuzi nasibu bila nakala, basi tumia mbinu zilizofafanuliwa katika mafunzo haya.

Iboreshe uteuzi nasibu kutoka kwenye orodha isiyo na nakala

Inafanya kazi ndani pekee Excel 365 na Excel 2021 zinazotumia safu badilika.

Ili kufanya uteuzi nasibu kutoka kwa orodha isiyo na marudio, tumia fomula hii ya kawaida:

Ambapo n ni ukubwa unaotakiwa wa uteuzi.

Kwa mfano, ili kupata majina 5 ya kipekee ya nasibu kutoka kwenye orodha katika A2:A10, hii ndiyo fomula ya kutumia:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Kwa ajili ya urahisishaji, unaweza kuingiza saizi ya sampuli katika kisanduku kilichofafanuliwa awali, sema C2, na usambaze rejeleo la kisanduku kwa chaguo za kukokotoa za SEQUENCE:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Jinsi fomula hii inavyofanya kazi:

Hapa kuna maelezo ya hali ya juu ya mantiki ya fomula: chaguo za kukokotoa za RANDARRAY huunda safu ya nambari nasibu, SORTBY hupanga thamani asili kwa nambari hizo, na INDEX hupata thamani nyingi kadiriimebainishwa na SEQUENCE.

Uchanganuzi wa kina unafuata hapa chini:

Kitendo cha kukokotoa ROWS huhesabu ni safu ngapi za safu wima ya data yako na kupitisha hesabu kwa chaguo za kukokotoa za RANDARRAY, ili iweze kutoa idadi sawa ya desimali nasibu:

RANDARRAY(ROWS(A2:C10))

Safu hii ya desimali nasibu inatumika kama safu ya "kupanga kulingana" na chaguo la kukokotoa la SORTBY. Kwa hivyo, data yako asili huchanganyikiwa nasibu.

Kutoka kwa data iliyopangwa kwa nasibu, unatoa sampuli ya saizi mahususi. Kwa hili, unatoa safu iliyochanganyika kwa chaguo za kukokotoa INDEX na unaomba kurejesha thamani za kwanza za N kwa usaidizi wa chaguo za kukokotoa za SEQUENCE, ambayo hutoa mlolongo wa nambari kutoka 1 hadi N . Kwa sababu data asili tayari imepangwa kwa mpangilio nasibu, hatujali kabisa ni nafasi zipi za kurejesha, ni wingi pekee ndio unaohusika.

Chagua safu mlalo nasibu katika Excel bila nakala

Hufanya kazi pekee. katika Excel 365 na Excel 2021 zinazotumia safu zinazobadilika.

Ili kuchagua safu mlalo nasibu bila marudio, tengeneza fomula kwa njia hii:

Ambapo n ni sampuli ya saizi na {1,2,…} ni nambari za safu wima za kutoa.

Kwa mfano, hebu tuchague safu mlalo nasibu kutoka kwa A2:C10 bila nakala rudufu, kulingana na sampuli ya ukubwa katika F1. Kwa vile data yetu iko katika safu wima 3, tunasambaza safu hii mara kwa mara kwa fomula:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

Na upate matokeo yafuatayo:

Jinsi fomula hii inavyofanya kazi:

Mfumo huu hufanya kazi kwa mantiki sawa kabisa na ya awali. Badiliko dogo linaloleta tofauti kubwa ni kwamba unabainisha hoja zote mbili za safu_ya_nambari na safu_ya_nambari za chaguo za kukokotoa za INDEX: row_num hutolewa na SEQUENCE na safu_num kwa safu thabiti.

Jinsi ya kufanya sampuli nasibu katika Excel 2010 - 2019

Kama Excel pekee ya Microsoft 365 na Excel 2021 inayoauni safu badilika, vitendakazi vya safu badilika vinavyotumika katika mifano ya awali hufanya kazi katika Excel 365 pekee. Kwa matoleo mengine, itabidi utafute suluhu tofauti.

Tuseme unataka uteuzi nasibu kutoka kwa orodha katika A2:A10. Hili linaweza kufanywa kwa fomula 2 tofauti:

1. Tengeneza nambari nasibu kwa fomula ya Randi. Kwa upande wetu, tunaiingiza katika B2, na kisha kunakili hadi B10:

   =RAND()

2. Ondoa thamani ya kwanza ya nasibu na fomula iliyo hapa chini, ambayo unaingiza katika E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Nakili fomula iliyo hapo juu kwa visanduku vingi kadiri thamani nyingi unavyotaka kuchagua. Katika mfano huu, tunataka majina 4, kwa hivyo tunakili fomula kutoka E2 hadi E5.

Imekamilika! Sampuli yetu nasibu bila nakala inaonekana kama ifuatavyo:

Jinsi fomula hii inavyofanya kazi:

Kama ilivyo katika mfano wa kwanza, unatumia Chaguo za kukokotoa INDEX ili kupata thamani kutoka safu wima A kulingana na safu mlalo nasibunambari. Tofauti ni jinsi unavyopata nambari hizo:

Kitendo cha kukokotoa cha RAND hujaza safu B2:B10 na desimali nasibu.

Kitendaji cha RANK.EQ hukokotoa nafasi ya nambari nasibu katika nambari fulani. safu. Kwa mfano, katika E2, RANK.EQ(B2, $B$2:$B$10) hupanga nambari katika B2 dhidi ya nambari zote katika B2:B10. Inaponakiliwa hadi E3, rejeleo la jamaa B2 hubadilika hadi B3 na kurudisha kiwango cha nambari katika B3, na kadhalika.

Kitendaji cha COUNTIF hupata idadi ya matukio ya nambari fulani katika visanduku vilivyo hapo juu. Kwa mfano, katika E2, COUNTIF($B$2:B2, B2) hukagua kisanduku kimoja tu - B2 yenyewe, na kurudisha 1. Katika E5, fomula inabadilika kuwa COUNTIF($B$2:B5, B5) na kurejesha 2, kwa sababu B5 ina thamani sawa na B2 (tafadhali kumbuka, hii ni kueleza vyema mantiki ya fomula; kwenye mkusanyiko mdogo wa data, uwezekano wa kupata nakala za nambari nasibu ni karibu na sifuri).

Kama matokeo, kwa wote Tukio la 1, COUNTIF inarejesha 1, ambapo unaondoa 1 ili kuweka nafasi asili. Kwa matukio ya 2, COUNTIF inarejesha 2. Kwa kutoa 1 unaongeza cheo kwa 1, hivyo basi kuzuia safu rudufu.

Kwa mfano, kwa B2, RANK.EQ inarejesha 1. Kwa vile hili ni tukio la kwanza, COUNTIF pia inarejesha 1. RANK.EQ + COUNTIF inatoa 2. Na - 1 inarejesha cheo 1.

Sasa, tazama kitakachotokea ikiwa tukio la 2 litatokea. Kwa B5, RANK.EQ pia hurejesha 1 huku COUNTIF ikirudisha 2. Kuongeza hizi inatoa3, ambapo unaondoa 1. Kama matokeo ya mwisho, unapata 2, ambayo inawakilisha kiwango cha nambari katika B5.

Cheo huenda kwa row_num hoja ya chaguo la kukokotoa la INDEX. , na huchagua thamani kutoka kwa safu mlalo inayolingana (hoja ya column_num imeachwa, kwa hivyo inabadilika kuwa 1). Hii ndio sababu ni muhimu sana kuzuia uwekaji nakala. Kama isingekuwa kwa chaguo za kukokotoa za COUNTIF, RANK.EQ ingetoa 1 kwa B2 na B5, na kusababisha INDEX kurudisha thamani kutoka safu mlalo ya kwanza (Andrew) mara mbili.

Jinsi ya kuzuia sampuli nasibu ya Excel isibadilike.

Kwa vile vitendaji vyote vya kubahatisha katika Excel kama vile RAND, RANDBETWEEN na RANDARRAY ni tete, vinakokotoa upya kwa kila mabadiliko kwenye laha ya kazi. Kama matokeo, sampuli yako ya nasibu itakuwa ikibadilika kila wakati. Ili kuzuia hili kutokea, tumia Bandika Maalum > Thamani huangazia kubadilisha fomula na thamani tuli. Kwa hili, tekeleza hatua hizi:

1. Chagua seli zote zilizo na fomula yako (fomula yoyote iliyo na kitendakazi cha RAND, RANDBETWEEN au RANDARRAY) na ubonyeze Ctrl + C ili kuzinakili.
2. Bofya kulia fungu la visanduku lililochaguliwa na ubofye Bandika Maalum > Thamani . Vinginevyo, bonyeza Shift + F10 na kisha V , ambayo ni njia ya mkato ya kipengele kilichotajwa hapo juu.

Kwa hatua za kina, tafadhali angalia Jinsi ya kubadilisha fomula hadi thamani katika Excel.

Uteuzi wa nasibu bora zaidi: safu mlalo, safu wimaau seli

Hufanya kazi katika matoleo yote ya Excel 365 hadi Excel 2010.

Ikiwa umesakinisha Ultimate Suite yetu katika Excel yako, basi unaweza kufanya sampuli nasibu kwa kutumia bonyeza mouse badala ya fomula. Hivi ndivyo jinsi:

1. Kwenye kichupo cha Zana za Ablebits , bofya Badilisha > Chagua Nasibu .
2. Chagua masafa ambayo ungependa kuchagua sampuli.
3. Kwenye kidirisha cha programu jalizi, fanya yafuatayo:
   • Chagua kama ungependa kuchagua safu mlalo, safu wima au visanduku nasibu.
   • Fafanua saizi ya sampuli: hiyo inaweza kuwa asilimia au nambari.
   • Bofya kitufe cha Chagua .

Hiyo ndiyo ni! Kama inavyoonyeshwa kwenye picha hapa chini, sampuli nasibu huchaguliwa moja kwa moja kwenye seti yako ya data. Ikiwa ungependa kuinakili mahali fulani, bonyeza tu njia ya mkato ya nakala ya kawaida (Ctrl + C) .

Hiyo ndiyo jinsi ya kuchagua sampuli nasibu katika Excel bila nakala. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogu yetu wiki ijayo!

Vipakuliwa vinavyopatikana

Sampuli nasibu bila nakala - mifano ya fomula (.xlsx file)

Ultimate Suite Toleo linalofanya kazi kikamilifu la siku 14 (.exe faili)