Kolommen vergelijken in Excel is iets wat we allemaal wel eens doen. Microsoft Excel biedt een aantal opties om gegevens te vergelijken en te matchen, maar de meeste zijn gericht op het zoeken in één kolom. In deze zelfstudie zullen we verschillende technieken verkennen om twee kolommen vergelijken in Excel en zoek overeenkomsten en verschillen daartussen.

Hoe 2 kolommen in Excel rij per rij vergelijken

Wanneer u gegevens analyseert in Excel, is een van de meest voorkomende taken het vergelijken van gegevens in elke afzonderlijke rij. Deze taak kan worden uitgevoerd met behulp van de IF-functie, zoals gedemonstreerd in de volgende voorbeelden.

Voorbeeld 1. Vergelijk twee kolommen op overeenkomsten of verschillen in dezelfde rij

Om twee kolommen in Excel rij per rij te vergelijken, schrijft u een gebruikelijke IF-formule die de eerste twee cellen. Voer de formule in een andere kolom in dezelfde rij in, en kopieer deze vervolgens naar andere cellen door de vulgreep (een klein vierkantje in de rechterbenedenhoek van de geselecteerde cel) te verslepen. Terwijl u dit doet, verandert de cursor in het plusteken:

Formule voor wedstrijden

Om cellen te vinden binnen dezelfde rij met dezelfde inhoud, A2 en B2 in dit voorbeeld, is de formule als volgt:

=IF(A2=B2,"Match","")

Formule voor verschillen

Om cellen in dezelfde rij met verschillende waarden te vinden, vervangt u gewoon het gelijkteken door het niet-gelijkteken ():

=IF(A2B2,"No match","")

Overeenkomsten en verschillen

En natuurlijk belet niets u om met één enkele formule zowel overeenkomsten als verschillen te vinden:

=IF(A2=B2,"Match","No match")

Of

=IF(A2B2,"Geen match","Match")

Het resultaat kan er ongeveer zo uitzien:

Zoals u ziet, behandelt de formule nummers , data , keer en tekststrings net zo goed.

Tip. U kunt ook twee kolommen rij per rij vergelijken met behulp van Excel Advanced Filter. Hier is een voorbeeld dat laat zien hoe u overeenkomsten en verschillen tussen 2 kolommen kunt filteren.

Voorbeeld 2. Vergelijk twee lijsten voor hoofdlettergevoelige overeenkomsten in dezelfde rij

Zoals u waarschijnlijk heeft gemerkt, negeren de formules uit het vorige voorbeeld hoofdletters en kleine letters bij het vergelijken van tekstwaarden, zoals in rij 10 in de bovenstaande schermafbeelding. Als u wilt zoeken naar hoofdlettergevoelige overeenkomsten tussen 2 kolommen in elke rij, gebruik dan de functie EXACT:

=IF(EXACT(A2, B2), "Match", "")

Te vinden hoofdlettergevoelige verschillen in dezelfde rij de overeenkomstige tekst ("Uniek" in dit voorbeeld) in het 3e argument van de IF-functie, bijv:

=IF(EXACT(A2, B2), "Match", "Unique")

Vergelijk meerdere kolommen voor overeenkomsten in dezelfde rij

In uw Excel-werkbladen kunnen meerdere kolommen worden vergeleken op basis van de volgende criteria:

• Zoek rijen met dezelfde waarden in alle kolommen (Voorbeeld 1)
• Zoek rijen met dezelfde waarden in 2 willekeurige kolommen (Voorbeeld 2)

Voorbeeld 1. Zoek overeenkomsten in alle cellen binnen dezelfde rij

Als uw tabel drie of meer kolommen heeft en u wilt rijen vinden die in alle cellen dezelfde waarden hebben, dan werkt een IF-formule met een AND-instructie uitstekend:

=IF(AND(A2=B2, A2=C2), "Full match", "")

Als uw tabel veel kolommen heeft, is het gebruik van de functie COUNTIF een elegantere oplossing:

=IF(COUNTIF($A2:$E2, $A2)=5, "Full match", "")

Waarbij 5 het aantal kolommen is dat u vergelijkt.

Voorbeeld 2. Zoek overeenkomsten in twee willekeurige cellen in dezelfde rij

Als u een manier zoekt om kolommen te vergelijken voor twee of meer cellen met dezelfde waarden binnen dezelfde rij, gebruikt u een IF-formule met een OR-instructie:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

