Sarakkeiden vertailu Excelissä on jotain, jota me kaikki teemme silloin tällöin. Microsoft Excel tarjoaa useita vaihtoehtoja tietojen vertailemiseen ja yhteensovittamiseen, mutta useimmat niistä keskittyvät hakuun yhdessä sarakkeessa. Tässä opetusohjelmassa tutustumme useisiin tekniikoihin, joilla voimme vertaa kahta saraketta Excelissä ja löytää niiden väliset yhtäläisyydet ja erot.

Miten vertailla 2 saraketta Excelissä rivi riviltä riviltä?

Kun teet data-analyysiä Excelissä, yksi yleisimmistä tehtävistä on verrata tietoja kullakin rivillä. Tämä tehtävä voidaan tehdä käyttämällä IF-funktiota, kuten seuraavissa esimerkeissä osoitetaan.

Esimerkki 1. Vertaile kahta saraketta saman rivin vastaavuuksien tai erojen löytämiseksi.

Jos haluat verrata kahta saraketta Excelissä riveittäin, kirjoita tavallinen IF-kaava, joka vertaa sarakkeita seuraavasti kaksi ensimmäistä solua. Kirjoita kaava johonkin toiseen sarakkeeseen samalla rivillä ja kopioi se sitten muihin soluihin vetämällä täyttökahvaa (pieni neliö valitun solun oikeassa alakulmassa). Kun teet näin, kursori muuttuu plusmerkiksi:

Otteluiden kaava

Jos haluat löytää saman rivin solut, joilla on sama sisältö, tässä esimerkissä A2 ja B2, kaava on seuraava:

=IF(A2=B2,"Match","")

Erojen kaava

Jos haluat löytää samalta riviltä soluja, joilla on eri arvot, korvaa yhtäläisyysmerkki ei-yhtäläisyysmerkillä ():

=IF(A2B2, "Ei vastaavuutta","")

Ottelut ja erot

Mikään ei tietenkään estä sinua löytämästä sekä yhteneväisyyksiä että eroja yhdellä kaavalla:

=IF(A2=B2, "Osuma", "Ei osumaa")

Tai

=IF(A2B2, "Ei vastaavuutta", "Vastaavuus")

Tulos voi näyttää samankaltaiselta kuin tämä:

Kuten näet, kaava käsittelee numerot , päivämäärät , kertaa ja tekstijonot yhtä hyvin.

Vihje. Voit myös vertailla kahta saraketta rivi riviltä Excelin Advanced Filter -suodattimen avulla. Tässä on esimerkki, jossa näytetään, miten suodatetaan 2 sarakkeen väliset yhtäläisyydet ja erot.

Esimerkki 2. Vertaile kahta luetteloa, jos samalla rivillä on isojen ja pienten kirjainten välisiä osumia.

Kuten olet varmaan huomannut, edellisen esimerkin kaavat eivät huomioi isoja ja pieniä kirjaimia verrattaessa tekstiarvoja, kuten rivillä 10 yllä olevassa kuvakaappauksessa. Jos haluat löytää seuraavat arvot isojen ja pienten kirjainten erittely 2 sarakkeen välillä kullakin rivillä, käytä sitten EXACT-funktiota:

=IF(EXACT(A2, B2), "Match", "")

Löytää isojen ja pienten kirjainten väliset erot kirjoita samalle riville vastaava teksti ("Unique" tässä esimerkissä) IF-funktion kolmanteen argumenttiin, esim:

=IF(EXACT(A2, B2), "Match", "Unique")

Vertaa useita sarakkeita samalle riville osuvien otteluiden löytämiseksi

Excel-taulukoissa voidaan vertailla useita sarakkeita seuraavien kriteerien perusteella:

• Etsi rivit, joilla on samat arvot kaikki sarakkeet (Esimerkki 1)
• Etsi rivit, joilla on samat arvot mikä tahansa 2 saraketta (Esimerkki 2)

Esimerkki 1. Etsitään osumia kaikista saman rivin soluista.

