Att jämföra kolumner i Excel är något som vi alla gör ibland. Microsoft Excel erbjuder ett antal alternativ för att jämföra och matcha data, men de flesta av dem fokuserar på att söka i en kolumn. I den här handledningen kommer vi att utforska flera tekniker för att jämföra två kolumner i Excel och hitta överensstämmelser och skillnader mellan dem.

Hur man jämför 2 kolumner i Excel rad för rad

När du gör dataanalyser i Excel är en av de vanligaste uppgifterna att jämföra data i varje enskild rad. Den här uppgiften kan göras med hjälp av IF-funktionen, vilket visas i följande exempel.

Exempel 1: Jämför två kolumner för att hitta överensstämmelser eller skillnader i samma rad.

Om du vill jämföra två kolumner i Excel rad för rad skriver du en vanlig IF-formel som jämför de två första cellerna. Skriv in formeln i en annan kolumn på samma rad och kopiera den sedan ner till andra celler genom att dra i fyllningshandtaget (en liten fyrkant i det nedre högra hörnet av den markerade cellen). När du gör detta ändras markören till plustecknet:

Formel för matchningar

För att hitta celler inom samma rad med samma innehåll, A2 och B2 i det här exemplet, är formeln följande:

=IF(A2=B2,"Match","")

Formel för skillnader

Om du vill hitta celler i samma rad med olika värden ersätter du helt enkelt likhetstecknet med icke likhetstecknet ():

=IF(A2B2, "Ingen matchning","")

Matchningar och skillnader

Det finns naturligtvis inget som hindrar dig från att hitta både överensstämmelser och skillnader med en enda formel:

=IF(A2=B2, "Matchning", "Ingen matchning")

Eller

=IF(A2B2, "Ingen matchning", "Matchning")

Resultatet kan se ut ungefär så här:

Som du ser hanterar formeln nummer , datum , gånger och textsträngar lika bra.

Tips: Du kan också jämföra två kolumner rad för rad med hjälp av Excel Advanced Filter. Här är ett exempel som visar hur du filtrerar matchningar och skillnader mellan två kolumner.

Exempel 2: Jämför två listor för att hitta matchningar som är känsliga för stora och små bokstäver i samma rad.

Som du säkert har märkt ignorerar formlerna från föregående exempel storleken när de jämför textvärden, som i rad 10 i skärmdumpen ovan. Om du vill hitta Skiftlägeskänsliga matchningar. mellan två kolumner i varje rad, använd sedan EXACT-funktionen:

=IF(EXACT(A2, B2), "Match", "")

Att hitta Skiftlägeskänsliga skillnader På samma rad anger du motsvarande text ("Unique" i detta exempel) i det tredje argumentet i IF-funktionen, t.ex:

=IF(EXACT(A2, B2), "Match", "Unique")

Jämför flera kolumner för matchningar i samma rad

I dina Excel-arbetsblad kan flera kolumner jämföras utifrån följande kriterier:

• Hitta rader med samma värden i alla kolumner (Exempel 1)
• Hitta rader med samma värden i 2 kolumner valfritt (Exempel 2)

Exempel 1. Hitta matchningar i alla celler i samma rad.

Om din tabell har tre eller fler kolumner och du vill hitta rader som har samma värden i alla celler fungerar en IF-formel med ett AND-uttalande utmärkt:

=IF(AND(A2=B2, A2=C2), "Fullständig matchning", "")

Om din tabell har många kolumner är en elegantare lösning att använda funktionen COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Fullständig matchning", "")

Där 5 är antalet kolumner som du jämför.

Exempel 2. Hitta matchningar i två valfria celler i samma rad.

Om du letar efter ett sätt att jämföra kolumner för två eller flera celler med samma värden i samma rad, använd en IF-formel med ett OR-uttalande:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

