Порівняння стовпців в Excel - це те, що ми всі робимо час від часу. Microsoft Excel пропонує ряд варіантів для порівняння та зіставлення даних, але більшість з них зосереджені на пошуку в одному стовпці. У цьому уроці ми розглянемо кілька методів для порівняти дві колонки в Excel та знайти збіги та відмінності між ними.

Як порівняти 2 стовпці в Excel по рядках

При аналізі даних в Excel одним з найпоширеніших завдань є порівняння даних в кожному окремому рядку. Це завдання можна виконати за допомогою функції ЕСЛИ, як це продемонстровано в наступних прикладах.

Приклад 1: Порівняйте два стовпчики на предмет збігів або розбіжностей в одному рядку

Щоб порівняти два стовпці в Excel по рядкам, напишіть звичайну формулу ЕСЛИ, яка порівнює перші дві клітини. Введіть формулу в іншому стовпчику того ж рядка, а потім скопіюйте її в інші клітинки, перетягнувши маркер заповнення (маленький квадратик у правому нижньому куті виділеної клітинки). При цьому курсор змінює свій вигляд на знак "плюс":

Формула проведення матчів

Щоб знайти клітинки в одному рядку з однаковим вмістом, A2 і B2 в даному прикладі, формула виглядає наступним чином:

=IF(A2=B2,"Match","")

Формула різниць

Щоб знайти клітинки в одному рядку з різними значеннями, просто замініть знак рівності на знак нерівності ():

=IF(A2B2, "Немає збігів","")

Збіги та відмінності

І звичайно, ніщо не заважає знайти як збіги, так і відмінності за допомогою єдиної формули:

=IF(A2=B2, "Співпадає", "Не співпадає")

Або

=IF(A2B2, "Немає збігу", "Збіг")

Результат може виглядати приблизно так:

Як бачите, формула обробляє цифри , дати , разів і текстові рядки однаково добре.

Порада: Ви також можете порівняти два стовпці по рядках за допомогою розширеного фільтра Excel. Ось приклад, який показує, як відфільтрувати збіги та відмінності між 2 стовпцями.

Приклад 2. Порівняння двох списків на предмет збігів з урахуванням регістру в одному рядку

Як ви, напевно, помітили, формули з попереднього прикладу ігнорують регістр при порівнянні текстових значень, як в рядку 10 на скріншоті вище. Якщо ви хочете знайти збіги з урахуванням регістру між 2 стовпчиками в кожному рядку, то використовуйте функцію EXACT:

=IF(EXACT(A2, B2), "Збіг", "")

Щоб знайти відмінності, що залежать від конкретного випадку в цьому ж рядку в 3-му аргументі функції ЕСЛИ ввести відповідний текст (в даному прикладі "Унікальний"), наприклад:

=IF(EXACT(A2, B2), "Match", "Unique")

Порівняйте кілька стовпців для пошуку збігів в одному рядку

У ваших таблицях Excel можна порівнювати кілька стовпців на основі наступних критеріїв:

• Знайдіть рядки з однаковими значеннями в всі колонки (Приклад 1)
• Знайдіть рядки з однаковими значеннями в будь-які 2 колонки (Приклад 2)

Приклад 1: Знайти збіги у всіх комірках одного рядка

Якщо у вашій таблиці є три або більше стовпців, і ви хочете знайти рядки, які мають однакові значення у всіх клітинках, формула ЕСЛИ з оператором І буде чудово працювати:

=IF(AND(A2=B2, A2=C2), "Повний збіг", "")

Якщо у вашій таблиці багато стовпчиків, більш елегантним рішенням буде використання функції COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Повний збіг", "")

Де 5 - кількість стовпчиків, які ви порівнюєте.

Приклад 2. Знайти збіги в будь-яких двох комірках одного рядка

Якщо ви шукаєте спосіб порівняти стовпці для будь-які дві або більше комірки з однаковими значеннями в межах одного рядка, використовуйте формулу IF з оператором OR:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