Jos taulukossasi on kolme tai useampia sarakkeita ja haluat etsiä rivejä, joiden kaikissa soluissa on samat arvot, IF-kaava AND-lauseen kanssa toimii hyvin:

=IF(AND(A2=B2, A2=C2), "Täydellinen vastaavuus", "")

Jos taulukossasi on paljon sarakkeita, tyylikkäämpi ratkaisu olisi käyttää COUNTIF-funktiota:

=IF(COUNTIF($A2:$E2, $A2)=5, "Täydellinen ottelu", "")

Jossa 5 on vertailtavien sarakkeiden lukumäärä.

Esimerkki 2. Etsitään osumia kahdesta minkä tahansa saman rivin solusta.

Jos etsit tapaa verrata sarakkeita sarakkeiden kaksi tai useampi solu joilla on samat arvot samalla rivillä, käytä IF-kaavaa OR-lauseen kanssa:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

Jos vertailtavia sarakkeita on paljon, OR-lauseesi voi kasvaa liian suureksi. Tällöin parempi ratkaisu olisi lisätä useita COUNTIF-funktioita. Ensimmäinen COUNTIF laskee, kuinka monessa sarakkeessa on sama arvo kuin 1. sarakkeessa, toinen COUNTIF laskee, kuinka monessa jäljellä olevassa sarakkeessa on sama arvo kuin 2. sarakkeessa, ja niin edelleen. Jos laskenta on 0, kaava palauttaa arvon "Unique","Match" muuten. Esimerkiksi:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unique", "Match")

Miten vertailla kahta saraketta Excelissä otteluiden ja erojen löytämiseksi?

Oletetaan, että Excelissä on kaksi tietoluetteloa, ja haluat löytää kaikki arvot (numerot, päivämäärät tai tekstijonot), jotka ovat sarakkeessa A mutta eivät sarakkeessa B.

Tätä varten voit upottaa COUNTIF($B:$B, $A2)=0-funktion IF:n loogiseen testiin ja tarkistaa, palauttaako se nollan (yhtään vastaavuutta ei löydy) vai jonkin muun luvun (vähintään yksi vastaavuus löytyy).

Esimerkiksi seuraava IF/COUNTIF-kaava etsii koko sarakkeesta B solun A2 arvoa. Jos vastaavuutta ei löydy, kaava palauttaa "No match in B", muuten tyhjä merkkijono:

=IF(COUNTIF($B:$B, $A2)=0, "Ei vastaavuutta B:ssä", "")

Vihje: Jos taulukossasi on kiinteä määrä rivejä, voit määrittää tietyn alueen (esim. $B2:$B10) koko sarakkeen ($B:$B) sijasta, jotta kaava toimii nopeammin suurissa tietokokonaisuuksissa.

Samaan tulokseen päästään käyttämällä IF-kaavaa, johon on upotettu ISERROR- ja MATCH-funktiot:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Ei vastaavuutta B:ssä","")

Tai käyttämällä seuraavaa matriisikaavaa (muista painaa Ctrl + Shift + Enter, jotta se kirjoitetaan oikein):

=IF(SUM(--($B$2:$B$10=$A2))=0, " No match in B", "")

Jos haluat, että yksi kaava tunnistaa sekä osumat (kaksoiskappaleet) että erot (ainutlaatuiset arvot), laita teksti osumia varten tyhjiin lainausmerkkeihin ("") missä tahansa edellä mainituista kaavoista. Esimerkiksi:

=IF(COUNTIF($B:$B, $A2)=0, "Ei osumaa B:ssä", "Osuma B:ssä")

Miten vertailla kahta luetteloa Excelissä ja vetää ottelut

Joskus saatat tarvita kahden eri taulukon kahden sarakkeen yhteensovittamisen lisäksi myös vastaavien merkintöjen vetämistä hakutaulukosta. Microsoft Excel tarjoaa tätä varten erityisen toiminnon - VLOOKUP-toiminnon. Vaihtoehtoisesti voit käyttää tehokkaampaa ja monipuolisempaa INDEX MATCH -kaavaa. Excel 2021- ja Excel 365 -käyttäjät voivat suorittaa tehtävän XLOOKUP-toiminnolla.

