Tha an oideachadh ag amas air mar a nì thu samplachadh air thuaiream ann an Excel gun ath-aithris. Lorgaidh tu fuasglaidhean airson Excel 365, Excel 2021, Excel 2019 agus dreachan nas tràithe.

O chionn greis, thug sinn cunntas air grunn dhòighean eadar-dhealaichte airson taghadh air thuaiream ann an Excel. Tha a’ mhòr-chuid de na fuasglaidhean sin an urra ri gnìomhan RAND agus RANDBETWEEN, a dh’ fhaodadh àireamhan dùblaichte a ghineadh. Mar thoradh air an sin, dh’ fhaodadh gum bi luachan ath-aithris anns an t-sampall air thuaiream agad. Ma tha feum agad air taghadh air thuaiream às aonais dùblaidhean, cleachd na dòighean-obrach a tha air am mìneachadh san oideachadh seo.

Excel air thuaiream taghadh on liosta gun dùblaidhean

Ag obair a-staigh a-mhàin Excel 365 agus Excel 2021 a bheir taic do arrays fiùghantach.

Gus taghadh air thuaiream a dhèanamh à liosta gun ath-aithris, cleachd am foirmle coitcheann seo:

Càit a bheil n am meud taghaidh a thathar ag iarraidh.

Mar eisimpleir, gus 5 ainmean air thuaiream sònraichte fhaighinn bhon liosta ann an A2:A10, seo am foirmle airson a chleachdadh:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(5))

Air sgàth goireasachd, faodaidh tu meud an t-sampall a chuir a-steach ann an a cealla ro-mhìnichte, can C2, agus thoir seachad an t-iomradh cealla don ghnìomh SEQUENCE:

=INDEX(SORTBY(A2:A10, RANDARRAY(ROWS(A2:A10))), SEQUENCE(C2))

Mar a tha am foirmle seo ag obair:

Seo mìneachadh àrd-ìre air loidsig na foirmle: tha gnìomh RANDARRAY a’ cruthachadh sreath de àireamhan air thuaiream, bidh SORTBY a’ rèiteach nan luachan tùsail a rèir nan àireamhan sin, agus tha INDEX a’ faighinn na h-uimhir de luachanair a shònrachadh le SEQUENCE.

Tha briseadh sìos mionaideach a’ leantainn gu h-ìosal:

Tha an gnìomh ROWS a’ cunntadh cia mheud sreath a th’ anns an t-seata dàta agad agus a’ dol seachad air a’ chunntas gu gnìomh RANDARRAY, gus an cruthaich e an aon àireamh de deicheamhan air thuaiream:

RANDARRAY(ROWS(A2:C10))

Tha an sreath seo de dheicheamhan air thuaiream air a chleachdadh mar an t-sreath "sort by" leis a' ghnìomh SORTBY. Mar thoradh air an sin, thèid an dàta tùsail agad a ghluasad air thuaiream.

Bhon dàta a chaidh a sheòrsachadh air thuaiream, bheir thu a-mach sampall de mheud sònraichte. Airson seo, bidh thu a’ toirt seachad an t-sreath shuffled don ghnìomh INDEX agus ag iarraidh na ciad luachan N fhaighinn air ais le cuideachadh bhon ghnìomh SEQUENCE, a chruthaicheas sreath àireamhan bho 1 gu N . Leis gu bheil an dàta tùsail air a rèiteachadh ann an òrdugh air thuaiream mu thràth, chan eil dragh mòr againn dè na suidheachaidhean a gheibhear air ais, chan eil ach an àireamh a tha cudromach.

Tagh sreathan air thuaiream ann an Excel gun dùblaidhean

Obraich a-mhàin ann an Excel 365 agus Excel 2021 a bheir taic do arrays fiùghantach.

Gus sreathan air thuaiream a thaghadh gun ath-aithris, tog foirmle san dòigh seo:

Càit a bheil n meud an t-sampall agus 'S e àireamhan colbh a th' ann an {1,2,…} airson an toirt a-mach.

Mar eisimpleir, taghamaid sreathan air thuaiream bho A2:C10 gun inntrigidhean dùblaichte, stèidhichte air meud an t-sampall ann am F1. Leis gu bheil an dàta againn ann an 3 colbhan, bidh sinn a’ toirt seachad an t-sreath seo seasmhach don fhoirmle:{1,2,3}

