Primerjanje stolpcev v Excelu je nekaj, kar občasno počnemo vsi. Microsoft Excel ponuja številne možnosti za primerjavo in ujemanje podatkov, vendar se večina od njih osredotoča na iskanje v enem stolpcu. V tem učbeniku bomo raziskali več tehnik za primerja dva stolpca v Excelu ter poiščite ujemanje in razlike med njimi.

Kako primerjati 2 stolpca v Excelu po vrsticah

Pri analizi podatkov v programu Excel je ena najpogostejših nalog primerjanje podatkov v posameznih vrsticah. To nalogo lahko opravite z uporabo funkcije IF, kot je prikazano v naslednjih primerih.

Primer 1. Primerjanje dveh stolpcev za ujemanje ali razlike v isti vrstici

Če želite v Excelu primerjati dva stolpca po vrsticah, napišite običajno formulo IF, ki primerja prvi dve celici. Vnesite formulo v drug stolpec v isti vrstici in jo nato kopirajte v druge celice tako, da povlečete ročaj za zapolnitev (majhen kvadratek v spodnjem desnem kotu izbrane celice). Pri tem se kazalec spremeni v znak plus:

Formula za tekme

Za iskanje celic v isti vrstici z enako vsebino, v tem primeru A2 in B2, je formula naslednja:

=IF(A2=B2,"Match","")

Formula za razlike

Če želite poiskati celice v isti vrstici z različnimi vrednostmi, preprosto zamenjajte znak za enakost z znakom za neenakost ():

=IF(A2B2, "Ni ujemanja","")

Ujemanja in razlike

Seveda vam nič ne preprečuje, da bi z eno samo formulo poiskali tako ujemanje kot razlike:

=IF(A2=B2, "Ujemanje", "Ni ujemanja")

Ali

=IF(A2B2, "Ni ujemanja", "Ujemanje")

Rezultat je lahko podoben temu:

Kot vidite, formula obravnava številke , datumi , krat in . besedilni nizi enako dobro.

Nasvet. Dva stolpca lahko primerjate tudi po vrsticah z uporabo naprednega filtra Excel-a. Tukaj je primer, ki prikazuje, kako filtrirati ujemanja in razlike med dvema stolpcema.

Primer 2. Primerjava dveh seznamov za ujemanje z velikimi in malimi črkami v isti vrstici

Kot ste verjetno opazili, formule iz prejšnjega primera pri primerjavi besedilnih vrednosti ne upoštevajo velikosti črk, kot v vrstici 10 na zgornji sliki zaslona. Če želite najti ujemanja, občutljiva na velikost črk med dvema stolpcema v vsaki vrstici, nato uporabite funkcijo EXACT:

=IF(EXACT(A2, B2), "Match", "")

Poiskati razlike, občutljive na velikost črk v isto vrstico vnesite ustrezno besedilo ("Unique" v tem primeru) v tretji argument funkcije IF, npr:

=IF(EXACT(A2, B2), "Match", "Unique")

Primerjanje več stolpcev za ujemanje v isti vrstici

V delovnih listih programa Excel lahko več stolpcev primerjate na podlagi naslednjih meril:

• Poiščite vrstice z enakimi vrednostmi v vsi stolpci (primer 1)
• Poiščite vrstice z enakimi vrednostmi v poljubna 2 stolpca (primer 2)

Primer 1. Iskanje ujemanj v vseh celicah v isti vrstici

Če ima vaša tabela tri ali več stolpcev in želite poiskati vrstice, ki imajo v vseh celicah enake vrednosti, bo formula IF z izjavo AND delovala odlično:

=IF(AND(A2=B2, A2=C2), "Popolno ujemanje", "")

Če ima vaša tabela veliko stolpcev, bi bila elegantnejša rešitev uporaba funkcije COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Popolno ujemanje", "")

Pri čemer je 5 število stolpcev, ki jih primerjate.

Primer 2. Poiščite ujemanje v poljubnih dveh celicah v isti vrstici

Če iščete način za primerjavo stolpcev za dve ali več celic z enakimi vrednostmi v isti vrstici, uporabite formulo IF z izjavo OR:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

