Сравняването на колони в Excel е нещо, което всички правим от време на време. Microsoft Excel предлага редица опции за сравняване и съпоставяне на данни, но повечето от тях се фокусират върху търсенето в една колона. В този урок ще разгледаме няколко техники за сравняване на две колони в Excel и да откриете съвпадения и разлики между тях.

Как да сравнявате 2 колони в Excel ред по ред

Когато извършвате анализ на данни в Excel, една от най-често срещаните задачи е да сравнявате данните във всеки отделен ред. Тази задача може да бъде изпълнена с помощта на функцията IF, както е показано в следните примери.

Пример 1. Сравняване на две колони за съвпадения или разлики в един и същи ред

За да сравните две колони в Excel ред по ред, напишете обикновена формула IF, която сравнява първите две клетки. Въведете формулата в някоя друга колона на същия ред и след това я копирайте в други клетки, като плъзнете дръжката за запълване (малък квадрат в долния десен ъгъл на избраната клетка). При това курсорът се променя на знак плюс:

Формула за съвпадения

За намиране на клетките в един и същи ред с еднакво съдържание, A2 и B2 в този пример, формулата е следната:

=IF(A2=B2,"Match","")

Формула за разликите

За да намерите клетки в един и същи ред с различни стойности, просто заменете знака за равенство със знака за неравенство ():

=IF(A2B2, "Няма съвпадение","")

Съвпадения и разлики

Разбира се, нищо не ви пречи да откриете както съвпадения, така и разлики с една формула:

=IF(A2=B2, "Съвпадение", "Няма съвпадение")

Или

=IF(A2B2, "Няма съвпадение", "Съвпадение")

Резултатът може да изглежда по следния начин:

Както виждате, формулата обработва номера , дати , пъти и текстови низове също толкова добре.

Съвет. Можете също така да сравнявате две колони ред по ред, като използвате разширения филтър на Excel. Ето един пример, показващ как да филтрирате съвпаденията и разликите между 2 колони.

Пример 2. Сравняване на два списъка за съвпадения, чувствителни към големи и малки букви, в един и същи ред

Както вероятно сте забелязали, формулите от предишния пример игнорират малкия и средния размер, когато сравняват текстови стойности, както е в ред 10 на снимката по-горе. Ако искате да намерите съвпадения с отчитане на големи и малки букви между 2 колони във всеки ред, след което използвайте функцията EXACT:

=IF(EXACT(A2, B2), "Match", "")

За да намерите разлики, чувствителни към големи и малки букви в същия ред въведете съответния текст ("Unique" в този пример) в третия аргумент на функцията IF, например:

=IF(EXACT(A2, B2), "Match", "Unique")

Сравняване на няколко колони за съвпадения в един и същи ред

В работните листове на Excel могат да се сравняват няколко колони въз основа на следните критерии:

• Намиране на редове със същите стойности в всички колони (Пример 1)
• Намиране на редове със същите стойности в всякакви 2 колони (Пример 2)

Пример 1. Намиране на съвпадения във всички клетки в рамките на един и същи ред

Ако таблицата ви има три или повече колони и искате да откриете редове, в които има еднакви стойности във всички клетки, формулата IF с оператор AND ще ви свърши работа:

=IF(AND(A2=B2, A2=C2), "Пълно съвпадение", "")

Ако таблицата ви има много колони, по-елегантно решение би било да използвате функцията COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Пълно съвпадение", "")

Където 5 е броят на колоните, които сравнявате.

Пример 2. Намиране на съвпадения във всякакви две клетки в един и същи ред

Ако търсите начин да сравните колони за две или повече клетки с едни и същи стойности в един и същи ред, използвайте формула IF с оператор OR:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

В случай че има много колони за сравняване, вашият оператор OR може да нарасне твърде много. В този случай по-добро решение би било добавянето на няколко функции COUNTIF. Първата функция COUNTIF преброява колко колони имат същата стойност като в първата колона, втората COUNTIF преброява колко от останалите колони са равни на втората колона и т.н. Ако броят е 0, формулата връща "Unique","Match" в противен случай. Например:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unique", "Match")

Как да сравнявате две колони в Excel за съвпадения и разлики

Да предположим, че имате 2 списъка с данни в Excel и искате да намерите всички стойности (числа, дати или текстови низове), които се намират в колона А, но не и в колона Б.

За тази цел можете да вградите функцията COUNTIF($B:$B, $A2)=0 в логическия тест на IF и да проверите дали тя връща нула (не е намерено съвпадение) или друго число (намерено е поне 1 съвпадение).

Например следната формула IF/COUNTIF търси в цялата колона B стойността в клетка A2. Ако не бъде намерено съвпадение, формулата връща "Няма съвпадение в B", а в противен случай - празен низ:

=IF(COUNTIF($B:$B, $A2)=0, "Няма съвпадение в B", "")

Съвет: Ако таблицата ви има фиксиран брой редове, можете да посочите определен диапазон (например $B2:$B10), а не цялата колона ($B:$B), за да работи формулата по-бързо при големи набори от данни.