Якщо є багато стовпців для порівняння, ваш оператор АБО може стати занадто великим за розміром. У цьому випадку кращим рішенням буде складання декількох функцій підрахунку. Перша функція підрахунку підраховує, скільки стовпців мають таке ж значення, як у 1-му стовпці, друга функція підрахунку підраховує, скільки стовпців, що залишилися, дорівнюють 2-му стовпцю і т.д. Якщо кількість стовпців дорівнює 0, формула повертає значення "Унікальний","Збігаються" інакше. Наприклад:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Унікальний", "Збіг")

Як порівняти два стовпці в Excel на збіги та відмінності

Припустимо, у вас є 2 списки даних в Excel, і ви хочете знайти всі значення (числа, дати або текстові рядки), які є в стовпці A, але відсутні в стовпці B.

Для цього можна вставити функцію COUNTIF($B:$B, $A2)=0 в логічний тест ЕСЛИ і перевірити, чи повертає вона нуль (не знайдено збігів) або будь-яке інше число (знайдено хоча б 1 збіг).

Наприклад, наступна формула ЕСЛИ/СЧЕТЕСЛИ шукає по всьому стовпчику B значення в комірці A2. Якщо збігів не знайдено, формула повертає "Немає збігів у B", в іншому випадку - порожній рядок:

=IF(COUNTIF($B:$B, $A2)=0, "Немає збігу в B", "")

Порада. Якщо таблиця має фіксовану кількість рядків, можна вказати певний діапазон (наприклад, $B2:$B10), а не весь стовпець ($B:$B), щоб формула швидше працювала на великих масивах даних.

Такого ж результату можна досягти, використовуючи формулу ЕСЛИ з вбудованими функціями ИСКЛЮЧАЮЩИЙ і СООТВЕТСТВУЮЩИЙ:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Немає збігу в B","")

Або за допомогою наступної формули масиву (не забудьте натиснути Ctrl + Shift + Enter для її коректного введення):

=IF(SUM(--($B$2:$B$10=$A2))=0, "Немає збігу в B", "")

Якщо ви хочете, щоб одна формула визначала як збіги (дублікати), так і відмінності (унікальні значення), помістіть текст для збігів в порожні подвійні лапки ("") в будь-якій з наведених вище формул. Наприклад:

=IF(COUNTIF($B:$B, $A2)=0, "Немає збігу в B", "Збіг в B")

Як порівняти два списки в Excel і знайти збіги

Іноді може знадобитися не тільки зіставити два стовпці в двох різних таблицях, але і витягнути відповідні записи з таблиці пошуку. Для цього в Microsoft Excel передбачена спеціальна функція - функція ВПРЗНАЙТИ. В якості альтернативи можна скористатися більш потужною і універсальною формулою ПОИСК ПО ИНДЕКСУ. Користувачі Excel 2021 і Excel 365 можуть виконати це завдання за допомогою функції XLOOKUP.

Наприклад, наступні формули порівнюють назви товарів у колонці D з назвами в колонці A і витягують відповідну цифру продажів з колонки B, якщо збіг знайдено, інакше повертається помилка #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Для отримання додаткової інформації див. розділ Як порівняти два стовпці за допомогою VLOOKUP.

Якщо ви не відчуваєте себе комфортно з формулами, ви можете виконати роботу за допомогою швидкого та інтуїтивно зрозумілого рішення - Майстра злиття таблиць.

Порівняйте два списки та знайдіть збіги та відмінності

Коли ви порівнюєте стовпці в Excel, вам може знадобитися "візуалізувати" елементи, які присутні в одному стовпці, але відсутні в іншому. Ви можете заштрихувати такі клітинки будь-яким кольором на ваш вибір, використовуючи функцію умовного форматування Excel, і наступні приклади демонструють детальні кроки.

Приклад 1: Підкресліть збіги та відмінності в кожному рядку

Порівняти два стовпці та Excel і виділити клітинки в стовпці A, які мають ідентичні записи у колонці В цього ж рядка виконати такі дії:

• Виділіть клітинки, які потрібно виділити (можна виділити клітинки в одному стовпчику або в декількох стовпчиках, якщо потрібно зафарбувати всі рядки).
• Натисніть Умовне форматування> Нове правило.> Використання формули для визначення, які клітинки форматувати .
• Створіть правило з простою формулою на кшталт =$B2=$A2 (припускаючи, що рядок 2 є першим рядком з даними, не включаючи заголовок стовпця). Будь ласка, перевірте, що ви використовуєте відносне посилання на рядок (без знаку $), як у формулі вище.