Als er veel kolommen te vergelijken zijn, kan uw OR-instructie te groot worden. In dat geval zou een betere oplossing zijn om verschillende COUNTIF-functies op te tellen. De eerste COUNTIF telt hoeveel kolommen dezelfde waarde hebben als in de 1e kolom, de tweede COUNTIF telt hoeveel van de resterende kolommen gelijk zijn aan de 2e kolom, enzovoort. Als de telling 0 is, geeft de formule "Uniek" terug,"Match" anders. Bijvoorbeeld:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0,"Unique","Match")

Hoe twee kolommen in Excel te vergelijken op overeenkomsten en verschillen

Stel, u hebt 2 lijsten met gegevens in Excel, en u wilt alle waarden (getallen, datums of tekststrings) vinden die in kolom A staan, maar niet in kolom B.

Hiervoor kunt u de functie COUNTIF($B:$B, $A2)=0 opnemen in de logische test van IF en controleren of deze nul teruggeeft (er is geen overeenkomst gevonden) of een ander getal (er is ten minste 1 overeenkomst gevonden).

Bijvoorbeeld, de volgende IF/COUNTIF-formule zoekt in de hele kolom B naar de waarde in cel A2. Als er geen overeenkomst wordt gevonden, geeft de formule "Geen overeenkomst in B", anders een lege tekenreeks:

=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "")

Tip. Als uw tabel een vast aantal rijen heeft, kunt u een bepaald bereik opgeven (bijv. $B2:$B10) in plaats van de hele kolom ($B:$B), zodat de formule sneller werkt op grote gegevenssets.

Hetzelfde resultaat kan worden bereikt met een IF-formule met de ingebouwde functies ISERROR en MATCH:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)),"No match in B","")

Of door de volgende matrixformule te gebruiken (vergeet niet op Ctrl + Shift + Enter te drukken om het correct in te voeren):

=IF(SUM(--($B$2:$B$10=$A2))=0, " No match in B", "")

Als u wilt dat een enkele formule zowel matches (duplicaten) als verschillen (unieke waarden) identificeert, zet dan wat tekst voor matches tussen de lege dubbele aanhalingstekens ("") in een van de bovenstaande formules. Bijvoorbeeld:

=IF(COUNTIF($B:$B, $A2)=0, "Geen overeenkomst in B", "Overeenkomst in B")

Hoe twee lijsten in Excel vergelijken en overeenkomsten trekken

Soms moet u niet alleen twee kolommen in twee verschillende tabellen met elkaar vergelijken, maar ook overeenkomende gegevens uit de opzoektabel halen. Microsoft Excel biedt hiervoor een speciale functie - de VLOOKUP-functie. Als alternatief kunt u een krachtigere en veelzijdigere INDEX MATCH-formule gebruiken. De gebruikers van Excel 2021 en Excel 365 kunnen deze taak uitvoeren met de XLOOKUP-functie.

De volgende formules vergelijken bijvoorbeeld de productnamen in kolom D met de namen in kolom A en halen een overeenkomstig verkoopcijfer uit kolom B als er een overeenkomst wordt gevonden, anders wordt de foutmelding #N/A teruggestuurd.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Voor meer informatie, zie Hoe twee kolommen te vergelijken met behulp van VLOOKUP.

Als u niet zo vertrouwd bent met formules, kunt u de klus klaren met een snelle en intuïtieve oplossing - Wizard Tabellen samenvoegen.

Twee lijsten vergelijken en overeenkomsten en verschillen markeren

Wanneer u kolommen in Excel vergelijkt, wilt u wellicht de items "visualiseren" die in de ene kolom aanwezig zijn maar in de andere ontbreken. U kunt dergelijke cellen in elke gewenste kleur arceren met behulp van de Excel-functie voor voorwaardelijke opmaak en de volgende voorbeelden demonstreren de gedetailleerde stappen.

Voorbeeld 1. Markeer overeenkomsten en verschillen in elke rij

Om twee kolommen te vergelijken en Excel en cellen in kolom A te markeren die identieke vermeldingen in kolom B in dezelfde rij, doe dan het volgende:

• Selecteer de cellen die u wilt markeren (u kunt cellen in één kolom selecteren of in meerdere kolommen als u hele rijen wilt inkleuren).
• Klik op Voorwaardelijke opmaak> Nieuwe regel.> Gebruik een formule om te bepalen welke cellen moeten worden opgemaakt .
• Maak een regel met een eenvoudige formule als =$B2=$A2 (ervan uitgaande dat rij 2 de eerste rij met gegevens is, zonder de kolomkop). Controleer goed of u een relatieve rijverwijzing gebruikt (zonder het $-teken) zoals in de bovenstaande formule.