=INDEX(SORTBY(A2:C10, RANDARRAY(ROWS(A2:C10))), SEQUENCE(F1), {1,2,3})

Agus faigh an toradh a leanas:

Mar a dh’obraicheas am foirmle seo:

Tha am foirmle ag obair leis an aon reusanachadh ris an fhear roimhe. Is e atharrachadh beag a nì eadar-dhealachadh mòr gu bheil thu a’ sònrachadh an dà chuid na h-argamaidean row_num agus column_num airson a’ ghnìomh INDEX: row_num ga sholar le SEQUENCE agus column_num leis a’ chonaltradh array.

Mar a nì thu samplachadh air thuaiream ann an Excel 2010 - 2019

Leis nach eil ach Excel airson Microsoft 365 agus Excel 2021 a’ toirt taic do arrays fiùghantach, tha na gnìomhan rèite fiùghantach air an cleachdadh ann an chan obraich na h-eisimpleirean roimhe seo ach ann an Excel 365. Airson tionndaidhean eile, feumaidh tu fuasgladh eile obrachadh a-mach.

A’ gabhail ris gu bheil thu ag iarraidh taghadh air thuaiream bhon liosta ann an A2:A10. Faodar seo a dhèanamh le 2 fhoirmle fa leth:

1. Cruthaich àireamhan air thuaiream leis an fhoirmle Rand. Anns a’ chùis againn, cuiridh sinn a-steach e ann am B2, agus an uairsin dèan lethbhreac sìos gu B10:

   =RAND()

2. Thoir a-mach a’ chiad luach air thuaiream leis an fhoirmle gu h-ìosal, a chuireas tu a-steach ann an E2:

   =INDEX($A$2:$A$10, RANK.EQ(B2, $B$2:$B$10) + COUNTIF($B$2:B2, B2) - 1)

3. Dèan lethbhreac dhen fhoirmle gu h-àrd gu na h-uimhir de cheallan ’s de luachan air thuaiream a tha thu airson taghadh. San eisimpleir seo, tha sinn ag iarraidh 4 ainmean, agus mar sin bidh sinn a’ dèanamh lethbhreac dhen fhoirmle bho E2 gu E5.

Dèanta! Tha an sampall air thuaiream againn gun dùblaidhean a’ coimhead mar a leanas:

Mar a tha am foirmle seo ag obair:

Mar a’ chiad eisimpleir, bidh thu a’ cleachdadh an Gnìomh INDEX gus luachan fhaighinn bho cholbh A stèidhichte air sreath air thuaireamàireamhan. Tha an diofar ann mar a gheibh thu na h-àireamhan sin:

Tha an gnìomh RAND a’ lìonadh an raoin B2:B10 le deicheamhan air thuaiream.

Tha an gnìomh RANK.EQ a’ tomhas ìre àireamh air thuaiream ann an tè a chaidh a thoirt seachad sreath. Mar eisimpleir, ann an E2, tha RANK.EQ(B2, $B$2:$B$10) a’ rangachadh an àireamh ann am B2 mu choinneamh nan àireamhan gu lèir ann am B2:B10. Nuair a thèid lethbhreac a dhèanamh gu E3, bidh an t-iomradh càirdeach B2 ag atharrachadh gu B3 agus a’ tilleadh ìre na h-àireimh ann am B3, is mar sin air adhart.

Lorgaidh an gnìomh COUNTIF cia mheud tachartas de dh’àireamh shònraichte a tha anns na ceallan gu h-àrd. Mar eisimpleir, ann an E2, bidh COUNTIF ($B$2:B2, B2) a’ sgrùdadh dìreach aon chealla - B2 fhèin, agus a’ tilleadh 1. Ann an E5, bidh am foirmle ag atharrachadh gu COUNTIF ($B$2:B5, B5) agus a’ tilleadh 2, a chionn Tha an aon luach aig B5 ri B2 (thoir an aire, chan eil seo ach airson loidsig na foirmle a mhìneachadh nas fheàrr; air stòr-dàta beag, tha cothroman ann àireamhan air thuaiream dùblaichte fhaighinn faisg air neoni).

Mar thoradh air an sin, dha na h-uile A’ chiad tachartas, bidh COUNTIF a’ tilleadh 1, às an toir thu air falbh 1 gus an rangachadh tùsail a chumail. Airson 2na tachartas, tillidh COUNTIF 2. Le bhith a' toirt air falbh 1 àrdaichidh tu an rangachadh le 1, mar sin a' cur casg air ìrean dùblaichte.

