Mae'r tiwtorial yn canolbwyntio ar sut i wneud samplu ar hap yn Excel heb unrhyw ailadrodd. Fe welwch atebion ar gyfer Excel 365, Excel 2021, Excel 2019 a fersiynau cynharach.

Ychydig yn ôl, fe wnaethom ddisgrifio ychydig o wahanol ffyrdd o ddewis ar hap yn Excel. Mae'r rhan fwyaf o'r atebion hynny'n dibynnu ar y swyddogaethau RAND a RANDBETWEEN, a all gynhyrchu rhifau dyblyg. O ganlyniad, efallai y bydd eich sampl ar hap yn cynnwys gwerthoedd ailadroddus. Os oes angen dewis ar hap heb ddyblygiadau arnoch, yna defnyddiwch y dulliau a ddisgrifir yn y tiwtorial hwn.

Excel hapdethol o'r rhestr heb unrhyw ddyblygiadau

Yn gweithio yn unig yn unig Excel 365 ac Excel 2021 sy'n cefnogi araeau deinamig.

I wneud dewis ar hap o restr heb unrhyw ailadrodd, defnyddiwch y fformiwla generig hon:

Lle n yw'r maint dewis a ddymunir.

Er enghraifft, i gael 5 enw ar hap unigryw o'r rhestr yn A2:A10, dyma'r fformiwla i'w defnyddio:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Er hwylustod, gallwch fewnbynnu maint y sampl mewn a cell rhagddiffiniedig, dyweder C2, a rhowch y cyfeirnod cell i'r swyddogaeth SEQUENCE:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Sut mae'r fformiwla hon yn gweithio:

Dyma esboniad lefel uchel o resymeg y fformiwla: mae ffwythiant RANDARRAY yn creu amrywiaeth o haprifau, mae SORTBY yn didoli'r gwerthoedd gwreiddiol yn ôl y rhifau hynny, ac mae INDEX yn adalw cymaint o werthoedd aga nodir gan SEQUENCE.

Mae dadansoddiad manwl yn dilyn isod:

Mae'r ffwythiant ROWS yn cyfrif faint o resi sydd yn eich set ddata ac yn trosglwyddo'r cyfrif i'r ffwythiant RANDARRAY, felly gall gynhyrchu'r un nifer o degolion ar hap:

RANDARRAY(ROWS(A2:C10))

Defnyddir yr arae hon o hap ddegolion fel yr arae "sort by" gan y ffwythiant SORTBY. O ganlyniad, mae eich data gwreiddiol yn cael ei gymysgu ar hap.

O'r data a drefnwyd ar hap, rydych yn tynnu sampl o faint penodol. Ar gyfer hyn, rydych chi'n cyflenwi'r arae wedi'i siffrwd i'r ffwythiant MYNEGAI ac yn gofyn am adalw'r gwerthoedd N cyntaf gyda chymorth y ffwythiant SEQUENCE, sy'n cynhyrchu dilyniant o rifau o 1 i N . Oherwydd bod y data gwreiddiol eisoes wedi'u didoli mewn trefn ar hap, nid oes ots gennym pa safleoedd i'w hadalw, dim ond y nifer sy'n bwysig.

Dewiswch resi ar hap yn Excel heb ddyblygiadau

Yn gweithio'n unig yn Excel 365 ac Excel 2021 sy'n cefnogi araeau deinamig.

I ddewis rhesi ar hap heb unrhyw ailadroddiadau, lluniwch fformiwla fel hyn:

Ble n mae maint y sampl a Mae {1,2,…} yn rhifau colofn i'w tynnu.

Fel enghraifft, gadewch i ni ddewis rhesi ar hap o A2:C10 heb gofnodion dyblyg, yn seiliedig ar faint y sampl yn F1. Gan fod ein data mewn 3 colofn, rydym yn cyflenwi'r arae hon yn gyson i'r fformiwla:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

A chewch y canlyniad canlynol:

Sut mae'r fformiwla hon yn gweithio:

Mae'r fformiwla'n gweithio gyda'r un rhesymeg yn union â'r un flaenorol. Newid bach sy'n gwneud gwahaniaeth mawr yw eich bod yn nodi'r arg row_num a column_num ar gyfer y ffwythiant INDEX: row_num yn cael ei gyflenwi gan SEQUENCE a column_num wrth y cysonyn arae.

Sut i wneud samplu ar hap yn Excel 2010 - 2019

Gan mai dim ond Excel ar gyfer Microsoft 365 ac Excel 2021 sy'n cefnogi araeau deinamig, mae'r swyddogaethau arae deinamig a ddefnyddir yn mae'r enghreifftiau blaenorol yn gweithio yn Excel 365 yn unig. Ar gyfer fersiynau eraill, bydd yn rhaid i chi weithio allan ateb gwahanol.

A chymryd eich bod eisiau dewis ar hap o'r rhestr yn A2:A10. Gellir gwneud hyn gyda 2 fformiwla ar wahân:

1. Cynhyrchu haprifau gyda'r fformiwla Rand. Yn ein hachos ni, rydyn ni'n ei nodi yn B2, ac yna'n ei gopïo i lawr i B10:

   =RAND()

2. Tynnwch y gwerth hap cyntaf gyda'r fformiwla isod, rydych chi'n ei nodi yn E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Copïwch y fformiwla uchod i gynifer o gelloedd â llawer o werthoedd ar hap yr ydych am eu dewis. Yn yr enghraifft hon, rydyn ni eisiau 4 enw, felly rydyn ni'n copïo'r fformiwla o E2 i E5.

Wedi'i wneud! Mae ein sampl ar hap heb ddyblygiadau yn edrych fel a ganlyn:

Sut mae'r fformiwla hon yn gweithio:

Fel yn yr enghraifft gyntaf, rydych chi'n defnyddio'r Swyddogaeth MYNEGAI i adalw gwerthoedd o golofn A yn seiliedig ar res ar hapniferoedd. Y gwahaniaeth yw sut rydych chi'n cael y rhifau hynny:

Mae'r ffwythiant RAND yn llenwi'r amrediad B2:B10 gyda degolion hap.

Mae'r ffwythiant RANK.EQ yn cyfrifo safle rhif hap mewn rhif penodol rhes. Er enghraifft, yn E2, mae RANK.EQ(B2, $B$2:$B$10) yn gosod y rhif yn B2 yn erbyn yr holl rifau yn B2:B10. Pan gaiff ei gopïo i E3, mae'r cyfeirnod cymharol B2 yn newid i B3 ac yn dychwelyd rheng y rhif yn B3, ac yn y blaen.