Esimerkiksi seuraavissa kaavoissa verrataan sarakkeissa D olevia tuotenimiä sarakkeessa A oleviin nimiin ja haetaan vastaava myyntiluku sarakkeesta B, jos vastaavuus löytyy, muuten palautetaan virhe #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Lisätietoja on kohdassa Kahden sarakkeen vertailu VLOOKUPin avulla.

Jos et tunne oloasi kovin mukavaksi kaavojen kanssa, voit tehdä työn nopealla ja intuitiivisella ratkaisulla - Merge Tables Wizardilla.

Vertaile kahta luetteloa ja korosta yhtäläisyydet ja erot

Kun vertaat sarakkeita Excelissä, saatat haluta "visualisoida" kohteet, jotka ovat läsnä yhdessä sarakkeessa mutta puuttuvat toisesta. Voit varjostaa tällaiset solut haluamallasi värillä käyttämällä Excelin ehdollisen muotoilun ominaisuutta, ja seuraavat esimerkit havainnollistavat yksityiskohtaiset vaiheet.

Esimerkki 1. Korosta vastaavuudet ja erot kullakin rivillä.

Voit vertailla kahta saraketta ja Exceliä ja korostaa sarakkeen A soluja, joissa on identtiset merkinnät sarakkeessa B samalla rivillä, toimi seuraavasti:

• Valitse solut, jotka haluat korostaa (voit valita soluja yhdestä sarakkeesta tai useasta sarakkeesta, jos haluat värittää kokonaisia rivejä).
• Klikkaa Ehdollinen muotoilu> Uusi sääntö.> Määritä kaavan avulla, mitkä solut muotoillaan. .
• Luo sääntö yksinkertaisella kaavalla kuten =$B2=$A2 (olettaen, että rivi 2 on ensimmäinen rivi, jolla on tietoja, lukuun ottamatta sarakeotsikkoa). Tarkista vielä kerran, että käytät suhteellista riviviittausta (ilman $-merkkiä) kuten yllä olevassa kaavassa.

Korostaa erot sarakkeiden A ja B välillä, luo sääntö tällä kaavalla:

=$B2$A2

Jos Excelin ehdollinen muotoilu on sinulle uutta, katso vaiheittaiset ohjeet kohdassa Kaavapohjaisen ehdollisen muotoilusäännön luominen.

Esimerkki 2. Korosta ainutlaatuiset merkinnät kussakin luettelossa

Kun vertaat kahta luetteloa Excelissä, voit korostaa 3 kohdetyyppiä:

• Kohteet, jotka ovat vain 1. luettelossa (ainutkertaiset).
• Kohteet, jotka ovat vain 2. luettelossa (ainutkertaiset).
• Kohteet, jotka ovat molemmissa luetteloissa (kaksoiskappaleet) - näytetään seuraavassa esimerkissä.

Tässä esimerkissä näytetään, miten vain yhdessä luettelossa olevat kohteet väritetään.

Oletetaan, että luettelo 1 on sarakkeessa A (A2:A6) ja luettelo 2 sarakkeessa C (C2:C5). Luodaan ehdollisen muotoilun säännöt seuraavilla kaavoilla:

Korosta luettelon 1 (sarake A) yksilölliset arvot:

=COUNTIF($C$2:$C$5, $A2)=0

Korosta ainutlaatuiset arvot luettelossa 2 (sarake C):

=COUNTIF($A$2:$A$6, $C2)=0

Ja saat seuraavan tuloksen:

Esimerkki 3. Korosta 2 sarakkeen väliset osumat (kaksoiskappaleet).

Jos seurasit tarkasti edellistä esimerkkiä, sinulla ei ole vaikeuksia säätää COUNTIF-kaavoja niin, että ne löytävät täsmääviä kohtia eikä eroja. Sinun tarvitsee vain asettaa luku suuremmaksi kuin nolla:

Korosta osumat luettelossa 1 (sarake A):

=COUNTIF($C$2:$C$5, $A2)>0

Korosta osumat luettelossa 2 (sarake C):

=COUNTIF($A$2:$A$6, $C2)>0

Korosta rivien erot ja vastaavuudet useissa sarakkeissa

Kun verrataan arvoja useissa sarakkeissa riveittäin, nopein tapa korostaa yhteneväisyyksiä on luoda ehdollinen muotoilusääntö, ja nopein tapa varjostaa eroja on käyttää komentoa Siirry erikoisohjelmaan ominaisuus, kuten seuraavissa esimerkeissä osoitetaan.

Esimerkki 1. Vertaile useita sarakkeita ja korosta rivien vastaavuudet

Korostaaksesi rivit, joilla on samat arvot kaikissa sarakkeissa , luo ehdollisen muotoilusäännön, joka perustuu johonkin seuraavista kaavoista:

=AND($A2=$B2, $A2=$C2)

tai

=COUNTIF($A2:$C2, $A2)=3

Jossa A2, B2 ja C2 ovat ylimmät solut ja 3 on vertailtavien sarakkeiden lukumäärä.

AND- tai COUNTIF-kaava ei tietenkään rajoitu vain kolmen sarakkeen vertailuun, vaan voit käyttää samankaltaisia kaavoja korostaaksesi rivejä, joilla on samat arvot 4, 5, 6 tai useammassa sarakkeessa.

Esimerkki 2. Vertaile useita sarakkeita ja korosta rivien väliset erot

Jos haluat nopeasti korostaa soluja, joissa on eri arvoja kullakin rivillä, voit käyttää Excelin komentoa Siirry erikoisohjelmaan ominaisuus.

1. Valitse solualue, jota haluat verrata. Tässä esimerkissä olen valinnut solut A2-C8.

   Oletusarvoisesti valitun alueen ylimpänä oleva solu on aktiivinen solu, ja saman rivin muiden valittujen sarakkeiden soluja verrataan kyseiseen soluun. Kuten yllä olevasta kuvakaappauksesta näkyy, aktiivinen solu on valkoinen, kun taas kaikki muut valitun alueen solut on korostettu. Tässä esimerkissä aktiivinen solu on A2, joten vertailusarake on sarake A.

   Osoitteeseen vaihda vertailusarake , käytä joko Tab-näppäintä siirtyäksesi valituissa soluissa vasemmalta oikealle tai Enter-näppäintä siirtyäksesi ylhäältä alas.

   Vihje. Valitse vierekkäiset sarakkeet , valitse ensimmäinen sarake, pidä Ctrl-näppäintä painettuna ja valitse sitten muut sarakkeet. Aktiivinen solu on viimeisessä sarakkeessa (tai vierekkäisten sarakkeiden viimeisessä lohkossa). Jos haluat vaihtaa vertailusaraketta, käytä Tab- tai Enter-näppäintä edellä kuvatulla tavalla.

2. On Etusivu välilehti, siirry kohtaan Muokkaaminen ja napsauta Etsi & valitse > Siirry erikoisohjelmaan... Valitse sitten Rivien erot ja napsauta OK nappi.
3. Solut, joiden arvot eroavat kunkin rivin vertailusolusta, väritetään. Jos haluat sävyttää korostetut solut jollakin värillä, napsauta yksinkertaisesti Täyttöväri kuvaketta nauhassa ja valitse haluamasi väri.

Miten vertailla kahta solua Excelissä

Itse asiassa kahden solun vertailu on erityinen tapaus kahden sarakkeen vertailusta Excelissä rivi riviltä, paitsi että sinun ei tarvitse kopioida kaavoja sarakkeen muihin soluihin.

Voit esimerkiksi verrata soluja A1 ja C1 seuraavilla kaavoilla.

Tulitikkuja varten:

=IF(A1=C1, "Match", "")

Erojen vuoksi:

=IF(A1C1, "Ero", "")

Jos haluat oppia muutamia muita tapoja vertailla soluja Excelissä, katso:

• Kuinka verrata kahta merkkijonoa Excelissä
• Tarkista, ovatko kaksi solua samanlaisia tai onko useampi solu yhtä suuri.

Kaavaton tapa verrata kahta saraketta / luetteloa Excelissä

Nyt kun tunnet Excelin tarjoukset sarakkeiden vertailuun ja yhteensovittamiseen, näytän sinulle oman ratkaisumme tähän tehtävään. Tämän työkalun nimi on Compare Two Tables (Vertaa kahta taulukkoa), ja se sisältyy Ultimate Suite -ohjelmistoon.

Lisäosa voi vertailla kahta taulukkoa tai luetteloa minkä tahansa sarakemäärän mukaan ja sekä tunnistaa vastaavuudet/erot (kuten teimme kaavojen avulla) että korostaa ne (kuten teimme ehdollisen muotoilun avulla).

Tässä artikkelissa vertaamme seuraavia kahta luetteloa löytääkseen yhteisiä arvoja, jotka ovat molemmissa.

Voit vertailla kahta luetteloa seuraavasti:

1. Aloita napsauttamalla Vertaa taulukoita painiketta Ablebits Data välilehti.
2. Valitse ensimmäinen sarake/luettelo ja klikkaa Seuraava Lisäosan osalta tämä on taulukko 1.
3. Valitse toinen sarake/lista ja klikkaa Seuraava Lisäosan kannalta se on taulukko 2, ja se voi sijaita samassa tai eri laskentataulukossa tai jopa toisessa työkirjassa.
4. Valitse, millaisia tietoja etsit:
   • Kaksoiskappaleet arvot (täsmää) - molemmissa luetteloissa olevat kohteet.
   • Ainutlaatuinen arvot (erot) - kohteet, jotka ovat luettelossa 1, mutta eivät luettelossa 2.

   Koska tavoitteenamme on löytää osumia, valitsemme ensimmäisen vaihtoehdon ja napsautamme painiketta Seuraava .

5. Tämä on tärkein vaihe, jossa valitset sarakkeet vertailua varten Meidän tapauksessamme valinta on ilmeinen, koska vertaamme vain kahta saraketta: Vuoden 2000 voittajat vastaan Vuoden 2021 voittajat Suuremmissa taulukoissa voit valita useita sarakepareja vertailtavaksi.
6. Viimeisessä vaiheessa valitset, miten löydettyjä kohteita käsitellään, ja napsautat sitten Viimeistely .

   Tässä on useita eri vaihtoehtoja, joista nämä kaksi ovat meidän tarkoituksiimme hyödyllisimmät:

   • Korosta värillä - valittujen värien sävyjen vastaavuudet tai erot (kuten Excelin ehdollinen muotoilu tekee).
   • Tunnista Status-sarakkeessa - lisää Tila sarakkeen "Duplicate" tai "Unique" -merkinnöillä (kuten IF-kaavat tekevät).

Tässä esimerkissä olen päättänyt korostaa kaksoiskappaleet seuraavalla värillä:

Ja hetken kuluttua sain seuraavan tuloksen:

Kun Tila sarakkeessa, tulos näyttäisi seuraavalta:

Vihje: Jos vertailtavat luettelot ovat eri työarkkeissa tai työkirjoissa, voi olla hyödyllistä tarkastella Excel-arkkeja vierekkäin.

Näin voit vertailla Excelin sarakkeita yhteneväisyyksien (päällekkäisyyksien) ja erojen (ainutlaatuisten arvojen) löytämiseksi. Jos olet kiinnostunut kokeilemaan tätä työkalua, voit ladata kokeiluversion alla olevasta linkistä.

Kiitän sinua lukemisesta ja kannustan sinua tutustumaan muihin hyödyllisiin opetusohjelmiin, joita meillä on :)

Saatavilla olevat lataukset

Excel-luetteloiden vertailu - esimerkkejä (.xlsx-tiedosto)

Ultimate Suite - kokeiluversio (.exe-tiedosto)