Същият резултат може да се постигне чрез използване на формула IF с вградените функции ISERROR и MATCH:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Няма съвпадение в B","")

Или като използвате следната формула за масиви (не забравяйте да натиснете Ctrl + Shift + Enter, за да я въведете правилно):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Няма съвпадение в B", "")

Ако искате една формула да идентифицира както съвпадения (дубликати), така и разлики (уникални стойности), поставете текст за съвпадения в празните двойни кавички ("") в някоя от горните формули:

=IF(COUNTIF($B:$B, $A2)=0, "Няма съвпадение в B", "Съвпадение в B")

Как да сравнявате два списъка в Excel и да извличате съвпадения

Понякога може да ви се наложи не само да съпоставите две колони в две различни таблици, но и да изтеглите съвпадащи записи от таблицата за търсене. Microsoft Excel предоставя специална функция за това - функцията VLOOKUP. Като алтернатива можете да използвате по-мощната и универсална формула INDEX MATCH. Потребителите на Excel 2021 и Excel 365, могат да изпълнят задачата с функцията XLOOKUP.

Например следните формули сравняват имената на продуктите в колони D с имената в колона А и извличат съответната стойност на продажбите от колона Б, ако е намерено съвпадение, а в противен случай се връща грешка #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

За повече информация вижте Как да сравним две колони с помощта на VLOOKUP.

Ако не се чувствате много комфортно с формулите, можете да свършите работата с помощта на бързо и интуитивно решение - съветника за сливане на таблици.

Сравнете два списъка и подчертайте съвпаденията и разликите

Когато сравнявате колони в Excel, може да искате да "визуализирате" елементите, които присъстват в едната колона, но липсват в другата. Можете да засенчите такива клетки в избран от вас цвят, като използвате функцията за условно форматиране на Excel, а следващите примери демонстрират подробните стъпки.

Пример 1. Подчертайте съвпаденията и разликите във всеки ред

Сравняване на две колони и Excel и маркиране на клетките в колона А, които имат идентични вписвания в колона В на същия ред, направете следното:

• Изберете клетките, които искате да маркирате (можете да изберете клетки в една колона или в няколко колони, ако искате да оцветите цели редове).
• Кликнете върху Условно форматиране> Ново правило.> Използвайте формула, за да определите кои клетки да форматирате .
• Създайте правило с проста формула, например =$B2=$A2 (ако приемем, че ред 2 е първият ред с данни, без да включваме заглавието на колоната). Моля, проверете два пъти дали използвате относителна препратка към реда (без знака $), както във формулата по-горе.

За да подчертаете разлики между колони A и B, създайте правило с тази формула:

=$B2$A2

Ако сте начинаещи в областта на условното форматиране в Excel, вижте Как да създадем правило за условно форматиране, базирано на формула, за инструкции стъпка по стъпка.

Пример 2. Подчертаване на уникалните записи във всеки списък

Когато сравнявате два списъка в Excel, можете да маркирате 3 типа елементи:

• Елементи, които се намират само в първия списък (уникални)
• Елементи, които се намират само във втория списък (уникални)
• Елементи, които се намират и в двата списъка (дубликати) - демонстрирано в следващия пример.

Този пример демонстрира как да оцветите елементите, които се намират само в един списък.

Предполагаме, че списък 1 е в колона A (A2:A6), а списък 2 - в колона C (C2:C5). Създавате правилата за условно форматиране със следните формули:

Подчертайте уникалните стойности в Списък 1 (колона А):

=COUNTIF($C$2:$C$5, $A2)=0

Подчертайте уникалните стойности в списък 2 (колона В):

=COUNTIF($A$2:$A$6, $C2)=0

И получавате следния резултат:

Пример 3. Подчертаване на съвпадения (дубликати) между 2 колони

Ако сте следвали внимателно предишния пример, няма да ви е трудно да настроите формулите COUNTIF така, че да намират съвпадения, а не разлики. Всичко, което трябва да направите, е да зададете брояч, по-голям от нула:

Подчертайте съвпаденията в Списък 1 (колона А):

=COUNTIF($C$2:$C$5, $A2)>0

Подчертайте съвпаденията в Списък 2 (колона В):

=COUNTIF($A$2:$A$6, $C2)>0

Подчертаване на разликите в редовете и съвпаденията в няколко колони

Когато сравнявате стойности в няколко колони ред по ред, най-бързият начин да подчертаете съвпаденията е като създадете правило за условно форматиране, а най-бързият начин да засенчите разликите е като използвате Отидете на специален както е показано в следните примери.

Пример 1. Сравняване на няколко колони и подчертаване на съвпаденията на редовете

За да маркирате редове, които имат еднакви стойности във всички колони , създайте правило за условно форматиране въз основа на една от следните формули:

=AND($A2=$B2, $A2=$C2)

или

=COUNTIF($A2:$C2, $A2)=3

Където A2, B2 и C2 са най-горните клетки, а 3 е броят на колоните за сравнение.

Разбира се, нито формулата AND, нито COUNTIF са ограничени до сравняване само на 3 колони, можете да използвате подобни формули, за да подчертаете редове с еднакви стойности в 4, 5, 6 или повече колони.