Če je stolpcev, ki jih je treba primerjati, veliko, je lahko vaša izjava OR prevelika. V tem primeru je boljša rešitev dodajanje več funkcij COUNTIF. Prva funkcija COUNTIF šteje, koliko stolpcev ima enako vrednost kot prvi stolpec, druga funkcija COUNTIF šteje, koliko preostalih stolpcev je enakih drugemu stolpcu, in tako naprej. Če je število enako 0, formula vrne "Unique","Ujemanje" drugače. Na primer:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unique", "Match")

Kako primerjati dva stolpca v Excelu za ujemanje in razlike

Recimo, da imate v Excelu dva seznama podatkov in želite poiskati vse vrednosti (številke, datume ali besedilne nize), ki so v stolpcu A, ne pa tudi v stolpcu B.

V ta namen lahko funkcijo COUNTIF($B:$B, $A2)=0 vgradite v logični test IF in preverite, ali vrne nič (ni bilo najdeno nobeno ujemanje) ali katero koli drugo število (najdeno je bilo vsaj eno ujemanje).

Naslednja formula IF/COUNTIF na primer v celotnem stolpcu B išče vrednost v celici A2. Če ne najde ujemanja, formula vrne "Ni ujemanja v B", sicer pa prazen niz:

=IF(COUNTIF($B:$B, $A2)=0, "Ni ujemanja v B", "")

Nasvet: Če ima vaša tabela določeno število vrstic, lahko določite določeno območje (npr. $B2:$B10) in ne celotnega stolpca ($B:$B), da bo formula hitreje delovala pri velikih naborih podatkov.

Enak rezultat lahko dosežete s formulo IF z vgrajenima funkcijama ISERROR in MATCH:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Ni ujemanja v B","")

Lahko pa uporabite naslednjo formulo (za pravilen vnos ne pozabite pritisniti kombinacije tipk Ctrl + Shift + Enter):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Ni ujemanja v B", "")

Če želite v eni formuli prepoznati tako ujemanja (podvojitve) kot razlike (edinstvene vrednosti), vstavite besedilo za ujemanja v prazne dvojne narekovaje ("") v kateri koli od zgornjih formul. Na primer:

=IF(COUNTIF($B:$B, $A2)=0, "Ni ujemanja v B", "Ujemanje v B")

Kako primerjati dva seznama v Excelu in ugotoviti ujemanje

Včasih morda ne boste potrebovali le ujemanja dveh stolpcev v dveh različnih tabelah, temveč boste morali iz preglednice iskanja izvleči tudi ujemajoče se vnose. Microsoft Excel za to ponuja posebno funkcijo - funkcijo VLOOKUP. Kot alternativo lahko uporabite zmogljivejšo in vsestransko formulo INDEX MATCH. Uporabniki programov Excel 2021 in Excel 365 lahko to nalogo izvedejo s funkcijo XLOOKUP.

Naslednje formule na primer primerjajo imena izdelkov v stolpcih D z imeni v stolpcu A in, če najdejo ujemanje, iz stolpca B izpišejo ustrezno prodajno številko, sicer se vrne napaka #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Za več informacij glejte Kako primerjati dva stolpca z uporabo VLOOKUP.

Če vam formule ne ustrezajo, lahko delo opravite s hitro in intuitivno rešitvijo - čarovnikom za združevanje tabel.

Primerjajte dva seznama in poudarite ujemanja in razlike.

Pri primerjanju stolpcev v Excelu boste morda želeli "vizualizirati" elemente, ki so prisotni v enem stolpcu, manjkajo pa v drugem. Take celice lahko obarvate s poljubno barvo z uporabo funkcije pogojnega oblikovanja v Excelu, naslednji primeri pa prikazujejo podrobne korake.

Primer 1. Označite ujemanja in razlike v vsaki vrstici

Primerjava dveh stolpcev in programa Excel ter označitev celic v stolpcu A, ki imajo enaki vnosi v stolpcu B v isti vrstici naredite naslednje:

• Izberite celice, ki jih želite označiti (izberete lahko celice v enem stolpcu ali v več stolpcih, če želite obarvati cele vrstice).
• Kliknite . Pogojno oblikovanje> Novo pravilo.> S formulo določite, katere celice je treba oblikovati .
• Ustvarite pravilo s preprosto formulo, kot je =$B2=$A2 (ob predpostavki, da je vrstica 2 prva vrstica s podatki, brez glave stolpca). Dvakrat preverite, ali uporabljate relativni sklic na vrstico (brez znaka $), kot v zgornji formuli.

