이 튜토리얼은 반복 없이 Excel에서 무작위 샘플링을 수행하는 방법에 중점을 둡니다. Excel 365, Excel 2021, Excel 2019 및 이전 버전에 대한 솔루션을 찾을 수 있습니다.

얼마 전에 Excel에서 무작위로 선택하는 몇 가지 방법을 설명했습니다. 이러한 솔루션의 대부분은 중복 번호를 생성할 수 있는 RAND 및 RANDBETWEEN 함수에 의존합니다. 결과적으로 무작위 샘플에 반복 값이 포함될 수 있습니다. 중복 없이 임의 선택이 필요한 경우 이 자습서에 설명된 접근 방식을 사용하십시오.

중복 없이 목록에서 Excel 임의 선택

다음에서만 작동합니다. 동적 배열을 지원하는 Excel 365 및 Excel 2021.

반복 없이 목록에서 임의로 선택하려면 다음 일반 수식을 사용하세요.

여기서 n 는 원하는 선택 크기입니다.

예를 들어, A2:A10의 목록에서 5개의 고유한 임의 이름을 얻으려면 사용할 수식은 다음과 같습니다.

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

편의를 위해 샘플 크기를 미리 정의된 셀(예: C2) 및 SEQUENCE 함수에 대한 셀 참조를 제공합니다.

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

이 수식 작동 방식:

다음은 수식의 논리에 대한 높은 수준의 설명입니다. RANDARRAY 함수는 난수 배열을 생성하고 SORTBY는 해당 숫자를 기준으로 원래 값을 정렬하며 INDEX는 가능한 한 많은 값을 검색합니다.SEQUENCE에 의해 지정됩니다.

자세한 분석은 다음과 같습니다.

ROWS 함수는 데이터 세트에 포함된 행 수를 세고 그 수를 RANDARRAY 함수에 전달하므로 동일한 수의 행을 생성할 수 있습니다. 임의 소수점:

RANDARRAY(ROWS(A2:C10))

이 임의 소수점 배열은 SORTBY 함수에서 "정렬 기준" 배열로 사용됩니다. 그 결과 원본 데이터가 무작위로 섞입니다.

임의로 정렬된 데이터에서 특정 크기의 샘플을 추출합니다. 이를 위해 뒤섞인 배열을 INDEX 함수에 제공하고 SEQUENCE 함수의 도움으로 첫 번째 N 값을 검색하도록 요청합니다. 이 함수는 1에서 N 까지의 숫자 시퀀스를 생성합니다. . 원본 데이터는 이미 임의 순서로 정렬되어 있기 때문에 검색할 위치는 신경 쓰지 않고 수량만 중요합니다.

Excel에서 중복 없이 임의 행 선택

작동만 가능 동적 배열을 지원하는 Excel 365 및 Excel 2021에서.

반복 없이 임의의 행을 선택하려면 다음과 같은 방식으로 수식을 작성합니다.

여기서 n 는 샘플 크기이고 {1,2,…}는 추출할 열 번호입니다.