Mar eisimpleir, airson B2, bidh RANK.EQ a' tilleadh 1. Leis gur e seo a' chiad tachartas, bidh COUNTIF cuideachd a' tilleadh 1. RANK.EQ + COUNTIF a' toirt seachad 2. Agus - tha 1 ag ath-nuadhachadh an ìre 1.

A-nis, faic dè thachras ma thachras an 2na tachartas. Airson B5, bidh RANK.EQ cuideachd a’ tilleadh 1 agus COUNTIF a’ tilleadh 2. Le bhith gan cur suas bheir sin seachad3, às an toir thu air falbh 1. Mar an toradh deireannach, gheibh thu 2, a tha a' riochdachadh ìre na h-àireimh ann am B5.

Tha an rang a' dol dhan argamaid row_num den ghnìomh INDEX , agus taghaidh e an luach bhon t-sreath fhreagarrach (tha an argamaid column_num air a fàgail a-mach, agus mar sin bidh e a’ dol gu 1). Is e seo an adhbhar gu bheil e cho cudromach rangachadh dùblaichte a sheachnadh. Mura b’ ann airson gnìomh COUNTIF, bheireadh RANK.EQ 1 an dà chuid airson B2 agus B5, a’ toirt air INDEX an luach a thilleadh bhon chiad sreath (Anndra) dà uair.

Mar a chuireas casg air sampall air thuaiream Excel bho bhith ag atharrachadh

Leis gu bheil a h-uile gnìomh air thuaiream ann an Excel leithid RAND, RANDBETWEEN agus RANDARRAY luaineach, bidh iad ag ath-àireamhachadh le gach atharrachadh air an duilleag-obrach. Mar thoradh air an sin, bidh an sampall air thuaiream agad ag atharrachadh gu leantainneach. Gus casg a chuir air seo, cleachd am Paste Special > Feart luachan gus luachan statach a chuir an àite foirmlean. Airson seo, dèan na ceumannan seo:

1. Tagh a h-uile cealla leis an fhoirmle agad (foirmle sam bith anns a bheil gnìomh RAND, RANDBETWEEN no RANDARRAY) agus brùth Ctrl + C airson lethbhreac a dhèanamh dhiubh.
2. Dèan briogadh deas air an raon taghte agus cliog air Paste Special > Luachan . Air neo, brùth Shift + F10 agus an uairsin V , a tha na ath-ghoirid airson an fheart gu h-àrd.

Airson na ceumannan mionaideach, faic Mar a thionndaidheas tu foirmlean gu luachan ann an Excel.

Taghadh air thuaiream Excel: sreathan, colbhanno ceallan

Ag obair anns a h-uile dreach de Excel 365 tro Excel 2010.

Ma tha an Ultimate Suite againn air a chuir a-steach san Excel agad, faodaidh tu samplachadh air thuaiream a dhèanamh le a cliog na luchaige an àite foirmle. Seo mar a leanas:

1. Air an taba Ablebits Tools , briog air Randomize > Tagh air thuaiream .
2. Tagh an raon às a bheil thu airson sampall a thaghadh.
3. Air pana an tuilleadain, dèan na leanas:
   • Tagh a bheil thu airson sreathan, colbhan no ceallan air thuaiream a thaghadh.<14
   • Sònraich meud an t-sampla: faodaidh sin a bhith mar àireamh sa cheud no àireamh.
   • Briog air a’ phutan Tagh .

Sin e! Mar a chithear san dealbh gu h-ìosal, thèid sampall air thuaiream a thaghadh gu dìreach anns an t-seata dàta agad. Ma tha thu airson a chopaigeadh an àiteigin, dìreach brùth air ath-ghoirid leth-bhreac cunbhalach (Ctrl + C).

Sin mar a roghnaicheas tu sampall air thuaiream ann an Excel gun dùblaidhean. Tha mi a' toirt taing dhut airson an leughadh agus an dòchas ur faicinn air a' bhlog againn an ath sheachdain!

Luchdaich a-nuas ri fhaighinn

Sampall air thuaiream gun dùblaidhean - eisimpleirean foirmle (faidhle .xlsx)

Ultimate Suite Tionndadh làn-ghnìomhach 14-latha (faidhle .exe)