Poudarjanje razlike med stolpcema A in B, ustvarite pravilo s to formulo:

=$B2$A2

Če ste novinec na področju pogojnega oblikovanja v Excelu, glejte Kako ustvariti pravilo pogojnega oblikovanja, ki temelji na formuli, kjer so navodila po korakih.

Primer 2. Poudarite edinstvene vnose na vsakem seznamu

Kadar v Excelu primerjate dva seznama, lahko poudarite tri vrste elementov:

• Elementi, ki so samo na 1. seznamu (edinstveni)
• Elementi, ki so samo na 2. seznamu (edinstveni)
• Elementi, ki so na obeh seznamih (dvojniki) - prikazano v naslednjem primeru.

Ta primer prikazuje, kako obarvati elemente, ki so samo na enem seznamu.

Seznam 1 je v stolpcu A (A2:A6), seznam 2 pa v stolpcu C (C2:C5). Pravila pogojnega oblikovanja ustvarite z naslednjimi formulami:

Označite edinstvene vrednosti v seznamu 1 (stolpec A):

=COUNTIF($C$2:$C$5, $A2)=0

Označite edinstvene vrednosti na seznamu 2 (stolpec C):

=COUNTIF($A$2:$A$6, $C2)=0

In dobite naslednji rezultat:

Primer 3. Označite ujemanja (podvojitve) med dvema stolpcema

Če ste natančno sledili prejšnjemu primeru, vam ne bo težko prilagoditi formul COUNTIF, tako da bodo našle ujemanja in ne razlike. Vse, kar morate storiti, je, da nastavite število večje od nič:

Podčrtajte zadetke na seznamu 1 (stolpec A):

=COUNTIF($C$2:$C$5, $A2)>0

Podčrtajte zadetke na seznamu 2 (stolpec C):

=COUNTIF($A$2:$A$6, $C2)>0

Poudarite razlike v vrsticah in ujemanja v več stolpcih

Pri primerjanju vrednosti v več stolpcih po vrsticah je najhitrejši način za poudarjanje ujemanj ustvarjanje pravila pogojnega oblikovanja, najhitrejši način za senčenje razlik pa je uporaba Pojdi na poseben kot je prikazano v naslednjih primerih.

Primer 1. Primerjanje več stolpcev in poudarjanje ujemanj vrstic

Če želite poudariti vrstice, ki imajo enake vrednosti v vseh stolpcih , ustvarite pravilo pogojnega oblikovanja na podlagi ene od naslednjih formul:

=AND($A2=$B2, $A2=$C2)

ali

=COUNTIF($A2:$C2, $A2)=3

Pri čemer so A2, B2 in C2 najvišje celice, 3 pa je število stolpcev za primerjavo.

Seveda niti formula AND niti formula COUNTIF nista omejeni na primerjavo samo treh stolpcev, temveč lahko s podobnimi formulami označite vrstice z enakimi vrednostmi v 4, 5, 6 ali več stolpcih.

Primer 2. Primerjanje več stolpcev in poudarjanje razlik v vrsticah

Če želite hitro označiti celice z različnimi vrednostmi v vsaki posamezni vrstici, lahko uporabite Excelov Pojdi na poseben funkcija.

1. Izberite obseg celic, ki jih želite primerjati. V tem primeru sem izbral celice od A2 do C8.

   Privzeto je najvišja celica izbranega območja aktivna celica, celice iz drugih izbranih stolpcev v isti vrstici pa se primerjajo s to celico. Kot lahko vidite na zgornji sliki zaslona, je aktivna celica bela, vse druge celice izbranega območja pa so označene. V tem primeru je aktivna celica A2, zato se primerjalni stolpec je stolpec A.

   Na naslov spremenite primerjalni stolpec , uporabite tipko Tab za premikanje po izbranih celicah od leve proti desni ali tipko Enter za premikanje od zgoraj navzdol.

   Nasvet. Če želite izbrati nesorodni stolpci , izberite prvi stolpec, pritisnite in pridržite tipko Ctrl , nato pa izberite druge stolpce. Aktivna celica bo v zadnjem stolpcu (ali v zadnjem bloku sosednjih stolpcev). Če želite spremeniti primerjalni stolpec, uporabite tipko Tab ali Enter, kot je opisano zgoraj.

