La lernilo fokusiĝas pri kiel fari hazardan specimenigon en Excel sen ripetoj. Vi trovos solvojn por Excel 365, Excel 2021, Excel 2019 kaj pli fruaj versioj.

Antaŭ iom da tempo, ni priskribis kelkajn malsamajn manierojn por hazarde elekti en Excel. La plej multaj el tiuj solvoj dependas de la funkcioj RAND kaj RANDBETWEEN, kiuj povas generi duplikatajn nombrojn. Sekve, via hazarda specimeno povus enhavi ripetantajn valorojn. Se vi bezonas hazardan elekton sen duplikatoj, tiam uzu la metodojn priskribitajn en ĉi tiu lernilo.

Excel hazarda elekto el listo sen duplikatoj

Nur funkcias en Excel 365 kaj Excel 2021, kiuj subtenas dinamikajn tabelojn.

Por fari hazardan elekton el listo sen ripetoj, uzu ĉi tiun ĝeneralan formulon:

Kie n estas la dezirata elektograndeco.

Ekzemple, por akiri 5 unikajn hazardajn nomojn el la listo en A2:A10, jen la formulo por uzi:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Por komforto, vi povas enigi la specimenan grandecon en antaŭdifinita ĉelo, diru C2, kaj liveru la ĉelan referencon al la SEQUENCE-funkcio:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Kiel ĉi tiu formulo funkcias:

Jen altnivela klarigo pri la logiko de la formulo: la funkcio RANDARRAY kreas tabelon de hazardaj nombroj, SORTBY ordigas la originalajn valorojn laŭ tiuj nombroj, kaj INDEX retrovas tiom da valoroj kiomspecifita de SEQUENCE.

Detala difekto sekvas sube:

La funkcio ROWS kalkulas kiom da vicoj enhavas via datumaro kaj pasas la kalkulon al la funkcio RANDARRAY, do ĝi povas generi la saman nombron da hazardaj decimaloj:

RANDARRAY(ROWS(A2:C10))

Tiu ĉi tabelo de hazardaj decimaloj estas uzata kiel la tabelo "ordigi laŭ" per la funkcio SORTBY. Kiel rezulto, viaj originaj datumoj estas miksitaj hazarde.

El la hazarde ordigitaj datumoj, vi ĉerpas specimenon de specifa grandeco. Por tio, vi provizas la miksitan tabelon al la INDEX-funkcio kaj petas retrovi la unuajn N -valorojn helpe de la SEQUENCE-funkcio, kiu produktas sinsekvon de nombroj de 1 ĝis N . . Ĉar la originaj datumoj jam estas ordigitaj en hazarda ordo, ni vere ne zorgas pri kiuj pozicioj repreni, nur la kvanto gravas.

Elektu hazardajn vicojn en Excel sen duplikatoj

Nur funkcias. en Excel 365 kaj Excel 2021, kiuj subtenas dinamikajn tabelojn.

Por elekti hazardajn vicojn sen ripetoj, konstruu formulon tiamaniere:

Kie n estas la specimena grandeco kaj {1,2,...} estas kolumnombroj por ĉerpi.

Ekzemple, ni elektu hazardajn vicojn el A2:C10 sen duplikataj enskriboj, surbaze de la specimena grandeco en F1. Ĉar niaj datumoj estas en 3 kolumnoj, ni provizas ĉi tiun tabelkonstanton al la formulo:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

Kaj ricevu la sekvan rezulton:

Kiel funkcias ĉi tiu formulo:

La formulo funkcias ĝuste kun la sama logiko kiel la antaŭa. Malgranda ŝanĝo, kiu faras grandan diferencon, estas, ke vi specifas ambaŭ la argumentojn row_num kaj column_num por la INDEX-funkcio: row_num estas liverita de SEQUENCE kaj column_num per la tabelkonstanto.

Kiel fari hazardan specimenigon en Excel 2010 - 2019

Ĉar nur Excel por Microsoft 365 kaj Excel 2021 subtenas dinamikajn tabelojn, la dinamikaj tabelaj funkcioj uzataj en la antaŭaj ekzemploj funkcias nur en Excel 365. Por aliaj versioj, vi devos ellabori alian solvon.

Supoze, ke vi volas hazardan elekton el la listo en A2:A10. Ĉi tio povas esti farita per 2 apartaj formuloj:

1. Generu hazardajn nombrojn per la Rand-formulo. En nia kazo, ni enigas ĝin en B2, kaj poste kopiu malsupren al B10:

   =RAND()

2. Eltiru la unuan hazardan valoron per la suba formulo, kiun vi enigas en E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Kopiu la supran formulon al tiom da ĉeloj kiom da hazardaj valoroj vi volas elekti. En ĉi tiu ekzemplo, ni volas 4 nomojn, do ni kopias la formulon de E2 ĝis E5.

Fine! Nia hazarda specimeno sen duplikatoj aspektas jene:

Kiel ĉi tiu formulo funkcias:

Kiel en la unua ekzemplo, vi uzas la INDEX-funkcio por preni valorojn de kolumno A bazita sur hazarda viconombroj. La diferenco estas en kiel vi ricevas tiujn nombrojn:

La funkcio RAND plenigas la intervalon B2:B10 per hazardaj decimaloj.

La funkcio RANK.EQ kalkulas la rangon de hazarda nombro en donita. vico. Ekzemple, en E2, RANK.EQ(B2, $B$2:$B$10) rangigas la nombron en B2 kontraŭ ĉiuj nombroj en B2:B10. Kopiite al E3, la relativa referenco B2 ŝanĝas al B3 kaj redonas la rangon de la nombro en B3, kaj tiel plu.

La funkcio COUNTIF trovas kiom da aperoj de donita nombro estas en la supraj ĉeloj. Ekzemple, en E2, COUNTIF($B$2:B2, B2) kontrolas nur unu ĉelon - B2 mem, kaj liveras 1. En E5, la formulo ŝanĝiĝas al COUNTIF($B$2:B5, B5) kaj redonas 2, ĉar B5 enhavas la saman valoron kiel B2 (bonvolu noti, tio estas nur por pli bone klarigi la logikon de la formulo; sur malgranda datumaro, ŝancoj akiri duplikatajn hazardajn nombrojn estas proksimaj al nulo).

Kiel rezulto, por ĉiuj Unuaj okazoj, COUNTIF liveras 1, el kiu vi subtrahas 1 por konservi la originalan rangon. Por 2-a okazoj, COUNTIF donas 2. Subtrahante 1, vi pliigas la rangon je 1, tiel malhelpante duplikatajn rangojn.

Ekzemple, por B2, RANK.EQ donas 1. Ĉar ĉi tiu estas la unua okazo, COUNTIF ankaŭ donas 1. RANK.EQ + COUNTIF donas 2. Kaj - 1 restarigas la rangon 1.

Nun, vidu kio okazas en kazo de la 2-a okazo. Por B5, RANK.EQ ankaŭ donas 1 dum COUNTIF donas 2. Aldonante ĉi tiujn donas3, el kiu vi subtrahas 1. Kiel la fina rezulto, vi ricevas 2, kiu reprezentas la rangon de la nombro en B5.

La rango iras al la argumento row_num de la INDEX-funkcio. , kaj ĝi elektas la valoron el la responda vico (la argumento column_num estas ellasita, do ĝi defaŭlte estas 1). Ĉi tio estas la kialo, kial estas tiel grave eviti duoblan rangon. Se ĝi ne estus por la COUNTIF-funkcio, RANK.EQ donus 1 por kaj B2 kaj B5, igante INDEX resendi la valoron de la unua vico (Andreo) dufoje.

Kiel malhelpi Excel hazarda specimeno ŝanĝiĝi.

Ĉar ĉiuj hazardaj funkcioj en Excel kiel RAND, RANDBETWEEN kaj RANDARRAY estas volatilaj, ili rekalkulas kun ĉiu ŝanĝo en la laborfolio. Kiel rezulto, via hazarda specimeno senĉese ŝanĝiĝos. Por eviti ke tio okazu, uzu la Specialan Alglui > Valoroj prezentas por anstataŭigi formulojn per senmovaj valoroj. Por tio, faru ĉi tiujn paŝojn:

1. Elektu ĉiujn ĉelojn kun via formulo (iu ajn formulo enhavanta funkcion RAND, RANDBETWEEN aŭ RANDARRAY) kaj premu Ctrl + C por kopii ilin.
2. Dekstre alklaku la elektitan gamon kaj alklaku Alglui Specialan > Valoroj . Alternative, premu Shift + F10 kaj poste V , kiu estas la ŝparvojo por la supre menciita funkcio.

Por la detalaj paŝoj, bonvolu vidi Kiel konverti formulojn al valoroj en Excel.

Excel hazarda elekto: vicoj, kolumnojaŭ ĉeloj

Funkcias en ĉiuj versioj de Excel 365 ĝis Excel 2010.

Se vi havas nian Ultimate Suite instalitan en via Excel, tiam vi povas fari hazardan specimenon per musklako anstataŭ formulo. Jen kiel:

1. En la langeto Ablebits Tools , alklaku Hazarde > Elektu Hazarde .
2. Elektu la gamo el kiu vi volas elekti specimenon.
3. En la panelo de aldonaĵo, faru la jenon:
   • Elektu ĉu vi volas elekti hazardajn vicojn, kolumnojn aŭ ĉelojn.
   • Difinu la specimenan grandecon: tio povas esti procento aŭ nombro.
   • Alklaku la butonon Elektu .

Tio estas ĝi! Kiel montrite en la suba bildo, hazarda specimeno estas elektita rekte en via datuma aro. Se vi ŝatus kopii ĝin ie, simple premu regulan kopikopion (Ctrl + C) .

Tiel elekti hazardan specimenon en Excel sen duplikatoj. Mi dankas vin pro legi kaj esperas vidi vin en nia blogo venontsemajne!

Haveblaj elŝutoj

Hazarda specimeno sen duplikatoj - formulekzemploj (.xlsx-dosiero)

Ultimate Suite 14-taga plenfunkcia versio (.exe dosiero)