Mae'r ffwythiant COUNTIF yn darganfod sawl digwyddiad o rif penodol sydd yn y celloedd uchod. Er enghraifft, yn E2, mae COUNTIF ($B$2:B2, B2) yn gwirio un gell yn unig - B2 ei hun, ac yn dychwelyd 1. Yn E5, mae'r fformiwla yn newid i COUNTIF($B$2:B5, B5) ac yn dychwelyd 2, oherwydd Mae B5 yn cynnwys yr un gwerth â B2 (sylwer, dim ond er mwyn esbonio rhesymeg y fformiwla yn well y mae hyn; ar set ddata fach, mae'r siawns i gael haprifau dyblyg yn agos at sero).

Fel canlyniad, i bawb Yn digwydd yn 1af, mae COUNTIF yn dychwelyd 1, ac rydych yn tynnu 1 ohono i gadw'r safle gwreiddiol. Ar gyfer 2il ddigwyddiad, mae COUNTIF yn dychwelyd 2. Trwy dynnu 1 rydych yn cynyddu'r safle gan 1, ac felly'n atal rhengoedd dyblyg.

Er enghraifft, ar gyfer B2, mae RANK.EQ yn dychwelyd 1. Gan mai dyma'r digwyddiad cyntaf, mae COUNTIF hefyd yn dychwelyd 1. RANK.EQ + COUNTIF yn rhoi 2. Ac - 1 yn adfer y rheng 1.

Nawr, gwelwch beth sy'n digwydd rhag ofn y bydd yr 2il ddigwyddiad. Ar gyfer B5, mae RANK.EQ hefyd yn dychwelyd 1 tra bod COUNTIF yn dychwelyd 2. Mae adio'r rhain yn rhoi3, rydych yn tynnu 1 ohono. Fel y canlyniad terfynol, byddwch yn cael 2, sy'n cynrychioli rheng y rhif yn B5.

Mae'r safle yn mynd i'r arg row_num y ffwythiant INDEX , ac mae'n dewis y gwerth o'r rhes gyfatebol (mae'r arg column_num wedi'i hepgor, felly mae'n rhagosod i 1). Dyma'r rheswm pam ei bod mor bwysig osgoi graddio dyblyg. Oni bai am swyddogaeth COUNTIF, byddai RANK.EQ yn rhoi 1 ar gyfer B2 a B5, gan achosi MYNEGAI i ddychwelyd y gwerth o'r rhes gyntaf (Andrew) ddwywaith.

Sut i atal hapsampl Excel rhag newid

Gan fod yr holl swyddogaethau ar hap yn Excel megis RAND, RANDBETWEEN a RANDARRAY yn gyfnewidiol, maent yn ailgyfrifo gyda phob newid ar y daflen waith. O ganlyniad, bydd eich sampl ar hap yn newid yn barhaus. I atal hyn rhag digwydd, defnyddiwch y Paste Special > Nodwedd gwerthoedd i ddisodli fformiwlâu â gwerthoedd statig. Ar gyfer hyn, dilynwch y camau hyn:

1. Dewiswch yr holl gelloedd gyda'ch fformiwla (unrhyw fformiwla sy'n cynnwys swyddogaeth RAND, RANDBETWEEN neu RANDARRAY) a gwasgwch Ctrl + C i'w copïo.
2. De-gliciwch yr ystod a ddewiswyd a chliciwch Gludwch Arbennig > Gwerthoedd . Fel arall, pwyswch Shift + F10 ac yna V , sef y llwybr byr ar gyfer y nodwedd a grybwyllwyd uchod.

Am y camau manwl, gweler Sut i drosi fformiwlâu yn werthoedd yn Excel.

Dewis hap Excel: rhesi, colofnauneu gelloedd

Yn gweithio ym mhob fersiwn o Excel 365 trwy Excel 2010.

Os ydych wedi gosod ein Ultimate Suite yn eich Excel, yna gallwch chi wneud samplu ar hap gyda a cliciwch ar y llygoden yn lle fformiwla. Dyma sut:

1. Ar y tab Ablebits Tools , cliciwch Ar hap > Dewiswch Ar Hap .
2. Dewiswch yr ystod yr ydych am ddewis sampl ohoni.
3. Ar baen yr ychwanegyn, gwnewch y canlynol:
   • Dewiswch a ydych am ddewis rhesi, colofnau neu gelloedd ar hap.<14
   • Diffiniwch faint y sampl: gall hynny fod yn ganran neu'n rhif.
   • Cliciwch y botwm Dewiswch .

Dyna mae'n! Fel y dangosir yn y ddelwedd isod, dewisir sampl ar hap yn uniongyrchol yn eich set ddata. Os hoffech ei gopïo yn rhywle, pwyswch lwybr byr copi rheolaidd (Ctrl + C).

Dyna sut i ddewis sampl ar hap yn Excel heb ddyblygiadau. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

Ar gael i'w lawrlwytho

Sampl ar hap heb ddyblygiadau - enghreifftiau fformiwla (ffeil .xlsx)

Ultimate Suite Fersiwn cwbl weithredol 14 diwrnod (ffeil .exe)