Nakatuon ang tutorial sa kung paano gumawa ng random sampling sa Excel na walang pag-uulit. Makakahanap ka ng mga solusyon para sa Excel 365, Excel 2021, Excel 2019 at mga mas naunang bersyon.

Kanina pa, inilarawan namin ang ilang magkakaibang paraan upang random na pumili sa Excel. Karamihan sa mga solusyong iyon ay umaasa sa RAND at RANDBETWEEN function, na maaaring makabuo ng mga duplicate na numero. Dahil dito, ang iyong random na sample ay maaaring maglaman ng mga umuulit na halaga. Kung kailangan mo ng random na pagpili nang walang mga duplicate, pagkatapos ay gamitin ang mga approach na inilalarawan sa tutorial na ito.

Excel random selection mula sa listahan na walang duplicate

Gumagana lang sa Excel 365 at Excel 2021 na sumusuporta sa mga dynamic na array.

Upang gumawa ng random na pagpili mula sa isang listahan na walang pag-uulit, gamitin ang generic na formula na ito:

Kung saan ang n ay ang gustong laki ng seleksyon.

Halimbawa, para makakuha ng 5 natatanging random na pangalan mula sa listahan sa A2:A10, narito ang formula na gagamitin:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Para sa kaginhawahan, maaari mong ipasok ang sample size sa isang paunang natukoy na cell, sabihin ang C2, at ibigay ang cell reference sa SEQUENCE function:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Paano gumagana ang formula na ito:

Narito ang isang mataas na antas na paliwanag ng lohika ng formula: ang RANDARRAY function ay lumilikha ng hanay ng mga random na numero, SORTBY ay nag-uuri ng mga orihinal na halaga ayon sa mga numerong iyon, at ang INDEX ay kumukuha ng kasing dami ng mga halagatinukoy ng SEQUENCE.

Sumusunod ang isang detalyadong breakdown sa ibaba:

Binibilang ng ROWS function kung gaano karaming mga row ang nilalaman ng iyong data set at ipinapasa ang bilang sa RANDARRAY function, upang makabuo ito ng parehong bilang ng mga random na decimal:

RANDARRAY(ROWS(A2:C10))

Ang hanay ng mga random na decimal na ito ay ginagamit bilang array na "sort by" ng SORTBY function. Bilang resulta, random na na-shuffle ang iyong orihinal na data.

Mula sa random na pinagsunod-sunod na data, kukuha ka ng sample na may partikular na laki. Para dito, ibibigay mo ang shuffled array sa INDEX function at humiling na kunin ang unang N value sa tulong ng SEQUENCE function, na gumagawa ng sequence ng mga numero mula 1 hanggang N . Dahil ang orihinal na data ay nakaayos na sa random na pagkakasunud-sunod, wala kaming pakialam kung aling mga posisyon ang kukunin, ang dami lang ang mahalaga.

Pumili ng mga random na row sa Excel nang walang mga duplicate

Gumagana lang sa Excel 365 at Excel 2021 na sumusuporta sa mga dynamic na array.

Upang pumili ng mga random na row na walang pag-uulit, bumuo ng formula sa ganitong paraan:

Kung saan ang n ay ang sample size at Ang {1,2,…} ay mga numero ng column na i-extract.

Bilang halimbawa, pumili tayo ng mga random na row mula sa A2:C10 nang walang mga duplicate na entry, batay sa laki ng sample sa F1. Dahil ang aming data ay nasa 3 column, ibinibigay namin ang array constant na ito sa formula:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

At kunin ang sumusunod na resulta:

Paano gumagana ang formula na ito:

Gumagana ang formula sa eksaktong kaparehong lohika gaya ng nauna. Ang isang maliit na pagbabago na gumagawa ng malaking pagkakaiba ay ang pagtukoy mo sa parehong row_num at column_num na mga argumento para sa INDEX function: row_num ay ibinibigay ng SEQUENCE at column_num sa pamamagitan ng array constant.

Paano gumawa ng random sampling sa Excel 2010 - 2019

Bilang Excel lamang para sa Microsoft 365 at Excel 2021 ang sumusuporta sa mga dynamic na array, ang dynamic na array function na ginagamit sa gumagana lang ang mga nakaraang halimbawa sa Excel 365. Para sa iba pang mga bersyon, kakailanganin mong gumawa ng ibang solusyon.

Ipagpalagay na gusto mo ng random na seleksyon mula sa listahan sa A2:A10. Magagawa ito gamit ang 2 magkahiwalay na formula:

1. Bumuo ng mga random na numero gamit ang Rand formula. Sa aming kaso, ipinasok namin ito sa B2, at pagkatapos ay kopyahin pababa sa B10:

   =RAND()

2. I-extract ang unang random na halaga gamit ang formula sa ibaba, na iyong ipinasok sa E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Kopyahin ang formula sa itaas sa kasing dami ng mga cell na kasing dami ng random na value na gusto mong piliin. Sa halimbawang ito, gusto namin ng 4 na pangalan, kaya kinopya namin ang formula mula sa E2 hanggang E5.

Tapos na! Ang aming random na sample na walang mga duplicate ay ganito ang hitsura:

Paano gumagana ang formula na ito:

Tulad ng sa unang halimbawa, ginagamit mo ang INDEX function upang kunin ang mga halaga mula sa column A batay sa random na rownumero. Ang pagkakaiba ay sa kung paano mo makukuha ang mga numerong iyon:

Pinapuno ng RAND function ang hanay na B2:B10 ng mga random na decimal.

Kinakalkula ng RANK.EQ function ang ranggo ng isang random na numero sa isang naibigay na hilera. Halimbawa, sa E2, niraranggo ng RANK.EQ(B2, $B$2:$B$10) ang numero sa B2 laban sa lahat ng numero sa B2:B10. Kapag kinopya sa E3, ang kamag-anak na reference na B2 ay nagbabago sa B3 at ibinabalik ang ranggo ng numero sa B3, at iba pa.

Hinahanap ng COUNTIF function kung gaano karaming mga paglitaw ng isang naibigay na numero ang nasa mga cell sa itaas. Halimbawa, sa E2, sinusuri ng COUNTIF($B$2:B2, B2) ang isang cell lamang - B2 mismo, at nagbabalik ng 1. Sa E5, nagbabago ang formula sa COUNTIF($B$2:B5, B5) at nagbabalik ng 2, dahil Ang B5 ay naglalaman ng parehong halaga ng B2 (pakitandaan, ito ay para lamang maipaliwanag nang mas mahusay ang lohika ng formula; sa isang maliit na dataset, ang mga pagkakataong makakuha ng mga duplicate na random na numero ay malapit sa zero).

Bilang resulta, para sa lahat Ang mga unang paglitaw, ang COUNTIF ay nagbabalik ng 1, kung saan mo ibabawas ang 1 upang mapanatili ang orihinal na ranggo. Para sa ika-2 pangyayari, ang COUNTIF ay nagbabalik ng 2. Sa pamamagitan ng pagbabawas ng 1, dinaragdagan mo ang ranggo ng 1, kaya pinipigilan ang mga duplicate na ranggo.

Halimbawa, para sa B2, ang RANK.EQ ay nagbabalik ng 1. Dahil ito ang unang pangyayari, COUNTIF din nagbabalik ng 1. Ang RANK.EQ + COUNTIF ay nagbibigay ng 2. At - 1 ay nagpapanumbalik ng ranggo 1.

Ngayon, tingnan kung ano ang mangyayari kung sakaling mangyari ang ika-2 pangyayari. Para sa B5, ang RANK.EQ ay nagbabalik din ng 1 habang ang COUNTIF ay nagbabalik ng 2. Ang pagdaragdag ng mga ito ay nagbibigay ng3, kung saan ibawas mo ang 1. Bilang huling resulta, makakakuha ka ng 2, na kumakatawan sa ranggo ng numero sa B5.

Napupunta ang ranggo sa row_num argument ng INDEX function , at pinipili nito ang halaga mula sa kaukulang row (ang column_num argument ay tinanggal, kaya ito ay nagde-default sa 1). Ito ang dahilan kung bakit napakahalagang maiwasan ang duplicate na ranggo. Kung hindi dahil sa function na COUNTIF, magbubunga ang RANK.EQ ng 1 para sa parehong B2 at B5, na magiging dahilan upang maibalik ng INDEX ang halaga mula sa unang row (Andrew) nang dalawang beses.

Paano pigilan ang pagbabago ng random na sample ng Excel.

Dahil ang lahat ng randomizing function sa Excel gaya ng RAND, RANDBETWEEN at RANDARRAY ay pabagu-bago, muling kinakalkula ang mga ito sa bawat pagbabago sa worksheet. Bilang resulta, ang iyong random na sample ay patuloy na magbabago. Upang maiwasang mangyari ito, gamitin ang Paste Special > Nagtatampok ang mga value upang palitan ang mga formula ng mga static na halaga. Para dito, isagawa ang mga hakbang na ito:

1. Piliin ang lahat ng mga cell gamit ang iyong formula (anumang formula na naglalaman ng RAND, RANDBETWEEN o RANDARRAY function) at pindutin ang Ctrl + C upang kopyahin ang mga ito.
2. I-right click ang napiling hanay at i-click ang I-paste ang Espesyal > Mga Value . Bilang kahalili, pindutin ang Shift + F10 at pagkatapos ay ang V , na siyang shortcut para sa nabanggit na feature.

Para sa mga detalyadong hakbang, pakitingnan ang Paano mag-convert ng mga formula sa mga value sa Excel.

Excel random selection: mga row, columno mga cell

Gumagana sa lahat ng bersyon ng Excel 365 hanggang Excel 2010.

Kung naka-install ang aming Ultimate Suite sa iyong Excel, maaari kang gumawa ng random sampling gamit ang isang pag-click ng mouse sa halip na isang formula. Ganito:

1. Sa tab na Ablebits Tools , i-click ang Randomize > Select Randomly .
2. Piliin ang hanay kung saan mo gustong pumili ng sample.
3. Sa pane ng add-in, gawin ang sumusunod:
   • Piliin kung gusto mong pumili ng mga random na row, column, o cell.
   • Tukuyin ang laki ng sample: maaaring porsyento o numero iyon.
   • I-click ang button na Piliin .

Iyon ay ito! Gaya ng ipinapakita sa larawan sa ibaba, direktang pinili ang isang random na sample sa iyong set ng data. Kung gusto mo itong kopyahin sa isang lugar, pindutin lang ang isang regular na shortcut sa pagkopya (Ctrl + C) .

Ganito ang pumili ng random na sample sa Excel nang walang mga duplicate. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

Random na sample na walang mga duplicate - mga halimbawa ng formula (.xlsx file)

Ultimate Suite 14 na araw na ganap na gumaganang bersyon (.exe file)