Om te benadrukken verschillen tussen kolom A en B, maak een regel met deze formule:

=$B2$A2

Als u niet bekend bent met voorwaardelijke opmaak in Excel, raadpleeg dan Hoe maak ik een regel voor voorwaardelijke opmaak op basis van een formule voor stapsgewijze instructies.

Voorbeeld 2. Markeer unieke vermeldingen in elke lijst

Wanneer u twee lijsten in Excel vergelijkt, zijn er 3 soorten items die u kunt markeren:

• Items die alleen in de 1e lijst staan (uniek)
• Items die alleen in de 2e lijst staan (uniek)
• Items die in beide lijsten staan (duplicaten) - gedemonstreerd in het volgende voorbeeld.

Dit voorbeeld demonstreert hoe je de items die slechts in één lijst staan kunt inkleuren.

Stel dat uw Lijst 1 in kolom A staat (A2:A6) en Lijst 2 in kolom C (C2:C5). U maakt de voorwaardelijke opmaakregels met de volgende formules:

Markeer unieke waarden in lijst 1 (kolom A):

=COUNTIF($C$2:$C$5, $A2)=0

Markeer unieke waarden in lijst 2 (kolom C):

=COUNTIF($A$2:$A$6, $C2)=0

En krijg het volgende resultaat:

Voorbeeld 3. Markeer overeenkomsten (duplicaten) tussen 2 kolommen

Als u het vorige voorbeeld nauwkeurig hebt gevolgd, zult u geen moeite hebben om de COUNTIF-formules zo aan te passen dat ze de overeenkomsten vinden in plaats van de verschillen. U hoeft alleen de telling groter dan nul te maken:

Markeer de overeenkomsten in lijst 1 (kolom A):

=COUNTIF($C$2:$C$5, $A2)>0

Markeer de overeenkomsten in lijst 2 (kolom C):

=COUNTIF($A$2:$A$6, $C2)>0

Markeer rijverschillen en overeenkomsten in meerdere kolommen

Wanneer u waarden in verschillende kolommen rij per rij vergelijkt, is de snelste manier om overeenkomsten te markeren het maken van een voorwaardelijke opmaakregel, en de snelste manier om verschillen te arceren het omarmen van de Ga naar Speciale functie, zoals blijkt uit de volgende voorbeelden.

Voorbeeld 1. Meerdere kolommen vergelijken en rij-overeenkomsten markeren

Om rijen te markeren die identieke waarden in alle kolommen Maak een regel voor voorwaardelijke opmaak op basis van een van de volgende formules:

=AND($A2=$B2, $A2=$C2)

of

=COUNTIF($A2:$C2, $A2)=3

Waarbij A2, B2 en C2 de bovenste cellen zijn en 3 het aantal te vergelijken kolommen.

Natuurlijk is de formule AND noch COUNTIF beperkt tot het vergelijken van slechts 3 kolommen, u kunt soortgelijke formules gebruiken om rijen met dezelfde waarden in 4, 5, 6 of meer kolommen te markeren.

Voorbeeld 2. Meerdere kolommen vergelijken en rijverschillen markeren

Om cellen met verschillende waarden in elke afzonderlijke rij snel te markeren, kunt u Excel's Ga naar Speciale functie.

1. Selecteer het cellenbereik dat u wilt vergelijken. In dit voorbeeld heb ik de cellen A2 tot en met C8 geselecteerd.

   Standaard is de bovenste cel van het geselecteerde bereik de actieve cel, en de cellen van de andere geselecteerde kolommen in dezelfde rij zullen met die cel worden vergeleken. Zoals u in de bovenstaande schermafbeelding kunt zien, is de actieve cel wit, terwijl alle andere cellen van het geselecteerde bereik zijn gemarkeerd. In dit voorbeeld is de actieve cel A2, dus het vergelijkingskolom is kolom A.

   Naar de vergelijkingskolom wijzigen Gebruik de Tab-toets om van links naar rechts door de geselecteerde cellen te navigeren, of de Enter-toets om van boven naar beneden te gaan.

   Tip. Om te selecteren niet-aangrenzende kolommen Selecteer de eerste kolom, houd Ctrl ingedrukt en selecteer vervolgens de andere kolommen. De actieve cel komt in de laatste kolom te staan (of in het laatste blok van aangrenzende kolommen). Om de vergelijkingskolom te wijzigen, gebruikt u de Tab- of Enter-toets zoals hierboven beschreven.

