Kennslan fjallar um hvernig á að gera slembiúrtak í Excel án endurtekningar. Þú finnur lausnir fyrir Excel 365, Excel 2021, Excel 2019 og fyrri útgáfur.

Fyrir nokkru síðan lýstum við nokkrum mismunandi leiðum til að velja af handahófi í Excel. Flestar þessar lausnir treysta á RAND og RANDBETWEEN aðgerðirnar, sem geta myndað afrit af tölum. Þar af leiðandi gæti slembiúrtakið innihaldið endurtekin gildi. Ef þú þarft handahófsval án afrita, notaðu þá aðferðirnar sem lýst er í þessari kennslu.

Excel handahófsval af lista án afrita

Virkar aðeins í Excel 365 og Excel 2021 sem styðja kraftmikla fylki.

Til að velja af handahófi af lista án endurtekningar, notaðu þessa almennu formúlu:

Þar sem n er æskileg valstærð.

Til dæmis, til að fá 5 einstök tilviljunarkennd nöfn af listanum í A2:A10, hér er formúlan sem á að nota:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Til þæginda geturðu sett inn sýnishornið í fyrirfram skilgreindan reit, segjum C2, og gefðu reittilvísunina í RAÐA fallið:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Hvernig þessi formúla virkar:

Hér er skýring á háu stigi á rökfræði formúlunnar: RANDARRAY aðgerðin býr til fylki af handahófskenndum tölum, SORTBY flokkar upprunalegu gildin eftir þeim tölum og INDEX sækir eins mörg gildi ogtilgreint af RÖÐU.

Nákvæm sundurliðun fylgir hér að neðan:

ROWS aðgerðin telur hversu margar raðir gagnasettið þitt inniheldur og sendir talninguna til RANDARRAY fallsins, svo það getur myndað sama fjölda af handahófskenndir aukastafir:

RANDARRAY(ROWS(A2:C10))

Þessi fylking af handahófi aukastafa er notuð sem "raða eftir" fylki með SORTBY fallinu. Afleiðingin er sú að upprunalegu gögnunum þínum er stokkað af handahófi.

Úr handahófsröðuðu gögnunum dregur þú út sýnishorn af ákveðinni stærð. Fyrir þetta gefur þú stokkaða fylkinu í INDEX fallið og biður um að sækja fyrstu N gildin með hjálp SEQUENCE fallsins, sem framleiðir talnaröð frá 1 til N . Vegna þess að upprunalegu gögnin eru þegar flokkuð í handahófskenndri röð er okkur alveg sama hvaða stöður á að sækja, aðeins magnið skiptir máli.

Veldu handahófskenndar línur í Excel án afrita

Virkar aðeins. í Excel 365 og Excel 2021 sem styðja kraftmikla fylki.

Til að velja handahófskenndar línur án endurtekningar skaltu búa til formúlu á þennan hátt:

Þar sem n er úrtaksstærðin og {1,2,…} eru dálknúmer til að draga út.

Sem dæmi skulum við velja handahófskenndar línur úr A2:C10 án tvítekinna færslu, byggt á úrtaksstærðinni í F1. Þar sem gögnin okkar eru í 3 dálkum, gefum við þennan fylkisfasta í formúluna:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

Og fáðu eftirfarandi niðurstöðu:

Hvernig þessi formúla virkar:

Formúlan virkar með nákvæmlega sömu rökfræði og sú fyrri. Lítil breyting sem skiptir miklu máli er að þú tilgreinir bæði röð_númer og dálkurnúmer fyrir INDEX fallið: röð_númer er gefið af SEQUENCE og column_num við fylkisfastann.

Hvernig á að gera slembiúrtak í Excel 2010 - 2019

Þar sem aðeins Excel fyrir Microsoft 365 og Excel 2021 styður kvik fylki, þá eru kvik fylkisföll sem notuð eru í fyrri dæmin virka aðeins í Excel 365. Fyrir aðrar útgáfur þarftu að finna aðra lausn.

Svo sem þú vilt valið af handahófi af listanum í A2:A10. Þetta er hægt að gera með 2 aðskildum formúlum:

1. Búa til handahófskenndar tölur með Rand formúlunni. Í okkar tilviki sláum við það inn í B2 og afritum síðan niður í B10:

   =RAND()

2. Dregið út fyrsta handahófskennda gildið með formúlunni hér að neðan, sem þú slærð inn í E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Afritaðu formúluna hér að ofan í eins margar hólf og mörg handahófskennd gildi sem þú vilt velja. Í þessu dæmi viljum við 4 nöfn, svo við afritum formúluna frá E2 í gegnum E5.

Lokið! Slembiúrtakið okkar án afrita lítur svona út:

Hvernig þessi formúla virkar:

Eins og í fyrsta dæminu notarðu INDEX fall til að sækja gildi úr dálki A byggt á handahófskenndri röðtölur. Munurinn er í því hvernig þú færð þessar tölur:

RAND fallið fyllir bilið B2:B10 með handahófskenndum aukastöfum.

RANK.EQ fallið reiknar stöðu slembitölu í tiltekinni röð. Til dæmis, í E2, rankar RANK.EQ(B2, $B$2:$B$10) tölunni í B2 á móti öllum tölunum í B2:B10. Þegar það er afritað í E3 breytist hlutfallsleg tilvísun B2 í B3 og skilar stöðu tölunnar í B3, og svo framvegis.

FALLA fallið finnur hversu mörg tilvik tiltekinnar tölu eru í ofangreindum hólfum. Til dæmis, í E2, athugar COUNTIF($B$2:B2, B2) aðeins einn reit - B2 sjálfan og skilar 1. Í E5 breytist formúlan í COUNTIF($B$2:B5, B5) og skilar 2, vegna þess að B5 inniheldur sama gildi og B2 (vinsamlega athugið að þetta er aðeins til að útskýra betur rökfræði formúlunnar; á litlu gagnasafni eru líkurnar á að fá tvíteknar handahófskenndar tölur nálægt núlli).

Svo sem afleiðing, fyrir alla 1. tilvik, COUNTIF skilar 1, sem þú dregur 1 frá til að halda upprunalegri röðun. Fyrir 2. tilvik skilar COUNTIF 2. Með því að draga frá 1 hækkarðu röðunina um 1 og kemur þannig í veg fyrir tvítekna röð.

Til dæmis, fyrir B2, RANK.EQ skilar 1. Þar sem þetta er fyrsta tilvikið, COUNTIF einnig skilar 1. RANK.EQ + COUNTIF gefur 2. Og - 1 endurheimtir stöðu 1.

Sjáðu nú hvað gerist ef um 2. tilvikið er að ræða. Fyrir B5 skilar RANK.EQ einnig 1 á meðan COUNTIF skilar 2. Ef þetta er lagt saman gefur3, sem þú dregur 1 frá. Sem lokaniðurstaða færðu 2, sem táknar stöðu tölunnar í B5.

Röðin fer í row_num rökin í INDEX fallinu , og það velur gildið úr samsvarandi röð ( dálkur_númer breytunni er sleppt, þannig að það er sjálfgefið 1). Þetta er ástæðan fyrir því að það er svo mikilvægt að forðast tvítekna röðun. Ef það væri ekki fyrir COUNTIF fallið myndi RANK.EQ gefa 1 fyrir bæði B2 og B5, sem veldur því að INDEX skilar gildinu úr fyrstu röðinni (Andrew) tvisvar.

Hvernig á að koma í veg fyrir að Excel slembiúrtak breytist

Þar sem allar slembivalsaðgerðir í Excel eins og RAND, RANDBETWEEN og RANDARRAY eru sveiflukenndar, endurreikna þær við hverja breytingu á vinnublaðinu. Fyrir vikið mun slembiúrtakið þitt breytast stöðugt. Til að koma í veg fyrir að þetta gerist skaltu nota Paste Special > Gildi lögun til að skipta út formúlum með kyrrstæðum gildum. Til þess skaltu framkvæma þessi skref:

1. Veldu allar frumurnar með formúlunni þinni (hverja formúlu sem inniheldur RAND, RANDBETWEEN eða RANDARRAY fall) og ýttu á Ctrl + C til að afrita þær.
2. Hægrismelltu á valið svið og smelltu á Paste Special > Values . Að öðrum kosti, ýttu á Shift + F10 og svo V , sem er flýtileið fyrir ofangreindan eiginleika.

Fyrir ítarleg skref, vinsamlegast sjáðu Hvernig á að umbreyta formúlum í gildi í Excel.

Excel handahófsval: raðir, dálkareða frumur

Virkar í öllum útgáfum af Excel 365 til og með Excel 2010.

Ef þú ert með Ultimate Suite uppsetta í Excel, þá geturðu gert slembisýni með a. músarsmellur í stað formúlu. Svona er það:

1. Á flipanum Ablebits Tools , smelltu á Slembiraðað > Veldu af handahófi .
2. Veldu sviðið sem þú vilt velja sýnishorn úr.
3. Á glugganum í viðbótinni skaltu gera eftirfarandi:
   • Veldu hvort þú vilt velja handahófskenndar línur, dálka eða reiti.
   • Tilgreindu úrtaksstærðina: það getur verið prósenta eða tala.
   • Smelltu á hnappinn Veldu .

Það er það! Eins og sést á myndinni hér að neðan er slembiúrtak valið beint í gagnasafnið þitt. Ef þú vilt afrita það einhvers staðar, ýttu bara á venjulegan afritunarflýtileið (Ctrl + C) .

Svona á að velja slembiúrtak í Excel án afrita. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Laust niðurhal

Slembisýni án afrita - formúludæmi (.xlsx skrá)

Ultimate Suite 14 daga fullvirk útgáfa (.exe skrá)