Пример 2. Сравняване на няколко колони и подчертаване на разликите в редовете

За да подчертаете бързо клетките с различни стойности във всеки отделен ред, можете да използвате функцията на Excel Отидете на специален функция.

1. Изберете диапазона от клетки, които искате да сравните. В този пример съм избрал клетките от A2 до C8.

   По подразбиране най-горната клетка на избрания диапазон е активната клетка и клетките от другите избрани колони в същия ред ще бъдат сравнени с тази клетка. Както можете да видите на снимката по-горе, активната клетка е бяла, докато всички останали клетки от избрания диапазон са подчертани. В този пример активната клетка е A2, така че колона за сравнение е колона А.

   За промяна на колоната за сравнение , използвайте клавиша Tab, за да преминете през избраните клетки отляво надясно, или клавиша Enter, за да преминете отгоре надолу.

   Съвет. За да изберете несъседни колони , изберете първата колона, натиснете и задръжте Ctrl , а след това изберете останалите колони. Активната клетка ще бъде в последната колона (или в последния блок от съседни колони). За да промените колоната за сравнение, използвайте клавиша Tab или Enter, както е описано по-горе.

2. На Начало отидете в раздела Редактиране на и щракнете върху Намиране & Избор > Отидете на специалния... След това изберете Разлики в редовете и щракнете върху OK бутон.
3. Клетките, чиито стойности се различават от тези на сравнителната клетка във всеки ред, са оцветени. Ако искате да оцветите маркираните клетки в някакъв цвят, просто щракнете върху Цвят на запълване икона в лентата и изберете желания от вас цвят.

Как да сравнявате две клетки в Excel

Всъщност сравняването на 2 клетки е частен случай на сравняването на две колони в Excel ред по ред, с тази разлика, че не е необходимо да копирате формулите надолу към други клетки в колоната.

Например за сравняване на клетките A1 и C1 можете да използвате следните формули.

За мачове:

=IF(A1=C1, "Match", "")

За разликите:

=IF(A1C1, "Difference", "")

За да научите няколко други начина за сравняване на клетки в Excel, вижте:

• Как да сравнявате два низа в Excel
• Проверка дали две клетки съвпадат или няколко клетки са равни

Начин за сравняване на две колони/списъци в Excel без формули

Сега, след като вече познавате предложенията на Excel за сравняване и съпоставяне на колони, нека ви покажа нашето собствено решение за тази задача. Този инструмент се нарича Сравни две таблици и е включен в нашия Ultimate Suite.

Добавката може да сравнява две таблици или списъци по произволен брой колони и да идентифицира съвпадения/различия (както направихме с формулите) и да ги подчертава (както направихме с условното форматиране).

За целите на тази статия ще сравним следните два списъка, за да намерим общите стойности, които присъстват и в двата.

За да сравните два списъка, ето какви стъпки трябва да следвате:

1. Започнете с щракване върху Сравняване на таблици на бутона Данни от Ablebits таб.
2. Изберете първа колона/списък и щракнете върху Следваща . По отношение на добавката това е вашата таблица 1.
3. Изберете втория колона/списък и щракнете върху Следваща . По отношение на добавката това е вашата Таблица 2 и тя може да се намира в същия или друг работен лист или дори в друга работна книга.
4. Изберете какъв вид данни да търсите:
   • Дублиране на стойности (съвпадения) - елементите, които съществуват и в двата списъка.
   • Уникален стойности (разлики) - елементите, които присъстват в списък 1, но не присъстват в списък 2.

   Тъй като целта ни е да намерим съвпадения, избираме първата опция и щракваме върху Следваща .

5. Това е ключовата стъпка, в която избирате колони за сравнение В нашия случай изборът е очевиден, тъй като сравняваме само 2 колони: Победители за 2000 г. срещу Победители за 2021 г. . В по-големи таблици можете да изберете няколко двойки колони, които да сравнявате по тях.
6. В последната стъпка избирате как да се справите с намерените елементи и щраквате върху Завършете .

   Тук са налични няколко различни опции. За нашите цели тези две са най-полезни:

   • Подчертаване с цвят - нюанси на съвпадения или разлики в избрания цвят (както прави условното форматиране в Excel).
   • Идентифицирайте в колоната Статус - вмъква Статус колона с етикети "Duplicate" или "Unique" (както правят формулите IF).

За този пример реших да подчертая дубликатите със следния цвят:

И след малко получих следния резултат:

С Статус резултатът ще изглежда по следния начин:

Съвет. Ако списъците, които сравнявате, са в различни работни листове или работни книги, може да е полезно да видите листовете на Excel един до друг.

По този начин сравнявате колони в Excel за съвпадения (дубликати) и разлики (уникални стойности). Ако искате да изпробвате този инструмент, можете да изтеглите версия за оценка, като използвате връзката по-долу.

Благодаря ви, че прочетохте, и ви насърчавам да разгледате и други полезни уроци, които имаме :)

Налични изтегляния

Сравняване на списъци в Excel - примери (.xlsx файл)

Ultimate Suite - пробна версия (.exe файл)