Om det finns många kolumner att jämföra kan OR-angivelsen bli för stor. En bättre lösning är då att lägga ihop flera COUNTIF-funktioner. Den första COUNTIF-funktionen räknar hur många kolumner som har samma värde som den första kolumnen, den andra COUNTIF-funktionen räknar hur många av de återstående kolumnerna som är lika med den andra kolumnen, och så vidare. Om antalet är 0 returnerar formeln "Unique","Match" annars. Till exempel:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unik", "Match")

Hur man jämför två kolumner i Excel för att hitta matchningar och skillnader

Anta att du har två listor med data i Excel och vill hitta alla värden (siffror, datum eller textsträngar) som finns i kolumn A men inte i kolumn B.

För detta kan du bädda in funktionen COUNTIF($B:$B, $A2)=0 i IF:s logiska test och kontrollera om den returnerar noll (ingen matchning har hittats) eller något annat nummer (minst en matchning har hittats).

Följande IF/COUNTIF-formel söker till exempel i hela kolumn B efter värdet i cell A2. Om ingen träff hittas returnerar formeln "Ingen träff i B", annars en tom sträng:

=IF(COUNTIF($B:$B, $A2)=0, "Ingen matchning i B", "")

Tips: Om din tabell har ett fast antal rader kan du ange ett visst intervall (t.ex. $B2:$B10) i stället för hela kolumnen ($B:$B) för att formeln ska fungera snabbare på stora datamängder.

Samma resultat kan uppnås genom att använda en IF-formel med de inbyggda funktionerna ISERROR och MATCH:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Ingen matchning i B","")

Eller genom att använda följande formel (kom ihåg att trycka på Ctrl + Shift + Enter för att skriva in den korrekt):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Ingen matchning i B", "")

Om du vill att en enda formel ska identifiera både matchningar (dubbletter) och skillnader (unika värden), kan du skriva en text för matchningar i de tomma dubbla citattecken ("") i någon av ovanstående formler, till exempel:

=IF(COUNTIF($B:$B, $A2)=0, "Ingen matchning i B", "Matchning i B")

Hur man jämför två listor i Excel och drar fram matchningar

Ibland behöver du inte bara matcha två kolumner i två olika tabeller, utan också hämta matchande poster från uppslagstabellen. Microsoft Excel har en särskild funktion för detta - VLOOKUP-funktionen. Som ett alternativ kan du använda en mer kraftfull och mångsidig INDEX MATCH-formel. Användarna av Excel 2021 och Excel 365 kan utföra uppgiften med XLOOKUP-funktionen.

Följande formler jämför t.ex. produktnamnen i kolumn D med namnen i kolumn A och hämtar en motsvarande försäljningssiffra från kolumn B om en matchning hittas, annars returneras felet #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Mer information finns i Hur man jämför två kolumner med hjälp av VLOOKUP.

Om du inte känner dig bekväm med formler kan du göra jobbet med en snabb och intuitiv lösning - guiden Merge Tables Wizard.

Jämföra två listor och markera likheter och skillnader

När du jämför kolumner i Excel kanske du vill "visualisera" de objekt som finns i den ena kolumnen men saknas i den andra. Du kan skugga sådana celler i valfri färg genom att använda Excel-funktionen Villkorlig formatering och följande exempel visar de detaljerade stegen.

Exempel 1. Markera likheter och skillnader i varje rad.

Om du vill jämföra två kolumner och Excel och markera de celler i kolumn A som har identiska poster i kolumn B på samma rad, gör följande:

• Markera de celler du vill markera (du kan markera celler i en kolumn eller i flera kolumner om du vill färglägga hela rader).
• Klicka på Villkorlig formatering> Ny regel.> Använd en formel för att bestämma vilka celler som ska formateras .
• Skapa en regel med en enkel formel som =$B2=$A2 (om vi antar att rad 2 är den första raden med data, exklusive kolumnhuvudet). Kontrollera att du använder en relativ radreferens (utan $-tecknet) som i formeln ovan.