예를 들어 F1의 샘플 크기를 기준으로 A2:C10에서 중복 항목이 없는 행을 임의로 선택해 보겠습니다. 데이터가 3열에 있으므로 이 배열 상수를 수식에 제공합니다.{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

결과는 다음과 같습니다.

이 공식의 작동 방식:

이 공식은 이전 공식과 완전히 동일한 논리로 작동합니다. 큰 차이를 만드는 작은 변화는 INDEX 함수에 대해 row_num 및 column_num 인수를 모두 지정한다는 것입니다. row_num 은 SEQUENCE 및 에서 제공됩니다. column_num 배열 상수로.

Excel 2010 - 2019에서 무작위 샘플링을 수행하는 방법

Excel for Microsoft 365 및 Excel 2021에서만 동적 배열을 지원하므로 동적 배열 함수는 앞의 예는 Excel 365에서만 작동합니다. 다른 버전의 경우 다른 솔루션을 찾아야 합니다.

A2:A10의 목록에서 임의로 선택한다고 가정합니다. 이것은 2개의 별도 수식을 사용하여 수행할 수 있습니다.

1. Rand 수식을 사용하여 난수를 생성합니다. 우리의 경우 B2에 입력한 다음 B10에 복사합니다.

   =RAND()

2. 아래 공식을 사용하여 첫 번째 임의의 값을 추출합니다. E2에 입력합니다.

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. 선택하려는 임의의 값만큼 위의 수식을 셀에 복사합니다. 이 예에서는 4개의 이름이 필요하므로 E2에서 E5까지 수식을 복사합니다.

완료! 중복이 없는 임의 샘플은 다음과 같습니다.

이 공식 작동 방식:

첫 번째 예와 마찬가지로 임의의 행을 기반으로 열 A에서 값을 검색하는 INDEX 함수번호. 차이점은 이러한 숫자를 얻는 방법에 있습니다.

RAND 함수는 B2:B10 범위를 임의의 소수점으로 채웁니다.

RANK.EQ 함수는 주어진 범위에서 임의의 숫자 순위를 계산합니다. 열. 예를 들어, E2에서 RANK.EQ(B2, $B$2:$B$10)는 B2:B10의 모든 숫자에 대해 B2의 숫자 순위를 매깁니다. E3에 복사하면 상대 참조 B2가 B3으로 변경되고 B3에 있는 숫자의 순위를 반환하는 식으로 계속됩니다.

COUNTIF 함수는 위의 셀에 지정된 숫자가 몇 번 나타나는지 찾습니다. 예를 들어, E2에서 COUNTIF($B$2:B2, B2)는 하나의 셀(B2 자체)만 확인하고 1을 반환합니다. E5에서 수식은 COUNTIF($B$2:B5, B5)로 변경되고 2를 반환합니다. B5는 B2와 동일한 값을 포함합니다(참고: 이것은 수식의 논리를 더 잘 설명하기 위한 것입니다. 작은 데이터 세트에서는 중복 난수를 얻을 확률이 0에 가깝습니다.)

결과적으로 모든 첫 번째 발생, COUNTIF는 1을 반환하고 여기서 1을 빼서 원래 순위를 유지합니다. 두 번째 발생의 경우 COUNTIF는 2를 반환합니다. 1을 빼면 순위가 1씩 증가하므로 중복 순위가 방지됩니다.

예를 들어 B2의 경우 RANK.EQ는 1을 반환합니다. 이것이 첫 번째 발생이므로 COUNTIF도 RANK.EQ + COUNTIF는 2를 반환하고 - 1은 순위를 1로 복원합니다. B5의 경우 RANK.EQ도 1을 반환하고 COUNTIF는 2를 반환합니다. 이들을 더하면 다음과 같습니다.3에서 1을 뺍니다. 최종 결과는 B5에 있는 숫자의 순위를 나타내는 2가 됩니다.

순위는 INDEX 함수의 row_num 인수로 이동합니다. , 해당 행에서 값을 선택합니다( column_num 인수가 생략되었으므로 기본값은 1임). 이것이 중복 순위를 피하는 것이 중요한 이유입니다. COUNTIF 함수가 아닌 경우 RANK.EQ는 B2와 B5 모두에 대해 1을 생성하여 INDEX가 첫 번째 행(Andrew)의 값을 두 번 반환하도록 합니다.

Excel 임의 샘플이 변경되지 않도록 하는 방법

RAND, RANDBETWEEN 및 RANDARRAY와 같은 Excel의 모든 무작위 함수는 휘발성이므로 워크시트가 변경될 때마다 다시 계산됩니다. 결과적으로 임의 샘플은 지속적으로 변경됩니다. 이를 방지하려면 선택하여 붙여넣기 > 수식을 정적 값으로 대체하는 값 기능. 이를 위해 다음 단계를 수행합니다.

1. 수식이 있는 모든 셀(RAND, RANDBETWEEN 또는 RANDARRAY 함수를 포함하는 수식)을 선택하고 Ctrl + C를 눌러 복사합니다.
2. 선택한 범위를 마우스 오른쪽 버튼으로 클릭하고 선택하여 붙여넣기 > 값 을 클릭합니다. 또는 위에서 언급한 기능의 단축키인 Shift + F10을 누른 다음 V를 누릅니다.

자세한 단계는 Excel에서 수식을 값으로 변환하는 방법을 참조하세요.

Excel 무작위 선택: 행, 열or cells

Excel 365부터 Excel 2010까지 모든 버전에서 작동합니다.

Ultimate Suite가 Excel에 설치되어 있는 경우 수식 대신 마우스 클릭. 방법은 다음과 같습니다.

1. Ablebits 도구 탭에서 무작위화 > 무작위로 선택 을 클릭합니다.
2. 선택 샘플을 선택하려는 범위.
3. 추가 기능 창에서 다음을 수행합니다.
   • 임의의 행, 열 또는 셀을 선택할지 여부를 선택합니다.
   • 샘플 크기 정의: 백분율 또는 숫자일 수 있습니다.
   • 선택 버튼을 클릭합니다.

즉, 그것! 아래 이미지와 같이 임의 샘플이 데이터 세트에서 직접 선택됩니다. 어딘가에 복사하고 싶다면 일반 복사 단축키(Ctrl + C)를 누르기만 하면 됩니다. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙기를 바랍니다!

사용 가능한 다운로드

중복 없는 무작위 샘플 - 수식 예제(.xlsx 파일)

Ultimate Suite 14일 정식 버전(.exe 파일)