Виділити відмінності між стовпчиком A і B створити правило з такою формулою:

= $B2$A2

Якщо ви не знайомі з умовним форматуванням в Excel, див. покрокові інструкції в розділі Як створити правило умовного форматування на основі формули.

Приклад 2: Виділити унікальні записи в кожному списку

Щоразу, коли ви порівнюєте два списки в Excel, є 3 типи елементів, які ви можете виділити:

• Елементи, які є тільки в 1-му списку (унікальні)
• Елементи, які є тільки в 2-му списку (унікальні)
• Елементи, які є в обох списках (дублікати) - продемонстровано на наступному прикладі.

Цей приклад демонструє, як розфарбувати елементи, які знаходяться тільки в одному списку.

Припустимо, що Список 1 знаходиться в колонці A (A2:A6), а Список 2 - в колонці C (C2:C5). Ви створюєте правила умовного форматування за допомогою наступних формул:

Виділіть унікальні значення в Переліку 1 (колонка А):

=COUNTIF($C$2:$C$5, $A2)=0

Виділіть унікальні значення в Переліку 2 (колонка С):

=COUNTIF($A$2:$A$6, $C2)=0

І отримуємо наступний результат:

Приклад 3. Виділити збіги (дублікати) між 2 колонками

Якщо ви уважно стежили за попереднім прикладом, вам не складе труднощів налаштувати формули COUNTIF так, щоб вони знаходили збіги, а не відмінності. Все, що вам потрібно зробити, - це задати значення count більше нуля:

Виділіть збіги в списку 1 (колонка А):

=COUNTIF($C$2:$C$5, $A2)>0

Виділіть збіги в списку 2 (колонка С):

=COUNTIF($A$2:$A$6, $C2)>0

Виділіть відмінності рядків і збіги в декількох стовпчиках

При построковому порівнянні значень у декількох стовпцях найшвидшим способом виділення збігів є створення правила умовного форматування, а найшвидшим способом затінення відмінностей - застосування Перейти до спеціальних пропозицій як показано на наступних прикладах.

Приклад 1. Порівняння декількох стовпців і виділення збігів у рядках

Щоб виділити рядки, які мають однакові значення в усіх колонках створіть правило умовного форматування на основі однієї з наведених нижче формул:

=AND($A2=$B2, $A2=$C2)

або

=COUNTIF($A2:$C2, $A2)=3

Де A2, B2 і C2 - крайні верхні клітинки, а 3 - кількість стовпчиків для порівняння.

Звичайно, ні формула AND, ні формула COUNTIF не обмежуються порівнянням тільки 3-х стовпців, ви можете використовувати аналогічні формули для виділення рядків з однаковими значеннями в 4, 5, 6 і більше стовпцях.

Приклад 2. Порівняння декількох стовпців та виділення відмінностей у рядках

Для швидкого виділення комірок з різними значеннями в кожному окремому рядку можна скористатися функцією Excel Перейти до спеціальних пропозицій особливість.

1. Виділіть діапазон комірок, які потрібно порівняти. У цьому прикладі я виділив комірки з A2 по C8.

   За замовчуванням верхня комірка виділеного діапазону є активною, і комірки інших виділених стовпців того ж рядка будуть порівнюватися з нею. Як видно на скріншоті вище, активна комірка виділена білим кольором, тоді як всі інші комірки виділеного діапазону підсвічені. У цьому прикладі активною коміркою є комірка A2, тому функція порівняльна колонка це стовпчик А.

   До змінити стовпець порівняння використовуйте клавішу Tab для переміщення по виділених комірках зліва направо або клавішу Enter для переміщення зверху вниз.

   Порада. Щоб вибрати несуміжні стовпчики виберіть перший стовпець, натисніть і утримуйте клавішу Ctrl , а потім виберіть інші стовпці. Активна комірка буде в останньому стовпці (або в останньому блоці суміжних стовпців). Для зміни стовпця порівняння використовуйте клавішу Tab або Enter, як описано вище.