Markera Skillnader mellan kolumn A och B, skapa en regel med denna formel:

=$B2$A2

Om du är nybörjare på villkorlig formatering i Excel kan du läsa hur du skapar en formelbaserad regel för villkorlig formatering för stegvisa instruktioner.

Exempel 2. Markera unika poster i varje lista

När du jämför två listor i Excel finns det tre typer av objekt som du kan markera:

• Poster som endast finns i den första listan (unika)
• Poster som endast finns i den andra listan (unika)
• Objekt som finns i båda listorna (dubbletter) - visas i nästa exempel.

Det här exemplet visar hur du färglägger objekt som bara finns i en lista.

Antag att lista 1 finns i kolumn A (A2:A6) och lista 2 i kolumn C (C2:C5). Du skapar reglerna för villkorlig formatering med följande formler:

Markera unika värden i lista 1 (kolumn A):

=COUNTIF($C$2:$C$5, $A2)=0

Markera unika värden i lista 2 (kolumn C):

=COUNTIF($A$2:$A$6, $C2)=0

Jag får följande resultat:

Exempel 3. Markera matchningar (dubbletter) mellan 2 kolumner.

Om du följde det föregående exemplet noggrant kommer du inte att ha några problem med att justera COUNTIF-formlerna så att de hittar överensstämmelser snarare än skillnader. Allt du behöver göra är att ställa in antalet större än noll:

Markera matchningar i lista 1 (kolumn A):

=COUNTIF($C$2:$C$5, $A2)>0

Markera matchningar i lista 2 (kolumn C):

=COUNTIF($A$2:$A$6, $C2)>0

Markera radskillnader och matchningar i flera kolumner

När du jämför värden i flera kolumner rad för rad är det snabbaste sättet att markera överensstämmelser att skapa en villkorlig formateringsregel, och det snabbaste sättet att skugga skillnader är att använda Gå till Special funktionen, vilket visas i följande exempel.

Exempel 1: Jämför flera kolumner och markera radöverensstämmelser

Om du vill markera rader som har identiska värden i alla kolumner skapa en regel för villkorlig formatering baserad på en av följande formler:

=AND($A2=$B2, $A2=$C2)

eller .

=COUNTIF($A2:$C2, $A2)=3

Där A2, B2 och C2 är de översta cellerna och 3 är antalet kolumner som ska jämföras.

Naturligtvis är varken AND- eller COUNTIF-formeln begränsad till att jämföra endast tre kolumner, du kan använda liknande formler för att markera rader med samma värden i fyra, fem, sex eller fler kolumner.

Exempel 2: Jämför flera kolumner och markera radskillnader

Om du snabbt vill markera celler med olika värden i varje enskild rad kan du använda Excels Gå till Special funktion.

1. Välj det område av celler som du vill jämföra. I det här exemplet har jag valt cellerna A2 till C8.

   Som standard är den översta cellen i det valda intervallet den aktiva cellen, och cellerna från de andra valda kolumnerna i samma rad kommer att jämföras med den cellen. Som du kan se i skärmdumpen ovan är den aktiva cellen vit medan alla andra celler i det valda intervallet är markerade. I det här exemplet är den aktiva cellen A2, så den Jämförelsekolumn. är kolumn A.

   Till ändra jämförelsekolumnen Använd antingen Tab-tangenten för att navigera genom markerade celler från vänster till höger eller Enter-tangenten för att gå från topp till botten.

   Tips. Om du vill välja kolumner som inte ligger intill varandra , markera den första kolumnen, håll ned Ctrl och markera sedan de andra kolumnerna. Den aktiva cellen kommer att ligga i den sista kolumnen (eller i det sista blocket av intilliggande kolumner). Om du vill ändra jämförelsekolumnen använder du Tab- eller Enter-tangenten på det sätt som beskrivs ovan.