2. Op de Home tabblad, ga naar Bewerken van groep, en klik op Vinden & selecteren > Ga naar Speciale... Selecteer vervolgens Rij verschillen en klik op de OK knop.
3. De cellen waarvan de waarden verschillen van de vergelijkingscel in elke rij zijn gekleurd. Als u de gemarkeerde cellen in een bepaalde kleur wilt weergeven, klikt u op de knop Vulkleur pictogram op het lint en selecteer de kleur van uw keuze.

Hoe twee cellen vergelijken in Excel

In feite is het vergelijken van 2 cellen een bijzonder geval van het vergelijken van twee kolommen in Excel rij per rij, behalve dat u de formules niet hoeft te kopiëren naar andere cellen in de kolom.

Om bijvoorbeeld de cellen A1 en C1 te vergelijken, kunt u de volgende formules gebruiken.

Voor wedstrijden:

=IF(A1=C1, "Match", "")

Voor verschillen:

=IF(A1C1, "Verschil", "")

Voor enkele andere manieren om cellen in Excel te vergelijken, zie:

• Hoe twee tekenreeksen vergelijken in Excel
• Controleer of twee cellen overeenkomen of meerdere cellen gelijk zijn

Formulevrije manier om twee kolommen/lijsten te vergelijken in Excel

Nu u het aanbod van Excel voor het vergelijken en matchen van kolommen kent, laat ik u onze eigen oplossing voor deze taak zien. Deze tool heet Vergelijk twee tabellen en is opgenomen in onze Ultimate Suite.

De invoegtoepassing kan twee tabellen of lijsten vergelijken op een willekeurig aantal kolommen en zowel overeenkomsten/verschillen vaststellen (zoals we deden met formules) als deze markeren (zoals we deden met voorwaardelijke opmaak).

In dit artikel vergelijken we de volgende 2 lijsten om gemeenschappelijke waarden te vinden die in beide lijsten voorkomen.

Om twee lijsten te vergelijken, zijn hier de stappen die u moet volgen:

1. Begin met het klikken op de Tabellen vergelijken knop op de Ablebits gegevens tab.
2. Selecteer de eerste kolom/lijst en klik op Volgende In termen van de add-in, is dit uw tabel 1.
3. Selecteer de tweede kolom/lijst en klik op Volgende In termen van de invoegtoepassing is het uw Tabel 2, en die kan zich in hetzelfde of een ander werkblad bevinden, of zelfs in een andere werkmap.
4. Kies wat voor soort gegevens u zoekt:
   • Dubbele waarden (overeenkomsten) - de items die in beide lijsten voorkomen.
   • Uniek waarden (verschillen) - de items die in lijst 1 voorkomen, maar niet in lijst 2.

   Aangezien ons doel is om overeenkomsten te vinden, selecteren wij de eerste optie en klikken op Volgende .

5. Dit is de belangrijkste stap waarbij u de kolommen voor vergelijking In ons geval ligt de keuze voor de hand omdat we slechts 2 kolommen vergelijken: 2000 winnaars tegen 2021 Winnaars In grotere tabellen kunt u meerdere kolommenparen selecteren om te vergelijken.
6. In de laatste stap kiest u hoe u met de gevonden items omgaat en klikt u op Afwerking .

   Hier zijn een paar verschillende opties beschikbaar. Voor onze doeleinden zijn deze twee het meest bruikbaar:

   • Markeer met kleur - tinten overeenkomsten of verschillen in de geselecteerde kleur (zoals Excel voorwaardelijke opmaak doet).
   • Identificeer in de kolom Status - voegt de Status kolom met de labels "Duplicaat" of "Uniek" (zoals IF-formules doen).

Voor dit voorbeeld heb ik besloten duplicaten te markeren in de volgende kleur:

En in een ogenblik, kreeg het volgende resultaat:

Met de Status kolom, zou het resultaat er als volgt uitzien:

Tip. Als de lijsten die u vergelijkt in verschillende werkbladen of werkmappen staan, kan het nuttig zijn om Excel-bladen naast elkaar te bekijken.

Zo vergelijkt u kolommen in Excel op overeenkomsten (duplicaten) en verschillen (unieke waarden). Als u deze tool wilt proberen, kunt u een evaluatieversie downloaden via onderstaande link.

Ik dank u voor het lezen en moedig u aan om andere nuttige tutorials te bekijken :)

Beschikbare downloads

Excel-lijsten vergelijken - voorbeelden (.xlsx-bestand)

Ultimate Suite - proefversie (.exe bestand)