2. Про це йдеться на Головна сторінка перейдіть на вкладку Редагування групу і натисніть Знайти та вибрати > Перейдіть до спеціальних... Потім виберіть Різниця між рядами і натисніть кнопку ГАРАЗД. кнопку.
3. Комірки, значення яких відрізняються від комірки порівняння в кожному рядку, зафарбовані. Якщо ви хочете заштрихувати виділені комірки певним кольором, просто клацніть по кнопці Колір заливки на стрічці та оберіть колір на свій смак.

Як порівняти дві комірки в Excel

Фактично, порівняння 2 клітинок є окремим випадком порівняння двох стовпців в Excel по рядках, за винятком того, що вам не потрібно копіювати формули в інші клітинки стовпця.

Наприклад, для порівняння комірок А1 і С1 можна скористатися наступними формулами.

На сірники:

=IF(A1=C1, "Збіг", "")

За відмінності:

=IF(A1C1, "Різниця", "")

Щоб дізнатися ще кілька способів порівняння комірок в Excel, будь ласка, подивіться:

• Як порівняти два рядки в Excel
• Перевірка збігу двох клітинок або рівності декількох клітинок

Безформульний спосіб порівняння двох стовпців / списків в Excel

Тепер, коли ви знаєте пропозиції Excel для порівняння та зіставлення стовпців, дозвольте мені показати вам наше власне рішення для цього завдання. Цей інструмент називається "Порівняння двох таблиць", і він включений до нашого Ultimate Suite.

Доповнення може порівнювати дві таблиці або списки за будь-якою кількістю стовпців і як виявляти збіги/розбіжності (як ми робили з формулами), так і виділяти їх (як ми робили з умовним форматуванням).

Для цілей цієї статті ми порівняємо наступні 2 списки, щоб знайти спільні цінності, які присутні в обох списках.

Для того, щоб порівняти два списки, необхідно виконати наступні кроки:

1. Почніть з натискання кнопки Порівняльні таблиці на кнопці Дані про абіти рахунок.
2. Виберіть пункт перша колонка/список і натисніть Далі З точки зору доповнення, це ваша таблиця 1.
3. Виберіть другий стовпчик/список і натисніть Далі З точки зору надбудови, це ваша Таблиця 2, і вона може знаходитися на тому ж або іншому аркуші або навіть в іншій робочій книзі.
4. Оберіть, які саме дані шукати:
   • Дублікат цінності (збіги) - елементи, які є в обох списках.
   • Унікальний цінності (відмінності) - позиції, які присутні в переліку 1, але відсутні в переліку 2.

   Оскільки наша мета - знайти збіги, вибираємо перший варіант і натискаємо Далі .

5. Це ключовий крок, на якому ви обираєте колонки для порівняння У нашому випадку вибір очевидний, оскільки ми порівнюємо лише 2 колонки: Переможці 2000 року проти Переможці 2021 року У великих таблицях можна вибрати кілька пар стовпців для порівняння.
6. На останньому кроці ви обираєте, як вчинити зі знайденими предметами і натискаєте Фініш .

   Тут є кілька різних варіантів. Для наших цілей найбільш корисними є ці два:

   • Виділити кольором - відтінки збігів або відмінностей у вибраному кольорі (подібно до умовного форматування Excel).
   • Ідентифікувати в колонці "Статус - вставляє Статус стовпчик з мітками "Дублікат" або "Унікальний" (як у формулах ЕСЛИ).

Для цього прикладу я вирішив виділити дублікати наступним кольором:

І за мить отримали наступний результат:

За допомогою Статус результат виглядав би наступним чином:

Порада: Якщо списки, які ви порівнюєте, знаходяться на різних аркушах або в різних книгах, може бути корисно переглянути аркуші Excel поруч.

Таким чином ви порівнюєте стовпці в Excel на наявність збігів (дублікатів) та відмінностей (унікальних значень). Якщо ви зацікавлені спробувати цей інструмент, ви можете завантажити ознайомчу версію, скориставшись наведеним нижче посиланням.

Дякую за прочитання та рекомендую ознайомитися з іншими корисними матеріалами, які у нас є :)

Доступні для завантаження

Порівняння списків Excel - приклади (файл .xlsx)

Ultimate Suite - пробна версія (файл .exe)