2. På den Hem gå till fliken Redigering av grupp och klicka på Hitta & Välj > Gå till Special... Välj sedan Skillnader mellan raderna och klicka på OK knapp.
3. De celler vars värden skiljer sig från jämförelsecellen i varje rad är färgade. Om du vill skugga de markerade cellerna med en viss färg klickar du helt enkelt på Fyllningsfärg ikonen på bandet och välj den färg du vill ha.

Hur man jämför två celler i Excel

Att jämföra två celler är faktiskt ett särskilt fall av att jämföra två kolumner i Excel rad för rad, förutom att du inte behöver kopiera formlerna till andra celler i kolumnen.

Om du till exempel vill jämföra cellerna A1 och C1 kan du använda följande formler.

För matchningar:

=IF(A1=C1, "Match", "")

För skillnader:

=IF(A1C1, "Skillnad", "")

Du hittar några andra sätt att jämföra celler i Excel på:

• Hur man jämför två strängar i Excel
• Kontrollera om två celler matchar varandra eller om flera celler är lika.

Formelfritt sätt att jämföra två kolumner/listor i Excel

Nu när du känner till Excels möjligheter att jämföra och matcha kolumner, vill jag visa dig vår egen lösning för den här uppgiften. Verktyget heter Jämför två tabeller och ingår i vår Ultimate Suite.

Tilläggsprogrammet kan jämföra två tabeller eller listor med ett valfritt antal kolumner och både identifiera matchningar/skillnader (som vi gjorde med formler) och markera dem (som vi gjorde med villkorlig formatering).

I den här artikeln jämför vi följande två listor för att hitta gemensamma värden som finns i båda.

För att jämföra två listor följer du de här stegen:

1. Börja med att klicka på Jämför tabeller på knappen på Uppgifter om Ablebits fliken.
2. Välj den första kolumnen/förteckningen och klicka på Nästa När det gäller tillägget är detta din tabell 1.
3. Välj den andra kolumn/lista och klicka på Nästa När det gäller tillägget är det din tabell 2, och den kan finnas i samma eller ett annat arbetsblad eller till och med i en annan arbetsbok.
4. Välj vilken typ av uppgifter du vill söka efter:
   • Dubbla värden (matchningar) - de objekt som finns i båda listorna.
   • Unik värden (skillnader) - de poster som finns i lista 1 men inte i lista 2.

   Eftersom vårt mål är att hitta matchningar väljer vi det första alternativet och klickar på Nästa .

5. Detta är det viktigaste steget där du väljer den kolumner för jämförelse I vårt fall är valet uppenbart eftersom vi bara jämför två kolumner: Vinnare 2000 mot Vinnare 2021 I större tabeller kan du välja flera kolumnpar för att jämföra dem.
6. I det sista steget väljer du hur du vill hantera de funna objekten och klickar på Slutförande .

   Här finns några olika alternativ, men för våra syften är dessa två mest användbara:

   • Markera med färg - nyanser som matchar eller skiljer sig åt i den valda färgen (precis som Excel villkorlig formatering gör).
   • Identifiera i kolumnen Status - infogar den Status kolumnen med etiketterna "Duplicate" eller "Unique" (som IF-formler gör).

I det här exemplet har jag valt att markera dubbletter med följande färg:

På ett ögonblick fick jag följande resultat:

Med hjälp av Status kolumnen, skulle resultatet se ut på följande sätt:

Tips: Om listorna du jämför finns i olika kalkylblad eller arbetsböcker kan det vara bra att visa Excel-ark sida vid sida.

Det är så här du jämför kolumner i Excel för att hitta matchningar (dubbletter) och skillnader (unika värden). Om du är intresserad av att prova det här verktyget är du välkommen att ladda ner en utvärderingsversion via länken nedan.

Jag tackar dig för att du läste och uppmuntrar dig att kolla in andra hjälpsamma handledningar som vi har :)

Tillgängliga nedladdningar

Jämför Excel-listor - exempel (.xlsx-fil)

Ultimate Suite - testversion (.exe-fil)