2. Na Domov zavihek, pojdite na zavihek Urejanje in kliknite Poišči & amp; Izberite > Pojdi na poseben... Nato izberite Razlike v vrsticah in kliknite na V REDU gumb.
3. Celice, katerih vrednosti se razlikujejo od primerjalne celice v vsaki vrstici, so obarvane. Če želite označene celice obarvati s kakšno barvo, preprosto kliknite Barva polnila na traku in izberite želeno barvo.

Kako primerjati dve celici v Excelu

Dejansko je primerjava dveh celic poseben primer primerjave dveh stolpcev v programu Excel po vrsticah, le da vam formul ni treba kopirati v druge celice v stolpcu.

Za primerjavo celic A1 in C1 lahko na primer uporabite naslednji formuli.

Za tekme:

=IF(A1=C1, "Match", "")

Za razlike:

=IF(A1C1, "Razlika", "")

Če želite izvedeti še nekaj drugih načinov za primerjavo celic v Excelu, glejte:

• Kako primerjati dva niza v Excelu
• Preverite, ali se dve celici ujemata ali je več celic enakih

Način brez formul za primerjavo dveh stolpcev / seznamov v Excelu

Zdaj, ko poznate Excelovo ponudbo za primerjanje in ujemanje stolpcev, vam bom predstavil našo lastno rešitev za to nalogo. To orodje se imenuje Primerjaj dve preglednici in je vključeno v naš komplet Ultimate Suite.

Dodatek lahko primerja dve preglednici ali seznama po poljubnem številu stolpcev in ugotavlja ujemanja/razlike (kot smo to storili s formulami) ter jih poudarja (kot smo to storili s pogojnim oblikovanjem).

V tem članku bomo primerjali naslednja dva seznama in poiskali skupne vrednosti, ki so prisotne na obeh.

Če želite primerjati dva seznama, sledite naslednjim korakom:

1. Začnite s klikom na Primerjava tabel gumb na Podatke o abilitah zavihek.
2. Izberite prvi stolpec/seznam in kliknite Naslednji . Kar zadeva dodatek, je to vaša tabela 1.
3. Izberite drugo stolpec/list in kliknite Naslednji . Kar zadeva dodatek, je to vaša tabela 2 in se lahko nahaja v istem ali drugem delovnem listu ali celo v drugem delovnem zvezku.
4. Izberite vrsto podatkov, ki jih želite poiskati:
   • Duplikatni vrednosti (ujemanja) - elementi, ki obstajajo na obeh seznamih.
   • Edinstvene vrednosti (razlike) - elementi, ki so na seznamu 1, niso pa na seznamu 2.

   Ker je naš cilj poiskati ujemanje, izberemo prvo možnost in kliknemo Naslednji .

5. To je ključni korak, v katerem izberete stolpci za primerjavo V našem primeru je izbira očitna, saj primerjamo le dva stolpca: Zmagovalci za leto 2000 proti Zmagovalci za leto 2021 V večjih tabelah lahko izberete več parov stolpcev za primerjavo.
6. V zadnjem koraku izberete, kako ravnati z najdenimi predmeti, in kliknete Zaključek .

   Na voljo je več različnih možnosti. Za naše namene sta najbolj uporabni ti dve:

   • Poudarite z barvo - odtenke ujemanj ali razlik v izbrani barvi (kot to počne pogojno oblikovanje v Excelu).
   • V stolpcu Status navedite - vstavi Status stolpec z oznakama "Podvojeno" ali "Edinstveno" (kot to počnejo formule IF).

V tem primeru sem se odločil, da podvojitve označim z naslednjo barvo:

In v trenutku sem dobil naslednji rezultat:

Z Status stolpec, bi bil rezultat videti takole:

Nasvet: Če sta seznama, ki ju primerjate, v različnih delovnih listih ali delovnih zvezkih, je morda koristno, da si liste programa Excel ogledate drug ob drugem.

Tako lahko v Excelu primerjate stolpce za ujemanje (podvojitve) in razlike (edinstvene vrednosti). Če želite preizkusiti to orodje, lahko prenesete preizkusno različico na spodnji povezavi.

Zahvaljujem se vam za branje in vas spodbujam, da si ogledate druge koristne vaje, ki jih imamo :)

Razpoložljivi prenosi

Primerjava seznamov Excel - primeri (.xlsx datoteka)

Ultimate Suite - preizkusna različica (.exe datoteka)