Tutorial museurkeun kana cara ngalakukeun sampling acak dina Excel tanpa ulangan. Anjeun bakal mendakan solusi pikeun Excel 365, Excel 2021, Excel 2019 sareng versi sateuacana.

Sakedap ka tukang, kami ngajelaskeun sababaraha cara pikeun milih sacara acak dina Excel. Seuseueurna solusi éta ngandelkeun fungsi RAND sareng RANDBETWEEN, anu tiasa ngahasilkeun angka duplikat. Akibatna, sampel acak Anjeun bisa ngandung nilai repeating. Upami anjeun peryogi pilihan acak tanpa duplikat, teras nganggo pendekatan anu dijelaskeun dina tutorial ieu.

Excel pilihan acak tina daptar tanpa duplikat

Ngan dianggo dina Excel 365 jeung Excel 2021 nu ngarojong susunan dinamis.

Pikeun nyieun pilihan acak tina daptar nu taya ulangan, paké rumus umum ieu:

Dimana n mangrupa ukuran pilihan nu dipikahoyong.

Contona, pikeun meunangkeun 5 ngaran acak unik tina daptar di A2:A10, ieu rumus pikeun dipaké:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Demi genah, Anjeun bisa ngasupkeun ukuran sampel dina a sél nu geus ditangtukeun, sebutkeun C2, sarta nyadiakeun rujukan sél ka fungsi SEQUENCE:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Kumaha rumus ieu jalan:

Ieu katerangan tingkat luhur ngeunaan logika rumus: fungsi RANDARRAY nyiptakeun susunan angka acak, SORTBY nyortir nilai aslina dumasar kana angka-angka éta, sarta INDEX retrieves saloba nilai salakuditetepkeun ku SEQUENCE.

Ringkesan lengkepna kieu:

Fungsi ROWS ngitung sabaraha baris set data anjeun ngandung sarta ngalirkeun count ka fungsi RANDARRAY, jadi bisa ngahasilkeun jumlah nu sarua decimals acak:

RANDARRAY(ROWS(A2:C10))

Array desimal acak ieu dipaké salaku array "sort by" ku fungsi SORTBY. Hasilna, data asli anjeun diacak sacara acak.

Tina data anu diurutkeun sacara acak, anjeun nimba sampel tina ukuran husus. Jang ngalampahkeun ieu, anjeun nyadiakeun Asép Sunandar Sunarya shuffled kana fungsi INDEX sarta ménta pikeun meunangkeun nilai N munggaran kalayan bantuan fungsi SEQUENCE, nu ngahasilkeun runtuyan angka ti 1 nepi ka N . Kusabab data aslina tos diurutkeun sacara acak, kami henteu paduli posisi mana anu badé dicandak, ngan ukur kuantitas anu penting.

Pilih baris acak dina Excel tanpa duplikat

Ngan jalanna. dina Excel 365 jeung Excel 2021 nu ngarojong susunan dinamis.

Pikeun milih baris acak tanpa ulangan, jieun rumus ku cara kieu:

Dimana n nyaéta ukuran sampel jeung {1,2,…} nyaéta nomer kolom pikeun diekstrak.

Salaku conto, hayu urang milih baris acak tina A2:C10 tanpa éntri duplikat, dumasar kana ukuran sampel dina F1. Kusabab data kami aya dina 3 kolom, kami nyayogikeun konstanta ieu kana rumus:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

Jeung meunang hasil kieu:

Kumaha rumus ieu jalan:

Rumusna dianggo kalayan logika anu sami sareng anu sateuacana. Parobahan leutik nu ngajadikeun bédana badag nyaéta yén anjeun nangtukeun duanana argumen row_num jeung column_num pikeun fungsi INDEX: row_num disadiakeun ku SEQUENCE jeung column_num ku konstanta array.

Kumaha ngalakukeun sampling acak dina Excel 2010 - 2019

Salaku ngan Excel pikeun Microsoft 365 jeung Excel 2021 ngarojong arrays dinamis, fungsi array dinamis dipaké dina conto samemehna ngan bisa dipake dina Excel 365. Pikeun vérsi séjén, anjeun bakal kudu néangan solusi béda.

Anggap anjeun hoyong pilihan acak tina daptar di A2:A10. Ieu bisa dilakukeun ku 2 rumus misah:

1. Jieun angka acak ku rumus Rand. Dina kasus urang, urang lebetkeun kana B2, lajeng nyalin ka handap ka B10:

   =RAND()

2. Ekstrak nilai acak munggaran kalayan rumus di handap, nu anjeun lebetkeun dina E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Salin rumus di luhur ka saloba sél saloba nilai acak nu Anjeun hoyong pilih. Dina conto ieu, urang hoyong 4 ngaran, jadi urang nyalin rumus ti E2 ngaliwatan E5.

Rengse! Sampel acak kami tanpa duplikat katingalina kieu:

Kumaha rumus ieu jalanna:

Sapertos dina conto kahiji, anjeun nganggo Fungsi INDEX pikeun meunangkeun nilai tina kolom A dumasar kana baris acakangka. Bédana nyaéta kumaha anjeun kéngingkeun angka-angka éta:

Fungsi RAND ngeusian rentang B2:B10 ku desimal acak.

Fungsi RANK.EQ ngitung pangkat hiji angka acak dina hiji angka. baris. Contona, dina E2, RANK.EQ (B2, $ B $ 2: $ B $ 10) urutan angka dina B2 ngalawan sakabéh angka dina B2: B10. Lamun disalin ka E3, référénsi rélatif B2 robah jadi B3 sarta mulangkeun pangkat angka dina B3, jeung saterusna.

Pungsi COUNTIF manggihan sabaraha kali kajadian tina hiji angka nu tangtu aya dina sél di luhur. Contona, dina E2, COUNTIF ($ B $ 2: B2, B2) mariksa ngan hiji sél - B2 sorangan, sarta mulih 1. Dina E5, rumus robah jadi COUNTIF ($ B $ 2: B5, B5) sarta mulih 2, sabab. B5 ngandung nilai anu sami sareng B2 (punten perhatikeun, ieu ngan ukur pikeun ngajelaskeun logika rumus anu langkung saé; dina set data leutik, kasempetan pikeun kéngingkeun nomer acak duplikat caket kana nol).

Hasilna, pikeun sadayana. Kajadian kahiji, COUNTIF ngabalikeun 1, dimana anjeun ngirangan 1 pikeun ngajaga peringkat asli. Pikeun kajadian ka-2, COUNTIF ngabalikeun 2. Ku ngirangan 1, anjeun ningkatkeun rangking ku 1, ku kituna nyegah rangking duplikat.

Contona, pikeun B2, RANK.EQ ngabalikeun 1. Kusabab ieu mangrupikeun kajadian anu munggaran, COUNTIF ogé mulih 1. RANK.EQ + COUNTIF méré 2. Jeung - 1 restores rank 1.

Ayeuna, tingali naon kajadian bisi kajadian 2nd. Pikeun B5, RANK.EQ ogé ngabalikeun 1 sedengkeun COUNTIF ngabalikeun 2. Nambahkeun ieu masihan3, dimana anjeun ngirangan 1. Salaku hasil ahir, anjeun nampi 2, anu ngagambarkeun pangkat nomer dina B5.

Pangkatna nuju kana argumen row_num fungsi INDEX. , sarta nyokot nilai tina baris pakait (nu column_num argumen disingkahkeun, jadi ingkar 1). Ieu alesan naha éta jadi penting pikeun nyingkahan duplikat ranking. Upami sanés pikeun fungsi COUNTIF, RANK.EQ bakal ngahasilkeun 1 pikeun B2 sareng B5, nyababkeun INDEX ngabalikeun nilai ti baris kahiji (Andrew) dua kali.

Kumaha carana nyegah sampel acak Excel tina robih

Kusabab sadaya fungsi ngaramekeun dina Excel sapertos RAND, RANDBETWEEN sareng RANDARRAY teu stabil, aranjeunna ngitung deui unggal parobahan dina lembar kerja. Hasilna, sampel acak anjeun bakal terus-terusan robih. Pikeun nyegah ieu lumangsung, ngagunakeun Témpél husus & GT; Nilai fitur pikeun ngaganti rumus ku nilai statik. Jang ngalampahkeun ieu, laksanakeun léngkah-léngkah ieu:

1. Pilih sadaya sél nganggo rumus anjeun (rumus naon waé anu ngandung fungsi RAND, RANDBETWEEN atanapi RANDARRAY) teras pencét Ctrl + C pikeun nyalinna.
2. Klik katuhu dina rentang nu dipilih teras klik Tempelkeun Husus > Nilai . Alternatipna, pencét Shift + F10 terus V , nu mangrupakeun potong kompas pikeun fitur nu disebutkeun di luhur.

Pikeun léngkah-léngkah nu lengkep, mangga tingali Cara ngarobah rumus kana nilai dina Excel.

Pilihan acak Excel: baris, kolomatawa sél

Gawe dina sakabéh vérsi Excel 365 nepi ka Excel 2010.

Lamun anjeun geus dipasang Ultimate Suite di Excel anjeun, mangka anjeun bisa ngalakukeun random sampling ku klik mouse tinimbang rumus. Kieu carana:

1. Dina tab Ablebits Tools , klik Acak > Pilih Acak .
2. Pilih rentang ti mana Anjeun hoyong milih sampel.
3. Dina panel add-in, lakukeun ieu:
   • Pilih naha anjeun hoyong milih baris acak, kolom, atanapi sél.
   • Tetepkeun ukuran sampel: nu bisa mangrupa persentase atawa angka.
   • Klik tombol Pilih .

Éta ieu! Ditémbongkeun saperti dina gambar di handap ieu, sampel acak dipilih langsung dina set data Anjeun. Upami anjeun hoyong nyalin dimana waé, pencét potong kompas salinan biasa (Ctrl + C) .

Kukituna cara milih sampel acak dina Excel tanpa duplikat. Kuring hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali anjeun dina blog kami minggu payun!

Sadia undeuran

Sampel acak tanpa duplikat - conto rumus (.xlsx file)

Ultimate Suite 14 poé Vérsi fungsi pinuh (file .exe)